Book内で完結するフォーム表示のHelp画面
１．背景
Excelでシステムを作った後工程として、その使い方やFAQ（よくある質問）を取扱説明書にしたり教育したりするのは、プログラムを考える以上に大変な仕事です。システム立ち上げ以降も電話やら呼出しやらで時間を多く取られる事も良くあります。それらをゼロに出来るとは思えませんが、少しでも減らすために「Help画面を作る」のは対策の１つです。少なくとも時間稼ぎをするくらいの効果はあるはずです。
ということで、今回はHelp画面をフォームで表示させる手法について説明します。
２．概要
Excelを使ったシステムがあり、画面（シート）ごとに機能が分かれていると仮定します。不明な点があった場合にはユーザーが「WindowsのヘルプキーであるF1キー」を押すと、図２－１のような「Help選択ダイアログ」が表示され、「アプリのHelp画面」or「WindowsのHelp画面」を選択します。
図２－１
Help選択ダイアログで「アプリのHelp画面」を選択すると、図２－２のようなHelp内容がダイアログ上に現れます。Help内容は、使っている画面内容に合った内容がまず表示され、ボタンによって異なるページを開くことも可能です。
図２－２
また、Helpを表示しているダイアログは、通常のブラウザと同様にマウスでサイズを変更出来ます。
（図２－３は実際にはあり得ない画面ですが、ダイアログをマウスでサイズを変更している事を表したものです。）
図２－３
|
３．プログラムの概要
３－１．Help表示の手法について
今回は、事前にHTML文を作成しておき、それをフォーム上に表示することでHelp画面としています。まず、「ExcelのシステムからHelp画面を表示」する手段として、どのようなものがあるかを整理します。
ExcelのVBAを使って起動できる外部アプリは多々あり、Helpとして使えそうなものだけでも、IE（Internet Explorer）、MS-Word、PDF（Acrobat Reader他）などが考えられます。
しかし、そのHelpファイルを開けるアプリがPCにインストールされていなくてはならず、今回はExcelのみで完結できるという考え方でフォームを使う事としました。環境によっては外部アプリを使用した方が簡単な場合もありますので、「Excelで完結する」ことを前提にしない方が良いと思います。
次に、フォームでHelp表示するとして、どのコントロールを使うかを考えます。文章を表示できそうなコントロールを図３－１で比較してみます。
| コントロール | 使用法 | メリット・デメリット | |
|---|---|---|---|
| イ | Label | 設計時に直接記入 | 長い文章を全て見せるには､ﾌｫｰﾑｻｲｽﾞが大きくなる |
| ロ | ﾏｸﾛで記入 | ｽｸﾛｰﾙﾊﾞｰ等との組合せで頁送りが可 | |
| ハ | TextBox | ﾏｸﾛで記入 | TextBoxのｽｸﾛｰﾙﾊﾞｰ表示可 |
| 二 | WebBrowser | HTMLﾃﾞｰﾀを指定 | ｼﾞｬﾝﾌﾟ可。文字ｻｲｽﾞ大小可。彩色可。画像挿入可 |
図３－１の通り「外部アプリと同等のHelp」を狙うのであれば、HTML機能を使えるWebBrowserが良いと考えました。
ではHTMLデータをBook内に保管する方法ですが、以下のようなものがあると思います。
| 保管場所 | サイズ制限 | メリット・デメリット | |
|---|---|---|---|
| ① | セル内にHTMLを記述 | ～32,767文字 | 縦長のHTMLの全容を掴み難い 改行はCtrl+Enter要 |
| ② | String型定数でﾏｸﾛ中に記述 | ～2GB(約10億文字?) | ﾏｸﾛ内では"(ﾀﾞﾌﾞﾙｸｫｰﾃｰｼｮﾝ) の扱いが異なる |
| ③ | ﾜｰｸｼｰﾄ上のﾃｷｽﾄﾎﾞｯｸｽ内に記述 | 不明(30万文字以上) | ﾃｷｽﾄﾎﾞｯｸｽ内は､Enterｷｰが効く 但しﾀｲﾌﾟﾐｽ発見し難い |
| ④ | ﾜｰｸｼｰﾄ上にﾃｷｽﾄ埋込ｵﾌﾞｼﾞｪｸﾄとして貼付 | 60KB(ﾒﾓ帳の制限) | ﾄﾗｲしたが､直接ﾃｷｽﾄを 取り出せそうに無い |
別のエディタでHTMLデータを作り、それを貼り付けるのであれば、①でも③でも同じと思います。但し②は、そのまま貼り付けると「"（ダブルクォーテーション）」の意味が変わってしまいますので、修正が発生します。
今回は、HTMLデータを貼り付けた後でも修正が楽な③を採用しました。もちろん状況によっては①③にするのも有りと思います。
３－２．今回システムの概要
事前にHelpボタンである「F1キー」にマクロを登録しておき、ユーザーが押すことで分岐のダイアログが出るようにしています。また入力画面ではないワークシート（Sheet1）上にテキストボックスを置き、複数のHTML文書を保存しておきます。ユーザーが「F1キー」を押し「アプリ側のHelp」に分岐すると、現在開いているシート名を調べ、適切なHTML文書をフォーム上のWebBrowserコントロールに書き込み表示させます。（図３－１）
図３－３
一方「標準Help」を選択した際には、Excelの標準Helpを表示します。
またExcelのフォームのサイズは、標準ではユーザー側からは変更出来ませんので、Windows APIを使って変更可能にしています。
４．ワークシート上のHTMLデータ
システム入力に使用していないワークシート（ここではSheet1）上に図形のテキストボックスを置き、そこに「Help内容」を「HTML言語」で記入します（図４－１）。または、他のエディタで作ったHTMLデータをテキストボックスに貼り付ける方法でもOKです。
図４－１
テキストボックス内に記載するHelp内容は「<body>から</body>の間のみ」です。
HTML言語の文法については割愛しますが、ページ内リンクを含めた他ページへのリンク（ a タグ）、画像の貼付け（img タグ）、Styleタグによる装飾も可能です。
尚、PngやJpg等の画像ファイルをアドレス指定できない場合は、「画像をBase64でテキストデータにエンコード（変換）し、src属性にアドレスの代わりに指定」する方法もあります。（図４－１の左テキストボックスの中央付近）
画像のBase64変換は、様々なサイトで出来ますので捜してみて下さい。
作られたばかりのテキストボックスには「TextBox 1」のような名前ついています。（右上の名前ボックス欄に表示される名前は「テキスト ボックス１」の様なカタカナになります。）
この自動的に付けられた名前を、自分が分かり易い名前に変更しておくと管理が楽になります。
今回は図４－２の様に、目的のテキストボックスをアクティブにした状態で左上の「名前ボックス」をクリックすることで、管理し易い名前に変更します。すると、テキストボックスのNameプロパティが変更され、呼び出す時も「Sheet1.Shapes(新たに付けた名前)」で呼び出せます。
図４－２
システム入力画面が仮に２つ（Sheeet2とSheet3）あり、それぞれにHelp画面を作るとすると、２つのテキストボックスを設けてHTMLデータを記入します。（今回は、１つ目のシステムHelpの名前をhtml-01、２つ目をhtml-02としました。）
５．フォームへのコントロールの配置
フォーム（UserForm1）上には、CommandButton２つとWebBrowser１つを図５－１のように配置します。
図５－１
WebBrowserコントロールは「初期のツールボックスには表示されていません」ので、ツールボックス上で右クリックし「コントロールの追加リスト」の中から「Microsoft Web Browser」にチェックを入れて「
」印を追加します。２つのCommandButtonの表面の文字（Caption）はマクロ側で変更しますので、そのままでもOKです。
また、CommandButtonのすぐ下にWebBrowserを配置します。WebBrowserの幅・高さは自動的に調整しています。
６．フォームコード
６－１．フォーム起動の準備
フォームの起動中に実行されるのが図６－１になります。最初にInitializeイベント、次にActivateイベントが発生します。- '========== ⇩① フォームの初期化（Initializeイベント） ===================
- Private Sub UserForm_Initialize()
- Me.WebBrowser1.Navigate ""
- Me.WebBrowser1.Left = 0
- Me.CommandButton1.Caption = "Help①"
- Me.CommandButton2.Caption = "Help②"
- End Sub
- '========== ⇩② フォームの初期化（Activateイベント） ========
- Private Sub UserForm_Activate()
- Call FormResize '// フォームのリサイズを可能にする
- Call UserForm_Resize '// WebBrowserのｻｲｽﾞを調整
- Do While WebBrowser1.Busy = True Or WebBrowser1.ReadyState <> 4 '//WebBrowserの準備待ち
- DoEvents
- Loop
- If ActiveSheet.Name = "Sheet2" Then '// 開いているｼｰﾄでHelpを分ける
- Call WebStart("html-01")
- Else
- Call WebStart("html-02")
- End If
- End Sub
Initializeイベントでは、フォームの普遍的な設定をします。
３行目ではWebBrowserのNavigateメソッドで「""（長さゼロの文字列）」を渡しています。本来の使い方であれば、このNavigateメソッドに表示するページを指定するのですが、今回は表示内容を直接プロパティに書き込みますので、このようにWebBrowserコントロールに空文字列を読み込ませます。
尚、今回の方法では、フォーム起動時に一瞬「このページを表示できません」とエラー画面が出ることになります。これを嫌って「白画面」にしようと「WebBrowser1.Navigate "about:blank"」を使うと、「ページ内リンクが不能」になってしまいますので注意下さい。
原因はページの情報として「blank」という文字列が入ってしまうためのようです。
４行目では、WebBrowserコントロールの左右方向の位置をフォームの左端に密着させます。このWebBrowserの位置は、最終的には図６－８の「UserForm_Resizeイベント」で「ボタンを除いたフォーム全体をWebBrowserが占める」形に整えられます。
尚、WebBrowserコントロールのサイズを決める機能が２つ（Initialize と UserForm_Resize）に分かれたのは、今回フォームのサイズをユーザーが変更できるようにした為です。
Initialize側では「WebBrowserの位置（左上のポイント位置）」を決め、UserForm_Resize側では「WebBrowserの幅と高さ」を決めています。
６～７行目は、ボタンの表面文字の変更をしています。
１１～２４行目はActivateイベントの処理です。
まず１２行目は、標準モジュールの「FormResizeプロシージャ」を呼び出し、ユーザーがフォームのサイズを変更できる処置をします。詳細は図７－４で説明します。
１３行目は「UserForm_Resizeイベントプロシージャ」を手動で呼び出しています。通常「UserForm_Resize」は「フォームのサイズを変更した」ら発生するイベントですが、手動で呼び出すことによりその中に記載してあるコードを実行することが出来ます。
今回「UserForm_Resize」の中に記載したコード内容は、図６－８の如く「WebBrowserコントロールをフォーム一杯に表示する」ことになります。
１５～１７行目は「WebBrowserの準備待ちをしているコードです。１５行目のDo～Loopの条件には「WebBrowser1.Busy = True」と「WebBrowser1.ReadyState <> 4」の２つが使われています。
まず「WebBrowser1.Busy」は、図６－２の内容を示しています。
| 値 | 説明 |
|---|---|
| True | 新しいドキュメントを読み込んでいる |
| False | それ以外 |
また「WebBrowser1.ReadyState」は、図６－３の内容を示しています。
| 定数 | 値 | 説明 |
|---|---|---|
| READYSTATE_UNINITIALIZED | 0 | デフォルト値。未完了状態 |
| READYSTATE_LOADING | 1 | ページのロード中状態 |
| READYSTATE_LOADED | 2 | ページのロード完了状態。ただし操作不可能状態 |
| READYSTATE_INTERACTIVE | 3 | ページの操作可能状態 |
| READYSTATE_COMPLETE | 4 | ページの全データ読み込み完了状態 |
この２つを「Or」で繋いでいますので、どちらかがTrueの時は式全体がTrueになるためDo～Loopが続きます。つまり「WebBrowser1.Busy = False」「WebBrowser1.ReadyState = 4」と両方とも「一番下の状態になるまでDo～Loopが続く」事になります。
また１６行目のDoEventsは、制御をO/S側に渡しているコードで、Excelが固まってしまうのを防止しています。
今回は３行目でページを与えていないので、「Busy」と「ReadyState」の状態がどうなるかを調べてみました。
すると、新しいドキュメントを読ませているわけでは無いのでBusy は最初から「False」の状態なのですが、ReadyStateの方はデフォルト値から完了状態（値４）へ順に移行してるようでした。
なお、この処理法は、IE（Internet Explorer）等のブラウザからページ内容を取得する時によく使われる「ページ読み取り待ち」のコードで、今回もこの処置をしないで実行すると「ページ書込み時（図６－４）にエラー」が発生します。
つぎに１９行目で現在開いているシートを判断し、２０・２２行目で「WebStartプロシージャ」を呼び出します。
「WebStart（図６－４）」は「HTML文を読み込み、WebBrowserに書き込む」役目を持っていますので、「どの内容を読み込むか」を引数として受け渡しをします。
例えば、開いているシートがSheet2であるなら「システムその①を使っている」と判断し、それに対応したHelp内容は「html-01」であるため、２０行目では引数に「html-01」を指定して「WebStart」を呼び出しているのです。
今回のサンプルファイルでは、Sheet2とSheet3の２画面しかシステムでは使っていない事にしましたので、「システムその②」はElseの「html-02」になります。
６－２．HTMLデータを読み込み、WebBrowserに書き込み
図６－１の２０・２２行目から呼び出されるのが、図６－４のWebStartプロシージャです。引数として、ワークシート上に貼り付けたテキストボックスの名前を受取ります。
- '========== ⇩③ HTML文の読み込みとWebBrowserへの書込み ================
- Private Sub WebStart(str As String)
- Dim HtmlStr As String
- HtmlStr = Sheet1.Shapes(str).TextEffect.Text
- WebBrowser1.Document.body.InnerHtml = HtmlStr
- WebBrowser1.Document.parentWindow.scrollTo 0, 0
- End Sub
２９行目はテキストボックスからのHTML文の読み取りです。
テキストボックスの名前は引数strですので、テキストボックス自体へのアクセスは「Sheet1.Shapes(str)」となります。
そのテキストボックスのTextEffect（図形のテキストの書式設定プロパティ）のText（テキスト内容）で、記載してある内容を取得することが出来ます。
３０行目は、２９行目で取得したHTMLコードをWebBrowserに代入する部分です。
WebBrowserに表示されるHTMLコード（Bodyタグに挟まれたHTMLコード。但しBodyタグは含まず）は「WebBrowser1.Document.body.InnerHtml」に収まっています。
なお「InnerHtml」と似たプロパティとして「OuterHtml」が存在します。調べると「Bodyタグを含むHTMLコード」と説明されているのですが、「Bodyタグを含めたHTMLコードをOuterHtmlに代入」しようとすると、図６－５の様に「実行時エラー600」が発生してしまいます。
図６－５
３１行目は、Help画面を先頭に持ってくるコードです。Help画面がダイアログよりも大きな場合には、図６－６のように縦・横にスクロールバーが現れます。
図６－６
そのスクロールバーをズラした状態でHelp画面を変更（ダイアログの上のボタンを押す）すると、そのままズレた状態で新たなHelp画面が表示されてしまいます。
それを３１行目の「WebBrowser1.Document.parentWindow.scrollTo」で「スクロールの位置を設定」します。設定値は「水平軸上のピクセル値 , 垂直軸上のピクセル値」であるため、「0,0」とすることで「先頭が表示」されます。
ちなみに、スクロールバーが出ない画面の場合には、画面は当然ズレません。
６－３．ダイアログ上のボタン操作イベント
ダイアログの上に配置したCommandButtonを押した時のイベントが、図６－７になります。- '========== ⇩④ ページ移動ボタンでの動作 ================
- Private Sub CommandButton1_Click() '←Help-01へ移動
- Call WebStart("html-01")
- End Sub
- Private Sub CommandButton2_Click() '←Help-02へ移動
- Call WebStart("html-02")
- End Sub
HTML読み込み・書込みのWebStartプロシージャ（図６－４）は、引数として「HTMLコードを記したテキストボックス名」を受け取って処理します。図６－７の各ボタンも、そのテキストボックス名を引数にしてWebStartプロシージャを呼び出します。
ボタンの内「Help①」となっているCommandButton１は、テキストボックス「html-01」の内容を表示するものですので、html-01を引数に渡しています。一方「Help②」は「html-02」を引数に渡します。
６－４．フォームサイズの変更イベント
ユーザーがダイアログの枠をドラッグしサイズを変更した時に、図６－８のResizeイベントが発生します。なお、このイベントはマウスを離した時ではなく、サイズを変更している最中ずっと発生しています。- '========== ⇩⑤ フォームサイズ変更イベント ================
- Private Sub UserForm_Resize()
- Me.WebBrowser1.Width = Me.InsideWidth
- Me.WebBrowser1.Height = Me.InsideHeight - Me.WebBrowser1.Top
- End Sub
イベントコードの説明の前に、フォームの幅と高さについて説明します。（図６－９）
図６－９
フォームに関わらず、コントロール等は最も外側のサイズを「Width」「Height」プロパティとして持っています。但しExcelのグラフ及びフォームには「InsideWidth」「InsideHeight」プロパティもあり、フォームに於いては「配置したコントロールが表示される範囲」を示しています。
図６－９を見て分かる通り、枠の太さは「(Width － InsideWidth )/2」という事になりますが、この値はＰＣの環境で異なるようです。同様に「Height － InsideHeight 」は「枠太さ＋タイトル高さ」ですが、これも環境で値が変わります。
４４行目は、WebBrowserの幅をフォームの表示幅（InsideWidth）と同一にしています。
尚、Initializeイベント（図６－１）の４行目で「WebBrowser1.Left = 0」としている事で、フォームとズレること無く「フォームの内側一杯にWebBrowserを表示」する事が出来るのです。
また４５行目はWebBrowserの高さを、上部の２つのCommandButtonの下（WebBrowser配置時の上下位置）から、フォームの一番下まで一杯に表示させています。
ここで、Resizeイベントはフォームのサイズを変更している間ずっと発生していますので、ユーザーがフォームサイズを変更するに伴って、フォーム内のWebBrowserコントロールも追いついてサイズ変更されるため、フォームとWebBrowserコントロールの分離感無く動作することになります。
７．標準モジュールのコード
７－１．定数宣言、API参照宣言
標準モジュールの先頭で宣言するのが図７－１です。今回は全て「ユーザーによるフォーム変形のための宣言」です。- '========== ⇩⑥ 定数・参照宣言（Module1） ================
- '// Win32API用定数
- Private Const GWL_STYLE As Long = -16 '// ウィンドウスタイル
'Private Const WS_MAXIMIZEBOX As Long = &H10000'//最大化ボタンを持つウィンドウ'Private Const WS_MINIMIZEBOX As Long = &H20000'//最小化ボタンを持つウィンドウ- Private Const WS_THICKFRAME As Long = &H40000 '//サイズ変更境界を持つウィンドウ
- '// Win32API参照宣言
- Private Declare Function GetActiveWindow Lib "user32" () As Long
- Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal Hwnd As Long, ByVal nIndex As Long) As Long
- Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal Hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
- Private Declare Function DrawMenuBar Lib "user32" (ByVal Hwnd As Long) As Long
今回、フォームのサイズをユーザーが変更できるようにしています。Excelの標準状態ではサイズ変更は不可ですので、Win32APIの中から以下の４つの機能を使って実現させます。
アクティブウィンドウを取得（５４行目）
ウィンドウに関しての情報を取得（５５行目）
ウィンドウに関しての情報を設定（５６行目）
ウィンドウのメニューバー外枠を再描画（５７行目）
５５・５６行目の「GetWindowLong」・「SetWindowLong」で取得・設定する「ウィンドウ情報」の中で、今回必要となるのは「ウィンドウのスタイル」です。ですので第二引数には図７－２の内、「GWL_STYLE（値：-16）」を使いますので、４９行目で定数として設定しています。
| 定数 | 値 | 取得される属性 |
|---|---|---|
| GWL_WNDPROC | -4 | ウィンドウプロシージャのアドレス （直接ｳｨﾝﾄﾞｳﾌﾟﾛｼｰｼﾞｬを呼び出すには CallWindowProc関数を使う） |
| GWL_HINSTANCE | -6 | アプリケーションのインスタンスハンドル |
| GWL_HWNDPARENT | -8 | 親ウィンドウのハンドル |
| GWL_STYLE | -16 | ウィンドウスタイル |
| GWL_EXSTYLE | -20 | 拡張ウィンドウスタイル |
| GWL_USERDATA | -21 | ウィンドウに関連付けられたアプリケーション定義の32ビット値 |
| GWL_ID | -12 | ウィンドウ ID |
なお、他のExcelサイトでは４９行目を「･･･= (-16)」とカッコで囲むことが多いのですが、この理由は「user32.dllの中では(-16)と定義しているから」としています。しかし、他言語サイトではカッコ有りのサンプルコードは見当たらず、またExcel中ではカッコ有無で動作に違いはありません。
user32.dll定義については調べ切れませんでしたが、サンプルファイルでは「カッコ無し」にしました。
また「ウィンドウのスタイル」には、図７－３の様に多くのスタイル項目があり、今回必要なのは「サイズ変更境界を持つウィンドウ」ですのでNo.15の値：0x00040000（＝&H40000）を５２行目で定数設定しています。
| ウィンドウスタイル | 値 | 意味 | |
|---|---|---|---|
| 1 | WS_OVERLAPPED, WS_TILED | 0x00000000 | オーバーラップウィンドウを作成します。 オーバーラップウィンドウはタイトルと枠を持ちます。 |
| 2 | WS_POPUP | 0x80000000 | ポップアップウィンドウを作成します。 このスタイルは、WS_CHILD スタイルと一緒には使えません。 |
| 3 | WS_CHILD, WS_CHILDWINDOW | 0x40000000 | 子ウィンドウを作成します。 このスタイルは、WS_POPUP スタイルと一緒には使えません。 |
| 4 | WS_MINIMIZE, WS_ICONIC | 0x20000000 | ウィンドウを最小化の状態で作成します。 |
| 5 | WS_VISIBLE | 0x10000000 | 可視状態のウィンドウを作成します。 |
| 6 | WS_DISABLED | 0x08000000 | 無効 (使用不能) なウィンドウを作成します。 無効なウィンドウは、有効にするまで、 ユーザーからの入力を受け取りません。 |
| 7 | WS_CLIPSIBLINGS | 0x04000000 | 兄弟関係にある子ウィンドウをクリップします。 |
| 8 | WS_CLIPCHILDREN | 0x02000000 | 親ウィンドウ内部を描画するときに、 子ウィンドウが占める領域を除外します。 このスタイルは、親ウィンドウを作成するときに使います。 |
| 9 | WS_CAPTION | 0x00C00000 | タイトルバーを持つウィンドウを作成します。 （WS_BORDER | WS_DLGFRAME） |
| 10 | WS_BORDER | 0x00800000 | 境界線を持つウィンドウを作成します。 |
| 11 | WS_DLGFRAME | 0x00400000 | ダイアログボックスで一般的に使われるスタイルの 境界を持つウィンドウを作成します。 |
| 12 | WS_VSCROLL | 0x00200000 | 垂直スクロールバーを持つウィンドウを作成します。 |
| 13 | WS_HSCROLL | 0x00100000 | 水平スクロールバーを持つウィンドウを作成します。 |
| 14 | WS_SYSMENU | 0x00080000 | タイトルバー上にウィンドウメニューボックスを持つ ウィンドウを作成します。 |
| 15 | WS_THICKFRAME, WS_SIZEBOX | 0x00040000 | サイズ変更境界を持つウィンドウを作成します。 |
| 16 | WS_GROUP | 0x00020000 | コントロールグループの最初のコントロールを指定します。 このコントロールから、次に WS_GROUP スタイルのコントロールがくる までに定義されたコントロールが、コントロールグループになります。 |
| 17 | WS_TABSTOP | 0x00010000 | ユーザーが［Tab］キーを押すと入力フォーカスを受け取る コントロールを指定します。［Tab］キーを押すと、WS_TABSTOP スタイルを持つ次のコントロールに、入力フォーカスが移動します。 |
| 18 | WS_MINIMIZEBOX | 0x00020000 | 最小化ボタンを持つウィンドウを作成します。 WS_SYSMENU スタイルも指定する必要があります。 拡張スタイルに WS_EX_CONTEXTHELP を指定することはできません。 |
| 19 | WS_MAXIMIZEBOX | 0x00010000 | 最大化ボタンを持つウィンドウを作成します。 WS_SYSMENU スタイルも指定する必要があります。 拡張スタイルに WS_EX_CONTEXTHELP を指定することはできません。 |
| 20 | WS_OVERLAPPED WINDOW | 0x00CF0000 | WS_OVERLAPPED | WS_CAPTION | WS_SYSMENU | WS_THICKFRAME | WS_MINIMIZEBOX | WS_MAXIMIZEBOX に等しい。 |
| 21 | WS_POPUP WINDOW | 0x80880000 | WS_POPUP | WS_BORDER | WS_SYSMENU に等しい。 |
なお、ウィンドウの最大化・最小化も利用する場合は、No.18、No.19の値を使用しますので、コメントアウトしてある図７－１の５０・５１行目を生かし、且つ図７－４の１４８行目を生かして下さい（１４７行目は不要になりますので、代わりにコメントアウトして下さい）。
７－２．フォームのリサイズ可能手続き
フォームを起動する際に、図６－１の１２行目より呼び出されるのが図７－４のFormResizeプロシージャです。ここではフォームのリサイズを可能にする手続きをします。- '========== ⇩⑦ フォームのリサイズ可能手続き（Module1） =============
- Public Sub FormResize()
- Dim Hwnd As Long '// ウィンドウハンドル
- Dim Style As Long '// ウィンドウスタイル
- Hwnd = GetActiveWindow() '// ウィンドウハンドルの取得
- Style = GetWindowLong(Hwnd, GWL_STYLE) '// ウィンドウスタイルの取得
- Style = Style Or WS_THICKFRAME '// ウィンドウのスタイルにウィンドウサイズ可変を追加
'style = style Or WS_THICKFRAME Or WS_MINIMIZEBOX Or WS_MAXIMIZEBOX- '↑ ＋最小ボタン＋最大ボタンも追加の時
- Call SetWindowLong(Hwnd, GWL_STYLE, Style) '// ウィンドウのスタイルを再セットする
- Call DrawMenuBar(Hwnd) '//メニューバー外枠を再描画する
- End Sub
６３行目では「GetActiveWindow」を実行し、現在Activeになっているウィンドウの番号を取得します。このプロシージャは、フォームのActivateイベントの中から呼ばれていますので、フォーム自身がActiveなウィンドウとなります。
６４行目では、そのフォームの情報を取得します。情報の種類は「GWL_STYLE」で指定していますので、「ウィンドウのスタイル」を得ることになり、そのデータは変数Styleに代入されます。
対象となっているウィンドウ内に「どのスタイルが組み込まれているか」は、変数Styleの値を計算すれば分かる事になっています。値は、図７－３の表の中で「組み込まれている項目の値を足したもの」だからです。但し、図７－３以外にもコントロール固有のスタイル値も存在するため、人力での計算は大変です。
そのため現状の分析は止めて、自分の「必要な項目を追加」するのが６６行目になります。
６６行目は「足し算」ではなく「Or」を使ってつないでいます。これについて、図７－３のウィンドウスタイルを簡易的にA～Eで置き換えた図７－５で説明します。
図７－５
各スタイルの値は左上の枠内に記載してある通り、項目ごとに１桁ずつズレた値となっています。なお、分かり易いように２進法で表示してあります。
一番左側の①はＡ・Ｂ・Ｄのスタイルが含まれた値（オリジナル値とします）に相当し、この計算はＡ・Ｂ・Ｄの値を足し算すれば求まります。
次に、そのオリジナルにスタイルＥを追加することを考えます。（②）
オリジナルにはスタイルＥが含まれていないので、普通に足し算すればＡ＋Ｂ＋Ｄ＋Ｅの値は求まります。
しかし、もしオリジナルにスタイルＥが既に含まれていたとしたら、どうなるでしょう（③）
普通に足し算をすると、桁が繰り上がってしまい思っていた値とは異なる値になります。③では「Ａ＋Ｂ＋Ｄ＋Ｅ」のはずが「Ａ＋Ｂ＋Ｃ」になってしまうのです。これでは困ります。
ということで、足し算ではなく「Or を使った計算」の方法を図７－６で確認してみます。
図７－６
「Or の計算」は、If文で使用するOrと同じです。「If Ａ Or Ｂ」とあった場合、「ＡかＢのどちらかがTrueだったらTrue」ですね。２進数での計算の場合「１がTrue 、０がFalse」ですので、その計算結果は図７－６の一番左の様な結果になります。
この計算法だと、先程の「スタイルＥが含まれている値に、更にスタイルＥを追加」しても、 図７－６の③のように計算結果が崩れることは無くなります。ちなみに、元の値にスタイルＥが含まれていなくても、②のように大丈夫です。
このように「仕様有無を１つの値で表す場合、仕様追加にはOr」を使う事で正しい結果が得られます。
ちなみに仕様削除する際は「Orで追加後、引き算」が必要です。これは「値に削除する項目値が入っていない」場合に、間違った値になる事を防ぐためです。
６７行目はコメントアウトしてありますが、フォームのサイズ変更のみで無く「最大化」「最小化」も可能にしたい場合には、「WS_MINIMIZEBOX 」と「WS_MAXIMIZEBOX 」も「Or」でつないでスタイルを追加してください。
尚、WS_MINIMIZEBOX等は値を事前に設定しておかなければ使えませんので、図７－１の５０～５１行目を生かしてから使用して下さい。
６９行目では、サイズ可変のスタイルを追加した変数Styleを使って、ウィンドウ（フォーム）のスタイルを設定します。
また７０行目ではメニューバー外枠を再描画していますが、フォーム右上のマークが変わらない「サイズ可変」のみならず、マークの変わる「最大化・最小化」を追加した時でも、見た目の変化は確認できませんでした。
理論的には必要と思いますので今回は「DrawMenuBar」を呼び出していますが、他サイトのサンプルコードでは無視しているところも多いようです。
７－３．ヘルプの起動
今回のシステムの場合、ユーザーが「F1キー」を押した時に呼び出されるプロシージャが図７－７です。この「Help_Changeプロシージャ」が呼び出されるのは、Workbook_Openイベント（図８－１）で、「F1キーが押された場合にHelp_Changeプロシージャを呼び出す」ように登録されているからです。
- '========== ⇩⑧ ヘルプの起動（Module1） ================
- Public Sub Help_Change()
- Dim Ans As Integer
- Ans = MsgBox("アプリのHelpを開きますか（はい）" & vbCrLf & _
- "標準のHelpを開きますか（いいえ）" & vbCrLf & _
- "キャンセルしますか（キャンセル）", 3)
- Select Case Ans
- Case 6
- UserForm1.Show
- Case 7
- Application.Help
- Case 2
- End Select
- End Sub
７５～７７行目は１つの繋がったコードで、MsgBoxを呼び出しています。
MsgBox関数の構文は「MsgBox(prompt[, buttons] [, title] [, helpfile, context])」となっています。第一引数（メッセージ内容）のみを設定すると第二引数のボタンの種類は既定値の「０」となりますので、[OK]ボタンのみが表示されます。
反対に、第二引数の「buttons」に以下の値を設定することで様々なボタン表示が可能です。
尚、第二引数にはボタンの種類以外にも、アイコン種類や標準ボタンの設定の値も準備されています。
| 定数 | 値 | 内容 |
|---|---|---|
| vbOKOnly | 0 | [OK] ボタンのみを表示（既定値） |
| vbOKCancel | 1 | [OK] ボタンと [キャンセル] ボタンを表示 |
| vbAbortRetryIgnore | 2 | [中止]、[再試行]、および [無視] の 3 つのボタンを表示 |
| vbYesNoCancel | 3 | [はい]、[いいえ]、および [キャンセル] の 3 つのボタンを表示 |
| vbYesNo | 4 | [はい] ボタンと [いいえ] ボタンを表示 |
| vbRetryCancel | 5 | [再試行] ボタンと [キャンセル] ボタンを表示 |
今回、ユーザーがF1ボタンを押した理由を以下の様に考えました。
①：ユーザーがアプリとしてのHelpを表示したいと考えてF1を押した
②：ExcelとしてのHelpを表示したいと考えてF1を押した
③：間違えて押してしまった
となると３種類の分岐が必要となり、図７－８の値で言うと「２」か「３」となりますが、この中から選ぶのであればボタンの文字から「３」しか無いと考え、７７行目の第二引数は「３」にしました。
尚、フォームを使ってダイアログを作り、もっとカッコ良く分岐をさせるのも良いと思います。
そのMsgBoxでユーザーが操作（ボタンを押す）した結果は、MsgBox関数の戻り値として返ってきます。その戻り値は図７－９となります。
| 定数 | 値 | 内容 |
|---|---|---|
| vbOK | 1 | [OK] |
| vbCancel | 2 | [キャンセル] |
| vbAbort | 3 | [中止] |
| vbRetry | 4 | [再試行] |
| vbIgnore | 5 | [無視] |
| vbYes | 6 | [はい] |
| vbNo | 7 | [いいえ] |
MsgBox関数の第二引数に「３」を指示しましたので、ボタンの種類としては「はい、いいえ、キャンセル」になりますので、戻り値としては「６、７、２」のどれかになります。
この戻り値は７５行目で変数Ansに代入され、MsgBoxとしては閉じられます。
その戻り値が代入された変数Ansを７８～８５行目のSelect Case文で分岐します。
８０行目は「６＝はい」でシステムHelpを起動させるため、UserForm1を立ち上げます。
８２行目は「７＝いいえ」でExcelのHelpを起動させるため、「Application.Help」でApplication ＝ExcelのHelpを呼び出します。
「２＝キャンセル」の時は何もしない（MsgBoxを閉じただけ）ので、８４行目は空欄です。なお「Case 2」のコード自体を削除してしまってもOKです。
８．ワークブックモジュール
本Book（＝アプリ）を開いた時にF1キーにマクロを割り当て、閉じた時に解除するのが図８－１になります。- '========== ⇩⑨ F1キーのマクロ割り当て・解除（Workbook） ================
- Private Sub Workbook_Open()
- Application.OnKey "{F1}", "Help_Change"
- End Sub
- Private Sub Workbook_BeforeClose(Cancel As Boolean)
- Application.OnKey "{F1}"
- End Sub
マクロ割り当ては「Workbook_Open」イベント内で行います。
Application.OnKeyメソッドの第一引数に「押すキーを示す文字列」を指定します。キー毎のコードは図８－２のようになっています。
なお、PCによっては存在しないキーも含まれています。
|
|
|
また今回は使っていませんが、図８－２のキーと一緒に「Shift・Ctrl・Altキーを押す時」には、図８－３の記号を先頭に追加します。
| キー | コード |
|---|---|
| Shift | + (正符号) |
| Ctrl | ^ (カレット) |
| Alt | % (パーセント記号) |
今回はHelpを表す「F1キー」ですので「{F1}」となり、８９行目ではこれを文字列の「"（ダブルクォーテーション）」で囲み、第一引数としています。
第二引数には、図７－７の「Help_Change」プロシージャを指定します。こちらも文字列として渡しますので「"（ダブルクォーテーション）」で囲みます。尚、呼び出すプロシージャに引数が必要となる場合の設定方法については「再計算されたか否かのチェック法」を参照下さい。
９４行目ではアプリ終了（＝Bookを閉じる）のときに、マクロ割り当てをしたF1キーを元の機能に戻すために「Application.OnKey "{F1}"」と設定します。
この最後の処置をしない（処理失敗も含めて）と、Excelで他の作業をしている際に、キー操作が思い通りにならなくなりますのでご注意下さい。
９．最後に
今回Excelを作っている途中で、図６－４の３０行目を実行する際に、図９－１のエラーが極たまに発生していました。
図９－１
もしかしたら、HTMLデータを代入する先を「Document.body.InnerHtml」では無く、当初「Document.ActiveElement.InnerHtml」に代入していたからかもしれませんが、最後まで発生する条件等が把握できませんでした。これを使われる皆さんにもしかしたらご迷惑をお掛けするかもしれません。先に謝っておきます。
１つだけ分かっているのは「HTMLデータ（Bodyタグの内側）を代入する前に入っている内容が、Headタグを含む内容のHTMLデータ」ということです。どういうタイミングでInnerHtmlの中にHeadタグを含むデータが入ってしまうのかは分かりません。また、ダイアログを初めてLoadした時に発生している様な感じでした。
今回は、空文字をNavigateしてHTMLデータを直接代入するような手法が祟ってエラーが出たのかもしれませんが、HTMLとExcelをつなぐWebBrowserコントロールをうまく使うことで、使い勝手が良くなる気がします。これからも色々探っていくつもりです。
Book内で完結するフォーム表示のHelp画面（it-034.xlsm）|
セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。 |