2021/10/02

図形カレンダーをクリックし日付入力

• １．背景
• ２．システム概要
• ３．プログラムの流れ
• ４．作業用シートのマクロ
• ５．カレンダーシート（Sheet1）
• 　５－１．カレンダー数式
• 　５－２．カレンダーの条件付き書式
• ６．標準モジュール（Module1）
• ７．ユーザーフォーム（UserForm1）
• 　７－１．レイアウト
• 　７－２．フォームモジュール
• 　　７－２－１．起動時初期設定
• 　　７－２－２．フォームの起動・戻し
• 　　７－２－３．表示年月の移動
• 　　７－２－４．カレンダーの表示
• 　　　よりみち（Repaintの必要性）
• 　　　よりみち（画像ファイルの形式）
• 　　７－２－５．日付の選択
• 　　７－２－６．OK／Cancelボタン
• 　　７－２－７．表示年月／指定日の表示
• ８．アドインとしてExcelにマクロを登録
• ９．最後に
• サンプルファイル

１．背景

実務では日付を入力する場面は多いと思います。しかし日付を決める時には、曜日を考えたり他の予定との関係を考えたりする必要がありますし、日付の数字をキーボードから打ち込むよりは、カレンダーの日付をクリックする方が便利だと考え、以前このサイトで「セルへの日付入力をカレンダー日付クリックで選定する」を紹介しました。

図１－１（以前紹介したクリック式カレンダー）

この時は、フォーム上にコマンドボタンを６行×７列に並べ、ボタンの表面文字列を日付にしカレンダーの形を作りました。そしてWithEventsによりボタンクリックのイベントを共有し、クリックされたボタンの表面文字列（＝日付）から日付を計算し出力する、というものでした。
この方法は色々なサイトでも紹介されており、完成するとカッコイイのですが、フォーム上にボタンを数十個揃えながら並べるのは結構根気がいります。

そこで今回は、「ワークシート上で永久カレンダーを作る」で紹介した「ワークシート上に作ったカレンダー」をフォーム上に画像表示し、そのカレンダーをクリックすることで日付を出力するものを紹介します。
また、フォーム上のLabelにカレンダーを表示する「ラベルカレンダーをクリックし日付入力」も参考にして下さい。

２．システム概要

今回システムはExcelにアドイン登録しておき、日付を入力するセルに対し「呼出しマクロ」を仕込むことによってカレンダーが呼び出されるものです。この仕込む「マクロ」の内容については、「作業用シート 」の項で説明します。

その「呼出しマクロ」が、図２－１のワークシートに仕込んであるとします。「Ｃ４セルをダブルクリック①」すると呼び出されたり、「ボタンをクリック②」すると呼び出されたりするものです。
例えばＣ４セルをダブルクリックすると、カレンダーが表示③されます。今日の日付は赤字で表示されてます。

図２－１

カレンダーは、上部のスクロールバーの操作で表示年月を変更できます。スクロールバーの「スクロール矢印（図２－２参照）」部をクリックした際には１か月ずつ移動し、レール部をクリックすると１年移動します。
また「今月」というボタンをクリックすることで、どこが表示されていても今月にジャンプします。


図２－２

必要な年月まで移動させ、図２－３のように日付の部分をマウスクリック⑤すると、ダイアログ下部に「指定した日付」が表示されます。そしてダイアログ下部のOKボタンをクリック⑥すると、ダイアログが消えて「指定した日付がセルに出力」されます。

図２－３

なお図２－４のように「既に日付が入っている場合」は、起動時のカレンダーは「日付のある年月」を表示し、また下部にはその日付が指定日として表示されます。

図２－４

「OKボタン」をクリックした時には、上述した通りダイアログ下部の「指定日」がセルに出力されることになります。ですので「どこの日も指定していない状態」でOKボタンをクリックすると、セルは空白セルとなります。
また「Cancelボタン」をクリックした時には、何も出力しないため、元のセル値のままとなります。

３．プログラムの流れ

今回プログラムでは、カレンダーの表示に関わる情報（基準日、指定日など）は全てワークシート上に保存し、その値を使った数式および条件付き書式でカレンダーを作成しています。ですので、日付入力セルから呼び出される「CalSelectDate」では、そのセルの情報をシートカレンダーに書き込み、出来上がったシート上のカレンダーを画像としてフォーム上で表示し起動します。

起動したフォーム上で、表示カレンダーの年月を変更した際も、変更年月をシートカレンダーに書き込み、変更されたカレンダーを画像としてフォーム上で表示します。
ユーザーがフォーム上のカレンダーの日付を指定した際にも、そのクリック位置からシートカレンダー上のセル位置を割り出し、シートカレンダー値を変更します。

ユーザーが指定した日付でOKであれば、シートカレンダー上の指定日を呼出し元の日付入力セルに戻します。

図３－１

４．作業用シートのマクロ（サンプルファイルではSheet1）

日付を入力する作業用シートを図４－１とします。
　①N4セルをダブルクリックするとカレンダーを表示し、同じN4セルに指定した日付を入力
　②ボタンをクリックするとカレンダーを表示し、P4セルに指定した日付を入力
するためのマクロを考えます。

図４－１

まず①のマクロは図４－２のように、ワークシートのBeforeDoubleClickイベントを使用します。

1. '==========　⇩(1)　ダブルクリックでカレンダーを表示　============
2. Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
4. 　If Target.Address = Range("N4").Address Then
5. 　　Cancel = True
6. 　　Call CalSelectDate(Target)
7. 　End If
9. End Sub

図４－２

次に②のボタンによる操作では、図４－３のようにボタンのClickイベントを使用します。ボタンはActiveXコントロールで作った場合です。フォームコントロールでボタンを作る場合は、マクロ名を適当なものに変えて下さい。
内容的には単純に、１４行目「Call CalSelectDate(Range("P4"))」で、図４－４の「CalSelectDate」プロシージャを呼出します。CalSelectDateへの引数としては、日付を入力する「P4セル」をRange型で指定します。

11. '==========　⇩(2)　ボタン操作でカレンダーを表示　============
12. Private Sub CommandButton1_Click()
14. 　Call CalSelectDate(Range("P4"))
16. End Sub

図４－３

上記イベントから呼び出されるCalSelectDateプロシージャが図４－４です。引数として「単一セル範囲」を受取ります。

18. '==========　⇩(3)　　============
19. Private Sub CalSelectDate(D As Range)
20. 　Dim P As String 　　　 '←呼び出すファイルのフルパス
21. 　Dim F As String 　　　 '←呼び出すファイル名
23. 　P = Application.UserLibraryPath
24. 　F = "it-065.xlam"
26. '　P = ThisWorkbook.Path & "¥" 　　　 '←サンプルファイル用
27. '　F = ThisWorkbook.Name 　　　　　 '←サンプルファイル用
29. 　Application.Run "'" & P & F & "'!" & "CalSelectDate", D
30. End Sub

