2020/06/29

年月をスクロールバーで選択する予定表ひな型

• １．背景
• ２．概要
• ３．プログラム
• 　３－１．ワークシートとフォーム間の値の受け渡し方法
• 　　３－１－１．値の受け渡し方法１（Sub プロシージャを使用）
• 　　３－１－２．値の受け渡し方法２（Function プロシージャを使用）
• ４．フォームへのコントロールの配置
• ５．フォームコード
• 　５－１．変数の宣言
• 　５－２．フォームの起動
• 　５－３．フォームの初期化（Initialize）
• 　５－４．フォーム表示時の初期化（Activate）
• 　５－５．ダイアログの年月表示を書き換える
• 　５－６．スクロールバー操作時の動作
• 　　５－６ー１．スクロール矢印・レール部をクリック操作した場合
• 　　５－６ー２．スクロールボックスを移動させる操作をした場合
• 　５－７．「今月」ボタンをクリックした時の動作
• 　５－８．「OK」「Cancel」のボタンをクリックした時の動作
• ６．標準モジュールのコード
• 　６－１．定数の宣言
• 　６－２．「年月変更」ボタンによる起動
• 　６－３．カレンダーの作成
• 　６－４．カレンダーの「前月」・「次月」移動
• 　６－５．カレンダーの外観作成（現在のところ、手動で起動）
• ７．最後に

１．背景

システム内で「年月日」を入力するには、デジタル値を入力したり、カレンダーを表示させ日付を選択したりします。この手法は様々なサイトで紹介されています。
しかし、例えばカレンダーを表示する時の「年月までの入力」などについての効率化・直感化の手法については、あまり見掛ける事はありません。
「年月ならカレンダーの中で移動できるから」とか「月は１～１２と選択範囲が狭いから」という理由から少ないのかもしれませんが、「省力化」「入力ミスを防ぐ」という面から少し工夫をしてみました。
この年月選択をカレンダー表示切り替えに使ったものを今回紹介します。

なお予定の入出力の部分は、次項「CSVファイルでデータを読み書きする月間予定表」で紹介していますので、併せて参照下さい。

２．概要

見掛けは「カレンダー」と同じです。日付行の下に予定等が記入できる枠（日付とはセルを分けています）があります。

図２－１

Ｆ１セルに配置した「年月変更」ボタンを押すと「年月切り替えボックス」が表示され、スクロールバーを操作することで前後１年の年月が選択できる、というものです。
スクロールバーの指している年月は図２－１で言うと2020年2月になります。上段に年の「2020」、下段に月の「２」が表示されており、その両脇に前月・前々月、次月・次々月が表示されています。これは図２－２のように円筒の外周に文字が書いてあるように見せたかったからですが、今一つパッとせず申し訳ありません。

図２－２

年月を変更しダイアログボックスのＯＫボタンを押すことで、指定した年月のカレンダーに切り替わります。
また、Ｃ１セル・Ｇ１セルに配置した「前月」「次月」ボタンを押す事でもカレンダーを移動させることができます。

３．プログラム

プログラムは、フォームおよび標準モジュールに分かれています。主にダイアログボックス（＝年月切り替えボックス）関連はフォーム、ワークシートのカレンダー関連は標準モジュールに記述しています。

３－１．ワークシートとフォーム間の値の受け渡し方法

今回のアプリでは、「フォーム側で決めた表示年月」を使って「ワークシート側でカレンダーを表示」するのと同時に、「ワークシート側のカレンダーの表示年月」を「フォーム側の選択年月の初期値」にするという仕様にしています。
つまり、ワークシート側（＝標準モジュール）とフォーム側（＝フォームモジュール）で年月の「値を授受」する必要があります。

ワークシート側とフォーム側で値を受け渡す方法としては、以下の４つが考えられます。

		(1)　Book内で Public変数を使用	(2) ﾜｰｸｼｰﾄのｾﾙを使用	(3)　ﾌｫｰﾑ上の ｺﾝﾄﾛｰﾙの値を使用	(4)　ﾌｫｰﾑ上のSubや Functionを呼び出す
呼出側 (標準ﾓｼﾞｭｰﾙ)		Public変数に値を代入	セルに値を貼り付ける	ﾌｫｰﾑのLabel等に値を書き 込み後ﾌｫｰﾑを立ち上げる	ﾌｫｰﾑ上のSubやFunctionの引数 として値を渡す
ﾌｫｰﾑ側	受取	Public変数から値を受取る	セルから値を受取る	ﾌｫｰﾑ起動時にLabel等から 値を受取る	引数として値を受取った後､ ﾌｫｰﾑを起動する
	受渡	Public変数に値を代入	セルに値を貼り付ける	ﾌｫｰﾑを閉じる前にLabel等に 値を書き込み､Hideで閉じる	ﾌｫｰﾑが閉じた後，SubやFunction から引数･戻り値として値を返す
受取側 (標準ﾓｼﾞｭｰﾙ)		Public変数から値を受取る	セルから値を受取る	HideしたﾌｫｰﾑのLabel等から 値を受取る	引数･戻り値として値を受取る

図３－１

今回は図３－１の内、一番右の(4)の方法で値の受け渡しをしています。

まず、通常ならば「フォームの起動」は「標準モジュール側から実行」します。通常は図３－２の様なコードです。

1. 　UserForm1.Show　　　　　　'←通常のフォームの起動方法

図３－２

図３－１の(1)・(2)・(3)の方法を使う場合でしたら、事前処理（Public変数やセルやフォームのコントロールに値を代入・記入しておく）をしておけば図３－２の方法でフォームを呼び出してもＯＫです。
しかし(4)の方法の場合では、以下の「Subプロシージャでの呼出し」や「Function関数での呼び出し」を使用します。

３－１－１．値の受け渡し方法１（Sub プロシージャを使用）

図３－３は標準モジュール側のコードで、「他のプロシージャを引数付きで呼び出す」方法です。

2. 　TD = Sheet1.Range(YM)　　　　　　　'←日付セル(YM)の値を変数TDに代入
3. 　Call UserForm1.Start1(TD)　　　　　　'←日付値を引数にしてSubプロシージャを呼び出し

図３－３

