2020/09/24

両方向から換算可能なシート

• １．背景
• ２．概要
• 　２－１．ワークシート関数編
• 　２－２．マクロ編
• ３．ワークシート関数での両方向換算
• 　３－１．設定方法
• 　３－２．数式の保護等
• ４．マクロでの両方向換算
• 　４－１．シートモジュールのコード
• 　４－２．①変数宣言と変数値の設定
• 　４－３．②Changeされたのが対象セル（黄色セル）か否かの判定
• 　４－４．③黄色セルへの入力値種類の判定
• 　４－５．④どのセルに値が入力されているかの計算
• 　４－６．⑤書式の初期化
• 　４－７．⑥入力値で計算を実行し、その計算結果を出力
• ５．最後に

１．背景

例えば電気関係には「電流（A）ｘ電圧（V）＝電力（W）」のような関係式があり、その式を使って電圧と電力から残りの電流を求める場面は良くあります。Excelのワークシート関数でも簡単に計算できるので、値を入れると答えが計算される様なシートを作っている方も多いと思います。
但し上記のように常に「電流を求めたい」時ばかりではなく、「電圧や電力を求めたい」時だってありますので、計算シートだって「電力を求めるシート」「電圧を求めるシート」･･･と分けて作っているのではないでしょうか。
そうしなければいけない理由は、出力用セルには計算式が入っているため、入力用セルと出力用セルをゴッチャにできない為です。

今回は、入力・出力を気にせず「３つのセルの２つに入力すれば、残りの１つのセルに計算結果が表示される」ものを紹介します。
なお、ワークシート関数の方については説明を聞けば「なーんだ、しょうもな」と思われるはずですので、マクロで実現する方法についても併行して紹介いたします。

２．概要

２－１．ワークシート関数編

「ワークシート関数による両方向換算」の画面は、図２－１の様になります。

図２－１

図２－１の一番左側が何も入力されていないシートで、３つの黄色いセル（電流・電力・電圧）の内２つに値を入力することで、残りの１つのセルに計算結果（赤文字）が表示されます。
尚、３つのセル全てに値を入力した際には、関係式が崩れてしまっている可能性がありますので、図２－２の様にセルが赤くなります。

図２－２

２－２．マクロ編

「マクロによる両方向換算」の画面は、図２－３の様になります。

図２－３

マクロによるものは、ワークシート関数によるものと外見はほぼ同じです。また３つのセル全てを入力値にするとワークシート関数の時と同様にセルが赤くなります。
（「全てを入力値にする」のはマクロ内容を知っていれば可能ですが、ワークシート関数編よりは難しくなっています）

３．ワークシート関数での両方向換算

３－１．設定方法

ワークシート上は図３－１のようなレイアウト・配色にしています。
　・入力セル（Ｄ３，Ｄ５，Ｄ７セル）は黄色の背景にし、「ここが入力セル」であることを明確にする。
　・ワークシート関数は「入力セル（黄色セル）の１つ左のセル（Ｃ列）」に記入する。
　・ワークシート関数を記入したセルの文字色は赤色にする。
　・ワークシート関数を入力してあるセル（Ｃ列）は、列幅を極細にする。

図３－１

数式の内容を、例として「Ｃ３セル（電流の項目）」で説明します。（図３－２）

図３－２

見た通り数式はIF文で出来ており、まず条件式は「AND(ISNUMBER(D5),ISNUMBER(D7))」となってます。
Ｄ５セル・Ｄ７セルの値をISNUMBERで調べていますので、数値であればTrueとなります。ANDでつないでいますので「Ｄ５とＤ７の両方が数値」であればIF文としてはTrueになり「REPT(" ",10)&ROUND(D5/D7,2)」を実行します。またFalseであれば「""」で何も表示しません。
True時の「REPT(" ",10)&ROUND(D5/D7,2)」の後方の「D5/D7」は「「電力 ÷ 電圧」の計算で、その結果をROUND(数式,2)で小数点２桁で四捨五入をしています。
「REPT(" ",10)」は、半角スペースを１０個連続させたもので、それを「D5/D7」の計算結果の先頭に「&」で文字列結合させています。
ですので「REPT(" ",10)&ROUND(D5/D7,2)」は「文字列」として出力されます。