図４－４

今回システムは、サンプルファイル「it-065.xlsm」をExcelにアドインし、そのアドインファイルのマクロを呼び出す方法としました。
アドインでは無く、どこかの場所に「it-065.xlsm」を置いておき、そのxlsmファイルのマクロを呼び出す方法も考えられますが、やってみると「マクロ呼出し時に、xlsmファイルのワークシートが一瞬表示」されるため、見栄えの点からアドイン方式としました。（Application.ScreenUpdating = False をうまく使えば、一瞬表示は避けられるかもしれません。）

アドインファイル保存先は各PCで異なりますが、そのPathを取得するのが２３行目「P = Application.UserLibraryPath」です。
なおアドイン保存先は、通常「Environ("userprofile") & "¥AppData¥Roaming¥Microsoft¥AddIns¥"」の場所になります。
（「Environ("userprofile")」の部分で、ユーザーごとに異なる部分を環境変数userprofileで吸収しています。）

ファイル名は、サンプルファイル「it-065.xlsm」であれば「it-065.xlam」へと拡張子が変わります（.xlsm → .xlam）ので、２４行目「F = "it-065.xlam"」でアドインファイル名を設定します。

なお「サンプルファイル」は、カレンダー作成シートと作業用シートを同じにし、そのまま試行が出来るようにしていますので、２３～２４行目の代わりに２６～２７行目を生かしています。
　２６行目「P = ThisWorkbook.Path & "¥"」
　２７行目「F = "it-065.xlsm"」
なお「ThisWorkbook.Path」で得られるPathには、「Application.UserLibraryPath」の時と異なり最後に「¥」が付いて来ません。ですので、ファイル名との結合のために「¥」を追加しています。

２９行目「Application.Run "'" & P & F & "'!" & "CalSelectDate", D」では、Runメソッドを使い「アドイン保存先にあるアドインファイル」の中のマクロ「CalSelectDate」を呼び出しています。引数には、カンマの後ろに「D（引数として受け取ったセル範囲）」を指定します。
Runメソッドは、他のブックのプロシージャを呼び出すもので、呼び出すものがPrivateであっても呼び出せてしまいます。

「パス名＋ファイル名」は、図４－５のように両端を「'（シングルクォーテーション）」で囲み、またマクロ名との間には「!（エクスクラメーション：感嘆符）」を入れます。アドインファイルを保存後、「アドイン無効」「アドイン有効」のどちらの設定でも「シングルクォーテーション無しでは実行されない」ようです。


図４－５

またRunメソッドを使った場合に、マクロの引数に「Range型」を指定する例は、どのサイトにも載っていなかったため心配したのですが、実際にやってみるとちゃんとRange型として伝わっているようです。
なお、「Run」はApplicationのメソッドであるため、ここでは「Application.Run」と記していますが、Runがグローバルとして定義されているために単に「Run」だけでも動作します。

５．カレンダーシート（Sheet1）

カレンダー自体は、全てワークシート関数で作成しています。「ワークシート上で永久カレンダーを作る」も参考にして下さい。

５－１．カレンダー数式

まず、カレンダー作成の基準値について、図５－１の様に位置を決め、数式を記入します。

図５－１

カレンダーは日曜始まりとしています。これは、WEEKDAY関数で得られる数値が日曜始まりになっているためです。月曜始まりも可能ですが、数式の見直しは必要になります。

「D1～J1セル」は、曜日を表す数値を手入力しています。
「B3セル」は、「カレンダー上のクリックした日付」をマクロ側から記入します。
「B4セル」は、今日の日付とするため「=TODAY()」と数式を入力します。
「B6セル」は、表示カレンダー年月の初日（〇月1日）です。マクロ側から記入します。
「B7セル」は、表示カレンダー年月の初日の曜日（数値）です。数式として「=WEEKDAY(B6)」を入力します。
「B8セル」は、表示カレンダー年月の最終日（＝日数）です。「=DAY(DATE(YEAR(B6),MONTH(B6)+1,0))」を入力します。

カレンダー内部の数式は図５－２の様に入力します。なお、D2～J2セルの「日～土」の文字列は手入力です。

図５－２

カレンダーの数字の入る部分は、７列×６行で作成しています。これは「初日が土曜日で、日数が３１日」の月であっても、６行目の２コマ目までしか使われないことから６行としています。

数式を入れるエリアは、図５－２の様に①～⑤のエリアに分けて考えます。
まず①のエリアは、初日が入るエリアです。初日の曜日は「B7セル」で分かっていますので、その値とカレンダー上部の「曜日を表す数値（D1～J1セル）」を比較し、合致したセルに数値「１」を入れます。
その後ろ（初日の曜日値より右側）は、１つ左のセルの値に＋１をして連番を作ります。これを数式で表したのが「=IF($B$7>D$1,"",(IF($B$7=D$1,1,C3+1)))」（D3セルでの数式）となります。D3に数式を記入したら、同じエリア内の他のセルへは「フィルハンドルを持ってドラッグ」します。

次に②③のエリアです。カレンダーの枠が最も少なくて済むのは「初日が日曜日で、日数が２８日」の場合で、ちょうど７列×４行に収まります。つまり、１行目を除く「２～４行目は必ず数値が入る」ことになりますので、②③のエリアは空白になることはありません。単純に「一つ前の数値に＋１」をすれば良いすることになります。
数式としては、③の方は左隣セルに１を足した「=D4+1」、②の方は一つ上の行の最終日を参照して「=J3+1」とします。

