2021/03/28

マウス操作で日程の開始・完了を設定できるタスク表

• １．背景
• ２．システム概要
• ３．プログラムの流れ
• ４．ワークシート上の数式・条件付き書式の設定など（Sheet1）
• 　４－１．表示日付セルの数式
• 　４－２．スクロールバーの設定
• 　４－３．条件付き書式の設定
• 　４－４．「矢印取消」ボタンの設定
• ５．シートモジュール（Sheet1）
• 　５－１．ダブルクリック時の処理
• 　５－２．セルを選択した時の処理
• 　５－３．スクロールバー操作時の処理
• ６．標準モジュール（Module1）
• 　６－１．共有で使用する定数・変数の宣言
• 　６－２．矢印図形のサイズ・種類を計算
• 　６－３．矢印図形を作成
• 　６－４．矢印図形の変形を監視
• 　　６－４－１．エラー処理の設定
• 　　６－４－２．監視実行
• 　　６－４－３．ESCキーの処理
• 　　６－４－４．Do～Loopを抜けたあとの処理
• 　　６－４－５．エラー発生時の処理
• 　６－５．矢印図形の上下方向の位置・サイズを元に戻す
• 　６－６．矢印図形の位置をセル単位に補正する
• 　６－７．矢印図形が変形された時の処理
• 　　６－７－１．両矢印（ARtype=0）の処理
• 　　６－７－２．左矢印（ARtype=1）の処理
• 　　６－７－３．右矢印（ARtype=2）の処理
• 　６－８．矢印図形から開始日・完了日の書込み
• 　６－９．｢矢印取消｣ボタンが押された時の処理
• 　６－１０．図形グリッドのON-OFF
• ７．最後に

１．背景

日程表には様々な様式がありますが、図１－１のようなガントチャートもその１つです。

図１－１（図は、Wikipediaより引用し加工）

１つの仕事の中を細かい作業（タスク）に分けることが可能で、且つそのタスク同士に関係性がある（＝タスクの前後関係や、その間隔に決まりがある）場合には、このような日程表でスケジュール管理や工程管理をすることは有効と思います。
ガントチャートの良いところは、作業計画・実績が視覚的に分かることと、タスクの関係性をデータが保持しているために「日程を修正する時に、前後のタスクも同時に修正する（又は､注意を促すコメントが出る）」ことだと思います。
基本は横棒グラフなので「Excelでもグラフ機能を使えば近いことはできる」とは思いますが、市販でもプロジェクト管理ソフトはたくさん出ていますので、本格的に行うには専用アプリの方が良いと思います。

私も少しだけ「Microsoft Project」や「SynViz S2」などを使って日程管理をしたことがありますが、「タスクの日程線をマウスで前後に移動させたり、伸縮させる」という操作はExcelには無い操作感覚であり、昔から「ぜひExcelで実現させたい」と思っていました。

このサイトの１課題としてもトライと断念を何回か繰り返しましたが、今回「ちょっと使えるかも」というようなものが出来ましたので紹介します。

２．システム概要

サンプルファイルは図２－１のように日程表っぽくしてありますが、工夫したところは「G列～T列で日程線を視覚に基づいて引く」ことにより「E列～F列の開始日・完了日になる」ところです。

図２－１

G列～T列には「青い日程線」が引かれていますが、これは「G4～T13セルに条件付き書式がセット」されており「E列～F列の日付と、G2～T2セルのカレンダー日付を比較」し、「開始日から完了日までのセルを青く」しているだけです。
G2～T2セルのカレンダーは「表示週切り替えスクロールバー」で１週ずつ移動するようにしています。

日程線の変更方法ですが、例えば５行目の「稟議作成」の日付を変更したい場合、５行目の青色のセル（＝日程線）のどこかを「ダブルクリック」します。すると「青いセル範囲を囲むような図形枠（良く見ると、両方向矢印になっている）」が現れます。

その矢印図形を図２－２のように、変更したい日付のところまで「横方向に変形」させます。
なお矢印図形表示中は、図形がセルに吸着するように動く（グリッド合わせがONになる）ので、日付に合わ易くなっています。また、図２－２では「完了日を変更」させていますが、「開始日を変更」することも、期間は変えずに「全体を移動」することも可能です。

また、図形は上下方向への変形及び移動も可能ですが、矢印図形の動きについては常に監視をしており「上下方向の変形・移動をしても元に戻す」ようにしています。

図２－２

新たな日程（開始日・完了日）に図形矢印の位置がなりましたら、図２－３のように「任意のセルを選択」します。すると日程が確定し、矢印図形は消えて開始日・完了日が書き換わります。（変更しなかった場合は、日付はそのままです。）
また「任意のセルを選択」せずに「表示週切替」のスクロールバーを操作しても、日程変更をしてから週の移動をします。

図２－３

１つ１つのタスクの集合体は「プロジェクト」であり、その大日程の中に「過去のタスク」「現在進行中のタスク」「始まっていないタスク」などがあります。プロジェクト全体を見渡す係の人もいますが、作業をする人は「現在進行中のタスク」に注目し細かく見る必要があります。
ちょうど図２－４のように「全体の一部を窓から覗く」感じです。この窓枠が、今回サンプルファイルでは２週間の長さとし、スクロールバーを使えば左右に窓を移動できるようにしています。

図２－４

窓の位置（見ている日程の範囲）によって、日程線の見える形は異なります。
例えば図２－５の５行目は、見えている範囲よりも前から始まっているタスクですし、８行目は完了日が見えている範囲よりも先のタスクです。このように見えている範囲外に開始日・完了日があるタスクの場合は、片方の端部が矢印型ではない矢印図形としています。
７行目のように開始日・完了日の両方が、表示範囲に入っている場合は両矢印型の矢印図形となります。


図２－５

また図２－５の１０行目のように、開始日・完了日の両方とも表示範囲内に入っていない場合には、今回のシステムでは操作できないこととしました。操作しようとダブルクリックしても、図２－６の１０行目のように「メッセージが出て終了」します。
プロジェクト管理ソフトの中には、このようなタスクを操作しようとすると「両端の情報が確認できて操作可能」のようなものもありますが、今回は省略しました。

また、どの部分をダブルクリックするかで、図２－６のように動作が変わってきます。
青い日程線部分をダブルクリック①すれば、その日程線の形に合わせた図形枠が表示されますが、日程線以外の部分をダブルクリック②③すると、その選択したセルの日付の場所に矢印図形が現れます。②のように既に日程線が存在しても、その行の日程線以外でダブルクリックし日程を確定（どこかのセルを選択）すれば、そちらが「新たな日程」になります（既存の日程データが書き換えられる）ので注意が必要です。
なお、日程線の枠（今回で言えば、G4セル～T13セル）の外をダブルクリックしても、矢印図形は表示されず、通常のExcel操作（通常はセルの編集）となります。

図２－６

しかし「うっかり、違う場所をダブルクリックしてしまった」と言う場合もあるかと思います。
ダブルクリックしたのが既存の日程線上であれば、変形などをせず「どこかのセルを選択」すれば既存の開始日・完了日は変更されません。一方、日程線で無い部分をダブルクリックし、任意のセルを選択してしまうと、既存のデータが書き換わってしまいます。
このような場合は、G1セル辺りにある「矢印取消」ボタンをクリックしてキャンセルして下さい。
（書き換わった開始日・完了日データを元に戻すものではありません。）

なおプログラム的には、「ESCキー」「DELキー」でもキャンセルできるようにしていますが、少ない確率ですが失敗することもあるようなので「矢印取消」ボタンが確実だと思います。

３．プログラムの流れ

プログラムは「日程線領域（ArrowArea）」の中でダブルクリックをするところから始まります。

図３－１

まずダブルクリックをしたセルが日程線上（＝青色セル上）であるか否かで仕訳け、日程線以外の場合には「矢印図形の描画位置」は「ダブルクリックのセル」とします。また、矢印図形の形状は「両矢印」とします。
一方、ダブルクリックした位置が日程線上の場合は、開始日・完了日のデータから「青いセルの範囲」と、表示されている日付範囲の中に開始日・完了日が含まれているか否かで「矢印図形の形状（タイプ）」を決めます。

図形のタイプは、表示日付の範囲に開始日・完了日の両方が入っている場合は「⇔」、開始日が入っていない場合は「⇒」、完了日が入っていない場合は「⇐」という矢印形状にします。（矢印では無い『平らな側』は、動かす対象では無い という意味）

Shape_Formプロシージャで計算された「図形描画範囲」と「矢印図形のタイプ」を受け、Shape_MakeプロシージャではAddShapeメソッドを使い矢印図形を描画します。
続けて、描画した図形が変形されないかのチェック（Shape_Checkプロシージャ）を開始します。

ユーザーの図形操作により「図形が変形」された場合には、まずARcellFixプロシージャで「矢印図形がセル単位になる」ように図形の位置・寸法の微調整を行います。
今回のシステムでは、矢印図形は「図形のグリップ合わせ」機能を使って「セル単位」になるようにしているのですが、微妙なズレがあったり、また日付の列幅が揃っていない為に図形を移動した時にセル単位にならない、という場合が発生します。
まずはその「ズレ」を修正してから、「矢印図形が日程線領域をオーバーしているか等」の判断・処理をARareaFixプロシージャで行います。

ARareaFixプロシージャでは、主に「矢印図形が日程線領域をオーバーしていないか」をチェックし、オーバーしている時には「元に戻す」または「日程線領域内に入るように縮める」という処理をします。
またユーザーの図形操作によっては図形が左右が反転してしまう場合もあるため、その場合には反転を元に戻します。

ユーザーによる矢印図形での日程調整が完了し「任意セルをクリック」すると、「SelectionChangeイベント」が発生し、Data_Fixプロシージャが呼び出されます。
矢印図形の左端・右端に属するセル位置から、開始日・完了日の日付を計算します。片矢印の場合「端部が平な形状側」は「動かす対象では無い」ので、矢印側の日付だけを修正します。

日付修正をしたら、矢印図形を削除し、プルグラムを終了します。

４．ワークシート上の数式・条件付き書式の設定など（Sheet1）

４－１．表示日付セルの数式

図４－１のように、G2セル～T2セルの２週間分の日付セルには数式が入っています。
まず「基準となる日付」がD2セルに入っており、サンプルファイルでは2021年3月7日になっています。
また、E2セルには「基準日に加える週の数」が入っています。このE2セルの値は、すぐ隣のスクロールバーで書き換えます。

図４－１

そのD2セル、E2セルの値を使って、「日付セルの最左端（G2セル）」の数式を組み立てています。式は図４－１の数式バーにも表示されていますが「=D2 + E2*7」としています。つまり「基準日D2から、E2週間あとの日付」となります。
その先のH2セル～T2セルには「左隣に１を足す」という式が入っていますので、２週間分の日付が並ぶことになります。
またG3セル～T3セルに曜日を手入力で書き込んでいますが、日曜から始めていますので、D2セルの基準日も「日曜日」の日付にする必要があります。

なお、日曜日と土曜日の列の背景色は、手入力で設定しています。
また、D2セル、E2セルは「サンプルファイルでは見えてしまっています」が、本来はユーザーには隠すところです。別なところに設定するとか、スクロールバーの下にするとか、文字色を白にするなどの工夫をして下さい。

４－２．スクロールバーの設定

ワークシート上に配置できるスクロールバーには「フォームコントロール」と「ActiveXコントロール」の２種があります。
私も今回システムの作り初めは「フォームコントロール」で作り、その「リンクするセル」にE2セルを割り当てていました。

しかし日程線の矢印図形で日程を定めた後、どのセルも選択せずに「矢印図形がSelectされた状態から、直接『週を変更する』操作もある」ことに気が付きました。
Excelには「図形が選択状態で無くなる時に発生する『LostFocusイベント』のようなもの」はありませんし、スクロールバーによる「週変更」が実行された後で矢印図形の位置を計算してもダメです。

仕方なくスクロールバーは「ActiveXコントロール」にし、マクロで「矢印図形から開始日・完了日の書き出し（任意セルを選択した時と同等の作業）」を行ったあとに「E2セルへの値の書込み」を行うように変更しました。

なお作ったばかりのスクロールバーでは、Max値＝32767（Integer型の正数の上限値）、Min値＝0です。しかしスクロールバーのChangeイベントは「値が変更されないとイベントは発生しない」ので、例えば「スクロールバーの値がMax値、又はMin値」の場合は、それ以上動かそうとしても「値が変わらない」ことになり、つまりは「Changeイベントが発生しない」ことになってしまいます。