出力している文字列は、セル幅（＝Ｃ列の極細の列幅）よりも長くなりますので、もし隣のセル（Ｄ３セル）が空白であれば「はみ出して表示」されますので、あたかも「Ｄ３セルに計算結果が表示」されたように見える、という訳です。

なお「半角スペースを１０個連続」は今回のサンプルファイル用に調整した間隔です。計算結果は「入力セルと同等の位置に表示」されるとカッコイイのですが、計算結果としての値の桁数で表示位置が左右されるため、「ほぼ中央寄り」の無難な位置にしているつもりです。
スペースを増やして「文字列がＤ３セルの位置を超える」と、その隣のＥ３セルには「A（アンペア）」の文字が入っているため、文字列が欠落してしまいますので注意が必要です。

また、もしＤ７セルにゼロを入れる（ゼロで除算）と、計算結果は「#DIV/0!」とエラー表示になりますが、文字列ではないのでＤ３セルにはみ出して表示されることはありません。
なお、もしゼロ除算などのエラーを表示するのであれば、下記のようにIF文全体をISERRORでエラー検出をし、文字列として出力する必要があります。

Ｃ５セル・Ｃ７セルの数式も基本的には同じ構造で、異なるのは計算をする部分だけです。
なお、３つの黄色セル全てに値が入れられてしまうと「計算結果が黄色セル上に表示されない」ことになり、３つの黄色セル上の値は無関係になります。ですので「セル間に関係が無い（＝式が異常）」ことを示すため、３つのセルの色を赤くしています。

赤くするのには、図３－４の通り「条件付き書式」を使用しています。

図３－４

操作的には、Ｄ３・Ｄ５・Ｄ７セルを選択し、「ホーム」タブ→「スタイル」グループ→「条件付き書式」ボタンを押して、図３－４の右図のように数式を記入し、成立した時の書式を設定します。

３－２．数式の保護等

今回のデメリットはＣ列の列幅が極細で目立ちやすいことと、計算式がユーザーに見えてしまうことだと思いますので、その対策として以下の設定をするのが良いと思います。（サンプルファイルは、以下の設定はしていません。）

３－２－１．枠線の非表示

目立っている枠線を非表示にするのが、図３－５の設定です。
「ファイル」→「その他」→「オプション」→「詳細設定」→「次のシートで作業するときの表示設定」項の中にある「枠線を表示する」のレ点を外すと、アクティブシートの枠線が非表示になり列幅が目立たなくなります。

図３－５

３－２－２．シート保護設定

ユーザーが入力できるセル（今回は黄色セル）以外を「入力不可」とするためには、図３－６の様にシート保護を設定します。
まずは①黄色セルをCtrlキーを押しながら複数選択し、②「選択したセルを編集可にする」ために「範囲の編集を許可する」ボタンをクリックし、最後に③シート保護を設定します。
（パスワードを設定しないとユーザー側から解除できてしまいますので、適切なパスワードを設定して下さい。）


図３－６

シート保護の保護内容については、図３－７の様に細かく設定ができます。もしＣ列の数式も見せたくないのであれば「黄色セル以外は選択できない」ようにするため、「ロックされていないセル範囲の選択」のみにレ点が付くようにします。

図３－７

４．マクロでの両方向換算

４－１．シートモジュールのコード

マクロによる換算シートは、サンプルファイルではSheet２に作成しました。マクロはシート上のセル値の書き換えを察知して動かしますので、Sheet２のシートモジュール上に「Worksheet_Change」イベントプロシージャを記載しています。（図４－１）