最後に④⑤のエリアは、最終日が来る可能性があります（２８日の月で、初日が日曜から始まる場合は④⑤エリアは全て空白）。最後の日が来たら、その後ろは全て空白となります。
ですので「１つ前のセル値が最終日だったら空白」「１つ前のセル値が最終日で無かったら＋１」「１つ前のセル値が空白だったら空白」ということになります。これを数式にしたのが、⑤では「=IF(D7="","",IF(D7=$B$8,"",D7+1))」、④では「=IF(J6="","",IF(J6=$B$8,"",J6+1))」となります。
なお、④の先頭セル（D7セル）では、その１つ前のセル（J6セル）には「必ず数値が入っている」ので、数式前半の「=IF(J6="","", 」の部分は実行されることはありません。式としては「=IF(J6=$B$8,"",J6+1)」でもOKですが、今回はD8セルと数式の共通化を図るために、この数式としてあります。

５－２．カレンダーの条件付き書式

カレンダーへの彩色・文字色設定は、全て「カレンダー範囲への条件付き書式」で行っています。図５－３のように４種の設定をしています。

図５－３

条件付き書式の適用先は「D2～J8」ですので、左上角であるD2セルに対する数式を図５－４のように組み立てます。

目的	数式	書式
ﾕｰｻﾞｰ指定日	=$B$6+D2-1=$B$3	背景:緑色
今日の日付	=$B$6+D2-1=$B$4	赤字+太字
日曜日列	=D$2="日"	背景:薄ｵﾚﾝｼﾞ色
土曜日列	=D$2="土"	背景:薄水色

図５－４

例えばユーザー指定日の数式「=$B$6+D2-1=$B$3」は、「表示カレンダーの初日」＋「セルの数値」－１ が「指定日（$B$3）」になっている時に背景を緑色にしています。
また、日曜日列の「=D$2="日"」は、各セルの２行目の値が「日」であれば、背景色を薄オレンジ色にします。
なお書式は上にあるルールほど優先されますので、例えば「指定日が日曜日」だった場合は、上にある「ユーザー指定日の書式」が「日曜日の書式」よりも優先され、緑色の背景色セルとなります。

６．標準モジュール（Module1）

標準モジュールでは、システム全体で使用する変数の設定、及びカレンダーの基準値の設定をした後、フォーム（ユーザー操作用カレンダー）を起動します。またカレンダー終了時には作業用シートのセル値を書き換えます。

図６－１の宣言部では、システム全体で使用する変数の宣言をします。直値を使う方法もありますが、変数を使っていればもしカレンダー描画位置が変更になった時でも図６－２内の変数設定の修正で済みますし、またコードを短く出来たりするメリットもあります。

32. '==========　⇩(4)　変数宣言　============
33. Public CalSh As Worksheet 　 '←カレンダーのシート
34. Public CalRange As Range 　　 '←カレンダー表示範囲
35. Public CalstdD As Range 　　 '←カレンダーの基準日セル
36. Public DesigD As Range 　　　 '←指定日のセル(Designated Dateの略)

図６－１

作業用シートである図４－４の２９行目から呼び出されるのが「CalSelectDate」プロシージャです。３９行目でPrivate設定になっていますが、Application.Runメソッドを使って呼び出されているため、問題無く実行されます。
引数として「日付を入力するセル」且つ「既存の日付が入力されている可能性があるセル」のセル範囲を受取ります。

38. '==========　⇩(5)　起動プロシージャ　============
39. Private Sub CalSelectDate(D As Range)
40. 　Dim OkCancel As Boolean 　 '←ﾕｰｻﾞｰがｸﾘｯｸしたのが、OKﾎﾞﾀﾝかCancelﾎﾞﾀﾝか
42. 　Set CalSh = ThisWorkbook.Sheets(1)
43. 　Set CalRange = CalSh.Range("D2:J8")
44. 　Set CalstdD = CalSh.Range("B6")
45. 　Set DesigD = CalSh.Range("B3")
47. 　If IsDate(D.Value) = True Then
48. 　　DesigD.Value = D.Value
49. 　　CalstdD.Value = DateSerial(Year(D.Value), Month(D.Value), 1)
50. 　Else
51. 　　DesigD.Value = ""
52. 　　CalstdD.Value = DateSerial(Year(Date), Month(Date), 1)
53. 　End If
55. 　OkCancel = UserForm1.UFstart
57. 　If OkCancel = True Then
58. 　　D.Value = DesigD.Value
59. 　End If
60. End Sub

図６－２

４２～４５行目は、システム内で使用する変数への値代入です。
４２行目「Set CalSh = ThisWorkbook.Sheets(1)」は、シートカレンダーを作成しているシートを変数CalShに代入します。
４３行目「Set CalRange = CalSh.Range("D2:J8")」は、カレンダー範囲を変数CalRangeに代入します。
４４行目「Set CalstdD = CalSh.Range("B6")」は、カレンダーの表示年月初日を変数CalstdDに代入します。
４５行目「Set DesigD = CalSh.Range("B3")」は、ユーザーが指定した日付を変数DesigDに代入します。

４７～５３行目は、シートカレンダーを作成するための基準値をシートカレンダー脇に書き込んでいます。
４７行目「If IsDate(D.Value) = True Then」では、日付入力セルの値が「日付」である場合に４８～４９行目を実行します。
４８行目「DesigD.Value = D.Value」で、指定日付セルにその日付を書き込みます。
４９行目「CalstdD.Value = DateSerial(Year(D.Value), Month(D.Value), 1)」では、その日付のある年月の初日を基準日セルに書き込みます。

日付入力セルの値が日付では無かった（空白セル、文字列など）場合は、５１～５２行目を実行します。
５１行目「DesigD.Value = ""」では、指定日付セルを空白にしています。
５２行目「CalstdD.Value = DateSerial(Year(Date), Month(Date), 1)」は、「本日の年月」の初日を基準日セルに書き込みます。

なお、呼び出す側で間違えて「CalSelectDate」の引数に「複数セル範囲」を渡してしまった場合は、「D.Value」はエラーになりますが、「IsDate(D.Value)」はFalseになりますので、「指定日無し」の状態となります。
ここまでの段階で、表示するためのカレンダーは完成しています。

５５行目「OkCancel = UserForm1.UFstart」では、UserForm1内の「UFstart関数プロシージャ」を呼び出します。UFstartはフォームを起動し、ユーザーのダイアログ操作を受けて「OKボタンを押した→True」「Cancelボタンを押した→False」を戻して来ます。
そのTrue・False値を変数OkCancelで受け取ります。

５７行目「If OkCancel = True Then」で、ユーザーが「OKボタンを押した」時だけ、５８行目「D.Value = DesigD.Value」で「日付入力セルに、ユーザーが指定した日付を記入」します。
一方ユーザーが「Cancelボタンを押した」時には何もしないため、日付入力セルは元のままとなります。

７．ユーザーフォーム（UserForm1）

７－１．レイアウト

カレンダーを操作するためのフォームは、図７－１のようなレイアウトにしました。

図７－１

フォームの中央に「カレンダーを表示するImageコントロール」を配置します。その上部には年月を移動するScrollBar1と今月に移動するためのCommandButton3、年月を表示するLabel1を配置します。
また下部には、ユーザーが選択した日付を表示するLabel2、選択した日付を出力するためのCommandButton1（OKボタン）、カレンダー操作をキャンセルするCommandButton2（Cancelボタン）を配置します。

７－２．フォームモジュール

７－２－１．起動時初期設定

フォーム内で共通して使用する変数を図７－２のように宣言部で宣言しています。

62. '==========　⇩(6)　変数宣言　============
63. Dim IsMoveSB As Boolean 　 '←ﾏｸﾛ側からScrollBarを動かしているというﾌﾗｸﾞ
65. Dim OkCancel As Boolean 　 '←ﾕｰｻﾞｰがOKをｸﾘｯｸしたかCancelをｸﾘｯｸしたか
67. Dim ImgWidth As Single 　　 '←Image1の幅
68. Dim ImgHeight As Single 　　 '←Image1の高さ
69. Dim CalLeft As Double 　　　 '←ｼｰﾄｶﾚﾝﾀﾞｰの横位置(ﾎﾟｲﾝﾄ)
70. Dim CalTop As Double 　　　 '←ｼｰﾄｶﾚﾝﾀﾞｰの縦位置(ﾎﾟｲﾝﾄ)
71. Dim CalWidth As Double 　　 '←ｼｰﾄｶﾚﾝﾀﾞｰの幅(ﾎﾟｲﾝﾄ)
72. Dim CalHeight As Double 　　 '←ｼｰﾄｶﾚﾝﾀﾞｰの高さ(ﾎﾟｲﾝﾄ)

図７－２

フォームモジュール内では、ユーザーがImage1上のどの位置をクリックしたか、その位置がシートカレンダー上のどこに相当するかを計算して、カレンダーの日付を割り出しています。その基準となるImage1のサイズ、およびシートカレンダーの位置・サイズは「フォームが起動している間は固定」です。６７～７２行目で宣言している変数は、その固定している値を入れるためのものです。

フォーム起動時に最初に呼び出されるInitializeイベントプロシージャが、図７－３です。

74. '==========　⇩(7)　フォーム初期設定　============
75. Private Sub UserForm_Initialize()
77. 　Me.Image1.PictureSizeMode = fmPictureSizeModeStretch
79. 　IsMoveSB = True
80. 　　Me.ScrollBar1.SmallChange = 1
81. 　　Me.ScrollBar1.LargeChange = 12
82. 　　Me.ScrollBar1.Max = 12
83. 　　Me.ScrollBar1.Min = -12
84. 　　Me.ScrollBar1.Value = 0
85. 　IsMoveSB = False
87. 　Me.Label1.Font.Size = 14
88. 　Me.Label1.Width = 75
89. 　Me.CommandButton1.Caption = "OK"
90. 　Me.CommandButton2.Caption = "Cancel"
91. 　Me.CommandButton2.Cancel = True
92. 　Me.CommandButton2.SetFocus
93. 　Me.CommandButton3.Caption = "今月"
95. 　ImgWidth = Me.Image1.Width
96. 　ImgHeight = Me.Image1.Height
97. 　CalLeft = CalRange.Left
98. 　CalTop = CalRange.Top
99. 　CalWidth = CalRange.Width
100. 　CalHeight = CalRange.Height
102. End Sub

図７－３

７７行目「Me.Image1.PictureSizeMode = fmPictureSizeModeStretch」では、カレンダーを表示するImage1の表示モードを設定しています。PictureSizeModeプロパティに設定可能な値は図７－４です。

定数	値	内容
fmPictureSizeModeClip	0	はみ出ている画像はトリミング(既定値)
fmPictureSizeModeStretch	1	コントロールのサイズに合わせて引き延ばし
fmPictureSizeModeZoom	3	縦横比を保って引き延ばし

図７－４

今回は、クリックした位置を正確に割り出すためにも、Imageコントロールには目一杯のサイズでカレンダーを表示する必要がありますので、「fmPictureSizeModeStretch」を使用します。なおシートカレンダーの縦横比とImageコントロールの縦横比が大きく異なると文字が変形してしまうため、ある程度は合わせておく必要があります。

８０～８４行目は、年月移動用のスクロールバーの設定をしています。しかしスクロールバーのValue値が変化してしまうと、図７－６のChangeイベントが発生し、シートカレンダーの基準日（CalstdDセルの値）がズレてしまう（＝狙いの年月のカレンダーにならない）可能性があります。
ですのでスクロールバーの設定をしている間は、７９行目「IsMoveSB = True」でフラグを立て、図７－６のChangeイベントをスルーさせるようにしています。代わりに「Application.EnableEvents = False」を思いつく方もいるかもしれませんが、フォームのイベントは停止できませんので使えません。

スクロールバーは、図２－２で説明したように「スクロール矢印」のクリックで「１か月移動」、「レール部」のクリックで「１年移動」させるようにしています。ですので、８０行目「Me.ScrollBar1.SmallChange = 1」で、最小移動量を１に、８１行目「Me.ScrollBar1.LargeChange = 12」で最大移動量を１２に設定します。
また、操作後すぐに「スクロールボックス」は中央位置に戻るようにするため、８２行目「Me.ScrollBar1.Max = 12」で最大値を１２に、８３行目「Me.ScrollBar1.Min = -12」で最小値を－１２にし、８４行目「Me.ScrollBar1.Value = 0」でスクロールボックス（Value値）をゼロにしています。
最大値・最小値をそれ以上の値に設定してもOKですが「レール部を連打」されると、想定外の動作をするような気がしますので、制限を掛ける意味で「最大値・最小値は１年」としています。（試したところ、３連打すれば正常に３年移動するようですので、気にしなくても良いのかもしれません。）

Label1は「表示しているカレンダーの年月」を表示するものです。少し目立つように、８７行目「Me.Label1.Font.Size = 14」でフォントサイズを大きくします。また８８行目「Me.Label1.Width = 75」で、「YYYY年MM月」の文字が入りきるサイズにLabelの幅を設定しています（設定幅の75は、トライ＆エラーの結果です）。

８９行目「Me.CommandButton1.Caption = "OK"」は、ユーザーが選択した日付をシートの日付入力セルに書き出すOKボタンの表面文字を設定しています。
９０行目「Me.CommandButton2.Caption = "Cancel"」は、カレンダー操作をキャンセルするCancelボタンの表面文字を設定しています。また９１行目「Me.CommandButton2.Cancel = True」では、ユーザーがESCキーを押した時に「カレンダーのフォームを閉じる」設定をしています。更に９２行目「Me.CommandButton2.SetFocus」では、フォーム起動時にキャンセルボタン（CommandButton2）にフォーカスを当てることで、フォーム起動後すぐにEnterキーを押した時に「カレンダーのフォームを閉じる」設定をしています。
９３行目「Me.CommandButton3.Caption = "今月"」では、「今月に移動するボタン」の表面文字を設定しています。

前述した通り、Image1のサイズ、及びシートカレンダーの位置・サイズは「フォームが起動している間は固定」しているため、処理時間短縮を目的としフォーム起動時に変数に値を代入します。
まずImage1のサイズを、９５行目「ImgWidth = Me.Image1.Width」、９６行目「ImgHeight = Me.Image1.Height」で変数に代入します。
またシートカレンダーの位置を、９７行目「CalLeft = CalRange.Left」、９８行目「CalTop = CalRange.Top」で取得。サイズを９９行目「CalWidth = CalRange.Width」、１００行目「CalHeight = CalRange.Height」で取得します。
この９５～１００行目で設定した変数の関係を図で表したのが、図７－１９になります。

７－２－２．フォームの起動・戻し

図６－２の５５行目から呼び出される「UFstart関数プロシージャ」が、図７－５です。「関数」にしている意味は、標準モジュール側へ「ユーザーの指示（OKボタンを押したか、Cancelボタンを押したか）」を戻すためです。もちろん標準モジュール側に渡す方法は色々ありますが、今回は関数方式を使ってみました。

104. '==========　⇩(8)　フォーム起動・戻り値設定　============
105. Public Function UFstart() As Boolean
107. 　Call TitleYYMM 　　　 '←表示ｶﾚﾝﾀﾞｰの年月表示
108. 　Call DesigYYMM 　　　 '←指定日(下段)の表示
109. 　Call makeCal 　　　　 '←ｶﾚﾝﾀﾞｰの表示
111. 　Me.Show
113. 　UFstart = OkCancel 　　 '←｢OK・Cancel｣のどちらが押されたか
115. End Function

図７－５

１０７行目「Call TitleYYMM」で図７－２３を呼び出し、表示するカレンダーの年月を表示します。
１０８行目「Call DesigYYMM」で図７－２４を呼び出し、作業シート側の日付入力セルに既に入力済みの日付を、カレンダー下部の指定日に表示します。日付入力セルが空白の場合は指定日も空白です。
１０９行目「Call makeCal」で、カレンダー本体をフォーム上のImageコントロールに表示します。

１１１行目「Me.Show」でフォームを表示し、そのフォームに対してユーザーが操作することになります。そしてユーザーが「選択した日付で確定」するために「OKボタン」をクリックすれば、変数OkCancelにTrueが入ります。また、日付入力セル値は「元の値のままで良い」という意味で「Cancelボタン」をクリックした場合には、変数OkCancelにFalseが入った後でフォームが閉じるようにしています。
ですので１１３行目「UFstart = OkCancel」で、「ユーザーの指示」を呼出し側（図６－２の５５行目）へ戻しています。

７－２－３．表示年月の移動

年月を移動するためのツールとして、今回システムでは「スクロールバーによる年月設定（図７－６）」および「今月へのジャンプ（図７－７）」の２種を考えました。
スクロールバーでは、１か月単位・１年単位での移動となります。なお、スクロールボックスを使えば「１～１２か月での移動」も可能ですが、今回Scrollイベントを使っていないため、何か月移動しようとしているのかはユーザーには見えません。

117. '==========　⇩(9)　スクロールバーの移動　============
118. Private Sub ScrollBar1_Change()
119. 　If IsMoveSB = True Then Exit Sub
121. 　CalstdD.Value = DateAdd("m", Me.ScrollBar1.Value, CalstdD.Value)
122. 　Call TitleYYMM
123. 　Call makeCal
125. 　IsMoveSB = True
126. 　　Me.ScrollBar1.Value = 0
127. 　IsMoveSB = False
129. 　Me.CommandButton2.SetFocus
130. End Sub

図７－６

１１９行目「If IsMoveSB = True Then Exit Sub」は、変数IsMoveSBがTrueの時はスクロールバーのChangeイベントをスルーするという意味です。変数IsMoveSBをTrueにするのは、今回システムでは以下の２箇所です。
　・図７－３の７９行目で、フォームの初期設定としてスクロールバーの設定を行っている時
　・図７－６の１２５行目で、ユーザーが動かしたスクロールボックスを元の中央位置に戻す時
２箇所とも「その時点での表示カレンダーの年月が動いてしまっては困る」状況ですので、変数IsMoveSBをTrueにしChangeイベントをスルーすることで「表示カレンダーの年月はそのまま」にしています。

１２１行目「CalstdD.Value = DateAdd("m", Me.ScrollBar1.Value, CalstdD.Value)」は、表示カレンダーの年月を「ユーザーが移動させたスクロールバーの値（Me.ScrollBar1.Value）」の月数だけ移動させています。移動には今回「DateAdd関数」を使用し、「月数」を動かすため第一引数には「"m"」と指定しています。
この１２１行目を実行すると、ワークシート上の数式により、新しい年月のカレンダーになります。

１２２行目「Call TitleYYMM」では、図７－２３を呼出し、フォーム上のカレンダー年月の文字列を書き換えます。
１２３行目「Call makeCal」では、図７－８を呼び出し、シートカレンダーを画像コピーし、フォームのImageコントロールに貼り付けます。

この時点では、ユーザーがスクロールバーを動かしたままの状態（スクロールボックスは中央からズレた場所にある）です。このままだと、次にスクロールバーのレール部をクリックして「１年移動」しようとしても移動できなかったり、２年も移動してしまったりと、ユーザーの意図通りの動きをしてくれなくなります。
ですので、１２６行目の「Me.ScrollBar1.Value = 0」でスクロールボックスを中央位置に移動させ、次のユーザー操作に備えます。但しスクロールバーのValue値を変更すると、Changeイベント（自分自身を再帰呼び出し）が発生してしまいますので、１２５行目「IsMoveSB = True」でフラグを立ててChangeイベントをスルーするようにしています。
（なおフラグを立てなくても、カレンダーはユーザーの意思通りには動きます。但しフォームのImageコントロールへの貼付け動作が増えますので、処理時間は長くなります。）

この時点ではスクロールバーにフォーカスが当たっていますので、１２９行目「Me.CommandButton2.SetFocus」で、「Cancelボタン」にフォーカスを当て、ESCキーで終了できるようにします。

フォーム右上の「今月」ボタンをクリックした時に呼び出されるのが、図７－７です。内容としては図７－６と似通っています。

132. '==========　⇩(10)　今月への移動　============
133. Private Sub CommandButton3_Click()
135. 　CalstdD.Value = DateSerial(Year(Date), Month(Date), 1)
136. 　Call TitleYYMM
137. 　Call makeCal
139. 　Me.CommandButton2.SetFocus
140. End Sub

図７－７

１３５行目「CalstdD.Value = DateSerial(Year(Date), Month(Date), 1)」は、表示カレンダーの年月を「今月」にします。シートカレンダーの基準日は月の初日ですので、DateSerial関数の第三引数に「１」を指定することになります。
１３６行目「Call TitleYYMM」では、図７－２３を呼出し、フォーム上のカレンダー年月の文字列を書き換えます。
１３７行目「Call makeCal」では、図７－８を呼び出し、シートカレンダーを画像コピーし、フォームのImageコントロールに貼り付けます。

この時点では今月ボタンにフォーカスが当たっていますので、１３９行目「Me.CommandButton2.SetFocus」で、「Cancelボタン」にフォーカスを当て、ESCキーで終了できるようにします。

７－２－４．カレンダーの表示

シートカレンダーを画像コピーすると、その画像はパソコン内のクリップボードに一時保存されます。今回システムでは、そのクリップボードの画像を取り出し「ファイル名」を付けて保存し、その保存先をImageコントロールに指定することでカレンダー画像をフォーム上に表示しています。
この内「クリップボードにカレンダー画像を送付」＋「画像ファイルとして受け取り、フォーム上に表示」の部分が図７－８です。

142. '==========　⇩(11)　Imageコントロールへのカレンダー表示　============
143. Public Sub makeCal()
145. 　CalRange.CopyPicture Appearance:=xlScreen, Format:=xlBitmap
147. 　Me.Image1.Picture = LoadPicture(ImgSave(CalRange))
148. 　Me.Repaint
150. End Sub

図７－８

１４５行目「CalRange.CopyPicture Appearance:=xlScreen, Format:=xlBitmap」では、シートカレンダーのセル範囲である「CalRange」に対して、画面コピーをしています。Appearanceパラメータには図７－９の「画像のコピー形式」を、Formatパラメータには図７－１０の「画像形式」を指定します。

Appearanceパラメータ

定数	値	内容
xlScreen	1	画面表示に出来る限り近い形でコピー(既定値)
xlPrinter	2	印刷時と同じ形でコピー

図７－９

Formatパラメータ

定数	値	内容
xlBitmap	2	ビットマップ形式でコピーされた画像(bmp,jpg,gif,png)
xlPicture	-4147	ベクター形式でコピーされた画像(emf,wmf)(既定値)

図７－１０

色々なサイトでの説明を読むと「FormatパラメータにxlPictureを指定した方が画像拡大した時にもぼやけない」とありました。今回は画像を縮小しているため、どうなるか試してみた結果が図７－１１です。

図７－１１

この結果を見て分かる通り、何度やってもxlPictureを指定すると「カレンダーの横罫線がうまく出ない」ようです。今回の縮小の比率が悪いのかもしれませんが、日付をマウスで選択するのに境界線がはっきりしていないと困るため、今回は「xlScreen」×「xlBitmap」の組み合わせで実行することにしました。

１４７行目「Me.Image1.Picture = LoadPicture(ImgSave(CalRange))」は、カレンダーを表示するImageコントロールのPictureプロパティに、シートカレンダーの画像を設定しています。プロパティウィンドウを使ってPictureプロパティの設定を行う時には「パス名＋ファイル名を直接指定」しますが、コードで指定する場合は、LoadPicture関数を使用し、その引数に「画像のパス名＋ファイル名」を指定します。
そのLoadPictureの引数に指定している「ImgSave(CalRange)」は、図７－１２のImgSave関数プロシージャを使用しています。ImgSave関数は、画像ファイルのパス名＋ファイル名を戻してくれます。

１４８行目「Me.Repaint」では、フォームの再描画をして強制的に表示更新をし、現在の表示カレンダーにしています。

なお、このRepaintメソッドが無い場合でも、カレンダー起動後のスクロールバーや今月ボタンによる年月の移動では、カレンダーはちゃんと更新してくれるのですが、なぜか一旦Imageコントロールをクリックしてしまうと、そこからあとは年月移動でのカレンダー更新が行われない現象が発生しました。 なぜImageコントロールのMouseDownイベント（MouseUpイベントでも同様の現象が発生）が一度発生すると自動更新が行われないのか、原因は結局分かりませんでした。フォーム上の表示を変更した時（もしかしたら、ボタン表面文字の変更等も含めて？）には、安心のためRepaintメソッドを実行した方が良いのかもしれません。

上記図７－８の中間工程の、クリップボードに送ったカレンダー画像を「カレンダー画像ファイルに変換」するのが、図７－１２です。引数として、クリップボードにコピーしたセル範囲Rを受け取ります。
このクリップボードの画像をファイルに変換する手法にはいくつか種類がありますが、今回は「Excelからグラフ画像としてExport」する方法を使います。これ以外ではWindows APIを使う方法もあります。

152. '==========　⇩(12)　クリップボードの画像をファイル化　============
153. Private Function ImgSave(R As Range) As Variant
154. 　Dim Cht As Chart 　　　　　　　 '←グラフオブジェクト
155. 　Dim OutputPath As String 　　　 '←出力するパス
156. 　Dim OutputFname As String 　　 '←出力するファイル名
157. 　Dim buf As String 　　　　　　　 '←既存の画像ファイル名
158. 　Dim Fso As Object 　　　　　　　 '←FileSystemObjectオブジェクト
160. 　Set Cht = CalSh.ChartObjects.Add(0, 0, R.Width, R.Height).Chart
162. 　Cht.Parent.Select
163. 　Cht.Paste
165. 　OutputPath = ThisWorkbook.Path
166. 　OutputFname = "it-065img.bmp"
168. 　Set Fso = CreateObject("Scripting.FileSystemObject")
170. 　buf = Dir(OutputPath & "¥" & OutputFname)
171. 　If Not buf = "" Then
172. 　　Fso.getfile(OutputPath & "¥" & OutputFname).Delete
173. 　End If
175. 　Set Fso = Nothing
177. 　Cht.Export Filename:=OutputPath & "¥" & OutputFname, filtername:="BMP"
178. 　Cht.Parent.Delete
180. 　ImgSave = OutputPath & "¥" & OutputFname
182. End Function

図７－１２

１６０行目「Set Cht = CalSh.ChartObjects.Add(0, 0, R.Width, R.Height).Chart」は、図７－１３のように「CalSh（シートカレンダーのあるワークシート）」にグラフ枠を作成しています。

図７－１３

グラフ枠のサイズは、シートカレンダーの縦（R.Height）横（R.Width）サイズと同じ大きさにしています。もしコピー元のサイズより大きくしてしまうと、図７－１４の一番右側のように余白が出来てしまうことになります。
逆に小さくすると、ファイルサイズは小さくなり処理速度も上がるのですが、図７－１４の左側のように「画像が粗く」なってしまうデメリットがあります。今回は最も画像が良い「コピー元と同じサイズのグラフ枠」としています。

図７－１４

次に１６２行目「Cht.Parent.Select」では、図７－１５の左側のように「作成したグラフ枠を選択」しています。コード的に見ると、意味の分からないコードですが、これが無いと（私のExcel2016では）画像が貼り付きませんでした。
一説によると「Excel2016の不具合回避」「貼り付けまでの時間を確保する」とのことですが、「選択をせずに、数秒待ち時間を入れる」処理をしてもダメでしたので、単なるバグなのかもしれません。

１６３行目「Cht.Paste」で、図７－１５の右側のように「グラフ枠に、クリップボードのシートカレンダー画像を貼り付け」ています。貼り付けられる側と貼り付ける側の大きさは合わせていますので、ピッタリの大きさとなります。

図７－１５

１６５行目「OutputPath = ThisWorkbook.Path」では、画像ファイルを保存する場所を指定します。今回は、システム（ブック）が保存されている場所としていますので、アドインして使用する場合にはアドイン保存先になります。なお、実在する場所であればOKです。
１６６行目「OutputFname = "it-065img.bmp"」では、画像ファイルのファイル名を指定しています。今回はBMP形式の画像ファイルにしています。

１６８～１７５行目では、これから保存しようとしている画像ファイルが、既に保存先に存在するか否かを調べ、存在していたら事前に削除しています。ファイル削除にはFileSystemObjectオブジェクトのDeleteメソッドを使用します。

１６８行目「Set Fso = CreateObject("Scripting.FileSystemObject")」でFileSystemObjectオブジェクトを生成します。
１７０行目「buf = Dir(OutputPath & "¥" & OutputFname)」で、Dir関数を使って「画像ファイルが存在するか」を確かめています。もし画像ファイルが存在する場合には「Dir関数は、そのファイル名」を返し、存在しない場合は「""（長さゼロの文字列）」を返してきます。

ですので、１７１行目「If Not buf = "" Then」で変数bufの値を調べ「存在する」ならば、１７２行目「Fso.getfile(OutputPath & "¥" & OutputFname).Delete」で既存ファイルを削除します。
もちろんWindows本体や他のアプリで必要なファイルを削除してしまっては困るので、１６６行目で設定する画像ファイル名は「今回システムでしか使われないようなファイル名」をつける必要があります。
最後に１７５行目「Set Fso = Nothing」で、FileSystemObjectオブジェクトを解除します。

１７７行目「Cht.Export Filename:=OutputPath & "¥" & OutputFname, filtername:="BMP"」では、Exportメソッドを使って「グラフ（今回はカレンダー画像）を画像ファイルとして書き出し」をします。
この「画像ファイルとして書き出す」機能はグラフ（Chart）以外には見当たらないので、「グラフの上にカレンダー画像を乗せて、それを画像ファイルにする」手段を取っています。
Exportメソッドのパラメータとして、Filenameにはパス名＋ファイル名を指定し、filternameにはグラフィックフィルター名である「BMP」を指定しています。

これで、画像ファイルとして保存されましたので、１７８行目「Cht.Parent.Delete」で不要になったグラフ枠＋カレンダー画像を削除します。ここで削除するのは「Cht（Chart）」では無く「Cht.Parent（ChartObject）」です。「Chart」はグラフの軸やタイトルなどグラフ各部の代表（Object）なので、グラフそのものを削除するにはChartObjectを削除する必要があります。

１８０行目「ImgSave = OutputPath & "¥" & OutputFname」で、ImgSave関数プロシージャの戻り値を「カレンダー画像のパス名＋ファイル名」に設定し、図７－８の１４７行目に戻しています。

今回、保存する画像ファイルはBMP形式にしました。しかしBMPは「ファイルサイズが大きい」のが良く知られています。 ですのでJPG形式でも試してみました。コードの変更内容としては図７－１６のように、１６６行目・１７７行目をBMP→JPGに変更しています。 '==========　画像ファイル形式をBMP → JPEG　　============ 　OutputFname = "it-065img.bmp" 　OutputFname = "it-065img.jpg"　'//１６６行目の代替 　 　Cht.Export Filename:=OutputPath & "¥" & OutputFname, filtername:="BMP" 　Cht.Export Filename:=OutputPath & "¥" & OutputFname, filtername:="JPG"　'//１７７行目の代替 図７－１６ 結果は図７－１７です。サイズの大きいBMPの方が遅いと思ったら逆の結果です。ファイル圧縮に時間がかかるのかもしれません。また貼り付けたカレンダー画像には、差は感じられませんでした。 図７－１７ 以上の結果から、今回はBMP形式を使用しています。

７－２－５．日付の選択

フォームのImageコントロール上に表示されたカレンダーをクリックした時に呼び出されるのが図７－１８です。
引数を４つ受け取りますが、今回は第三・第四引数の「Imageコントロール上の、どの位置をクリックしたかを表す座標X（水平方向）・座標Y（垂直方向）」を使用します。

なお、ImageコントロールにはClickイベントというものが無いので、ユーザーがマウスのボタンを押したことに対して反応する「MouseDown」イベントを使用しています。また今回は第一引数のButton、第二引数のShiftの値は無視していますので、マウスを右クリックしても、Shiftを押しながらクリックしても、同じ動作として受け取ります。

184. '==========　⇩(13)　Imageコントロール上のクリック　============
185. Private Sub Image1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As Single, ByVal y As Single)
186. 　Dim Rx As Single 　　　　　　　 '←カレンダーシート上のX位置
187. 　Dim Ry As Single 　　　　　　　 '←カレンダーシート上のY位置
188. 　Dim CalR As Range 　　　　　　 '←カレンダー上のセル位置
190. 　Rx = CalLeft + CalWidth * x / ImgWidth
191. 　Ry = CalTop + CalHeight * y / ImgHeight
193. 　Set CalR = Point2Range(Rx, Ry)
195. 　If IsNumeric(CalR.Value) = True Then
196. 　　DesigD.Value = CalstdD.Value + CalR.Value - 1
197. 　　Call DesigYYMM
198. 　　Call makeCal
199. 　End If
201. 　Me.CommandButton1.SetFocus
202. End Sub