まず図３－３の２行目で日付セルの値を変数TDに代入し、呼び出しプロシージャの引数TDを準備します。３行目で、そのTDを引数に指定してプロシージャ「Start1」を呼び出します。
呼び出すプロシージャ「Start1」はフォームモジュールにあるので、「UserForm1.」をプロシージャ名の前に追加する必要があります。

呼び出されるStart1プロシージャは、図３－４です。

4. Public Sub Start1(TD As Date)
5. 　If TD = 0 Then TD = Now
6. 　Tdate = TD
7. 　Me.Show
8. 　TD = Tdate
9. End Sub

図３－４

詳細は図５－２で説明しますが、フォームモジュールのStart1プロシージャは「現在表示されているカレンダーの年月」であるTDを引数として受け取ります。
その引数を６行目でフォームモジュールの共通変数Tdateに代入した後、７行目でフォームを起動します。フォーム上のコードですので、「Me.Show」の「Me」は自身（＝フォーム）の事になります。
このフォームは「年月を選択する機能を持ち、新たに選択した年月を変数Tdateに代入する」役割を持っていますので、制御が８行目に移る時には「新たな年月が変数Tdateに入っている」ことになります。

少し戻りますが、呼び出し先のStart1プロシージャの引数TDと、呼び出し元の「Call UserForm1.Start1(TD)」の引数TDは、実は図３－５の様に「同じメモリーアドレスを割り当てられている」のです。

図３－５

図３－５のByRefのRefは「Reference（参照）」の略で、引数をByRef（参照渡し）とすると引数用のメモリー場所を確保し、呼び出し側と呼び出され側で共通のメモリー場所を使用しているのです。
（何も指定しなければByRefになります。逆に「ByVal（値渡し）」を指定すると、別々のメモリー場所になるため、フォームモジュール側と標準モジュール側での引数は独立している事になります。）

ですので、８行目でTdateの値を引数TDに代入してから９行目でStart1プロシージャを終了し図３－３の３行目の次に制御が移った時には、「標準モジュール側の変数TDには、新たに選択した年月値が入っている」ことになります。

３－１－２．値の受け渡し方法２（Function プロシージャを使用）

図３－６は標準モジュール側のコードで、Subプロシージャではなく「Functionプロシージャを呼び出し、その戻り値を使う」方法です。

10. 　TD = Sheet1.Range(YM)　　　　　　　'←日付セル(YM)の値を変数TDに代入
11. 　TD = UserForm1.Start2(TD)　　　　　　'←日付値を引数にしてFunctionプロシージャを呼び出し

図３－６

１０行目は図３－３の２行目と同じで、日付セル値を変数TDに代入し、１１行目でそのTDを引数にして「関数Start2」を呼び出します。呼び出されるStart2はフォームモジュールにありますので「UserForm1.」を頭につけます。

呼び出されるStart2プロシージャは、図３－７です。

12. Public Function Start2(TD As Date) As Date
13. 　If TD = 0 Then TD = Now
14. 　Tdate = TD
15. 　Me.Show
16. 　Start2 = Tdate
17. End Function

図３－７

フォームモジュールのStart2プロシージャは、TDを引数として受取ります。その後の処理は図３－４の「Sub Start1 」とほぼ同じですが、Start2は「Sub」であるStart1とは異なり、戻り値を持つ関数（Function）です。
ですので「共通のメモリー場所を持つ引数」を使って値をやり取りする必要は無く、１６行目で「Start2 = Tdate」と「Functionの戻り値として、新たな年月Tdateを指定」すれば良いことになります。

Start2の戻り値となった「新たな年月」は、図３－６の１１行目で「TD = UserForm1.Start2(TD)　」の左辺の値として受取ります。

戻り値のTDと引数のTDが同じスペルなので混乱しそうですが、今回は「左辺から新たな年月」が返ってきています。
Subを使うのかFunctionを使うのかは分かり易さで決めるべきですが、私なら「フォームで選んだ値を明示的に返してくれるFunctionを選ぶ」かもしれません。

尚、今回は「値を受取るために、フォームを起動するプロシージャを標準モジュールから呼び出す」という側面でこの手法を紹介しましたが、通常のプロシージャ呼び出しの場面でも「複数の引数を添付してプロシージャを呼び出し」すれば、「複数の戻り値が同時に得られる」ことにもなります。
「Functionだと１つしか戻り値が得られない」とか「戻り値を配列にしてから返すのは面倒」と思われている方は、試してみると良いかと思います。

４．フォームへのコントロールの配置

各コントロールをフォーム上に図４－１のように配置します。

図４－１

ボタン表面の文字、左端Label「年」「月」の文字は、配置時に変更しています。その他のLabel１～１０、スクロールバーのプロパティは初期状態のままで、フォームのコード（Initializeイベントプロシージャ）からプロパティ変更をしています。

５．フォームコード

次は、呼び出される側（＝フォームモジュール側）のコードです。

５－１．変数の宣言

まず図５－１はフォーム内で使用する変数の宣言です。フォーム上で指し示している年月（Date型）をTdate変数として保管しています。

18. '==========　⇩①　変数の宣言（フォームモジュール）　===========
19. Dim Tdate As Date

図５－１

５－２．フォームの起動

次に、標準モジュールから呼び出されるプロシージャが図５－２になります。
内容は、図３－４、図３－７で説明したコードと同じで、２１～２６行目がSubプロシージャで受け渡しするコード、２９～３４行目がFunctionプロシージャで受け渡しするコードです。
（サンプルファイルは、Subプロシージャの方を生かしてあります。）

20. '==========　⇩②　フォームの起動（Subプロシージャでデータ受け渡し）　==================
21. Public Sub Start1(TD As Date)
22. 　If TD = 0 Then TD = Now
23. 　Tdate = TD
24. 　Me.Show
25. 　TD = Tdate
26. End Sub
28. '==========　⇩③　フォームの起動（Functionプロシージャでデータ受け渡し）　==================
29. Public Function Start2(TD As Date) As Date
30. 　If TD = 0 Then TD = Now
31. 　Tdate = TD
32. 　Me.Show
33. 　Start2 = Tdate
34. End Function

図５－２

まず２１～２６行目の「Subプロシージャでデータ受け渡し」をする方法について説明します。