図４－２

ですので「クリックしても値が変わらない状態にしない」ことが必要なので、図４－２のように「Max値とMin値を大きな値に設定」する必要があります。今回システムの場合、スクロールバーのValue値は「週」を表しますので、100であれば約２年間となります。
プロジェクトの大きさによりMax値とMin値を決めてください。（図４－２では、±100に設定してあるので約4年間です）

なお、スクロールバーがMax値・Min値に達した時には、図４－３のように「スクロールボックスが片方に寄っている」ことになります。 その状態から「スクロール矢印（両側の矢印のあるボタン）」をクリックしても「Changeイベントは発生しない」のですが、「スクロールボックスをクリックする」と「Changeイベントが発生する」のです。 図４－３ 何故、スクロールバーのValue値が変わらないのにChangeイベントが発生してしまうのか分かりません。 しかし、今回システムでは「この現象」が役に立ち、スクロールバーがMax値・Min値に達していなくても「スクロールボックスを（動かさずに）チョコンと触る」だけでChangeイベントが発生してくれて、矢印図形の後処理をしてくれるのです。 つまり、本来は矢印図形を確定するために「矢印図形から、任意のセルにSelectionを移動」する動作の代わりとして、「矢印図形から、スクロールバーにSelectionを移動」が成立するのです。

４－３．条件付き書式の設定

日程線を表示している領域には、条件付き書式が設定されています。
まず、その領域（サンプルファイルでは、G4～T13セル）に「名前」をつけます。領域をセル範囲選択し、右上の名前ボックスに「ArrowArea」と入力します。この名前は条件付き書式では使用しませんが、マクロ内（図５－１の４行目）で使用しますので必須作業です。
領域に名前を付けておけば、行挿入などで領域を広げても「広がった領域を名前が指す」ことになります。今回システムのように、領域が下に広げられる可能性のあるものには適していると思います。

図４－４（図は、既に条件付き書式が設定してある状態を示しています）

次に、リボンの「ホーム」タブ→「スタイル」グループ→「条件付き書式」から「新しいルール」を選択します（図４－４）。
表示された「新しい書式ルール」ダイアログ（図４－５）の「数式を使用して、書式設定するセルを決定」を選択し、数式欄に「=AND(G$2>=$E4,G$2<=$F4)」と入力します。

この数式は、選択したセル範囲（今回は、G4～T13セル）の左上角のセルの式として入力し、他の範囲内には「その数式を相対的にコピー」することになります。これは手動で「G4セルに数式を入力」し、そのセルを「コピー」した後に貼付け範囲を選択し「貼り付け」をするのと同じことになります。

図４－５

左上角のセルの式として「=AND(G$2>=$E4,G$2<=$F4)」を見てみます。この式は「G$2>=$E4」と「G$2<=$F4」とを「AND」で結んでいます。
「G$2>=$E4」は「G4セルの日付（G2セル）が開始日（E4セル）以上」という意味になります。また「G$2<=$F4」は「G4セルの日付（G2セル）が完了日（F4セル）以下」となります。つまり「開始日と完了日とに挟まれている日付」の時に数式が成立します。
そして成立した時（条件に合致した時）だけ、セルの書式が「ダイアログの一番下で設定した書式」に変わります。

なおサンプルファイルでは、日曜日の列は薄い赤色、土曜日の列は薄い青色に手動で設定していますが、条件付き書式で数式が成立した時には「セルの元の書式の上に、条件付き書式の書式が上書きされる」ので、「薄い赤色が消えて、日程線の青色で線が引かれる」ことになります。
（E列・F列も手動で黄色の背景色にしています）

なお条件付き書式を後から調べたり、内容を修正するには、図４－６のように「ルールの管理」から行います。

図４－６

４－４．「矢印取消」ボタンの設定

「ダブルクリックする行を間違えた」や「日程線（青色セル）以外のセルをダブルクリックしてしまった」などの時には、「矢印図形をキャンセル」する必要があります。その際には上部の「矢印取消」ボタンをクリックするのですが、クリックすることで起動するマクロを登録しておく必要があります。
図４－７のように、「ESCstop」プロシージャ（図６－２８）を設定します。

図４－７

５．シートモジュール（Sheet1）

５－１．ダブルクリック時の処理

セルをダブルクリックした時は、図５－１の「BeforeDoubleClick」イベントが発生します。第一引数として「ダブルクリックしたセル位置」の「Target」と、第二引数の「Cancel」を受け取ります。

1. '==========　⇩(1)　ダブルクリック時の処理　============
2. Private Sub Worksheet_BeforeDoubleClick(ByVal target As Range, Cancel As Boolean)
4. 　If Not Intersect(Range("ArrowArea"), target) Is Nothing Then
5. 　　Cancel = True
6. 　　Call Shape_Form(target)
7. 　End If
9. End Sub

図５－１

４行目では、「ダブルクリックしたセル位置（Target）」が「日程矢印線の領域（ArrowArea）」の中か否かをしらべています。「ArrowArea」は図４－４で選択した範囲であり、且つ「条件付き書式」の適用先です。

領域内でダブルクリックされた場合は、５行目の「Cancel = True」で「セルのダブルクリックによる編集モード」をキャンセルします。そして６行目で「Shape_Form」プロシージャ（図６－３）を呼び出します。呼び出す時に渡す引数は、ダブルクリックをしたセル位置（Target）です。

５－２．セルを選択した時の処理

ユーザーが矢印図形でタスク日程を修正した後、確定させるために「任意のセルを選択」した時に実行されるのが、図５－２です。
受け取る引数Targetは「選択したセル位置」ですが、そのセル位置データは今回使用しません。

11. '==========　⇩(2)　セルを選択した時の処理　============
12. Private Sub Worksheet_SelectionChange(ByVal Target As Range)
14. 　If Not AR Is Nothing Then
15. 　　Call Date_Fix
16. 　End If
18. End Sub

図５－２

「矢印図形で日程を調整している間は、矢印図形は存在」し、「日程を確定したら矢印図形は削除」されるため、１４行目の「Not AR Is Nothing」で「矢印図形で日程を調整している間」のみ、１５行目でDate_Fixプロシージャ（図６－２７）を呼び出します。そのDate_Fixプロシージャでは「開始日・完了日の日付を書換」をしたのち「矢印図形の削除」をします。
矢印図形が存在しない場合（＝日程修正中以外）は、通常のセル選択となります。

５－３．スクロールバー操作時の処理

週の切り替え用スクロールバーを操作した時は、図５－３のChangeイベントが発生します。Changeイベントは「スクロールバーのValue値が変更された時に発生する」と様々なサイトで説明されていますが、今回調べたところ「スクロールボックス（図４－３参照）」を動かさずにクリックするだけでもChangeイベントが発生しますので、注意が必要です。

今回システムでは、ユーザーが「日程を確認するために」週を切り替える時と、「あるタスクの修正日程が決まり、続けて次のタスクの日程修正をしようと」週を切り替える時の両方でスクロールバーが使われると考えました。

20. '==========　⇩(3)　スクロールバー操作時の処理　============
21. Private Sub ScrollBar1_Change()
23. 　Call Worksheet_SelectionChange(Range("a1"))
25. 　Range(PlusWeek) = ScrollBar1.Value
27. End Sub

図５－３

２３行目では、図５－２の「SelectionChange」イベントプロシージャを呼び出します。SelectionChangeには引数としてRange型のセル範囲を渡す必要がありますが、今回システムでは「どのセルを選択したか」は関係ありませんので、適当な「A1セル」としています。
また、２５行目では「基準日に加える週の数」セルに、スクロールバーのValue値を入力しています。

上記で説明した「日程を確認するために」の場合と「続けて次のタスクの日程修正をしようと」の場合の両方とも、２３行目・２５行目の２つが実行されます。「続けて次のタスクの日程修正をしようと」の場合には２つとも必要になりますが、「日程を確認するために」の場合は必要なのは２５行目のみです。
しかし「日程を確認するために」の場合には「矢印図形は存在していない」状態ですので、図５－２の１４行目のIf文により「Data_Fix」は実行されずに終了してしまうことになり、実質上は問題有りません。

２５行目が実行されることで、図４－１で示した日付部数式の計算結果が変わり、日付が更新されます。

６．標準モジュール（Module1）

６－１．共有で使用する定数・変数の宣言

プロジェクト内で共通で使用する定数・変数の宣言が、図６－１です。

29. '==========　⇩(4)　定数・変数宣言　============
30. Public AR As Shape 　　　　　　　　　　　　　　 '変更矢印図形
31. Private ARtype As Integer 　　　　　　　　　　　 '矢印図形の形（⇔：0, ←：1　,　→：2 　,　―：3）
33. Private ARleft As Single 　　　　　　　　　　　　 '変更矢印の左端の位置
34. Private ARwidth As Single 　　　　　　　　　　　 '変更矢印の幅
35. Private ARtop As Single 　　　　　　　　　　　　 '変更矢印の上端
36. Private ARheight As Single 　　　　　　　　　　 '変更矢印の高さ
37. Private ARrow As Long 　　　　　　　　　　　　 '変更矢印の行位置
39. Private Const Scol As Long = 5 　　　　　　　　 '開始日の列位置
40. Private Const Ecol As Long = 6 　　　　　　　　 '完了日の列位置
41. Private Const Drow As Long = 2 　　　　　　　　 '日付の行位置
42. Private Const DstartCol As Long = 7 　　　　　 '日付開始列
43. Private Const Dwidth As Long = 14 　　　　　　 '日付の列数（幅：2週間だったら14日）
45. Private Const stdDay As String = "D2" 　　　　　 '基準日
46. Public Const PlusWeek As String = "E2" 　　　　 'プラス週数
48. Private myGrid As Boolean 　　　　　　　　　　 'ユーザーの元のGrid条件

図６－１

３０行目は、操作する矢印図形を変数「AR」（Arrowの略のつもり）と置き、今回システムの中ではARの寸法・位置を随所で使用しています。またその矢印形状については、図２－５でも説明したように３種類あり、開始日・完了日とも表示日付範囲に入っていないもの（タイプ３）も含め、３１行目でARtypeという変数名で表すことにしました。

３３～３７行目は、図６－２（茶色の寸法部分）のように図形のサイズと位置を表す変数として宣言しています。図形のLeft等のプロパティのデータ型はSingle型なので、同型としました。
また３７行目のARrowは矢印図形の行位置を保存するものです。矢印図形を表示中にユーザーが行高さを変更した時に、この値を使って矢印図形の上下方向の位置・図形の高さを修正します。
３９～４３行目は、図６－２（赤色の寸法・指示部分）のようにワークシート上の位置を表しています。


図６－２

４５～４６行目は、表示日付（今回は２週間分）の数式の元となっている「基準日（stdDay）」と「加える週の数（PlusWeek）」をセル位置として定数宣言（String型）しています。
Range型の変数として宣言する方法もありますが、今回システムの場合は起動ボタンのようなものがありません。「ThisWorkbookモジュール」に「Workbook_Open」イベントプロシージャを作りセル範囲を変数に代入する、という手もありますが面倒なので、String型の定数で宣言することにしました。

４８行目の変数「myGrid」は、ユーザーの「図形のグリッド設定条件」を記憶するものです。
今回システムでは、矢印図形を動かす時に「セル位置にはまるような感触で操作」させるために、矢印図形描画中は「グリッドをON」にさせています。しかしグリッドON-OFFはユーザー側が自由に設定するものなので、「矢印図形を描画する直前に現状のグリッドON-OFF状態を調べ、矢印図形を削除した後に元のグリッド状態に戻す」ようにしました。
変数「myGrid」は、「現状のグリッド状態」を記憶しておくものとしていますが、万一マクロエラー等で変数値が消えてしまう事を考慮し、既定値のFalseは「グリッドOFF状態（Excelの初期設定状態）」としています。

なお、この変数・定数の中で、ワークシートモジュールでも使用するのは、変数「AR」と定数「PlusWeek」のみです。ですので、その２つだけはPublicで宣言し、残りはPrivateと可視範囲を絞っています。

６－２．矢印図形のサイズ・種類を計算

ダブルクリックでBeforeDoubleClickイベント（図５－１）が起動し、ダブルクリックした位置が日程線領域内であれば、図６－３が呼び出されます。引数として、ダブルクリックしたセル範囲を受け取ります。