図７－１８

まず、フォームのImageコントロール上の画像カレンダーをクリックした位置を、シートカレンダー上に置き換える考え方を図７－１９で説明します。

図７－１９

変数CalRangeのセル範囲のシートカレンダーをコピーして「Imageコントロール上の画像カレンダー」を作っていますので、両カレンダーは縦横比は多少異なっていますが、「Imageコントロール上の画像カレンダーをクリックしたX･Y相対位置は、シートカレンダーのX･Y相対位置と合致」している事になります。
もう少し簡単に言うと、Imageコントロールの中央をクリックしたとしたら、その位置はシートカレンダー範囲の中央をクリックしているのと同じことになるのです。つまりは「縦寸法の何%の位置」「横寸法の何%の位置」という見方で見れば、Imageもシートカレンダーも一緒であると言えるのです。

但し、変数CalRangeのセル範囲の方は、Excelとしての原点（ワークシートの左上角）からズレて作られています。この分は補正する必要があり、その量は図７－１９の右側のように「CalLeft」「CalTop」（図７－３の９７～９８行目で計算）で得られます。

１９０行目「Rx = CalLeft + CalWidth * x / ImgWidth」は、X方向の両カレンダーの相対位置を使用してワークシート上のX座標を計算しています。
また１９１行目「Ry = CalTop + CalHeight * y / ImgHeight」は、Y方向の両カレンダーの相対位置を使用してワークシート上のY座標を計算します。