２１行目の「Sub Start1」が受け取る引数TDは「現在表示しているカレンダーの年月」です。
２２行目で、まず引数TDの値を調べますが、もしカレンダーが未表示（全くの初期状態を想定）の時は「年月のセルが空」という事になります。
文字列として引数を受取るのであれば「""（空文字）」になりますが、今回引数はDate型ですので「年月が空の時、引数TDの値はゼロ」となるため、２２行目で変数TDに今日の日付を代入（＝引数として今日の日付が来た事にする）しています。
２３行目では、そのTDをフォーム内変数であるTdateに代入してから、２４行目で自分（＝フォーム）を起動します。

フォーム起動後、ダイアログボックス内で年月を選択しますが、ダイアログボックスを閉じる際に最終的に選択した年月がフォーム内変数Tdateに入り、制御が２５行目に戻ってきます。
２５行目では「TD = Tdate 」で引数TDに代入した後「Sub Start1」を終了することで、処理は標準モジュール（図６－３の１６６行目の次の行）に移りますが、１６６行目の引数である「TD 」には「ダイアログボックスで選択した新しい年月」が入っていますので、標準モジュール側ではその新しい年月「TD」を使って処理していきます。

一方、２９～３４行目の「Functionプロシージャの引数で渡し、戻り値で返す方法」ですが、フォームの起動までは「Subプロシージャ」と同じです。
違いは３３行目で、フォームで選択した年月が代入されている変数Tdateの値をFunctionプロシージャStart2の戻り値にしています。
その後、制御が標準モジュール（図６－３の１６７行目）に戻り、関数の戻り値として左辺のTDに新たな年月値が返ってきます。 それ以降、標準モジュール側ではその新しい年月TDを使って処理していきます。

５－３．フォームの初期化（Initialize）

フォームを起動するときに、まず実行されるのが図５－３のInitializeイベントプロシージャです。
今回のInitializeに記載した内容には、フォームコントロールのプロパティ設定も含まれています。フォームにコントロールを配置する時に各プロパティを変更・設定しても良いのですが、「何のプロパティをどのように変更したか」が後から分からなくなり易いので、出来るだけInitializeイベント等に記載するようにしています。

35. '==========　⇩④　フォーム初期化（フォームモジュール）　===========
36. Private Sub UserForm_Initialize()
37. 　ScrollBar1.Min = -12
38. 　ScrollBar1.Max = 12
39. 　ScrollBar1.Value = 0
41. 　Me.Label1.TextAlign = fmTextAlignCenter
42. 　Me.Label2.TextAlign = fmTextAlignCenter
43. 　Me.Label3.TextAlign = fmTextAlignCenter
44. 　Me.Label4.TextAlign = fmTextAlignCenter
45. 　Me.Label5.TextAlign = fmTextAlignCenter
46. 　Me.Label6.TextAlign = fmTextAlignCenter
47. 　Me.Label7.TextAlign = fmTextAlignCenter
48. 　Me.Label8.TextAlign = fmTextAlignCenter
49. 　Me.Label9.TextAlign = fmTextAlignCenter
50. 　Me.Label10.TextAlign = fmTextAlignCenter
52. 　Me.Label1.ForeColor = RGB(128, 128, 128)
53. 　Me.Label2.ForeColor = RGB(64, 64, 64)
54. 　Me.Label3.ForeColor = RGB(0, 0, 0)
55. 　Me.Label4.ForeColor = RGB(64, 64, 64)
56. 　Me.Label5.ForeColor = RGB(128, 128, 128)
57. 　Me.Label6.ForeColor = RGB(128, 128, 128)
58. 　Me.Label7.ForeColor = RGB(64, 64, 64)
59. 　Me.Label8.ForeColor = RGB(0, 0, 0)
60. 　Me.Label9.ForeColor = RGB(64, 64, 64)
61. 　Me.Label10.ForeColor = RGB(128, 128, 128)
63. 　Me.Label1.Font.Size = 9
64. 　Me.Label2.Font.Size = 10
65. 　Me.Label3.Font.Size = 12
66. 　Me.Label4.Font.Size = 10
67. 　Me.Label5.Font.Size = 9
68. 　Me.Label6.Font.Size = 9
69. 　Me.Label7.Font.Size = 10
70. 　Me.Label8.Font.Size = 12
71. 　Me.Label9.Font.Size = 10
72. 　Me.Label10.Font.Size = 9
74. 　Me.Label3.Font.Bold = True
75. 　Me.Label8.Font.Bold = True
77. 　Me.Caption = "予定表の年月を選択して下さい"
78. End Sub

図５－３

まず、３７～３９行目はスクロールバーの設定値です。バーの中央値（Value = 0）を基準に、±１年を選択できるような値に設定しています。

４１～５０行目は、年月の文字（Label１～１０）を左右方向で中央揃えにしています。
５２～７５行目は、文字の色・サイズ・太文字化のプロパティを調整し文字に遠近感を持たせ、図５－４のように立体的に見える様な工夫をしています。

図５－４

５２～６１行目は、その文字の色を設定しています。一番手前側（Label３、Label８）は濃い黒（RGB(0,0,0)）にし、横に行くに従って薄い色にしています。
６３～７２行目は、文字サイズの設定です。手前側は大きな文字、横に行くに従って小さな文字にしています。
７４～７５行目は、最も近いはずの文字を太文字化（Bold）しています。

７７行目は、ダイアログボックスのタイトル部に、ユーザーへの指示を表示しています。

５－４．フォーム表示時の初期化（Activate）

フォームが初めて起動する時にはInitializeイベントが発生します。しかし、起動後一旦フォームを隠した（＝Hide）後で、再度表示（＝Show）した際にはInitializeイベントは発生しません。
ちなみに、フォームが完全に表示するまでに発生するイベントは、以下の順序（図５－５）で発生します。

.Show で最初の起動した時	Initialize → Layout → Activate
.Hide で閉じる	何も発生せず（「閉じるボタン」のイベントのみ）
.Show で再表示	Activate のみ
Unload で閉じる	QueryClose → Terminate

図５－５