49. '==========　⇩(5)　矢印図形のサイズ・種類を計算　============
50. Public Sub Shape_Form(Target As Range)
52. 　Dim StartDay As Date 　　　　　　 '開始日
53. 　Dim EndDay As Date 　　　　　　　 '完了日
54. 　Dim ArrowStart As Long 　　　　　 '矢印の開始列
55. 　Dim ArrowEnd As Long 　　　　　　 '矢印の完了列
57. 　StartDay = Cells(Target.Row, Scol)
58. 　EndDay = Cells(Target.Row, Ecol)
59. 　ARtype = 0
61. 　If (Cells(Drow, Target.Column) >= StartDay) And (Cells(Drow, Target.Column) <= EndDay) Then
63. 　　If StartDay < Cells(Drow, DstartCol).Value Then
64. 　　　ArrowStart = DstartCol
65. 　　　ARtype = ARtype + 2
66. 　　Else
67. 　　　ArrowStart = DstartCol + StartDay - Cells(Drow, DstartCol).Value
68. 　　End If
70. 　　If EndDay > Cells(Drow, DstartCol).Value + Dwidth - 1 Then
71. 　　　ArrowEnd = DstartCol + Dwidth - 1
72. 　　　ARtype = ARtype + 1
73. 　　Else
74. 　　　ArrowEnd = DstartCol + EndDay - Cells(Drow, DstartCol).Value
75. 　　End If
77. 　　Set Target = Range(Cells(Target.Row, ArrowStart), Cells(Target.Row, ArrowEnd))
79. 　End If
81. 　If ARtype = 3 Then
82. 　　MsgBox "日程操作は両端部で行って下さい"
83. 　　Exit Sub
84. 　End If
86. 　Call Shape_Make(Target)
88. End Sub

図６－３

５２～５５行目は、プロシージャ内で使用する変数宣言です。
「StartDay」と「EndDay」は、ダブルクリックした行の「開始日」と「完了日」です。プロシージャ内で何度も使われるため、５７～５８行目でデータを変数に取り込んでおきます。
「ArrowStart」「ArrowEnd」は、これから描画する矢印図形の「左端の列位置」と「右端の列位置」を指します。

５７～５８行目では、これから描画する矢印図形の「開始日」と「完了日」を変数に代入しています。
５９行目は、矢印図形のタイプ（変数ARtype）の値を初期化します。システム起動後、初めて図形描画する際には変数ARtypeは既定値のゼロですが、２回目以降に描画する時には「１つ前のARtype」の値が残っていますので、初期化する必要があります。

６１行目のIf文は「Cells(Drow, Target.Column) >= StartDay」且つ「Cells(Drow, Target.Column) <= EndDay」となっており、「ダブルクリックしたセルの日付（Cells(Drow, Target.Column)）が、開始日と完了日の間に入っているか」という意味になります。これは図４－５の条件付き書式の数式「=AND(G$2>=$E4,G$2<=$F4)」と内容は同じです。
つまり「ダブルクリックしたセルが青色セル（日程線上）」であれば、６３～７７行目を実行することになります。

６３～６８行目は、矢印図形の左端の列位置を計算しています。
６３行目のIf文「StartDay < Cells(Drow, DstartCol).Value」の内「Cells(Drow, DstartCol)」は、定数を数値に変えれば「Cells(2, 7)」となりますので、表示日付の「先頭日付」です。ですのでIf文は「開始日（StartDay）が表示日付よりも前の日付であれば」ということになります。

開始日が表示範囲よりも前であれば、矢印図形の左端列（ArrowStart）は「DstartCol（日程線領域の左端列）」になりますので、６４行目では「ArrowStart = DstartCol」としています。
また、開始日が表示範囲よりも前ということは、図２－５の５行目のように「左端が垂直」となります。ですので「矢印タイプ２」ですのでARtypeには「２」を代入します。
（５９行目でARtypeは初期化していますので本来は「ARtype = 2」で充分なのですが、７２行目の右端の式と形を合わせるために「ARtype = ARtype + 2」としています）。

一方「開始日（StartDay）が表示日付以上（＝表示されている日付の中に、開始日が存在する）」の場合は６７行目が実行されます。
６７行目は「ArrowStart = DstartCol + StartDay - Cells(Drow, DstartCol).Value」であり、その右辺は「日程線領域の左端列番号＋開始日ー表示日付の初めの日付」となっています。
つまり「表示日付の中での開始日の列位置」を計算し、それを矢印図形の左端列（ArrowStart）に代入しています。

ここで「開始日（StartDay）が表示日付以上」の場合は「ARtype = ・・・」というコードはありません。図形の左端部が矢印になっているので「ARtype = ARtype + 0 」という式になりますが、この式は仕事をしていませんので省略しています。

このように省略できるのは、図６－４のように「矢印図形の端部形状を二進数の考え方で表している」からです。
端部が矢印型であれば「０」垂直型であれば「１」とし、左側を二進数の２桁目、右側を１桁目としています。

図６－４

ですので「指定しなければ矢印型」となりますので、「開始日（StartDay）が表示日付以上」の場合は「ARtype = ARtype + 0 」となります。

７０～７５行目は、矢印図形の右端の列位置を計算しています。
７０行目の「If EndDay > Cells(Drow, DstartCol).Value + Dwidth - 1 Then」の内「Cells(Drow, DstartCol).Value + Dwidth - 1」は、「表示日付の先頭日＋表示日数（今回は14日）－１」という意味になり、「表示日付の最終日」を指しています。
その表示最終日よりも「完了日」が後ろならば７１～７２行目を実行します。

「完了日 ＞ 表示最終日」であるなら、矢印図形の右端は「日程線領域の右端」となりますので、７１行目では変数ArrowEndには「領域の左端列位置＋領域の幅ー１」である「DstartCol + Dwidth - 1」を代入します。
式が分かりにくければ「DendCol」のような「領域の右端列位置」を表す定数を作ってもOKです。ただしExcelの図形の位置・大きさを表すプロパティは「Left、Top、Width、Height」ですので、今回はこれに合わせ「領域の幅（Dwidth）」という定数を使用しています。

また、矢印図形の右端形状は垂直型となりますので、７２行目で「ARtype = ARtype + 1」としています。

一方「表示最終日 ＞＝ 完了日」、つまり「表示日付の中に完了日が存在する」場合は、７４行目で変数ArrowEndに「DstartCol + EndDay - Cells(Drow, DstartCol).Value」を代入してます。これは「日程線領域の左端列位置＋完了日ー表示日付の初日」という意味になり、完了日の列位置を示すことになります。

ここまでで「ダブルクリックしたセルが青いセル（＝日程線上をダブルクリックした）」の場合の、「どこから（ArrowStart）」「どこまで（ArrowEnd）」が日程線として表示されているかが計算できました。
この「ArrowStart」「ArrowEnd」を使って、本当は「日程線上の一部をダブルクリック」したのだが「（表示されている範囲内の）日程線全体を指定した」ことにするため、７７行目で「引数として渡されたTarget」を「日程線全体」に修正します。

６１～７９行目までで、ダブルクリックしたセルが青いセル（＝日程線上）だった場合の処理をし、端部の形状を変数ARtypeに代入してきました。タスクによっては「開始日が表示日付範囲より前」かつ「完了日が表示日付範囲よりも後ろ」という場合があるはずです。
このようなタスクの場合は、６５行目と７２行目の両方が実行され、結果としてARtype＝２＋１＝３になっているはずです。つまり「両端が垂直型」です。
このようなタスクの場合、一般のスケジュール管理ソフトなどでは「移動は可能」だったりするかもしれませんが、Excelではやっかいなので今回システムでは「操作出来ない」こととしました。
ですので８２行目でコメントを出し、８３行目でマクロ終了させています。

ここまでは「ダブルクリックしたセルが青いセル（＝日程線上）」の処理で、引数で得たTargetを「青いセル全体」に置き換えています。一方「青いセルでは無い（＝日程線上では無い）」場合には、ARtypeは５９行目で初期化したままですので８１行目の「If ARtype = 3 Then」も該当せずに、引数で得たTarget（ダブルクリックした単一セル範囲）をそのまま保持しています。

８６行目では、このTargetを引数にしてShape_Makeプロシージャ（図６－５）を呼び出して、矢印図形を作成します。
矢印図形の大きさ・位置は、引数の「Target」の大きさ・位置に合わせて作ります。

なお、もし「DstartCol」という定数を設定しない時には、「Cells(Drow, DstartCol).Value」の代わりに「Range(stdDay).Value + Range(PlusWeek).Value 」とする必要があります。これは、図４－１の表示日付の先頭セルの数式「= D2 + E2 * 7」と同じ意味になりますが、結構長い式になりますので今回は「DstartCol」という定数を設定しました。

６－３．矢印図形を作成

図６－３の８６行目から呼び出されるのが図６－５です。引数としてTarget「矢印図形を描画するセル範囲」を受取ります。

90. '==========　⇩(6))　矢印図形を作成　============
91. Public Sub Shape_Make(Target As Range)
92. 　Dim ShapeType As Long 　　 '←図形の形を表す定数値
94. 　Application.ScreenUpdating = False
95. 　　Range("a1").Select
96. 　Application.ScreenUpdating = True
98. 　Call GridChange(True)
100. 　ARleft = Target.Left
101. 　ARtop = Target.Top
102. 　ARwidth = Target.Width
103. 　ARheight = Target.Height
104. 　ARrow = Target.Row
106. 　Select Case ARtype
107. 　　Case 0
108. 　　　ShapeType = msoShapeLeftRightArrow
109. 　　Case 1
110. 　　　ShapeType = msoShapeLeftArrow
111. 　　Case 2
112. 　　　ShapeType = msoShapeRightArrow
113. 　End Select
115. 　Set AR = ActiveSheet.Shapes.AddShape(ShapeType, ARleft, ARtop, ARwidth, ARheight)
117. 　AR.Adjustments.Item(1) = 0.9
118. 　AR.Fill.Visible = msoFalse
119. 　AR.Line.ForeColor.RGB = RGB(0, 0, 0)
120. 　AR.Select
122. 　Call Shape_check
123. End Sub

図６－５

９２行目は矢印図形をAddShapeメソッドで作成する際に使用する「図形の種類」を宣言します。
図形には非常に多くの種類がありますが、今回使用する３種類を図６－６にまとめておきます。この表の定数値の入れ物が、変数「ShapeType」です。

図６－６

９５行目の「Range("a1").Select」は、ユーザーが矢印図形を操作する前までに実行すれば良いコードです。また、このコードは無くてもシステムとして成立するのですが、以下のような状況を考えて設けました。

ユーザーが、あるセル（ここではK6セルとします）をダブルクリックしたとします。K6セルが日程線上で無ければそのセルを囲むように矢印図形が描画されます。
１日だけのタスクであれば矢印図形を伸縮する必要もなく、任意のセルをクリックすれば日程が確定するのですが、最もクリックし易いのは「マウスを動かさずクリックできるK6セル」のはずです。
しかし、その時K6セルは選択済みで「選択セルが変更されていない」ため「SelectionChange」イベントは発生せず、開始日・完了日の書き換え処理が働きません。しかも今回システムでは、図形の動きを監視している図６－８の中で「ESCキーで図形からFocusが外れた処理（１４２行目）」をしているため、「ESCキーを押して、処理をキャンセルした」のと同等の操作となってしまいます。

ですので、矢印図形を操作している時には「ダブルクリックと同じセルを選択しても、開始日・完了日の処理が出来る」ように、「ユーザーが、日程確定のためには選択しないであろうセル位置（＝A1セル）」に選択セル位置を移動させています。

なお９５行目「Range("a1").Select」を、９４行目と９６行目の「Application.ScreenUpdating = False／True」で囲んでいます。つまり「A1セルを選択した事を画面更新しない」という意味です。
これは、スケジュール表が縦や横に長くなり、A1セルが見えない場所で図形操作をした時、画面更新を一時停止していないと「A1セルが見える状態まで画面がスクロールし、操作している部分か視界から消えてしまう」現象が起こります。
その画面スクロールを防止するには、常にA1セルが見えるように「ウィンドウ枠の固定」で「タイトル部を固定」する方法もありますが、今回は「セル選択の間だけ画面更新停止」する方法にしてみました。
なお「ウィンドウ枠の固定」とよく似た「表示領域の分割」では画面スクロール現象は防止できないようです。

９８行目は、図６－２９の「矢印図形のグリッド吸着（GridChange）」を呼び出しています。引数に「True」を指定することで、「現在のグリッド設定を記憶した上で、図形のグリッド吸着をON」にする設定になります。詳細は図６－２９で説明します。