１９３行目「Set CalR = Point2Range(Rx, Ry)」では、１９０～１９１行目の計算で得られた「ワークシート上のX･Y座標（Rx・Ry）」をPoint2Range関数プロシージャ（図７－２０）に渡すことで、「セル位置（Range型）」を取得し変数CalRに代入します。

１９５行目「If IsNumeric(CalR.Value) = True Then」は、クリックしたカレンダー上の値が数値だった時に、１９６～１９８行目を実行します。なお「日・月・火･･･などの曜日」または「空白セル」の場合は、数値では無いので何もしません。
まず、１９６行目「DesigD.Value = CalstdD.Value + CalR.Value - 1」では、クリックした値（日付）を「年月日」の形にして、シートカレンダーの指定日（変数DesigD）に書き込みます。
１９７行目「Call DesigYYMM」では、その指定日をフォームの指定日に表示させ、１９８行目「Call makeCal」でフォーム上のカレンダーを更新することで「緑色に着色された指定日のカレンダー」がフォーム上に表示されます。

最後に、２０１行目「Me.CommandButton1.SetFocus」で、OKボタンにフォーカスを当て、このままEnterキーを押せば日付入力セルに指定日が入るようにしています。

図７－１８の１９３行目から呼び出される「ワークシート上のX･Y座標をセル位置に変換」する関数プロシージャが図７－２０です。引数としてX座標値・Y座標値（単位ポイント）を受取ります。