今回の場合、フォームは「.Hide」で閉じます。フォームが閉じている間は「フォーム終了時の状態のまま保存」されます。しかし、閉じている間にユーザーが「前月」「次月」ボタンを使ってカレンダー表示を変更する事は可能です。
つまり、フォームを次に再表示する際「フォームの年月の表示」と「ワークシート上のカレンダーの年月」が異なっている可能性があるのです。
フォームを再表示した時に発生するイベントは「Activateイベント」のみです。そのため図５－６の様にActivateイベントで「フォームの表示を現在表示してあるカレンダーの年月に合わせる」ことをしています。

尚、YMout（Year Month OutPut の略のつもり）は、フォーム内に表示されている年月を「フォーム内共有変数Tdate（カレンダーの表示年月）」中心に書き換えるプロシージャ（図５－７）です。

79. '==========　⇩⑤　フォームアクティブ時（フォームモジュール）　=============
80. Private Sub UserForm_Activate()
81. 　Call YMout
82. End Sub

図５－６

５－５．ダイアログの年月表示を書き換える

図５－７が、「フォーム中の年月表示をTdate中心に書き換える」プロシージャです。

83. '==========　⇩⑥　年月の表示（フォームモジュール）　===========
84. Private Sub YMout()
85. 　Dim Ldate As Date, Fdate As Date, LLdate As Date, FFdate As Date
87. 　Ldate = DateAdd("m", -1, Tdate)　　　'←前月
88. 　LLdate = DateAdd("m", -2, Tdate)　　'←前々月
89. 　Fdate = DateAdd("m", 1, Tdate)　　　'←次月
90. 　FFdate = DateAdd("m", 2, Tdate)　　　'←次々月
92. 　Me.Label3 = Year(Tdate)
93. 　If Not Year(Tdate) = Year(Ldate) Then
94. 　　Me.Label2 = Year(Ldate)
95. 　Else
96. 　　Me.Label2 = ""
97. 　End If
99. 　If Not Year(Ldate) = Year(LLdate) Then
100. 　　Me.Label1 = Year(LLdate)
101. 　Else
102. 　　Me.Label1 = ""
103. 　End If
105. 　If Not Year(Tdate) = Year(Fdate) Then
106. 　　Me.Label4 = Year(Fdate)
107. 　Else
108. 　　Me.Label4 = ""
109. 　End If
111. 　If Not Year(Fdate) = Year(FFdate) Then
112. 　　Me.Label5 = Year(FFdate)
113. 　Else
114. 　　Me.Label5 = ""
115. 　End If
117. 　Me.Label6 = Month(LLdate)
118. 　Me.Label7 = Month(Ldate)
119. 　Me.Label8 = Month(Tdate)
120. 　Me.Label9 = Month(Fdate)
121. 　Me.Label10 = Month(FFdate)
122. End Sub

図５－７

フォーム内には共有変数「Tdate」があり、フォームの表示年月の中央値が代入されています。
しかしフォーム上の表示年月は「年月中央値 ± ２か月」は不明ですので、その計算を８７～９０行目で行い変数に代入します。
変数名として、Ldate ＝ 前月、LLdate ＝ 前々月、Fdate ＝ 次月、FFdate ＝ 次々月　と名前を付けました。

９２～１１５行目は、表示年月の上段部分の「年」の表示を行っている部分です。
表示の「年月の中央値 ± ２か月」の全てに年を表示しても良いのですが、ダブリを省いて見易くなるように「中央値の年は必ず表示」＋「年が切り替わるところだけは年を表示」することにしました。

まず年月を表示する為のLabelの位置を再確認します。

図５－８（図５－４と同一）

中央値の年はLabel３です。「中央値の年は必ず表示」するので、まず９２行目で「中央値の年」を記入しています。

次に、前月の年（Label２）をどうするか９３行目で判断します。つまり「中央値と同じ年か否か」で判断し、異なれば（＝中央値は１月で前月値は１２月）９４行目で年を記入します。
また同じであれば（＝１２月では無い）９６行目で空文字（""）を記入します。

前々月（Label１）の場合は、比較は中央値ではなく前月の値と比較します。
つまり「前月と同じ年か否か」で判断し、異なれば（＝前月が１月で、前々月が１２月）１００行目で年を記入、同じであれば１０２行目で空文字（""）を記入します。

次月（Label４）の場合は、中央値と異なれば（＝中央値が１２月で次月が１月）１０６行目で年を記入、同じであれば１０８行目で空文字（""）を記入。
次々月（Label５）の場合は、次月と異なれば（＝次月が１２月で次々月が１月）１１２行目で年を記入、同じであれば１１４行目で空文字（""）を記入します。

今回、Labelを配列にしなかったために、各Labelごとに条件式で判別せざるを得ず、ダラダラしたコードになってしまいました。また「年を比較」するのではなく「月が１か、月が１２か」で条件式を組み立てる方法もあると思います。ご自分の理解し易い方法でコードにして下さい。
尚、年を記入するLabel１～５の５つの内、年が記入されるのは多くても２つなので、まず最初にLabel１～５の５つ全てに空文字（""）を代入してしまう方法も、コードが短くなるため良い方法と考えられます。


１１７～１２１行目の「Label６～Label１０」は「月の表示」です。月は年と違って前後で同じになる事はありませんので、前々月～中央年月～次々月までの「月の表示」を記入します。

５－６．スクロールバー操作時の動作

スクロールバーを操作した時のイベントプロシージャが図５－１１になります。
「操作」といっても、どこを操作するかで発生するイベントも異なってきます。
図５－９はスクロールバーの部位を表したもので、発生するイベント等との関連は図５－１０になります。


図５－９

クリックする場所	操作	動く量・示す値	発生イベント
スクロール矢印	クリック	SmallChangeプロパティの量	Changeイベント
スクロールボックスと スクロール矢印の間の領域（レール）	クリック	LargeChangeプロパティの量	Changeイベント
スクロールボックス	クリックし移動中	スクロールボックスの位置のValue値 (動く量はValue=1ずつ)	Scrollイベント
	移動後クリックを離す	クリックを離した場所のValue値	Changeイベント

図５－１０