１００～１０４行目は、プロジェクト内で共有して使用する変数「ARleft」「ARtop」「ARwidth」「ARheight」「ARrow」に値を代入します。ARは１１５行目で作成する矢印図形のことで、そのサイズと位置を示している変数ですが、セルに沿った大きさ・位置で作成するため、引数のTarget（矢印図形を描画するセル範囲）のプロパティをそのまま使用しています。

１０６～１１３行目では、図６－３で計算した矢印図形の形状（ARtype）を「AddShapeメソッドの図形の種類」の値に置き換えます。
図６－６で示した定数を変数ShapeTypeに代入します。

１１５行目では、AddShapeメソッドを使い実際に矢印図形を作成します。作成した図形はオブジェクト変数「AR」という名前で管理していきます。

作成した図形は、そのままでも良いのですが、操作性・見栄えも考えて少し加工します。
まず１１７行目では矢印図形の軸部分を太くします。図形を調整には、図６－７のように図形のAdjustmentsで操作します。
矢印図形のAdjustmentsにはItem(1)とItem(2)の２種類があり、太さを変更するにはItem(1)の値（既定値0.5）を大きくします（最大で1.0）。今回は「少しだけ矢印の耳を残した」0.9を設定しています。

図６－７

太くしたのには理由があります。矢印図形を移動・伸縮し確定するために任意セルを選択しますが、「矢印図形が乗っているセルを選択」しようとすると、既定の太さの矢印図形では「図形を選択」したことになってしまい、うまくセルが選択できないことになります。
たぶんマウスのマークのサイズや、セルの高さなども影響するのでしょうが、「軸部分を太く」しておけば、図形の下のセルに触れやすくなるようです。

１１８行目の「AR.Fill.Visible = msoFalse」は、図形の「塗りつぶしなし」を選択するのと同等のものです。
元の日程線（青いセル範囲）が見易くなるのと併せて、上記の「矢印図形が乗っているセルをクリックし易くする」ために塗りつぶしなしにしています。

１１９行目の「AR.Line.ForeColor.RGB = RGB(0, 0, 0)」は、枠線の色を黒色にしています。これは趣味だけです。
最後に１２０行目で「AR.Select」とし、図矢印図形を選択した状態で「ユーザーの操作」を待ちます。

これで矢印図形の描画が完成しましたので、１２２行目で「図形監視（Shape_check）」プロシージャ（図６－８）に仕事を引き継ぎます。

６－４．矢印図形の変形を監視

図６－５の１２２行目から呼び出されるのが図６－８です。内部ではDo～Loopで図形の変化を監視し続けます。

124. '==========　⇩(7)　矢印図形の変形を監視　============
125. Private Sub Shape_check()
127. 　Application.EnableCancelKey = xlErrorHandler
129. 　On Error GoTo myErr
131. 　　Do Until AR Is Nothing
133. 　　　If AR.Top <> ARtop Or AR.Height <> ARheight Or Not AR.Rotation = 0 Then
134. 　　　　Call ARverticalFix
135. 　　　End If
137. 　　　If AR.Left <> ARleft Or AR.Width <> ARwidth Then
138. 　　　　Call ARcellFix
139. 　　　　Call ARareaFix
140. 　　　End If
142. 　　　If Not VarType(Selection) = vbObject Then
144. 　　　　If Selection = Range("a1") Then
145. 　　　　　Err.Number = 18
146. 　　　　　GoTo myErr
147. 　　　　End If
148. 　　　End If
150. 　　　DoEvents: DoEvents
152. 　　Loop
154. 　On Error GoTo 0
156. 　Application.EnableCancelKey = xlInterrupt
158. 　Call GridChange(False)
160. 　Exit Sub
162. myErr:
164. 　If Err.Number = 18 Then
165. 　　AR.Delete
166. 　　Set AR = Nothing
168. 　ElseIf Err.Number = 424 Then　　'手動で図形を削除されてしまった時
169. 　　Set AR = Nothing
171. 　Else
172. 　　MsgBox Err.Description
174. 　End If
176. 　Call GridChange(False)
178. End Sub

図６－８

図形には「Shape_Change」のようなイベントが無いため、Do～Loopを使って監視をします。ですので、このShape_checkプロシージャのメインの仕事は「図形の変形を監視（１３３行目および１３７行目）」です。その結果、縦方向の変形・移動があれば「元に戻す修正（１３４行目）」をし、また横方向の変形・移動があれば「その変形が正しい変形か、正しくなければ形を修正（１３８～１３９行目）」することです。

しかしDo～Loopが回っている最中に、ユーザーが操作をキャンセルしようと「ESCキー」が押されたり、「図形をDeleteキー等で削除」してしたりということは想定しておく必要がありますので、その分のコードが多くを占めることになってしまいます。

６－４－１．エラー処理の設定

１２７行目の「Application.EnableCancelKey = xlErrorHandler」は「ESCキー（またはCtrl+Breakキー）」が押された時の動作を指示するものです。図６－９のように３種あり、１２７行目では「xlErrorHandler」を指定していますので、ESCキーを押すとエラーが発生することになります。（エラー番号で正常処理するのが目的です）

EnableCancelKeyプロパティ

定数	値	内容
xldisabled	0	Escキーを無視
xlErrorHandler	2	エラーを発生。エラーコード＝18
xlInterrupt	1(既定)	プロシージャを停止

図６－９

そして１２７行目の設定を生かすため、１２９行目で「On Error GoTo myErr」と「エラー発生時はmyErrへ飛ぶ」設定をします。

６－４－２．監視実行

１３１～１５２行目のDo～Loop内で、矢印図形の変形を監視することになりますが、その継続条件は１３１行目の「Until AR Is Nothing」と「AR（矢印図形）が無くなるまでDo～Loopを続ける」ことにしています。

監視場所は２箇所あります。監視の１箇所目は１３３行目、２箇所目は１３７行目です。
まず、１箇所目の１３３行目「If AR.Top <> ARtop Or AR.Height <> ARheight Or Not AR.Rotation = 0 Then」は、
　・「AR.Top <> ARtop」：図形の上端が、前回と異なる
　・「AR.Height <> ARheight」：図形の高さが前回と異なる
　・「Not AR.Rotation = 0」：図形が回転した
の３項目を監視しています。この３つのどれかが当てはまる時、１３４行目で「ARverticalFix（図６－１０）」を呼出し、「Top」値、「Height」値、「Rotation」値を修正します。
なお図形のTop値等が変更されるのは、ユーザーが図形を動かした時だけではありません。ユーザーが「行の高さを変更」した時にも図形の上下方向のプロパティ値に変化が生じます。そのため、修正には変数ARrow値（何行目のデータか）を使い「常にダブルクリックした行の上に図形がある」ようにしています。

監視の２か所目は１３７行目です。If文は「If AR.Left <> ARleft Or AR.Width <> ARwidth Then」と、
　・「AR.Left <> ARleft」：図形の左端位置が前回と異なる
　・「AR.Width <> ARwidth」：図形の幅が前回と異なる
の２項目を監視しています。この２つのどれかが当てはまる時、１３８～１３９行目を実行します。

１３８行目から呼び出す「ARcellFix（図６－１１）」では、図形をセル境界にピッタリと沿うように微調整します。
また１３９行目から呼び出す「ARareaFix（図６－１５）」は、日程線領域をはみ出したり逆転したりしている図形を「開始日・完了日計算に支障の無いように図形の位置・サイズを調整」します。
当初「ARareaFix」のみで試行していたのですが、グリッド吸着でもセル境界にピッタリ合わない場合があったり、日程線領域の各列幅がバラバラな状態 も想定して、先に「ARcellFix」でセル境界に合うように微調整してから大きな形状修正をすることにしました。

なお、監視に使用している変数「ARtop」「ARleft」「ARwidth」「ARheight」は、「矢印図形を手動で動かす前の位置・サイズ」です。

６－４－３．ESCキーの処理

１４２行目の「If Not VarType(Selection) = vbObject Then」は、実は「ESCキーを押した時」の処理です。
１２７行目の「Application.EnableCancelKey = xlErrorHandler」のところで、矢印図形が描画されている時に「ESCキー」が押されるとエラー番号18が発生する説明をしました。１２９行目で「On Error GoTo myErr」としていますので、ESCキーを押すとmyErrへ飛ぶはずです。しかし、今回システムの場合「ESCキーでエラー番号18は、ほとんど発生しない」のです。

理由を考えてみました。通常ESCキーを押してプログラムが中断するのは、Excelが一生懸命にマクロコードの処理をしている最中です。
今回システムに置き換えれば「ユーザーが動かした矢印図形を、プログラムが位置・サイズ修正している最中」です。しかしプログラムにしてみれば、その処理さえも瞬時に完了させてしまうため、実質Do～Loop内で動いているコードは１３３行目と１３７行目の「図形が動いたか否か」の判断だけの非常に軽い処理です。
ですので、プログラムが修正している最中を狙ってESCキーを押してさえも、なかなかエラー番号18は発生しません。現在のPCは処理速度が早いこともあり、ほとんどは１５０行目の「DoEvents」のところでESCキーが実行されている感じです（私の感触）。

DoEventsの場所でESCキーが実行されると、それまで選択していた矢印図形からセル（図６－５の９５行目でSelectしたA1セル）に選択が移動します。手動でも「図形を選択した状態からESCキーを押すと、図形からはFocusが外れてセルへ移る」事が確認できます。
これを利用し、１４２行目の「VarType(Selection)」で「選択しているものの種類」を調べ、それが矢印図形「vbObject」でなかったら（セル選択の場合はNothingになります）、１４５～１４６行目のエラー処理への準備・移動をすることにしました。

ただし通常操作で「矢印図形の日程を確定しようとして、任意のセルをクリック」した時に、丁度１４２行目の「VarType(Selection)」を評価してしまうと、「日程を確定したつもりが、キャンセル扱いになってしまった」ということになってしまいます。
ですので「ESCキーで図形からFocusが外れた証拠」として１４４行目で「If Selection = Range("a1") Then」の条件式を入れました。
試行段階では、任意のセルをクリックした時には１４２～１４４行目よりも「SelectionChangeイベントの方が早く実行される」ようですが、確証が取れないので１４４行目は外さずにおいてあります。

ということで、ESCキーを押すとほとんどが１４２行目で引っ掛かり、図６－５の９５行目で図形描画前にA1セルに移動済みですので、１４４行目の「If Selection = Range("a1") Then」も成立し１４５～１４６行目を実行します。
１４５行目は、ESCキーがエラー番号18を発してエラーとなった時と合わせるため「Err.Number = 18」と強制的にエラー番号を付け、１４６行目では１２９行目の代わりに「GoTo myErr」と１６２行目へ飛ばしています。

但しこの手法を使えるのは、今回のような「図形を選択させて」から「ESCキーが押される」ことにより「図形から選択が外れる」というような状況にしか使えません。通常のセル操作中のESCキー検出などでは別な方法が必要と思います。

１５０行目は、O/S側に処理を渡しています。この間でユーザーは図形操作をしていることになります。

６－４－４．Do～Loopを抜けたあとの処理

ユーザーが矢印図形を操作している間は１３１～１５２行目のDo～Loopの中を回っていますが、任意のセルを選択すると開始日・完了日データを書き込み、その後矢印図形を削除します。
すると１３１行目のDo～Loopの終了条件「Until AR is Nothing」が成立するためDo～Loopから抜け出します。

抜け出した後は、１５４行目の「On Error GoTo 0」でエラー発生時の飛び先を解除し、１５６行目でESCキーの「EnableCancelKeyプロパティ」を既定の「xlinterrupt」に戻します。
両方ともマクロが終了すれば、勝手に元に戻ってくれるようですが、自分で設定したものは自分で解除しておくべきと考えます。

その後１５８行目で「GridChange」を呼出します。引数に「False」を指定していますので、グリッド吸着有無を元のユーザー環境に戻します。（矢印図形描画前にグリッド吸着有りにしてあれば、吸着解除をしないことになります。）
最後に１６０行目の「Exit Sub」でプロシージャを終了します。

６－４－５．エラー発生時の処理

１２９行目の「On Error GoTo myErr」と１５４行目の「On Error GoTo 0」の間でエラーが発生した場合は１６２行目のmyErrラベルに飛びます。通常のエラーのみで無く、１４２～１４８行目のESCキーを押した時の疑似エラーもmyErrラベルに飛びます。