204. '==========　⇩(14)　ワークシート上の座標をセル位置に変換　============
205. Private Function Point2Range(x As Single, y As Single) As Range
207. 　With Sheet1.Shapes.AddShape(msoShapeRectangle, x, y, 0, 0)
208. 　　Set Point2Range = .TopLeftCell
209. 　　.Delete
210. 　End With
212. End Function

図７－２０

ワークシート上の座標をセル位置に変換する方法はいくつか考えられますが、今回は「指定された座標に図形を描画し、その図形のTopLeftCellを取得」する方法としました。図形を描くのは処理時間的に心配でしたが、私のPCで試してみても0.015秒程度です。なお「Application.ScreenUpdating = False」で画面更新停止させると、逆に２倍くらいに処理時間が延びてしまいます。

２０７行目「With Sheet1.Shapes.AddShape(msoShapeRectangle, x, y, 0, 0)」で、指定されたX座標・Y座標に大きさゼロの四角形を描画します。この大きさは処理時間には無関係の様です。
２０８行目「Set Point2Range = .TopLeftCell」で、その図形のTopLeftCellプロパティ（Range型）を取得し、関数プロシージャの戻り値に設定します。
２０９行目「.Delete」で、作成した図形を削除します。

７－２－６．OK／Cancelボタン