1. Private Sub Worksheet_Change(ByVal Target As Range)
2. '==========　⇩①　変数宣言と変数値の設定　====================
3. 　Dim Rng(1 To 3) As Range
4. 　Dim sumRng As Range
5. 　Dim RngNo As Long
6. 　Dim AnsColor As Long
7. 　Dim InputColor As Long
8. 　Dim i As Long
9. 　AnsColor = RGB(255, 0, 0)
10. 　InputColor = RGB(0, 0, 0)
12. 　Set Rng(1) = Sheet2.Range("C3")
13. 　Set Rng(2) = Sheet2.Range("C5")
14. 　Set Rng(3) = Sheet2.Range("C7")
15. 　Set sumRng = Union(Rng(1), Rng(2), Rng(3))
17. '==========　⇩②　Changeされたセルの判断　====================
18. 　If Intersect(Target, sumRng) Is Nothing Then Exit Sub
20. '==========　⇩③　入力値種類の判定　====================
21. 　Application.EnableEvents = False
22. 　　For i = 1 To 3
23. 　　　If Rng(i).Font.Color = AnsColor Then Rng(i).Value = ""
24. 　　　If Not IsNumeric(Rng(i).Value) = True Then
25. 　　　　MsgBox Rng(i).Address & "　は､数値ではありません。"
26. 　　　　Application.EnableEvents = True
27. 　　　　Exit Sub
28. 　　　End If
29. 　　Next i
31. '==========　⇩④　どのセルに値が入力されてるか計算　====================
32. 　　RngNo = (Not (Rng(1) = "")) * -1 + (Not (Rng(2) = "")) * -2 + (Not (Rng(3) = "")) * -4
34. '==========　⇩⑤　書式の初期化　====================
35. 　　sumRng.Font.Color = InputColor
36. 　　sumRng.Interior.Color = RGB(255, 255, 0)
38. '==========　⇩⑥　計算実行と結果の出力　====================
39. 　　Select Case RngNo
40. 　　　Case 0, 1, 2, 4　　　　　　　　　 'どのｾﾙにも値が入っていないか､1つにしか値が入っていない時
42. 　　　Case 3　　　　　　　　　　　　　 '1番目、2番目に値が入っている時
43. 　　　　If Rng(1).Value = 0 Then
44. 　　　　　Rng(3).Value = "0除算"
45. 　　　　Else
46. 　　　　　Rng(3).Value = Rng(2).Value / Rng(1).Value
47. 　　　　End If
48. 　　　　Rng(3).Font.Color = AnsColor
49. 　　　Case 5　　　　　　　　　　　　　 '1番目、３番目に値が入っている時
50. 　　　　Rng(2).Value = Rng(1).Value * Rng(3).Value
51. 　　　　Rng(2).Font.Color = AnsColor
52. 　　　Case 6　　　　　　　　　　　　　　 '2番目、３番目に値が入っている時
53. 　　　　If Rng(3).Value = 0 Then
54. 　　　　　Rng(1).Value = "0除算"
55. 　　　　Else
56. 　　　　　Rng(1).Value = Rng(2).Value / Rng(3).Value
57. 　　　　End If
58. 　　　　Rng(1).Font.Color = AnsColor
59. 　　　Case 7　　　　　　　　　　　　　 '全ての３つのセルに値が入っている時
60. 　　　　sumRng.Interior.Color = RGB(255, 0, 0)
61. 　　End Select
62. 　Application.EnableEvents = True
63. End Sub

図４－１

４－２．①変数宣言と変数値の設定

３～８行目は変数宣言、９～１５行目はその変数への値の設定を行っています。
３行目のRng配列は、ユーザーが入力する黄色セルのRangeオブジェクトです。今回３つのセルが対象ですので１～３の要素として宣言しています。
４行目のsumRng変数は、Rng配列の集合体のオブジェクトです。
５行目のRngNoは、３つの黄色セルの内「どのセルに値が入っているか」を計算するための変数です。３２行目以降で使用します。
６行目のAnsColorは、「計算された値」を示すための文字色です。色はLong型で表わされますのでLong型で宣言しています。
７行目のInputColorは、AnsColorとは反対に「入力された値」を示すための文字色です。
８行目の i は、黄色セルの数を表すカウンター変数です。