１６４～１７４行目では、エラー番号で仕分けて処理をします。
まず１６４行目の「If Err.Number = 18 Then」が成立するのは、エラー番号が18の時です。
それに当てはまる条件の１つ目は、「ESCキーを押した」時に内部処理中（＝図形の位置・サイズの計算など）だった時です。その時は１２７行目の設定（Application.EnableCancelKey = xlErrorHandler）によりエラー番号18が発生します。
条件のもう１つは、「ESCキーを押した」事により矢印図形から選択が外れ、１４５行目の「Err.Number = 18」によりエラー番号が18になった時です。
その場合は１６５～１６７行目を実行します。

まず１６５行目の「AR.Delete」で矢印図形（AR）を削除し、１６６行目の「Set AR = Nothing」でARオブジェクトを解放します。
実は図形を削除しただけでは「ARオブジェクト」は残っています。
ですので、ここで解放をしておかないと「図形をESCキーでキャンセルしたのち、どこかのセルをクリック」した時に、図５－２の１４行目の「If Not AR Is Nothing Then」が成り立ってしまい、矢印図形の実体が無いのに１５行目の「Data_Fix」プロシージャを呼び出してしまいます。Data_Fixは、矢印図形ARの位置・サイズから開始日・完了日を計算する工程ですので、オブジェクトが存在しないことでエラーが発生します。

次に１６８行目の「ElseIf Err.Number = 424 Then」ですが、これは「選択している矢印図形をユーザーがDeleteキーで削除してしまった」事を想定しています。
Do～Loop内では、１３３～１３５行目で矢印図形（ARオブジェクト）の位置・サイズを常時監視していますが、図形削除でそのARオブジェクトが消えてしまうと実行時エラー「オブジェクトが必要です」が発生し、１２９行目の「On Error GoTo myErr」に従って、エラー処理部に飛んできます。この時のエラー番号は424です。
このエラーでの処理は、オブジェクト（AR）はユーザーによって既に削除済みですので、１６９行目の「Set AR = Nothing」でARオブジェクト開放のみをします。

それ以外のエラー（いわば本当のエラー）の場合は、１７２行目の「MsgBox Err.Description」でエラー内容を表示して終了します。
最後に１７６行目で「GridChange(False)」を呼出し、グリッド環境をユーザー仕様に戻します。

６－５．矢印図形の上下方向の位置・サイズを元に戻す

図６－８の１３４行目から呼び出されるのが図６－１０です。

180. '==========　⇩(8)　矢印図形の位置をセル単位に補正　============
181. Private Sub ARverticalFix()
183. 　AR.Rotation = 0
184. 　ARheight = Cells(ARrow, 1).Height
185. 　ARtop = Cells(ARrow, 1).Top
186. 　AR.Height = ARheight
187. 　AR.Top = ARtop
189. End Sub

図６－１０

このプロシージャ内では、図形の以下の３つのプロパティを修正をしています。
　・図形の回転（Rotation：１８３行目）
　・図形の高さ（Height：１８６行目）
　・図形の上下方向の位置（Top：１８７行目）

そしてその修正値となるのが、変数ARheight・ARtopです。
通常、矢印図形だけを操作している時は「ARheight・ARtopは不変」ですが、矢印図形が表示されている最中に「図形よりも上にある行の高さを変更」した時には「図形の上下方向の位置・図形の高さが変更」されてしまいます。
但し変数ARrow（操作している行位置）は不変ですので、その値を使って１８４行目の「ARheight = Cells(ARrow, 1).Height」と１８５行目の「ARtop = Cells(ARrow, 1).Top」とで変数ARheight・ARtopを書き換えています。
なお、Rotation値は常にゼロにしています。

また、この実行順番には意味があります。
実は図形を変形（今回は上下方向）させたのち、まずTopを修正し次にHeightを修正すると、修正した図形のTopがまた少しだけズレる（私のPCでは0.00008 ポイント）現象が時々発生するのです。（なお修正する順番を「Height → Top」にしても、Heightがズレることは今のところ確認されていません）
なお、回転方向の修正順序で、Topがズレる現象は（今のところ）発生しませんでした。

ですのでこの「上下方向の修正」では、影響の無い（少ない）「Height」と「Rotation」の修正を先に実行し、「Topを最後に修正することで、ズレを無くす（少なくする？）」ことにしました。

６－６．矢印図形の位置をセル単位に補正する

図６－８の１３８行目から呼び出される「矢印図形の位置をセル単位に補正」するプロシージャが図６－１１です。

190. '==========　⇩(9)　矢印図形の位置をセル単位に補正　============
191. Private Sub ARcellFix()
193. 　Dim ARscol As Range 　　　　　　 '←矢印図形の左端が含まれるセル（ARのstart columnの略）
194. 　Dim ARecol As Range 　　　　　　 '←矢印図形の右端が含まれるセル（ARのend columnの略）
196. 　If AR.TopLeftCell.Left + AR.TopLeftCell.Width / 2 < AR.Left Then
197. 　　Set ARscol = AR.TopLeftCell.Offset(0, 1)
198. 　Else
199. 　　Set ARscol = AR.TopLeftCell
200. 　End If
202. 　If AR.BottomRightCell.Left + AR.BottomRightCell.Width / 2 < AR.Left + AR.Width Then
203. 　　Set ARecol = AR.BottomRightCell.Offset(0, 1)
204. 　Else
205. 　　Set ARecol = AR.BottomRightCell
206. 　End If
208. 　AR.Width = ARecol.Left - ARscol.Left
209. 　AR.Left = ARscol.Left
211. End Sub

図６－１１

セル境界にピッタリとした図形では、図６－１２のように「図形の左端（TopLeftCellプロパティ）」は「オレンジ色のセル」を指し、「図形の右端（BottomRightCellプロパティ）」は「緑色のセル」を指します。
オレンジ色の方は感覚的に合いますが、緑色の方は１つズレている感じがします。しかし、セル幅にピッタリ収まっている図形では「図形の右端位置（図形のLeft ＋ 図形のWidth）」と「緑色セルのLeft」とは同じ値です。

図６－１２

今回システムも図形端部の位置とセルの位置の値を比較して、図６－１５のARareaFixプロシージャで「図形の左端・右端が矢印エリアをオーバーしていないか」、また図６－２７のData_Fixプロシージャで「図形の左端・右端がどの日付を指しているか」を計算しています。
ですので、その処理の前に「図形をセル幅ピッタリに微調整」しておくのが、このARcellFixプロシージャの役目です。

微調整の考え方ですが、図６－１３のように「左端・右端が属するセルの、近い方の端部に合わせる」ようにしました。

図６－１３

左端の位置把握と調整する位置の計算が、図６－１１の１９６～２００行目です。
１９６行目の「If AR.TopLeftCell.Left + AR.TopLeftCell.Width / 2 < AR.Left Then」の内「AR.TopLeftCell.Left」が図６－１３の(B)、「AR.TopLeftCell.Width / 2」が(A)/2 に相当します。ですので「(C)の位置」と「図形の左端（赤い点）」を比較することになり、赤い点の方が遠い（＝線(C)よりも右側にある）場合（図６－１３の(2)）に１９７行目を実行します。

(2)の場合１９７行目の「Set ARscol = AR.TopLeftCell.Offset(0, 1)」で、一つ右側のセルを変数ARscolに代入します。
赤い点の方が近い（＝線(C)よりも左側にある）場合（図６－１３の(1)）は、１９９行目「Set ARscol = AR.TopLeftCell」で、左端が属するセルを変数ARscolに代入します。

一方、右端の位置把握と調整する位置の計算が、２０２～２０６行目です。
２０２行目の「If AR.BottomRightCell.Left + AR.BottomRightCell.Width / 2 < AR.Left + AR.Width Then」の内、「AR.BottomRightCell.Left + AR.BottomRightCell.Width / 2」は、やはり図６－１３の(C)の閾線を表します。また「AR.Left + AR.Width」は、図形の右端（緑の点）になりますので、緑の点の方が遠い（＝線(C)よりも右側にある）場合（図６－１３の(4)）に２０３行目を実行します。

(4)の場合は２０３行目の「Set ARecol = AR.BottomRightCell.Offset(0, 1)」により、現在右端が属しているセルの一つ右側のセルをARecolに代入します。
また(3)の場合には２０５行目の「Set ARecol = AR.BottomRightCell」で現在右端が属しているセルをARecolに代入します。

上記で得られた「ARscol」「ARecol」を使って、２０８～２０９行目で「セル境界に沿った図形」に微修正していきます。
図６－１４のように「ARscol（オレンジ色のセル）」と「ARecol（緑色のセル）」が１９６～２０６行目で求められたので、２０８行目の「AR.Width = ARecol.Left - ARscol.Left」では、図形ARのWidthに「ARecolとARscolの横方向の差」を設定します。
また２０９行目の「AR.Left = ARscol.Left」で、図形ARのLeftに「ARscolのLeft値」を設定します。


図６－１４

Leftの設定をWidthの後ろで実行しているのは、図６－１０でTopの設定をHeightの設定の後で実施しているのと同じ理由です。Left→Widthの順番だとLeftがズレてしまう現象が、私のPCですと10～20回に１回発生していました。
順番を変更しWidth→Leftの順番にすると、100回ほど確認しましたが１回も発生せず、効果はありそうです。このあとのARareaFixプロシージャなどでも、この順番で実行していきます。

これで「セル境界に沿った図形」への修正が完了です。

６－７．矢印図形が変形された時の処理

図６－８の１３９行目から呼び出される「日程線領域からはみ出した図形の修正等」を行うプロシージャが図６－１５です。

213. '==========　⇩(10)　図形のはみ出し等を修正　============
214. Private Sub ARareaFix()
216. 　Select Case ARtype
217. 　　Case 0
218. 　　　If ((AR.Left + AR.Width) > Cells(1, DstartCol + Dwidth).Left) And AR.Left = ARleft Then 　 '(0-1)
219. 　　　　AR.Width = Cells(1, DstartCol + Dwidth).Left - ARleft
220. 　　　　ARwidth = AR.Width
221. 　　　ElseIf (AR.Left < Cells(1, DstartCol).Left) And AR.HorizontalFlip = True Then 　 '(0-2)
222. 　　　　AR.Flip msoFlipHorizontal
223. 　　　　AR.Width = ARleft - Cells(1, DstartCol).Left
224. 　　　　AR.Left = Cells(1, DstartCol).Left
225. 　　　　ARleft = AR.Left
226. 　　　　ARwidth = AR.Width
227. 　　　ElseIf (AR.Left < Cells(1, DstartCol).Left) And (AR.Left + AR.Width) = (ARleft + ARwidth) Then 　 '(0-3)
228. 　　　　AR.Width = ARleft + ARwidth - Cells(1, DstartCol).Left
229. 　　　　AR.Left = Cells(1, DstartCol).Left
230. 　　　　ARleft = AR.Left
231. 　　　　ARwidth = AR.Width
232. 　　　ElseIf (AR.Left + AR.Width) > Cells(1, DstartCol + Dwidth).Left And AR.HorizontalFlip = True Then 　 '(0-4)
233. 　　　　AR.Flip msoFlipHorizontal
234. 　　　　AR.Width = Cells(1, DstartCol + Dwidth).Left - AR.Left
235. 　　　　AR.Left = ARleft + ARwidth
236. 　　　　ARleft = AR.Left
237. 　　　　ARwidth = AR.Width
238. 　　　ElseIf AR.Left < Cells(1, DstartCol).Left Then 　 '(0-5)
239. 　　　　AR.Width = ARwidth
240. 　　　　AR.Left = Cells(1, DstartCol).Left
241. 　　　　ARleft = AR.Left
242. 　　　　ARwidth = AR.Width
243. 　　　ElseIf (AR.Left + AR.Width) > Cells(1, DstartCol + Dwidth).Left Then 　 '(0-6)
244. 　　　　AR.Width = ARwidth
245. 　　　　AR.Left = Cells(1, DstartCol + Dwidth).Left - ARwidth
246. 　　　　ARleft = AR.Left
247. 　　　　ARwidth = AR.Width
248. 　　　ElseIf AR.Left <> ARleft Or (AR.Left + AR.Width) <> (ARleft + ARwidth) Then 　 '(0-7)
249. 　　　　If AR.HorizontalFlip = True Then AR.Flip msoFlipHorizontal
250. 　　　　ARleft = AR.Left
251. 　　　　ARwidth = AR.Width
252. 　　　End If
254. 　　Case 1
255. 　　　If AR.HorizontalFlip = True And AR.Left + AR.Width >= Cells(1, DstartCol + Dwidth).Left Then 　 '(1-1)
256. 　　　　AR.Flip msoFlipHorizontal
257. 　　　　AR.Width = 0
258. 　　　　ARwidth = AR.Width
259. 　　　　AR.Left = Cells(1, DstartCol + Dwidth).Left
260. 　　　　ARleft = AR.Left
261. 　　　ElseIf AR.HorizontalFlip = True Then 　 '(1-2)
262. 　　　　AR.Flip msoFlipHorizontal
263. 　　　　AR.Width = ARwidth
264. 　　　　AR.Left = ARleft
265. 　　　ElseIf (AR.Left + AR.Width) <> (ARleft + ARwidth) Then 　 '(1-3)
266. 　　　　AR.Width = ARwidth
267. 　　　　AR.Left = ARleft
268. 　　　ElseIf AR.Left < Cells(1, DstartCol).Left Then 　 '(1-4)
269. 　　　　AR.Width = Cells(1, DstartCol + Dwidth).Left - Cells(1, DstartCol).Left
270. 　　　　ARwidth = AR.Width
271. 　　　　AR.Left = Cells(1, DstartCol).Left
272. 　　　　ARleft = AR.Left
273. 　　　ElseIf R.Left <> ARleft Then 　 '(1-5)
274. 　　　　ARwidth = AR.Width
275. 　　　　ARleft = AR.Left
276. 　　　End If
278. 　　Case 2
279. 　　　If AR.HorizontalFlip = True And AR.Left < Cells(1, DstartCol).Left Then 　 '(2-1)
280. 　　　　AR.Flip msoFlipHorizontal
281. 　　　　AR.Width = 0
282. 　　　　ARwidth = AR.Width
283. 　　　　AR.Left = Cells(1, DstartCol).Left
284. 　　　　ARleft = AR.Left
285. 　　　ElseIf AR.HorizontalFlip = True Then 　 '(2-2)
286. 　　　　AR.Flip msoFlipHorizontal
287. 　　　　AR.Width = ARwidth
288. 　　　　AR.Left = ARleft
289. 　　　ElseIf AR.Left <> ARleft Then 　 '(2-3)
290. 　　　　AR.Width = ARwidth
291. 　　　　AR.Left = ARleft
292. 　　　ElseIf AR.Left + AR.Width > Cells(1, DstartCol + Dwidth).Left Then 　 '(2-4)
293. 　　　　AR.Width = Cells(1, DstartCol + Dwidth).Left - ARleft
294. 　　　　ARwidth = AR.Width
295. 　　　ElseIf (AR.Left + AR.Width) <> (ARleft + ARwidth) Then 　 '(2-5)
296. 　　　　ARwidth = AR.Width
297. 　　　End If
299. 　End Select
301. End Sub