フォーム下段の「OKボタン」をクリックした時には、図７－２１が呼び出されます。

214. '==========　⇩(15)　OKボタン　============
215. Private Sub CommandButton1_Click()
216. 　OkCancel = True
217. 　Unload Me
218. End Sub

図７－２１

２１６行目「OkCancel = True」では「ユーザーの意思（選択した日付を入力セルに記入するのか、元の状態にしておくのか）」のフラグをTrue（選択した日付を入力セルに記入する）にします。
そして、２１７行目「Unload Me」でフォームを閉じます。

「Cancelボタン」をクリックした時には、図７－２２が呼び出されます。

220. '==========　⇩(16)　Cancelボタン　============
221. Private Sub CommandButton2_Click()
222. 　Unload Me
223. End Sub

図７－２２

２２２行目「Unload Me」で、単にフォームを閉じます。
尚、OKボタンの所で実行した「ユーザーの意思」のフラグ設定は、Cancelボタンで行う必要はありません。これは、フラグである変数OkCancelは図７－２の６５行目で宣言しているだけですので、初期値であるFalse（＝元の状態にしておく）になっている為です。

７－２－７．表示年月／指定日の表示

フォームの起動時、及び表示しているカレンダーを変更した時に呼び出されるのが、図７－２３です。

225. '==========　⇩(17)　表示カレンダーの年月表示　============
226. Private Sub TitleYYMM()
227. 　Me.Label1.Caption = Format(CalstdD.Value, "yyyy年mm月")
228. End Sub