通常スクロールバーと言うとChangeイベントを真っ先に思いつくと思いますが、スクロールボックスをつまんで動かしている間はChangeイベントは発生しません。「スクロールボックスを動かすと同時に年月の表示を変更」しようとするならば、Changeイベントと併せてScrollイベントも使用する必要が生じます。

123. '==========　⇩⑦　スクロールバー操作時の動作（フォームモジュール）　============
124. Private Sub ScrollBar1_Change()
125. 　Tdate = DateAdd("m", ScrollBar1.Value, Tdate)
126. 　ScrollBar1.Value = 0
127. 　Call YMout
128. End Sub
130. Private Sub ScrollBar1_Scroll()
131. 　Static LastValue As Integer
132. 　Tdate = DateAdd("m", ScrollBar1.Value - LastValue, Tdate)
133. 　LastValue = ScrollBar1.Value
134. 　Call YMout
135. End Sub

図５－１１

５－６ー１．スクロール矢印・レール部をクリック操作した場合

まず「スクロール矢印をクリック」又は「レール部をクリック」で年月の操作をした場合は、１２４～１２８行目のChangeイベントで処理します。

スクロールバーの初期値はゼロ（図５－３の３９行目で設定済み）で、動かした後にスクロールバーが指し示している値はValue値で得られます。その値を「〇か月のズレ」と置き換えて、１２５行目の「DateAdd("m", ScrollBar1.Value, Tdate)」で、年月の中央値（Tdate）をズラしています。
中央値をズラした後で、１２６行目でスクロールバーのValue値をゼロに戻し、スクロールボックスを中央に戻します。次に操作する時の初期値をゼロにするためです。
最後に、YMsoutプロシージャを呼び出し、年月の表示を更新します。

実は１２６行目で「Value値をゼロ」にすると、Changeイベントがまた発生（再帰呼び出し）するのです。実行順序としては、
つまり、１２７行目の「年月Labelの再表示」は２回実行されています。しかし、再表示時のTdate値は２回とも「ズラした後の値」ですので、パラパラと文字が動くような現象にはならないのと、Labelを１０箇所書き換えているだけで処理時間も短いと判断し、再表示はそのまま実行させています。
ただ、同じ処理の繰り返しは無駄であることに変わりありません。これを避ける方法としては、１２６行目の「Value値をゼロにする処理」を実行する際に「スクロールバーの初期化をしているだけなので、Changeイベントはスルーして下さい」という意味のフラグを立てる方法があります。（図５－１２）

• Private Sub ScrollBar1_Change()
• 　If Flag0=True Then Exit Sub　　　'←フラグがTrue(ｽｸﾛｰﾙﾊﾞｰのValue値をｾﾞﾛにしている)の時は終了
• 　Tdate = DateAdd("m", ScrollBar1.Value, Tdate)
• 　Flag0=True　　　　　　　　　　　'←フラグを立てる(True)
• 　　ScrollBar1.Value = 0
• 　Flag0=False　　　　　　　　　　'←フラグを寝かす(False)
• 　Call YMout
• End Sub

図５－１２

尚、図５－１２の方法を行う時は、フラグ変数「Dim Flag0 As Boolean」はフォームモジュール共有の変数としてモジュール先頭で宣言するか、またはプロシージャ内に「Static Flag0 As Boolean」と値保持型として宣言して下さい。
また、イベントを停止させると言うと「Application.EnableEvents = False」を思い出されると思いますが、このEnableEventsはワークシートでは通じますが、フォームでは通じませんので注意して下さい。

５－６ー２．スクロールボックスを移動させる操作をした場合

次に「スクロールボックスを移動させて年月を設定する方法」の処理が、１３０～１３５行目になります。

まず、１３１行目で「Static LastValue As Integer」と、変数「LastValue」を値保持型として宣言します。
これは、スクロールボックスの１つ前の位置を変数「LastValue」に記憶し、次にスクロールボックスが移動した場所との差を移動量とすることで、スクロールボックスの動きと年月表示を合わせるためです。

「スクロールボックス移動」の特徴として、スクロールボックスを「移動させている途中はScrollイベント」のみが発生していますが、ある年月の場所でマウスを止め「左クリックを外すとChangeイベント」が発生することです。
図５－１３は、初期に１月を表示していた場所からスクロールバーのスクロールボックスをマウスで移動し、４月で左クリックを外した時のコードの実行順序を示してあります。


図５－１３

図５－１３で、このイベントプロシージャで宣言している「LastValue」の値と表示年月の関係も説明していきます。

まず、スクロールボックスを動かすとScrollイベントが発生します。スクロールバーのValue値の初期値はゼロですので、そこから右側に１だけ動かした時を考えます。
１３２行目の右辺は「DateAdd("m", ScrollBar1.Value - LastValue, Tdate)」です。式の中のLastValue値は宣言したままの状態なのでゼロです。またスクロールバーのValue値は１に変化しています。
ですのでこの式は「DateAdd("m", 1 - 0, Tdate)」となり、Tdateつまり１月の１か月後となり「Tdate＝２月」になります。 １３３行目では、Value値を変数LastValueに代入しますので、LastValue＝１となります。
１３４行目ではTdate（＝２月）を中心にして年月を表示します。

スクロールボックスをマウスで掴んだまま、更に１だけ右に動かします。
またScrollイベントが発生し、１３２行目「DateAdd("m", ScrollBar1.Value - LastValue, Tdate)」を計算します。この時点ではTdateは２月、LastValue＝１で、スクロールバーのValue値は２になっています。ですから「DateAdd("m", 2 - 1, Tdate)」で、Tdateは３月になります。また１３３行目でLastValue＝２になります。

このようにスクロールボックスを右に動かしていくとTdateが１か月ずつ先に送られ、LastValue値も増えていきます。

スクロールバーのValue値が３になるとTdateは４月となり、LastValueには３が代入され１３４行目で４月を中心としたLabel表示になります。
ユーザーが「この年月でＯＫ」と、ここでマウスの左クリックを離したとします。

クリックを離すと、Scrollイベントのコードを全て実行した後、Changeイベントに移動します。
Changeイベントに入った時には、スクロールバーのValue値は３であり、またTdateは４月になっています。
１２５行目にコードが進むと、右辺は「DateAdd("m", ScrollBar1.Value, Tdate)」ですので、４月から３か月進みTdateは「７月」になります。