図６－１５

図形の修正方法は、矢印図形の種類によって大きく違いますので、プロシージャ内では「ARtype」によってプログラムを分けています。
両矢印（ARtype＝0）の場合は２１８～２５２行目、左矢印（ARtype＝1）の場合は、２５５～２７６行目、右矢印（ARtype＝2）の場合は、２７９～２９７行目を実行します。

６－７－１．両矢印（ARtype=0）の処理

両矢印の場合の、左右方向に移動・変形したとき「どのような形になるか」を図６－１６にまとめました。
３列に分けていますが、左列が「矢印図形の右端をクリックして変形」した時の形状、中央が「矢印図形の左端をクリックして変形」した時の形状、右列が「矢印図形全体をクリックして移動」した時の形状です。
また矢印図形の変形結果によっては「領域の左端・右端」をオーバーしますが、今回システムではオーバーは困りますので「領域内に引き戻す」必要があります。その引き戻した時の形状を「赤い点線」で表しています。

図６－１６

このプロシージャは「領域内に収まるように図形を修正」するのが目的ですので、この図６－１６の「赤い点線の修正内容」をパターン毎にまとめたのが図６－１７です。

図６－１７

また変形状態を「プログラム的に発見する方法」をまとめたのが図６－１８です。
これ以外にも発見の方法はあると思いますが、すぐに思いつきそうなものだけで表を作りました。

図６－１８

この「図６－１７」と「図６－１８」の２つの表から、プログラム的に「領域をはみ出した時に、どのような形状で変形させるか」を導く必要があります。しかし、この別々な表からでは難しいので、図６－１９のように合体してみます。

図６－１９

図形を変形させる内容を上側にA～Gに、発見する条件を下側に1～8にしてあります。「発見する条件＝変形内容」ではありませんので、「発見する条件を組み合わせ」て変形内容のパターンを抽出する必要があります。
恐らく色々な方法が存在するはずですが、私ならまず「上側の表で白丸の数の少ない行」を選び、「下側の表でその白丸の列を含み、且つ黒丸の数の少ない行」を見つけます。
例えば、上の表のB行はパターン２のみで、下の表でパターン２を含み数の少ないのは６行目です。しかし６行目にはパターン１２、１６，１７も含まれていますので、次に下の表で「パターン２は含んで、パターン１２，１６，１７は含まれない」または「パターン２は含まないでパターン１２，１６，１７は含む」行を探します。
すると２行目が「パターン２は含まないでパターン１２，１６，１７は含む」行に相当しますので、「B行を検出する条件」は「６行目の検出方法 ー ２行目の検出方法」となり、数式っぽく表すとすれば「(6) And Not(2)」となります（一番右の『パターンを絞り込む式』列）。

他の変形方式についても同様に考え、絞り込む式を作っていきますが、B行目のように「一度作った絞り込み式も発見する条件式」として考えていきます。例えばG行目ではB行目の結果を入れて「(6) And Not(B) And Not(E)」としています。
もし、どう考えても絞り込む式が立てられない場合は、下側の条件を増やすことを考えます。

次に、このようにして作った「パターンを絞り込む式」の実行順序を考えていきます。
式は「全て下の表の『発見する条件式』から作成」されていますので、「A～Gの結果を使用しない」のであればどの順番でもＯＫです。但し「A～Gの結果を使用する」のであれば、順番を考える必要が出てきます。

Excelでは「If～ElseIf～・・・」と条件式を何段にも重ね書き出来ますが、上流で条件が合致したものは、下流側でまた合致したとしても二度と実行されません。この特性を使い、例えば「Bの結果を使っている条件式」は「Bの条件式」よりも下に持ってくることで「Bの結果を外す」ことができるのです。

今回図６－１９でもA～Gの結果を使っている条件式は３つ（A、F、G）ありますので、それぞれが実行された後にもってくるように考え並べると、図６－２０のような順番になります。（この順番も色々なパターンが考えらえると思います）

図６－２０

図６－２０で薄い色にしている部分は「既に実行されていて対象外」になっている部分です。
この順番で「If～ElseIf～・・・」を並べたのが、２１８～２５２行目になります。

まず、図６－２０の順番１は「図形右端が領域右端をオーバー（Right > E）し、且つ図形左端が移動していない」ですので、式は「((AR.Left + AR.Width) > Cells(1, DstartCol + Dwidth).Left) And AR.Left = ARleft」としました。「Right > E」が「(AR.Left + AR.Width) > Cells(1, DstartCol + Dwidth).Left」に該当します。
矢印図形の右端位置は、直接は求められませんので「左端位置＋図形幅」で表します。領域右端の「E」は「Cells(1, DstartCol + Dwidth).Left」となります。

また「Leftが移動していない」は、単純に「AR.Left = ARleft」としました。
ARcellFitプロシージャ（図６－１１）で矢印図形をセル境界に合わせる際に「もしズレが発生」してしまったら、との心配は残りますが、試してみたところズレが出ることは無かったので、今回は誤差が出ないことを前提に式を立てました。

なお「図形右端が領域右端をオーバー」を「＞」と「＞＝」のどちらにするかですが、今回プログラムでは「＞」を使用しました。
図６－１６の②だけを見れば、図形を引き延ばして「ちょうど領域右端で止めた」時には「含めない（＞）」を使った方が処理が少なく良さそう　ぐらいの理由と思われがちです。
しかし「＞＝」を順番１～６の全てに適用（順番７は＜＞なので）してしまうと、例えば領域の右端に「幅ゼロ」の図形がある時に内側に引き延ばそうと変形させても、思惑と異なるElseIf文（この場合は順番６）が反応してしまい、図形を伸ばす事が出来なくなってしまうのです。
イコールの無い「＞」では今のところ不具合が見つかっていないので今回は「＞」を統一して使っていますが、図形の変化を網羅できていない可能性もありますので、もし変な動きをする状態が見つかったらごめんなさい。

順番１で図形に対して行う処理は「右端を領域の右端に＋左端はそのまま（図６－１６の②）」ですので、AR.Leftはそのままにして、２１９行目で「AR.Width = Cells(1, DstartCol + Dwidth).Left - ARleft」と、領域の右端位置（Cells(1, DstartCol + Dwidth).Left）から図形左端を引いた長さを図形幅としています。
また２２０行目では、変更になったAR.Width値を変数ARwidthに代入します。なお変更されない図形左端位置（変数ARleft）は変更しません。

順番２は図６－２０で「Left＜S And 反転している」ですので、２２１行目で「 (AR.Left < Cells(1, DstartCol).Left) And AR.HorizontalFlip = True」としています。図形の反転は、HorizontalFlipプロパティがTrueかFalseかで判断できます。

実行内容は「左端をSにし、右端は元の図形左端（ARleft）にする（図６－１６の⑥）」で、２２２～２２６行目を実行します。
まず２２２行目の「AR.Flip msoFlipHorizontal」で反転を戻します。両端矢印ですので、反転を戻さなくても形状的には大丈夫なのですが、HorizontalFlipプロパティがTrueのままだと「もう一度反転された時に、発見条件に合わなくなる」ので元に戻しておく必要があります。
２２３行目の「AR.Width = ARleft - Cells(1, DstartCol).Left」では、元の左端から現在の左端の距離を、新しい図形の幅にしています。これにより「右端は元の図形左端（ARleft）にする」が達成できます。
２２４行目の「AR.Left = Cells(1, DstartCol).Left」では、図形の左端を領域の左端にしています。

２２３行目と２２４行目におなじ「Cells(1, DstartCol).Left」を使っています。２２４行目を先に実行すれば、２２３行目は「AR.Width = ARleft - AR.Left」とスッキリするのですが、図６－１０で説明したように図形のTop位置にズレが発生し易いのと同様に、Left位置にもズレが発生し易いので、Leftの設定は出来るだけ後で実行するようにしています。
２２５行目の「ARleft = AR.Left」と２２６行目の「ARwidth = AR.Width」で、新しい図形の現在位置の変数値を置き換えています。

順番３は「Left＜S And Rightが移動していない」ですので、２２７行目で「(AR.Left < Cells(1, DstartCol).Left) And (AR.Left + AR.Width) = (ARleft + ARwidth)」としています。「移動していない」は２１８行目のIf文と同様に、ズレが出ないことを前提にしています。

実施内容は「左端をSに合わせ、右端は元の図形の位置にする（図６－１６の⑧）」で、２２８～２３１行目を実行します。
まず２２８行目の「AR.Width = ARwidth + (ARleft - Cells(1, DstartCol).Left)」は、右端を固定するため矢印図形の幅を計算しています。図６－１６の⑧を見て分かる様に、元の図形の左端（ARleft）と領域左端（Cells(1, DstartCol).Left）との差に、元の幅（ARwidth）を足すことで新たな図形の幅が求まります。
次に２２９行目の「AR.Left = Cells(1, DstartCol).Left」で図形左端を領域の左端に合わせます。
最後に、２３０行目の「Rleft = AR.Left」と２３１行目の「ARwidth = AR.Width」で、矢印図形の変数値を書き換えます。

順番４は「Right＞E And 反転している」ですので、２３２行目で「((AR.Left + AR.Width) > Cells(1, DstartCol + Dwidth).Left) And AR.HorizontalFlip = True」としています。
実施内容は「図形右端をEにし、図形の左端を元図形の右端にする（図６－１６の⑫）」で、２３３～２３７行目を実行します。
まず２３３行目で反転を戻し、２３４行目の「AR.Width = Cells(1, DstartCol + Dwidth).Left - AR.Left」で領域の右端と元の図形の左端の差を図形の幅（Width）にします。現在の図形の左端は元の図形の右端のまま固定されているように見えますが、操作によってはズレる時がありますので２３５行目の「AR.Left = ARleft + ARwidth」で元の右端位置に戻しています。
最後に２３６～２３７行目で矢印図形の変数値を書き換えます。