９行目はAnsColor（計算された値）に色を設定しています。RGB(255, 0, 0)は「赤色」です。
１０行目はInputColor（入力された値）に色を設定しています。RGB(0, 0, 0)は「黒色」です。

１２～１４行目は、Rng配列に黄色セルをオブジェクトとして代入します。
本当は定数としてセル位置を宣言出来れば良いのですが、オブジェクトは定数では宣言できません。他の方法として「"C3"」「"C5"」等のセル位置を示す文字列を定数（Const）として宣言する方法もありますが、今回は「セルへの値代入」や「セルの書式（文字色など）設定」をRangeオブジェクトに対して実行するコードが多かったため、配列変数として宣言をしています。

１５行目はsumRng変数へ、１２～１４行目で設定した各黄色セルを「Unionメソッド」で集合体にした後代入します。
入力セルを集合体にすることで、全ての入力セルの書式をまとめて変更できると共に、１８行目で使っているような「変更されたセルが対象セルか否か」を判断する時にもうまく利用できます。

４－３．②Changeされたのが対象セル（黄色セル）か否かの判定

１８行目は、Worksheet_Changeイベントの引数である「Target（変更されたセル範囲）」と、１５行目で代入された「入力セル（黄色セル）の集合体」をIntersectメソッドで比較しています。
Intersectは「重なっているセル範囲」を返しますが、もし重なっていない時は「Nothing」を返します。ですので重なっているか否かを判断するには「Is Nothing」がTrueかFalseかで判別します。
ですので１８行目は「重なっていない時はプロシージャを抜ける（Exit Sub）」という意味になります。

４－４．③黄色セルへの入力値種類の判定

２２～２９行目はFor～Nextで３つの入力セルの値を確認しています。
一見引数のTargetセルだけを調べれば良さそうですが、複数セルをまとめてChangeされたり、黄色セル以外のセルも含めた複数セルをChangeされたりすると、Targetを分解して１つ１つのセルを調べる必要が出てきます。ですので、１８行目で「Changeされたセルの中に黄色セルが含まれている」ことが分かったら、３つの黄色セル全てを確かめることにしています。
（対象セルが多数になる場合には、Targetに含まれるセルの位置を調べた方が処理時間が短くなる場合があるかもしれません。）

プログラムの流れを考えるために、まずユーザーの操作と画面の遷移のあるべき姿を図４－２に整理しました。
例として「Ｃ３セルとＣ５セルにユーザーが値を入力し、Ｃ７セルに計算結果が表示されいている」状態を一番上に表しています。プログラム側から見て「各セルをどう操作すれば良いか」について見ていきます。

図４－２

ユーザーが続けて換算作業をする場合、まず入力値（ここではＣ５セル）を操作した時にどうなるかを考えます｡

図４－２の①は入力値を上書きするパターンです。この場合Ｃ５セルが書き換わることでWorksheet_Changeイベントが発生し、Ｃ３とＣ５の値を使って計算しＣ７に代入します。
Ｃ７セルは、どうせ上書きされますので、事前に「Ｃ７セルをクリアしてもしなくてもＯＫ」です。

②はＣ５セルの値を（DELキー等で）削除するパターンです。Ｃ５が削除されてWorksheet_Changeイベントが発生するのですが、入力値はＣ３だけ（Ｃ７は計算結果だから入力値ではない）になりますので、計算できません。ですので計算結果である「Ｃ７はクリア」する必要があります。

以上①②は「Ｃ５セルに対するユーザー操作」でしたが、「Ｃ３セルに対する場合」でも同様になります。