そして１２６行目ではValue値にゼロを代入しますのでValue値＝０ですが、Value値が変化すると「スクロールボックスが動いた」と判断するようでScrollイベントが割り込んで発生します。

Scrollイベントプロシージャの中では、既にValue値はゼロになっていますが、スクロールボックスを離した位置はLastValue＝３としてまだ記憶されています。
したがって「DateAdd("m", ScrollBar1.Value - LastValue, Tdate)」の式は「DateAdd("m", 0 - 3, Tdate)」となり、７月の３か月前、つまりTdateは４月に戻され、１３４行目で４月を中心に表示が行われます。

表示が完了したらScrollイベントプロシージャを抜け、元のChangeイベントプロシージャの１２６行目の次の１２７行目に移り、Tdate＝４月を中心に表示が行われます。

ここで「Scrollイベントの後にChangeイベントが発生するはずなので、表示は３回では？」という疑問が出ますが、色々テストしてみると「表示は２回」の様です。
つまり「スクロールボックスを操作した後に発生するChangeイベント内でValue値を変更しても、Scrollイベントは発生するがChangイベントは再帰呼び出しされない」ようなのです。
この理屈は良く分かりません。

また「スクロールボックスでの操作」と「スクロール矢印等での操作」を混ぜた時に表示がおかしくならないか心配になりますが、「スクロールボックスでの操作」の工程の最後のScrollイベントプロシージャ内の１３３行目で「LastValue値＝ゼロ」と初期化しており、操作ごとに完結させているため誤表示はありません。

５－７．「今月」ボタンをクリックした時の動作

次に「今月」ボタンを押した時のClickイベントプロシージャが図５－１４になります。

136. '==========　⇩⑧　「今月ボタン」のクリック時（フォームモジュール）　==================
137. Private Sub CommandButton1_Click()　　'//「今月」ボタン
138. 　Tdate = Now
139. 　Call YMout
140. End Sub

図５－１４

１３８行目で、年月表示の中央値として現在の日付を代入した後、１３９行目で年月Labelの再表示を行うことで、「今月」を中央に持ってきてます。

５－８．「OK」「Cancel」のボタンをクリックした時の動作

「OK」ボタンをクリックした時が１４２～１４４行目、「Cancel」ボタンをクリックした時が１４６～１４９行目になります。
また、ダイアログの右上の×印で強制的に終了した時には１５１～１５５行目が働きます。

141. '==========　⇩⑨　フォーム終了時の処理（フォームモジュール）　=================
142. Private Sub CommandButton2_Click()　　'//「OK」ボタン
143. 　Me.Hide
144. End Sub
146. Private Sub CommandButton3_Click()　　'//「Cancel」ボタン
147. 　Tdate = 0
148. 　Me.Hide
149. End Sub
151. Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)　'//右上×印で終了した時
152. 　Cancel = True
153. 　Tdate = 0
154. 　Me.Hide
155. End Sub

図５－１５

まず「OK」ボタンをクリックした時は、「ユーザーが選んだ年月（Labelの中央値）を呼び出した標準モジュールに返す」必要があります。また、その他（「Cancel」ボタン、ダイアログの×印 ）の場合は、「変更をやめる」という意味にとらえて「標準モジュールにはゼロを返す」ことにしました。

「OK」ボタンの場合は、１４３行目でダイアログを閉じ（Hide：隠す）ます。ダイアログを閉じると、ダイアログを起動したコードの次に移動しますので、図５－２の２５行目、または図５－２の３３行目を実行します。
図５－２の「Sub Start1」は、２５行目で引数であるTDにPublic変数Tdate（選択した年月）を代入した後、２６行目で閉じますので、標準モジュール側に引数TDを通じて年月を渡すことになります。
また「Function Start2」の場合は、３３行目でFunctionの戻り値としてTdateを指定し３４行目で閉じますので、呼び出したFunctionの戻り値として選択した日付を受取ります。

「Cancel」ボタンの場合は１４７行目で選択した年月としてTdateにゼロを代入し、ゼロ値を標準モジュール側に返すことで、標準モジュール側で「戻り値がゼロか否かを判定」し、ゼロだったら「何もしない」ことにしています。

「ダイアログ右上×で閉じる」の場合は、まず１５２行目で「Cancell = True」の設定を行い「制御して閉じる」という状態にしておき、１５３行目でTdateにゼロを代入し、正常にダイアログを閉じています。

６．標準モジュールのコード

６－１．定数の宣言

標準モジュールの先頭に、カレンダー表示位置の定数を宣言しています。（図６－１）

156. '==========　⇩⑩　変数の宣言（標準モジュール）　=============
157. Const CalTitleRow As Integer = 2　　'カレンダーのタイトル行の行位置
158. Const CalStartRow As Integer = 3　　'カレンダーの日付範囲の開始行
159. Const CalStartCol As Integer = 2　　'カレンダーの日付範囲の開始列
160. Const YM As String = "D1"　　　　　'年月表示してあるセル位置

図６－１

カレンダーは通常７列ｘ６行ですが、各日付の下に予定を記入できるセルを追加したため、今回は７列ｘ１２行とします。
表示位置は「カレンダータイトル（曜日の書いてある行）の行」「カレンダー本体の開始行」「カレンダー本体の開始列」「表示年月を記入するセル」の４つを図６－２のように設定します。

図６－２

６－２．「年月変更」ボタンによる起動

Ｆ１セルの上に配置した「年月変更」ボタンを押すと実行されるのが図６－３です。
１６６行目、または１６７行目がフォームを呼び出すコードですが、サンプルファイルでは１６６行目を生かし、１６７行目はコメントアウトにしてあります。どちらでも動きますので、どちらかをコメントアウトして下さい。

161. '==========　⇩⑪　「年月変更」ボタンで作動（標準モジュール）　================
162. Sub Ymake()　　'「年月変更」ボタン
163. 　Dim TD As Date
165. 　TD = Sheet1.Range(YM)
166. 　Call UserForm1.Start1(TD)
167. 　' TD = UserForm1.Start2(TD)　
168. 　If TD = 0 Then Exit Sub
169. 　Call DateMake(TD)
170. End Sub