順番５は「Left＜S」ですので、２３８行目で「AR.Left < Cells(1, DstartCol).Left」としています。
実施内容は「図形の左端をSにし、長さは元の図形と同じ（図６－１６の⑭⑮）」です。図形は位置の変更（この場合は、左端位置を領域の左端へ）をしても、サイズ（この場合、長さ・幅）は変わりませんので、図形のWidthプロパティの変更は不要に思えます。
しかし今回システムでは、このプロシージャの前処理として「ARcellFixプロシージャ」でセル位置にピッタリするように図形の補正をしています。例えば日程線領域内では列幅が同一だとしても、その外側の列幅が異なるとすると、領域をはみ出した図形はまず「領域の外の列幅に合わせて図形サイズを補正」した後（元の図形とサイズが変わってしまっている）に、このプロシージャで処理を行うことになります。
ですので、２３９行目の「AR.Width = ARwidth」で矢印図形の幅を元に戻しています。そして２４０行目の「AR.Left = Cells(1, DstartCol).Left」で図形左端を領域の左端に併せています。
最後に２４１～２４２行目で矢印図形の変数値を書き換えます。

順番６は「Right＞E」ですので、２４３行目で「(AR.Left + AR.Width) > Cells(1, DstartCol + Dwidth).Left」としています。
実施内容は「図形の右端をEにし、長さは元の図形と同じ（図６－１６の⑯⑰）」で、ほぼ順番６と同じです。
２４４行目の「AR.Width = ARwidth」で図形幅を元に戻し、２４５行目の「AR.Left = Cells(1, DstartCol + Dwidth).Left - ARwidth」で、図形の右端を領域の右端に併せています。２４６～２４７行目で矢印図形の変数値を書き換えます。

順番７は「Leftが移動　または　Rightが移動」ですので、２４８行目で「AR.Left <> ARleft Or (AR.Left + AR.Width) <> (ARleft + ARwidth)」としています。
実施内容は「図形の変更を容認（図６－１６の①③④⑤⑦⑨⑩⑪⑬）」ですが、図形がもし反転していた場合は元に戻しておかないと「次に反転した時に、反転プロパティが消え（AR.HorizontalFlip = False）てしまい、正しい判定が出来なく」なってしまいます。ですので、２４９行目の「If AR.HorizontalFlip = True Then AR.Flip msoFlipHorizontal」で、反転図形の場合に元に戻しています。
その他は容認しますので、２５０～２５１行目で矢印図形の変数値を書き換えます。

なお２４８行目までで「修正するべき図形は全て処理済み」ですので、２４８行目のIf文は「Else」という方法も考えられます。ただしその場合は、動いていない矢印図形（図６－１６の『初期』のもの）も「このElseを通過する」ことになります。
今回システムはグリッド吸着で図形の動きに制限を与えていますが、それでも図形を微妙に動かすことが可能です。微妙に動かされた図形は「ARcellFix（図６－１１）」プロシージャでセル単位に補正され、そのあとに「ARareaFix（図６－１５の、このプロシージャ）」が必ず実行され、「Else」でAR.LeftとAR.Widthが同じ値で置き換えられることになります。
もし「ARcellFix」で修正された時に「微妙なズレが発生」してしまった場合は、Elseの場合は「ズレが正当化」されて、変数ARleft、及びARwidthがズレた値に置き換えられてしまいます。
このような「異常を少しでも取り込まない」ために、今回は「Else」にはせず、２４８行目のElseIf文を使うことにしました。

６－７－２．左矢印（ARtype=1）の処理

左矢印（完了日が領域の外にある）場合に、図形を移動・変形したときに「どのような形になるか」また「どのような形に収めるのか」をまとめたのが、図６－２１です。両矢印との大きな違いは、図形の右端が動いても元に戻すことです。

図６－２１

両矢印の時と同様に「図形の変形方法」と「発見方法」を１つの表にし、図６－２２の表を作成しました。そして、変更方法ごとに絞り込む式を立案しました。変形方法ごとにパターンを絞り込む式の作り方は、両矢印の時と同じです。

図６－２２

その作られた式には、他の変形方法を使用している（例えば、変形方法Dの式に変形方法Cの結果を使っている）ものもあるため、図６－２３のように実行する順序を考えて並べます。

図６－２３

この順番でIf～ElseIf～文を組み立てていきます。
まず順番１は「図形が反転していて、図形の右端が領域の右端をオーバーしている」ですので、２５５行目で「AR.HorizontalFlip = True And AR.Left + AR.Width >= Cells(1, DstartCol + Dwidth).Left」としています。

式の不等号はType0～2も含め、他のIf文ではイコール無しの「＞」を使っているのに、２５５行目だけは「イコール付き」にしています。これは左矢印図形を縮めて「領域の右端に幅ゼロにしよう」とした時に、図形の幅（Width）はゼロで且つ図形位置（Left）は領域右端ですので、「AR.Left + AR.Width = Cells(1, DstartCol + Dwidth).Left」となってしまい、イコール無しの不等号では２５５行目のIf文が不成立になります。
すると２６１行目（順番２）のIf文「AR.HorizontalFlip = True」で成立してしまうため、「元の状態に戻されて」しまいます。
原因は、図形を右方向に縮めてゼロにする時は、グリッド吸着の影響もあるため図形は反転した状態で極小になるためです。（なお、左方向に縮めてゼロにする時は反転しないで極小になるため、２７９行目のIf文にはイコールを付けていません。）

順番１の実施内容は「反転を戻し、領域右端で最小にする（図６－２１の④）」です。
まず２５６行目の「AR.Flip msoFlipHorizontal」で反転を戻します。次に２５７行目の「AR.Width = 0」で図形幅をゼロにし、２５８行目で変数ARwidth値を更新しています。
最後に２５８行目の「AR.Left = Cells(1, DstartCol + Dwidth).Left」で、図形の左端を領域の右端に合わせ、変数ARleft値を２５９行目で更新します。

順番２は「図形が反転している」ですので、２６１行目は「AR.HorizontalFlip = True」としています。
順番２の実施内容は「反転を戻し、初期状態に戻す（図６－２１の⑦⑧）」です。
まず２６２行目の「AR.Flip msoFlipHorizontal」で反転を戻します。次に２６３～２６４行目で、もとのWidth値・Left値をWidthプロパティ・Leftプロパティに設定することで「元の図形位置・サイズ」に戻しています。

順番３は「図形の右端が移動している」ですので、２６５行目は「(AR.Left + AR.Width) <> (ARleft + ARwidth)」としています。
順番３の実施内容は「初期状態に戻す（図６－２１の⑤⑥⑨⑩⑪⑫⑬）」です。
２６６～２６７行目で、もとのWidth・Left値をWidth・Leftプロパティに設定することで「元の図形位置・サイズ」に戻しています。

順番４は「図形の左端が領域の左端をオーバーしている」ですので、２６８行目は「AR.Left < Cells(1, DstartCol).Left」としています。
順番４の実施内容は「図形の左端を領域の左端に合わせる（図６－２１の②）」です。
まず２６９行目の「AR.Width = Cells(1, DstartCol + Dwidth).Left - Cells(1, DstartCol).Left」で、図形の幅を「領域の幅」に設定し、その値を２７０行目で変数ARwidthに代入します。
次に２７１行目の「AR.Left = Cells(1, DstartCol).Left」で左矢印図形の左端を領域左端に揃え、その値を２７２行目で変数ARleftに代入しています。

順番５は「図形の左端が移動している」ですので、２７３行目は「AR.Left <> ARleft」としました。
順番５の実施内容は「図形の変形を容認する（図６－２１の①③）」ですので、２７４～２７５行目では変数ARwidth・ARleftに図形のWidthプロパティ値とLeftプロパティ値をそれぞれ代入します。

６－７－３．右矢印（ARtype=2）の処理

右矢印（開始日が領域の外にある）場合に、図形を移動・変形しようとしたときに「どのような形になるか」「どのような形に収めるのか」をまとめたのが、図６－２４です。

図６－２４

図６－２５は、「図形の変更方法」と「発見方法」を一覧にしたものです。そして変更方法ごとに絞り込む式を立案しました。

図６－２５

その作られた式の中には、他の変形方法の式を参照しているものがありますので、図６－２６のように実行順序を考えて並べます。

図６－２６

内容はARtype=1をちょうど反転させた まず順番１は「図形が反転していて、図形の左端が領域の左端をオーバーしている」ですので、２７９行目のIf文は「AR.HorizontalFlip = True And AR.Left < Cells(1, DstartCol).Left」としました。
順番１の実施内容は「反転を戻し、領域左端で最小にする（図６－２４の④）」です。
まず２８０行目の「AR.Flip msoFlipHorizontal」で反転を戻します。次に２８１行目の「AR.Width = 0」で図形幅をゼロにし、その値を２８２行目で変数ARwidthに代入します。
最後に２８３行目の「AR.Left = Cells(1, DstartCol).Left」で図形左端を領域左端に合わせ、２８４行目でその値を変数ARleftに代入します。

順番２は「図形が反転している」ですので「AR.HorizontalFlip = True」とします。
順番２の実施内容は「反転を戻し、初期状態に戻す（図６－２４の⑦⑧）」です。
２８６行目の「AR.Flip msoFlipHorizontal」で反転を戻し、２８７～２８８行目で元の図形のARwidth・ARleft値を新しい図形のWidthプロパティ・Leftプロパティにそれぞれ設定します。

順番３は「図形の左端が移動している」ですので「AR.Left <> ARleft」としています。
順番３の実施内容は「初期形状に戻す（図６－２４の⑤⑥⑨⑩⑪⑫⑬）」です。
２９０～２９１行目で、元の図形のARwidth・ARleft値を新しい図形のWidthプロパティ・Leftプロパティにそれぞれ設定することで、初期状態の位置・サイズに戻しています。

順番４は「図形の右端が領域の右端をオーバーしている」ですので「AR.Left + AR.Width > Cells(1, DstartCol + Dwidth).Left」とします。
順番４の実施内容は「図形の右端を領域の右端にする（図６－２４の②）」です。
２９３行目の「AR.Width = Cells(1, DstartCol + Dwidth).Left - ARleft」で、図形の幅（Width）を領域の全幅に指定します。なお、２６９行目のように「AR.Width = Cells(1, DstartCol + Dwidth).Left - Cells(1, DstartCol).Left」としても良いですが、「右矢印の左端は領域の左端から動かない」ので、右矢印の場合に限り「ARleft」を定数のように使用できます。
２９４行目では、変更された図形の幅値を変数ARwidthに代入しています。

なお、ここでは図形のLeftプロパティに値を設定（コードとしては、AR.Left = ARleft）していません。もしかしたら２９３行目の実行時に「わずかに図形のLeftがズレる」可能性もあります。しかし変数ARleftの値は初期のまま残っていますので、Do～Loopでもう一周回った時に図６－８の１３７行目「If AR.Left <> ARleft Or AR.Width <> ARwidth Then」で引っ掛かり、ARcellFixプロシージャの実行でセル単位に揃えてくれますので、ここでの指定は省略しました。

順番５は「図形の右端が移動している」ですので「(AR.Left + AR.Width) <> (ARleft + ARwidth)」としています。
順番５の実施内容は「変形形状を容認する（図６－２４の①③）」ですので、２９６行目では変数ARwidthに図形のWidthプロパティ値を代入します。なお、図形のLeftプロパティに値を設定しないのは、順番４と同じ理由です。

６－８．矢印図形から開始日・完了日の書込み

矢印図形で日程の調整をしたのち、任意のセルを選択するとWorksheet_SelectionChangeイベントが発生し、図５－２のイベントプロシージャ内の１５行目から図６－２７の「Date_Fixプロシージャ」が呼び出されます。

303. '==========　⇩(11)　開始日・完了日の書込み　============
304. Public Sub Date_Fix()
306. 　Dim ARstartCol As Long 　　　 '←図形の左端の列位置
307. 　Dim ARendCol As Long 　　　　 '←図形の右端の列位置
309. 　ARstartCol = AR.TopLeftCell.Column
310. 　ARendCol = AR.BottomRightCell.Column
312. 　Select Case ARtype
313. 　　Case 0
314. 　　　If AR.Width = 0 Then
315. 　　　　Cells(ARrow, Scol).Value = ""
316. 　　　　Cells(ARrow, Ecol).Value = ""
317. 　　　Else
318. 　　　　Cells(ARrow, Scol).Value = Cells(Drow, ARstartCol).Value
319. 　　　　Cells(ARrow, Ecol).Value = Cells(Drow, ARendCol - 1).Value
320. 　　　End If
322. 　　Case 1
323. 　　　If AR.Width = 0 Then
324. 　　　　Cells(ARrow, Scol).Value = Cells(Drow, DstartCol + Dwidth - 1).Value + 1
325. 　　　Else
326. 　　　　Cells(ARrow, Scol).Value = Cells(Drow, ARstartCol).Value
327. 　　　End If
329. 　　Case 2
330. 　　　If AR.Width = 0 Then
331. 　　　　Cells(ARrow, Ecol).Value = Cells(Drow, DstartCol).Value - 1
332. 　　　Else
333. 　　　　Cells(ARrow, Ecol).Value = Cells(Drow, ARendCol - 1).Value
334. 　　　End If
336. 　End Select
338. 　AR.Delete
339. 　Set AR = Nothing
341. End Sub