図７－２３

２２７行目「Me.Label1.Caption = Format(CalstdD.Value, "yyyy年mm月")」では、シートカレンダーの「基準日（CalstdD）」を「〇〇年〇〇月」という表示にして、フォーム上のLabel1に表示します。

フォームの起動時、及びフォーム上のカレンダーの日付をクリックし指定日を変更した時に呼び出されるのが、図７－２４です。

230. '==========　⇩(18)　指定日の表示　============
231. Private Sub DesigYYMM()
232. 　Dim D As Date 　　　　　 '←指定日の日付
233. 　D = DesigD.Value
235. 　If D = 0 Then
236. 　　Me.Label2.Caption = ""
237. 　Else
238. 　　Me.Label2.Caption = Format(D, "yyyy/mm/dd")
239. 　End If
240. End Sub

図７－２４

２３３行目「D = DesigD.Value」は、「シートカレンダーの指定日の日付」を変数Dに代入します。もし指定日欄が空白セルだった場合は、変数Dにはゼロが代入されます。
２３５行目「If D = 0 Then」で変数Dの値を調べ、ゼロ（日付を指定していない空白セルに対して、システムを呼び出した）の場合は、２３６行目「Me.Label2.Caption = ""」でフォーム上の指定日は空白にします。
一方「日付を指定してあるセルに対してシステムを呼び出した」または「フォーム上のカレンダーの日付をクリックし指定日を変更した」時には、２３８行目「Me.Label2.Caption = Format(D, "yyyy/mm/dd")」でフォーム上の指定日に日付を表示します。

なお２３２～２３３行目で、わざわざ変数Dを使っているのは、出来るだけワークシート上にアタックしない方が処理時間的に有利と考えたからですが、コード数が増えただけであまり効果は無いかもしれません。

８．アドインとしてExcelにマクロを登録

このマクロをExcelのアドインに登録することで、「図形カレンダーをクリックし日付入力」を利用することが出来ます。アドイン方法については「年賀状リスト等の宛名検索と追記　アドイン登録」を参照下さい。
なお今回システムでは、ファイルをアドインとして保存するまででOKです。アドインを有効にしなくても動作しますし、リボンのボタンに登録する必要もありません（起動マクロに引数が付いているので、登録する事はできません）。

９．最後に

ワークシート上の図形をフォームのImageコントロール上に表示する手法については、様々なサイトで紹介されていました。しかし、どのような形で実用的に使えるか以前から悩んでいました。
そんな時、当サイトの使用状況を調べてみると「セルへの日付入力をカレンダー日付クリックで選定」に多くのアクセスがあることより、シートカレンダーをフォーム上に表示する方法を思い付き、今回の紹介となりました。

Image上のカレンダー画像がもう少し鮮明であれば良いのですが、コードも少なく面白い手法かもしれません。カレンダー以外にグラフや図形をフォーム上に表示することも可能なはずなので、応用すれば活用範囲が広がると思います。


図形カレンダーをクリックし日付入力（it-065.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。