図６－３

１６３行目は変数TD（ToDayの略）の宣言で、表示している・表示しようとするカレンダーの年月です。Public変数としてTdateを宣言する方法もあるとは思いますが、Publicにすると「フォームを「Cancel」ボタンで閉じる時、元の表示年月に戻るために別の変数にデータを保存しなければならない」等から、プロシージャ内変数としました。
なお、変数TDは「年月」と言ってもDate型ですので「年月日」と日付までのデータが入っています。しかし日付部分は無視し、年と月のデータだけを使って処理していきます。

１６５行目では表示カレンダーの年月を変数TDに代入したあと、フォームのStart1サブプロシージャ、又はStart2関数プロシージャを呼び出します。
もしワークシートにカレンダーが無い（＝カレンダー年月が無い）場合は、変数TDにはゼロとして代入されますので、図５－２の ２２行目・３０行目で「フォーム側で、ゼロの場合は今日の日付にする」処理をしています。

フォームを閉じて、その日付が変数TDに返されて来たら、まずは１６８行目でゼロか否かを判断します。ゼロが返されてきたということは、図５－１５で説明した通り「Cancelボタンがクリックされた」または「ダイアログ右上の×印がクリックされた」ことを示しているので、カレンダー年月を変更する必要は無くなるため「Exit Sub」で終了させます。

選択した年月がゼロで無かった場合だけ、１６９行目のDateMakeプロシージャを実行しカレンダーの日付を記入します。

６－３．カレンダーの作成

ダイアログで年月を選択しOKボタンをクリックした時、および図６－９の「前月」「次月」ボタンをクリックした時に実行されるのが図６－４です。引数として「表示するカレンダーの年月（変数TD）」を渡します。

171. '==========　⇩⑫　カレンダーの日付を記入　=====================
172. Sub DateMake(TD As Date)　　　　'カレンダーの数値記入
173. 　Dim FirstDay As Date
174. 　Dim LastDay As Integer
175. 　Dim FirstWeek As Integer
176. 　Dim CalArray(1 To 12, 1 To 7) As Integer
177. 　Dim i As Integer, j As Integer, k As Integer
179. 　FirstDay = DateSerial(Year(TD), Month(TD), 1)
180. 　LastDay = Day(DateSerial(Year(TD), Month(TD) + 1, 0))
181. 　FirstWeek = Weekday(FirstDay)
183. 　For i = FirstWeek To LastDay + FirstWeek - 1
184. 　　k = Int((i - 1) / 7) + 1
185. 　　j = i - (k - 1) * 7
186. 　　CalArray(k * 2 - 1, j) = i - FirstWeek + 1
187. 　Next i
189. 　Sheet1.Cells(CalStartRow, CalStartCol).Resize(12, 7) = CalArray
190. 　Sheet1.Range(YM).Value = FirstDay
191. End Sub

図６－４

１７３～１７７行目はプロシージャ内で使用する変数の宣言です。
１７３行目の「FirstDay」は、表示年月の初日（各月の1日目）の日付です。
１７４行目の「LastDay」は、表示年月の最終日です。例えば１月でしたら「31」という数値が入ってきます。
１７５行目の「FirstWeek」は「FirstDay」の曜日で、日曜なら１、月曜なら２という数値が入ってきます。
１７６行目の「CalArray」はカレンダー全体の配列です。図６－２で説明しましたが、カレンダーの各日付の下に予定を書き込むセルがありますので、７列ｘ１２行のサイズにしています。
１７７行目の「i」「j」「k」はカウンター変数です。

まず１７９行目では、引数TDの日付を含む年月の初日の日付を取得し、変数FirstDayに代入しています。これは１８１行目の「初日の曜日」を求めるための準備として実行しています。

初日を求める他の方法としては「Application.WorksheetFunction.EoMonth(Now, -1) + 1」という式も使えます。EoMonthはワークシート関数にもある月の末日を計算する関数です。第二引数にズラす月数を指定するのですが、「－１」を指定することで「前月の最終日」を得ることができます。その最終日に「＋１」をすることで当月の初日になります。
但しこの関数はExcel2007以降なので、１７９行目の式の方が安全です。

１８０行目は最終日の計算です。式の右辺は「次月の０日目」という意味になり、つまりは今月の最終日が得られます。
先程の例を使えば「Application.WorksheetFunction.EoMonth(Now, 0)」でも求めることができます。

１８１行目は、初日の曜日値を計算しています。Weekday関数の第二引数を指定していませんので、既定の「日曜日＝１」から始まる数値になります。

１８３から１８７行目はカレンダーの日付を配列に収めていくコードです。

まず、１８３行目の開始値「FirstWeek」と終了値「LastDay + FirstWeek + 1」です。
図６－５の様に「月の初日はカレンダーの１行目」に必ずなりますので、カレンダー先頭からの番号（図６－５の赤字の数値）と曜日値（曜日の上の数値）が一致します。ですので開始値は「FirstWeek」となります。
終了値は、その最終日の日付（LastDay）と、初日のズレ分（FirstWeek）＋１を足すことで、カレンダー先頭からの番号が得られます。

図６－５

次に１８４行目の「k = Int((i - 1) / 7) + 1」ですが、カレンダー配列の行位置を計算しています。
カレンダー先頭からの番号を「i-1」に置き換える（＝番号を１ずつ引く）と、図６－６のようになります。ここで、例えば１行目は「全て７未満なので、７で割った商はゼロ」になります。
つまり「Int((i - 1) / 7)＋1」が行位置になります。


図６－６

また、上で得られた行位置（k）を使って「(k - 1) * 7」を各行で計算してみると図６－７の中央部分になります。「カレンダーの先頭からの番号」からその値を引いたのが図６－７の右図になり、列位置を示すことになります。
つまり１８５行目の「j = i - (k - 1) * 7」が列位置になります。

図６－７

日付を入れる行位置（１８４行目）、列位置（１８５行目）を求める事ができましたので、１８６行目で日付を実際のカレンダー配列に入れていきます。但し今回は通常のカレンダーでは無く、１行置きに予定を書き込む行が入っています。
図で表現すると図６－８のようになりますので、代入する行位置は「K*2-1」と置き換えて代入していきます。