図６－２７

このプロシージャ内も矢印図形の形（ARtype）で処理内容が異なりますので、３１２行目の「Select Case ARtype」で分岐させています。両矢印（ARtype = 0）の場合が３１４～３２０行目、左矢印（ARtype = 1）の場合が３２３～３２７行目、右矢印（ARtype = 2）の場合が３３０～３３４行目です。
なお、このプロシージャ内で使用される共通変数・定数を整理しておきます。
　・ARrow　：図形の行位置
　・Scol　　：開始日の列位置
　・Ecol　　：完了日の列位置
　・Drow　　：日付の行位置

まず３０９行目の「ARstartCol = AR.TopLeftCell.Column」、３１０行目の「ARendCol = AR.BottomRightCell.Column」で、矢印図形の左端・右端の「列位置」を取得します。
次に３１２行目の「Select Case ARtype」で、矢印図形のTypeごとに分岐させます。

「両矢印（ARtype = 0）」の場合、矢印図形の幅（Width）がゼロか否かで更に分岐します。
ゼロの場合は、今回システムでは「予定を削除する」ことを表しますので、３１５～３１６行目で「開始日」と「完了日」の日付を空欄にします。
ゼロで無い場合は、３１８行目の「Cells(ARrow, Scol).Value = Cells(Drow, ARstartCol).Value」で、「開始日」に図形の左端が指す日付を記入します。
また３１９行目の「Cells(ARrow, Ecol).Value = Cells(Drow, ARendCol - 1).Value」で、「完了日」に図形の右端（図形的にはARendColは１つ右側を指しますので、１つ左（－１）にズレたところ）の日付を記入します。

「左矢印（ARtype = 1）」の場合も、矢印図形の幅（Width）がゼロか否かで更に分岐します。
ゼロの場合は、今回システムでは「表示日付の最終日の翌日を開始日にする」ことを表しますので、３２４行目の「Cells(ARrow, Scol).Value = Cells(Drow, DstartCol + Dwidth - 1).Value + 1」で、「開始日」に「表示日付の最終日の次の日（＋１）」を記入します。
ゼロで無い場合は、３２６行目の「Cells(ARrow, Scol).Value = Cells(Drow, ARstartCol).Value」で、「開始日」に図形の左端が指す日付を記入します。
左矢印では「完了日」は制御できませんので、操作しません。

「右矢印（ARtype = 2）」の場合も、矢印図形の幅（Width）がゼロか否かで更に分岐します。
ゼロの場合は、今回システムでは「表示日付の初日の前日を完了日にする」ことを表しますので、３３１行目の「Cells(ARrow, Ecol).Value = Cells(Drow, DstartCol).Value - 1」で、「完了日」に「表示日付の初日の前の日（－１）」を記入します。
ゼロで無い場合は、３３３行目の「Cells(ARrow, Ecol).Value = Cells(Drow, ARendCol - 1).Value」で、「完了日」に図形の右端（図形的にはARendColは１つ右側を指しますので、１つ左（－１）にズレたところ）が指す日付を記入します。
右矢印では「開始日」は制御できませんので、操作しません。

開始日・完了日を書き換えたら矢印図形は不要となりますので、３３８行目の「AR.Delete」で図形を削除し、３３９行目の「Set AR = Nothing」で「オブジェクトARを解除」します。ARを解除しないと、Deleteしてもオブジェクトが無くなったことにはならず、図６－８の「Do～Loopが回り続けます」し、図５－２で「図形も無いのにセルを選択すると、開始日・完了日を書き換えようとする（もちろんエラーが出ます）」不具合が発生します。

６－９．｢矢印取消｣ボタンが押された時の処理

ワークシート上の「矢印取消」ボタンをクリックした時に動作するプロシージャが図６－２８です。

343. '==========　⇩(12)　．｢矢印取消｣ボタン　============
344. Public Sub ESCstop()
346. 　If Not AR Is Nothing Then
347. 　　AR.Delete
348. 　　Set AR = Nothing
349. 　End If
351. End Sub

図６－２８

矢印図形が無い時にクリックしても、何も動作しないように３４６行目の「If Not AR Is Nothing Then」で仕訳けています。
図形が存在する時（Not AR Is Nothing がTrue）は、３４７行目の「AR.Delete」で矢印図形（オブジェクトAR）を削除し、３４８行目の「Set AR = Nothing」でオブジェクトを解除します。

６－１０．図形グリッドのON-OFF

図６－５の９８行目、図６－８の１５８行目・１７６行目から呼び出されるのが図６－２９です。
引数として「GridSetting_Get」を受け取り、その引数が
Trueの時は「ユーザーのグリッド設定条件を保存し、矢印図形を操作し易いようにグリッド吸着ONに変更」することを意味し、
Falseの時は「矢印図形の表示が終わったので、保存したユーザーのグリッド条件に戻す」ことを意味します。

353. '==========　⇩(13)　グリッド吸着の変更　============
354. Public Sub GridChange(GridSetting_Get As Boolean)
356. 　Dim CurrentGridSet As Boolean 　　　 '←現状のグリッド吸着の状態
358. 　With Application.CommandBars.FindControl(ID:=549)
360. 　　CurrentGridSet = .Control.State
362. 　　Select Case GridSetting_Get
363. 　　　Case True
364. 　　　　myGrid = CurrentGridSet
366. 　　　　If myGrid = False Then
367. 　　　　　.Execute
368. 　　　　End If
370. 　　　Case False
371. 　　　　If myGrid = Not CurrentGridSet Then
372. 　　　　　.Execute
373. 　　　　End If
375. 　　End Select
377. 　End With
378. End Sub

図６－２９

図形のグリッド吸着は図６－３０のように、図形を選択状態にしてからリボンの描画ツールの「書式」タブ→「配置」グループ→「配置」→「枠線に合わせる」で切り替えます。
左端のマークが選択状態（背景色が薄い灰色）がグリッドON、背景無し状態がグリッドOFFです。ONとOFFはトグルになっているのでクリックするたびに切り替わります。

図６－３０

このクリック操作をマクロ側から行うのが「Application.CommandBars.FindControl (ID:=549) .Execute」というコードです。現在の状態がONであればOFFになり、OFFであればONに切り替わります。
そして「現在のグリッド状態」を知るには「Application.CommandBars.FindControl (ID:=549) .Control.State」の値（Boolean型）で判断をします。値がTrueならON、値がFalseならOFFを表します。

ですので、このプロシージャ内では、３５８行目で「With Application.CommandBars.FindControl (ID:=549)」とし、「グリッド吸着の状態チェック」と「グリッド吸着をクリック」の組合せで、状態を切り替えていきます。なおユーザーのグリッド状態を保存しておくのは共通変数myGridです。

まず３６０行目の「CurrentGridSetting = .Control.State」で現状のグリッド状態を把握し、変数CurrentGridSettingに代入します。Control.Stateで取得する値は「グリッドON＝True」「グリッドOFF＝False」です。
ここで「ん？」と思われた方もいると思います。現状把握は「矢印図形を描画する前にのみ行うはず」なので「直接myGridに入れれば良い」はずですし、また元のユーザー設定に戻す時点では「矢印図形を操作している間は『グリッドON』」だから　です。

しかし今回仕様では、矢印図形を操作している間でもグリッドのON-OFF操作は可能です。もし「描画ツール」が表示されていなくても、事前に「リボンのユーザー設定」でどこかに「グリッド吸着」をセットしておけば可能となります。
ですので一見無駄なコードに見えますが、３６０行目で再確認の意味で現在の状態を取得しています。

次に引数「GridSetting_Get」の値を使って３６２行目のSelect Case文で、動作を切り替えます。
True（ユーザーのグリッド設定条件を保存し、グリッド吸着設定をON）の場合は３６４～３６８行目を実行し、False（保存したユーザーのグリッド条件に戻す）の場合は３７１～３７３行目を実行します。

Trueの場合（ユーザー設定を保管し、グリッド吸着をONにする）は、まず３６４行目の「myGrid = CurrentGridSetting」で、共通変数myGridに現在のグリッド状態を保管します。
そして現状がFalse（グリッドOFF）の時（３６６行目）だけ、３６７行目の「.Execute」でグリッドONに切り替えます。現状が既にONであれば、切り替える必要はありません。

３７０行目のFalseの場合（ユーザー設定に戻す）は、「保存されているユーザー設定」と「現状のグリッド設定」の関係があるので、図６－３１にまとめました。

ﾕｰｻﾞｰ設定 (myGrid)	現状ｸﾞﾘｯﾄﾞ設定 (CurrentGridSet)	実行要否	実行結果
True	True		True
	False	.Execute
False	True	.Execute	False
	False

図６－３１

この表から、ユーザー設定（myGrid）と現状グリッド設定（CurrentGridSet）の値が「逆のもの」について「.Execute」を実行すれば良いことが分かります。ですので、３７１行目で「If myGrid = Not CurrentGridSet Then」とし、成立する場合のみ３７２行目の「.Execute」でグリッド実行することにしました。

７．最後に

大袈裟に言えば今回システムは「図形を使ってセル値を制御する」というものですが、図形の位置・サイズは結構扱いにくく、面倒なプログラムになってしまいました。
もう少し単純に「領域を外れたか」だけを監視し、「領域を外れた図形は元の状態に戻す」というような仕様でも受け入れられるのかもしれません。

また、今回の図形の仕訳けだけでは充分では無く、おかしな動きをする部分が残ってしまいました。
例えば「左矢印」の図形を領域の右端に幅ゼロに縮め（＝表示日付の次週初日を開始日にする）ます。次にその幅ゼロとなった図形を「反転させて」復活させる（＝表示日付内に開始日を戻す）操作をすると、幅ゼロの図形に戻ってしまいます。
ここでポイントになっているのは、図形幅ゼロの状態から引き延ばすときに「反転させないように延ばす」か、または「反転させて延ばす」かです。
（なお、図形幅ゼロの図形に横方向からそっとマウスを近づけ、マウスの形状が「」から「」になり、次に「」になった時に図形をクリックして「マウスが近づいてきた方向に伸ばせば反転せずに変形」が出来るようです）

原因は「図形を幅ゼロから反転させて伸ばす」と「図６－２１には存在しない形」になってしまうため、プログラムとして判断を誤ってしまうためです。これは、図形をセルサイズに合わせる「ARcellFixプロシージャ」の副作用（中途半端な図形幅に出来ない）とも言えるのですが、これが無いとまたパターンが増えてしまうというやっかいなものです。
不具合解消には、幅ゼロの状態から図形を変形させた時のパターンを洗い出し、それぞれに「どのように形状修正をさせるか」を考える必要があります。
しかし通常のパターンの分けだけで疲れ切ってしまったので、今回は省略しています。また機会があったら再トライします。
期せずして図形幅がゼロになってしまった時には、「矢印取消」ボタンやESCキーなどで「一旦キャンセル」してから再実行するようにして下さい。

また、片矢印図形が表示された状態で、その範囲内の列幅を変更すると、固定側にズレが発生してしまします。原因は、「固定側が移動した」と判断し、図形の幅を元に戻そうとするロジックだからです。
更に悪いことに、その後矢印側を動かしても「固定側が移動している（順番３）」という判断が「矢印側が移動している（順番５）」の判断よりも前にあるために、動かなくなる現象になってしまいます。

対策として下記のような手法が考えられますが、内部で使うアプリであれば「注意しながら使ってもらう」でも良いかと思います。
１）常に領域の左端・右端をチェックする
２）左端・右端の位置をLeft・Widthと併せて列位置も記憶しておく
３）GridChange内に「ActiveWindow.DisplayHeadings = False／True」を仕込み、「図形描画時は行列番号を非表示」にする
４）シート保護で「列の書式設定」をロックする


マウス操作で日程の開始・完了を設定できるタスク表（it-053.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。