続いて計算結果セル（ここではＣ７セル）を操作した時にどうなるかを考えてみます｡
③は、計算結果であるＣ７セルに対して、ユーザーが値を入力しようとするパターンです。しかしここで入力を許してしまったら、３つのセル全てが入力値になってしまい「電流ｘ電圧＝電力」という関係が崩れる可能性があります。
ですのでプログラム側としては「Ｃ７への入力を拒否してＣ７セルの値を守る」か「入力した値は無視し、Ｃ３とＣ５セルの値を使って再計算しＣ７セルに代入する」かの実行が必要です。

④は、計算結果であるＣ７セルの値を（DELキー等で）削除するパターンです。Ｃ７が削除さると、Ｃ３・Ｃ５の入力値だけが残りますので「入力値が揃った段階」と同等となりますので、計算をしその結果をＣ７セルに代入すれば良いことになります。

これをプログラム側の立場でまとめてみると、図４－３のようになります。

	①	②	③	④
Ｃ３セル	実値入力済	実値入力済	実値入力済	実値入力済
Ｃ５セル	新入力値	空白セル	実値入力済	実値入力済
Ｃ７セル	計算結果を代入	値削除	入力拒否､又は計算結果を代入	計算結果を代入

図４－３

まず考えなければいけないのは「計算の条件（≒タイミング）」です。「計算ボタン」をユーザーにクリックしてもらえない場合には重要です。
今回は「電流ｘ電圧＝電力」という３要素の式ですので、３つの内２つが決まらないと計算できません。また、残りの１つが空で無いと計算結果を書き込めませんので、条件としては「２つの入力値＋結果欄が空」ということになります。

また③のＣ７セルの「入力拒否」ですが、方法としてはいくつか考えられます。
１つ目は「Excelの機能を利用して拒否（２個目の値を入力した時点で、残りの１つにはシート保護をかける等）」、２つ目は「記憶する（前回表示時の計算結果を保持しておく）」方法です。他にもあるかもしれません。
１つ目は少しプログラムが面倒そうです。２つ目はStatic変数を使えば簡単そうですが、計算結果を残したままファイルを保存されると、次回ファイルを開いた時には「記憶が消えている」ので、うまく行きません。
しかし上記の「計算の条件」を見ると、「２つの入力済の値が既にある」のですから、残りの「結果欄を空」にするためにＣ７セルをクリアすれば勝手に計算して値を入れてくれることに気が付きます。

同様に①④の場合も、Ｃ７をクリアするだけで計算してくれますし、②にあってはＣ７をクリアすることは必須です。
つまり、どういう場面であっても「計算結果のセルをクリア」すればスムーズに進むことになります。
ということで、２３行目では「計算結果である文字色が赤（AnsColor）のセルはクリア（.Value=""）」しています。

２４行目は、黄色セルに入れられた値が数値か否か（IsNumeric関数）を調べ、数値でなかったら２５行目でコメントを出し、２７行目でマクロ終了（Exit Sub）します。

なお、２６行目の「Application.EnableEvents = True」ですが、２１行目で「Application.EnableEvents = False」を実行している状態のままマクロ終了してしまうと、その後イベントが発生しなくなってしまいます。（「EnableEvents」は、「ScreenUpdating」などと違いプロシージャを抜けてもTrueにならない）
ですのでマクロを終了する前に「Application.EnableEvents = True」を実行し、正常な状態に戻しています。

ついでに２１行目の「Application.EnableEvents = False」について説明しておきます。
２３行目や４４・４６行目、５０行目、５４・５６行目では、セルに何かしらの値を書き込んでいます。書き込むと書き込んだ時点で新たに「Worksheet_Change」イベントが発生してしまいます。
たとえば２３行目を実行して計算結果セルをクリアするとイベントが発生し、また２３行目で計算結果セルをクリアしイベントが発生し、・・・と無限にイベントが発生します。このような異常を避けるために、黄色セルを処理中はイベントが発生しないように「Application.EnableEvents = False」を実行させています。

４－５．④どのセルに値が入力されているかの計算