図６－８

１８６行目の右辺は「i - FirstWeek + 1」となっています。計算すると１から始まり、月末値で終了します。
右辺の式が分かりにくい場合は、１から順に代入していく様な新たな変数を設けても良いと思います。

１８９行目では、ワークシートのカレンダー範囲にCalArray（カレンダー日付を入れた配列）を貼り付けます。
次に、そのカレンダーの年月を定められた位置（定数で決めたYMセル位置）に書き込みます。
年月を書き込むセルは「年月のみの表示」形式にしてあります（図６－１０の２０５行目）ので、代入値は「FirstDay」でなく引数「TD」でもOKです。

６－４．カレンダーの「前月」・「次月」移動

カレンダーの「前月」ボタン（Ｃ１セル部）、「次月」ボタン（Ｇ１セル部）をクリックした時のマクロが図６－９になります。

192. '==========　⇩⑬　「前月」「次月」ボタンで作動　================
193. Sub IncMonth()　　　'次月カレンダーの表示
194. 　Call DateMake(DateAdd("m", 1, Sheet1.Range(YM)))
195. End Sub
197. Sub DecMonth()　　　'前月カレンダーの表示
198. 　Call DateMake(DateAdd("m", -1, Sheet1.Range(YM)))
199. End Sub

図６－９

現在表示されている年月は「Sheet1.Range(YM)」ですので、次月は「DateAdd("m", 1, Sheet1.Range(YM))」となり、その値を引数にしてDateMakeプロシージャを呼び出して、カレンダーを再表示します。
また前月の場合は「DateAdd("m", -1, Sheet1.Range(YM))」を引数にしてDateMakeを呼び出します。

６－５．カレンダーの外観作成（現在のところ、手動で起動）

カレンダーの位置を表す定数（図６－１）さえ決まっていれば、どんな外観のカレンダーでもデータを貼り付けられますが、一応サンプルファイルのカレンダーを作るマクロを添付しておきます。
尚、色とか罫線はマクロにするのが面倒だったので記述しておりません。

200. '==========　⇩⑭　カレンダー外観作成　==============
201. Public Sub CalMake()　　　'カレンダーの外観作成。罫線・彩色は別（1回だけ実施）
202. 　Dim i As Integer
204. 　Windows(ThisWorkbook.Name).DisplayZeros = False　　'数値ゼロは非表示
205. 　Sheet1.Range(YM).NumberFormatLocal = "yyyy""年""m""月"""
207. 　With Sheet1.Cells(CalTitleRow, CalStartCol).Resize(1, 7)　　'曜日行
208. 　　.HorizontalAlignment = xlCenter
209. 　　.Font.Size = 11
210. 　　.Font.Bold = True
211. 　　.EntireRow.RowHeight = 19
212. 　End With
214. 　For i = 0 To 11 Step 2　　　'日付行
215. 　　With Sheet1.Cells(CalStartRow + i, CalStartCol).Resize(1, 7)
216. 　　　.HorizontalAlignment = xlCenter
217. 　　　.Font.Size = 16
218. 　　　.Font.Bold = True
219. 　　　.EntireRow.RowHeight = 21
220. 　　End With
221. 　Next i
223. 　For i = 1 To 11 Step 2　　　'コメント行
224. 　　With Sheet1.Cells(CalStartRow + i, CalStartCol).Resize(1, 7)
225. 　　　.HorizontalAlignment = xlGeneral
226. 　　　.Font.Size = 10
227. 　　　.Font.Bold = False
228. 　　　.EntireRow.RowHeight = 73
229. 　　End With
230. 　Next i
232. 　For i = 0 To 6　　　　　　'列の調整
233. 　　With Sheet1.Cells(CalStartRow, CalStartCol + i)
234. 　　　.EntireColumn.ColumnWidth = 19
235. 　　End With
236. 　Next i
237. End Sub

図６－１０

ワークシートの詳細設定に「ゼロ値のセルにゼロを表示する」という項目がありますが、２０４行目はその項目の「レ点を外す」指示をしています。
というのも、図６－４の１８９行目でデータの配列（CalArray）をワークシートに貼っていますが、そのCalArray配列は１７６行目でInteger型として宣言をしています。つまり、日付数値が入っていない部分には「ゼロが入っている」ことになります。
カレンダーの日付以外のセルにゼロが入っているのはカッコ悪いので、２０４行目でゼロ表示無しにしています。

２０５行目は既に説明してしまいましたが、カレンダーの年月表示セルには「年月日データ」が入っています。表示としては年月までにしたいため、そのような表示形式にしています。

２０７～２１２行目は、曜日行を「中央揃え」「文字サイズ11」「太文字化」「行高さ19ポイント」にしています。
２１４～２２１行目は、日付行を「中央揃え」「文字サイズ16」「太文字化」「行高さ21ポイント」にしています。
２２３～２３０行目は、コメント行を「標準揃え」「文字サイズ10」「普通文字」「行高さ73ポイント」にしています。
２３２～２３６行目は、列幅を「19ポイント」にしています。

日付行の下のセルにプログラムで予定等を入力する場合、その文字数によっては表示しきれない場合も生じるかもしれません。その場合には細かい調整（プログラムでセルの大きさを調整するか、枠の大きさに合わせて文字を調整するか）が必要になると思います。

７．最後に

予約を記入できるカレンダーの様な形で本件を紹介しましたが、本当は「予定表のひな型」を作りたかった訳では無く、最終的にはデータベースからデータを呼び出し、予定の埋まった月間予定表として表示することを目指していきます。
（日付の下の空きセルに、CSV等から読み込んだ予定データを貼り付けるつもりです）

今回、スクロールバーのScrollイベント・Changeイベントの動きを紹介しましたが、フォームのコントロールには似たような「Slider」というコントロールがあります。（標準では表示されておらず、その他の中の「Microsoft Slider Control」にレ点を付けてから作業します）
このスライダーも移動に伴ってScroll・Changeというイベントが発生し、その動作はスクロールバーのイベントと同じみたいです。見かけはスクロールバーとずいぶん違うので、代替として試してみる価値はあるかもしれません。


年月をスクロールバーで選択する予定表ひな型（it-032.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。