３２行目は、黄色セルの内、どのセルに値が入っているかを数値として表しています。
今回黄色セルは３つありますので、何番目に値が入っているかを知り、値が入っていないセルに計算結果を入れる必要があります。方法としては色々あると思いますが、ここでは２進数を活用した方法で行っています。

まず、図４－４のように「各セルの状態を入れる配列」のようなものを考えます。入れる値としては「値有り＝１、値無し＝０」とします。

図４－４

この「配列のようなもの」は、１と０が並んでいる「２進数」として見る事ができますので、人間が扱い易いようにこの２進数を１０進数にします。すると「３つのON-OFFの状態は、１０進数の０～７で表される」ことになります。

３２行目では「値がある（＝１）、値が無い（＝０）」になるように、まず「Rng(1) = ""」の数式で「値がある（＝False）、値が無い（＝True）」を計算し、次に「Not」で逆転し「値がある（＝True）、値が無い（＝False）」にします。
そのあと各桁をあらわす値（１桁目＝２^０，２桁目＝２^１、３桁目＝２^２）を掛けます。なお、ExcelでのTrueは「-1」になりますので、
「１桁目＝ -１，２桁目＝ -２、３桁目＝ -４」とします。

「True × -1 = -1」というのがピンと来ない場合は、「CInt(Not (Rng(1) = "")) * -1」のように「CIntで　Trueを-1、Falseを0　に変換」した後で「-1 × -1 = 1」と掛け算をするような式にすれば分かり易いと思います。

その値を変数RngNoに代入し、３９行目以降で分岐させます。

４－６．⑤書式の初期化

３５～３６行目は、３つの入力・出力セル（セルの集合体であるsumRng）の書式を標準（黒文字＋黄色背景）に戻しています。
これは「今回の実行結果が正しく表示させる」ために、「１つ前の計算時に、３９～６１行目の処理で文字色と背景色を変更している可能性がある」ので「書式を初期化」しているものです。

このような初期化を行わず、「実行ごとに全ての対象セルの書式を設定する」という方法もあります。
多くの対象セルに対して何らかの実行が必要な場合には、「どうせセルに対して別々の処理をするのだから、ついでに書式も」という考え方はあると思います。
しかし今回は「処理するのは、計算結果を書き込む１セルのみ」ですので、「ユーザーが操作したセルをわざわざ別々に処理」する必要は無いと考え、「セルの処理をする前」に「全セルの書式の初期化」をしています。

なお、３６行目の「RGB(255, 255, 0)」は黄色を指していますが、もちろん先頭で変数化してもＯＫです。
（今回変数化しなかったのは、この３６行目の１箇所でしか使用しなかったからです。）

４－７．⑥入力値で計算を実行し、その計算結果を出力

３９～６１行目は、３２行目での変数RngNo（どのセルに値が入っているかの値）の値に従って、各セルの処理をしている部分です。
RngNoが取る値は「0～7」の全８種類ですので、Select Caseで分岐をさせています。分岐先で実行する内容を図４－５に整理しました。

RngNo値毎の実行内容

RngNo値	各ｾﾙの値(有=〇)			状態	実行内容
	C7	C5	C3
0				全てのセルが空白	何もしない
1			〇	1セルしか値が無く計算不可	何もしない
2		〇		1セルしか値が無く計算不可	何もしない
3		〇	〇	C3･C5の値で計算可能	計算し､C7セルに結果を書込み
4	〇			1セルしか値が無く計算不可	何もしない
5	〇		〇	C3･C7の値で計算可能	計算し､C5セルに結果を書込み
6	〇	〇		C7･C5の値で計算可能	計算し､C3セルに結果を書込み
7	〇	〇	〇	全セルに値があり計算不可	異常を知らせる為､全セルを赤くする

図４－５

図４－５からも分かるように、「何もしない」のは RngNoが０･１･２･４ の時ですので、その分岐を４０行目に設定しました。
なお「何もしない」のですから、この４０行目は無くても問題ありません。

「RngNo＝３」の時は４３～４８行目を実行します。「３」は「Ｃ３セル・Ｃ５セル」に値が入ってることを示していますが、計算式は「Ｃ５セル値 ÷ Ｃ３セル値」ですので、例えＣ３に値が入っていても「Ｃ３セル＝０」では計算式の戻り値は「無限大（＝エラー）」になります。
ですので４３行目でＣ３セルの値を調べ、ゼロの場合にはＣ７セルに「０除算」とコメントを出力しています。（４４行目）
ゼロで無い場合に限り４６行目で計算を行い、その計算結果をＣ７セルに記入します。
４８行目は、計算結果であることを表すために、Ｃ７セルの文字色を赤色（AnsColor）に設定します。

「RngNo＝５」の時は５０～５１行目を実行します。「５」は「Ｃ３セル・Ｃ７セル」に値が入ってることを示し、計算式は「Ｃ３セル値 × Ｃ７セル値」ですので、「RngNo＝３」の時のようなゼロ除算がありませんので、そのまま素直に掛け算の値をＣ５セルに記入します。（５０行目）
５１行目は４８行目と同様に、計算結果であることを表すために、Ｃ５セルの文字色を赤色（AnsColor）に設定します。

「RngNo＝６」の時は５３～５８行目を実行します。「６」は「Ｃ５セル・Ｃ７セル」に値が入ってることを示し、計算式は「Ｃ５セル値 ÷ Ｃ７セル値」ですので「RngNo＝３」の時と同様に、Ｃ７セルがゼロの時は「０除算」のコメントを出力します。
Ｃ７＝０以外の時には割り算を実行しＣ３セルに記入します。（５６行目）
５８行目は、４８・５１行目と同様に、計算結果であることを表すために、Ｃ３セルの文字色を赤色（AnsColor）に設定します。

最後の「RngNo＝７」は、３つ全てのセルに入力されたことを示し、関係式が成立していない可能性があるのはもちろん、計算結果を記入するセルもありません。ですので、６０行目で３つ全てのセル（sumRng）の背景色を赤色（RGB(255, 0, 0)）にしています。

なお「RngNo＝７」を発生させる方法には、下記の様にいくつかあります。
１つ目は、Ｃ３セルに値を入れ、Ｃ３セル右下の「フィルハンドル」をマウスで下方向にドラッグする。
２つ目は、違う場所でＣ３・Ｃ５・Ｃ７の値を作り、１つのセル範囲としてコピーし、黄色セル上でペーストする。
３つ目は、計算結果の文字列の色を、手動で赤以外の色にする。

他にも方法はあると思いますが、その対策としてはワークシート関数の所でも紹介したシート保護が有効と思います。ただし３つ目の「手動で文字色を変える」は残念ながら防げません。
かと言って、入力のインターフェースをフォームを使ったダイアログにしてしまうと、ワークシートの手軽さが失われてしまう気がします。
取扱説明書で注意する等の、運用でカバーするのが良いかと思います。

６２行目の「Application.EnableEvents = True」は、２１行目で「Application.EnableEvents = False」と設定したイベント中止を解除し、マクロ終了と共に正常な状態に戻すものです。

５．最後に

今回は「電流ｘ電圧＝電力」という簡単な式でしたが、複雑な式の場合になるとワークシート関数方式では数式を作るのが、かなり大変かもしれません。その点マクロ方式は対応範囲が広く一般的だと思います。
しかし、マクロ付きのExcelファイルはセキュリティ的に難しい場合、ワークシート関数方式の考え方も役に立つのでは、と思っています。

なお、マクロ方式でのセルの表示桁数は指定していませんので、計算結果が極めて大きかったり小さかったりすると指数で表示されます。たぶん使われる業種により桁数の範囲があると思いますので、「V → ｋV」にするとかの工夫をして下さい。

両方向から換算可能なシート（it-040.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。