2021/12/28

ToDoリストで個人タスク管理

• １．背景
• ２．システム概要
• ３．プログラムの流れ
• ４．データ用シート(Sheet1)
• ５．標準モジュール(Module1)
• 　５－１．システムの起動
• 　５－２．テーブルの並べ替え
• 　５－３．テーブルの絞り込み
• 　５－４．絞り込みデータの配列化
• 　５－５．データの最大値取得
• 　５－６．新規データ挿入（Insert文）
• 　５－７．データの変更（Update文）
• 　　よりみち（絞り込み行がゼロの場合のUpdate）
• ６．操作用フォーム(UserForm1)
• 　６－１．フォーム上レイアウト
• 　６－２．フォームモジュール
• 　　６－２－１．フォーム起動時
• 　　６－２－２．Page1（ToDoリスト）
• 　　　６－２－２－１．ToDoリスト作成
• 　　　６－２－２－２．ToDoページの各ボタンの動作
• 　　６－２－３．Page2（新規/更新）
• 　　　６－２－３－１．優先度コンボボックスの設定
• 　　　６－２－３－２．新規/更新の実行
• 　　　　よりみち（実行後のページ移動）
• 　　　　よりみち（アドインへのデータ保存）
• 　　　６－２－３－３．入力欄のクリア
• 　　　６－２－３－４．定期タスクの設定
• 　　　６－２－３－５．期限日の入力欄の制限
• 　　６－２－４．Page3（完了一覧）
• 　　６－２－５．共通プロシージャ
• 　　　６－２－５－１．ページの変更
• 　　　６－２－５－２．完了・中止処置
• 　　　６－２－５－３．データを編集「新規/更新」ページへ送付
• ７．アドインとしてExcelにマクロを登録
• ８．最後に
• サンプルファイル

１．背景

人によって多い少ないはあるにしても、やらなければいけない事は誰でも持っています。しかし、それを忘れずに実行するのは至難の業です。多くの人は、カレンダーに予定を書き込んだりタスク管理アプリなどを利用したりと色々な道具を使って管理していると思います。
私もカレンダーに書いておくことが多いのですが、複数のカレンダーに記入したりするので時々抜けがあったり、また気まぐれにメモ紙に書いて机の前に貼ってみたりと情報がバラバラです。たぶん、常に使う道具に情報を集約しておくのが良い方法なのだと思います。

今回はExcelのアドインとして、やらなければいけない情報を保存するアプリを紹介します。Excelを毎日使っている方であれば、有効な手段かと思います。専用のアプリにはとても太刀打ちできませんが、基本機能である「登録」→「確認」→「完了処理」は出来ますので、参考として下さい。

なお今回システムでは、データはテーブル化（ListObject）した上で操作を行っています。ListObjectを使ったものとして、今回以外にも以下のものが有りますので、そちらも参照下さい。
　・DVD等の内容・保管場所等管理システム
　・先行予約可能な備品予約・貸出システム
　・会社番号検索システム

２．システム概要

今回のToDoリストは、Excelにアドイン登録して使うことを想定しています。アドインとして登録されたマクロ（図２－１の①）を実行すると、操作ダイアログ②が起動します。起動直後は、ToDoリストが表示されます。
なお「サンプルファイル」では、データテーブル横に起動用ボタンを置きました。そのボタンクリックでシステム起動します。

図２－１

表示されるToDoリストは、期限が１週間以内に迫っているタスク項目が表示されます（マクロの定数設定で変更可）。そしてタスクが完了したらリストの対象項目を選択し、上部の「完了」ボタンをクリックすることで完了処置され、ToDoリストから削除されます（項目は「完了一覧」ページへ移動）。
またタスクが不要になった場合には、「中止」ボタンをクリックすることで中止扱いにすることが可能です（この場合も、項目は「完了一覧」ページへ移動）。

タスク項目の登録は、ダイアログ上の「新規/更新」ページから行います。図２－２の左側ように必要項目を入力後、「登録③」ボタンをクリックすることで登録されます（期限が近ければ、ToDoリストに表示④される）。

図２－２

なお新規/更新ページで「定期的」のチェックボックスにレ点を入れ、「毎日・毎週・毎月・毎年」の何れかを選択して登録を行うと、タスクを自動的に繰返し発生させることが出来ます。（正確には、定期的タスクを終了させた時に、次のタスクを自動的に作成します。）

タスク項目の修正を行う場合は、図２－３の左側のようにToDoリストで対象項目を選択し「編集」ボタン⑤をクリックします。するとデータは「新規/更新」ページに移動しますので、修正の上「登録」ボタン⑥をクリックすると編集が完了します。

図２－３

ToDoリストで「完了」または「中止」した項目は、「完了一覧」ページのリストに移動します。完了一覧のリストは、完了・中止後、約１ヶ月分をリストボックスに表示しています（マクロの定数設定で変更可）。
完了・中止した項目は、復活も可能です。図２－４のように対象項目を選択し「復活⑦」ボタンをクリックすることで、データが「新規/更新」ページに移動します。そこで内容を修正し「登録⑧」ボタンをクリックするとデータが復活します。

図２－４

なお、中止した項目は文字通り復活して「完了一覧」から「ToDoリスト」へ移動しますが、完了した項目は「完了データを完了一覧に残し」たまま、新たに「ToDoリスト」にデータを作ります。

３．プログラムの流れ

操作ダイアログ上にはMultiPageコントロールを置き、「ToDoリスト」「新規/更新」「完了一覧」の３ページを作っています。また、Sheet1にテーブル（ListObject）を作り、データを保管します。


図３－１

「ToDo」ページと「完了一覧」ページのリストには、テーブルからデータを引っ張ってきて貼り付けます。当然データを引っ張る前のデータの並べ方と絞り込み条件は、それぞれのリストで異なります。また「新規/更新」ページでは、入力された値を配列にし、テーブル（ListObject）に新規追加・データ行更新を行います。
「ToDoリスト」のデータに対し「完了処置」「中止処置」をする際は、対象データの「FinD(実行日)」列、「Status（状態）」列に日付と処置内容を記入します。
「ToDoリスト」の編集、「完了一覧」の復活ボタンをクリックした際には、その対象のデータを「新規/更新」ページに移動させ、ユーザーがデータを修正後、新規データ追加と同様にデータの新規追加・データ行更新を行います。追加になるか更新になるかは、データの状態（Status列の値）により異なります。

４．データ用シート(Sheet1)

データは、Sheet1に置いています。図４－１のように７列のテーブル（ListObject）で、テーブル名「ToDoT」をあらかじめ設定済みです。

図４－１

各列の内容は、以下の通りになります。

列	列名	内容
A	Num	タスク番号（連番）
B	Task	タスク名
C	Priority	優先度(A･B･C)
D	EndD	期限日
E	FinD	完了･中止日(無印は､未完)
F	Every	定期の内容(無印は､単発)
G	Status	状態：完了or中止(無印は､未完)

図４－２

なおサンプルファイルでは、わざわざアドイン登録しなくても動作確認が出来るように、シート上に起動ボタン（標準モジュールのToDoStartプロシージャを登録）を設けています。

５．標準モジュール(Module1)

標準モジュールでは、システムの起動関係と、テーブル（ListObject）に保管したデータとの直接的なやり取りを行うプロシージャを置いています。

５－１．システムの起動

宣言部では、システムとして使用する変数・定数の宣言と、標準モジュール内で使用する定数の宣言を行っています。

1. '==========　⇩(1)　定数・変数の宣言　============
2. Public T1 As ListObject　　　　　　　　 '←保存データのテーブル
3. Const Sh As String = "Sheet1" 　　　　 '←テーブルの存在するシート名
4. Const Tbl As String = "ToDoT" 　　　　 '←テーブルの名前
5. Public Const Term1 As Integer = 7 　　 '←ToDoリストに載せる期間
6. Public Const Term2 As Integer = 30 　 '←完了リストに載せる期間

図５－１

２行目「Public T1 As ListObject」は、保存データのテーブルをListObjectとして宣言しています。今回システムではテーブルは１つしか使用していないため、テーブルへ直接アクセスするプロシージャ内（標準プロシージャ内）で共有すれば充分なのですが、複数テーブルを操作する時の汎用性を考えてプロジェクトレベル（Public）の変数としています。
３行目「Const Sh As String = "Sheet1"」は、データテーブルのシートを定数宣言しています。
４行目「Const Tbl As String = "ToDoT"」は、データテーブルのテーブル名を定数宣言しています。なお、テーブルのListObject設定は図５－２の１０行目で行っており、３・４行目は図５－２のToDoStartプロシージャ内で宣言することで充分です。しかし、定数値を変更する可能性のある値については「宣言部」で宣言した方が分かり易いと考え、宣言部での宣言を行っています。
５行目「Public Const Term1 As Integer = 7」は、「ToDoリスト」に表示する「期限の〇日前までを載せる」かを宣言しています。サンプルファイルでは「7」としていますので、「7日間（１週間）前になったらToDoリストに表示」しています。
６行目「Public Const Term2 As Integer = 30」は、「完了一覧」に表示する「完了・中止処理から〇日後までを載せる」かを宣言しています。サンプルファイルでは「30」としていますので、「完了・中止してから30日間（約１ヶ月）は完了一覧のリストに表示」しています。

システムを起動するプロシージャが図５－２です。Excelのアドインにサンプルファイルを登録後、起動マクロにはこのプロシージャを登録して下さい。

8. '==========　⇩(2)　システムの起動　============
9. Sub ToDoStart()
10. 　Set T1 = ThisWorkbook.Sheets(Sh).ListObjects(Tbl)
12. 　UserForm1.Show 0
13. End Sub

図５－２

１０行目「Set T1 = ThisWorkbook.Sheets(Sh).ListObjects(Tbl)」で、データのテーブルをObject設定しています。定数である「Sh」「Tbl」は、図５－１の宣言部で宣言しています。
１２行目「UserForm1.Show 0」では、操作ダイアログ（UserForm1）をモードレス（フォームが表示された状態でもExcelシートを操作できる状態）で表示しています。

５－２．テーブルの並べ替え

これ以降は、テーブルへ直接操作するプロシージャ類です。フォーム内から呼び出されるため、全てPublic宣言になっています。

まず図５－３は、テーブルのデータを並べ替えるプロシージャです。引数として、対象のListObjectオブジェクト（T）、並べ替える列名（col）、並べ替えの方向（Sorder：文字列（String）のOrderという意味のつもり）を受取ります。

15. '==========　⇩(3)　テーブルの並べ替え　============
16. Public Sub TableSort(T As ListObject, col As Variant, Sorder As Long)
17. 　With T.Sort
18. 　　.SortFields.Clear
19. 　　.SortFields.Add key:=T.ListColumns(col).Range, Order:=Sorder
20. 　　.Apply
21. 　End With
22. End Sub

図５－３

１７行目「With T.Sort」で、Sortオブジェクトの設定のベースを作っています。
１８行目「.SortFields.Clear」では、Clearメソッドで並び替えレベルの初期化を行います。以前実行した並び替え条件がもし残っていると正しく並び替えができません。

１９行目「.SortFields.Add key:=T.ListColumns(col).Range, Order:=Sorder」で、新たな並び替え条件を作成します。
Addメソッドのパラメータとして、まず「key:=T.ListColumns(col).Range」で、「並び替えの列のRangeオブジェクト」を第二引数で得た「列名col」を使って列を指定します。なお引数colは「列名」でも「列位置（整数）」でもOKですが、今回システムのフォーム内では、分かり易い「列名」を使用しています。
もう一つのパラメータ「Order:=Sorder」では、並び替えの方向を指定します。第三引数で得た「並び順Sorder」を使用します。
パラメータOrderに設定する値は図５－４のようになっており、今回システムでは「値」を使って指定していますが、定数を指定してもOKです。

Orderに設定する値

定数	値	内容
xlAscending	1	昇順で並べ替え（既定値）
xlDescending	2	降順で並べ替え

図５－４

なお、Sort.Addのパラメータは図５－５のように５つありますが、今回はKey（必須）とOrderのみを使用しました。他のパラメータは既定値でOKと判断したためです。

Sort.Addのパラメータ

名前	型	内容
Key	Range	並び替えの列(必須)
SortOn	Variant	並び替えのキー
Order	Variant	並び替え順序
CustomOrder	Variant	ﾕｰｻﾞｰ指定の並び替え順序
DataOption	Variant	データオプション

図５－５

また、Sortオブジェクトに設定できるプロパティは、SortFields以外にもいくつかあります（図５－６）。こちらも既定値でOKと判断し省略しています。今回使用しなかったパラメータ・プロパティについては「DVD等の内容・保管場所等管理システム」でもう少し詳しく説明しています。

Sortの設定可能プロパティ

プロパティ	内容
Header	先頭行を見出しとするか
MatchCase	大文字小文字の区別
Orientation	並べ替えの方向
SortFields	並び替えのキー値など
SortMethod	ふりがなを使うか

図５－６

並び替えの設定が完了したら、２０行目「.Apply」で「並び替えを実行」します。

５－３．テーブルの絞り込み

テーブルの絞り込みを行うのが図５－７です。
引数として、対象のListObjectオブジェクト（T）、絞り込む列名（col）、絞り込み条件（word）を受取ります。

24. '==========　⇩(4)　テーブルの絞り込み　============
25. Public Sub TableFilter(T As ListObject, col As Variant, word As String)
26. 　T.Range.AutoFilter Field:=T.ListColumns(col).Index, Criteria1:=word
27. End Sub

図５－７

２６行目「T.Range.AutoFilter Field:=T.ListColumns(col).Index, Criteria1:=word」では、見出しを含めたテーブル全体「T.Range」に対してフィルターを実行しています。
１つ目のパラメータ「Field:=T.ListColumns(col).Index」では、テーブルの左側から数える「列番号」を整数で指定します。第二引数として得ているcolは「列名」または「列番号」のどちらかですので、整数の列番号に揃えるために「T.ListColumns(col).Index」を使用します。なお、引数を「列番号のみ」とするのであれば直接「 Field:=col」と出来ますが、呼出し側のコードが読み難くなってしまうのと、列の順番を入れ替えたり、列を追加したり出来なくなるデメリットも生じます。

２つ目のパラメータ「Criteria1:=word」は、第三引数の「絞り込み条件」をCriteria1に設定しています。今回システムでは絞り込み条件は「日付列データ <＝ ある日付」のように「条件は１つ」しか使用していませんが、「ある日付 <＝ 日付列データ <＝ ある日付」のように挟み込む場合には、図５－８のように他のパラメータも使って絞り込む必要があります。

AutoFilterメソッドのパラメータ

名前	型	内容
Field	Variant	ﾌｨｰﾙﾄﾞ番号
Criteria1	Variant	抽出条件
Operator	XlAutoFilterOperator	2つの条件を関連付ける演算子 xlAnd、xlOrなど
Criteria2	Variant	2番目の抽出条件
SubField	Variant	抽出条件を適用するﾃﾞｰﾀ型のﾌｨｰﾙﾄﾞ
VisibleDropDown	Variant	ｵｰﾄﾌｨﾙﾀのﾄﾞﾛｯﾌﾟﾀﾞｳﾝ矢印の表示非表示

図５－８

絞り込んだ後は、絞り込みを解除する必要がありますが、そのプロシージャが図５－９です。引数として対象のListObjectオブジェクト（T）を受取ります。

29. '==========　⇩(5)　テーブルの絞り込み解除　============
30. Public Sub TableFilterOff(T As ListObject)
31. 　T.ShowAutoFilter = False
32. 　T.ShowAutoFilter = True
33. 　On Error Resume Next
34. 　　T.DataBodyRange.Rows.UseStandardHeight = True
35. 　On Error GoTo 0
36. End Sub

図５－９

絞り込みを解除するには、「T.AutoFilter Field:=i」というCriteria1パラメータが無いコードを列数（ｉ）だけ繰り返す方法が一般的なようですが、今回は「フィルターを一旦非表示にし、その後で再表示」させる方法としました。この方法によるメリットは 「先行予約可能な備品予約・貸出システム」でも説明していますが、処理速度が早くなる事です。

３１行目「T.ShowAutoFilter = False」で、フィルターを一旦非表示にし、３２行目「T.ShowAutoFilter = True」で再表示しています。
その後の３４行目「T.DataBodyRange.Rows.UseStandardHeight = True」で、「テーブルの行高さを標準高さに設定」していますが、これは、図５－１０の「絞り込みデータの配列化」の中で、「絞りこまれている行か否か」を判断するために「行の高さを調べる」必要が出て来たため、「フィルター解除の際には、行高さを標準に戻す」ようにしています。
なお、データが１つも無い場合には「DataBodyRange」オブジェクトが存在しませんので、エラー停止防止として３３行目「On Error Resume Next」でエラースルーをさせています。

５－４．絞り込みデータの配列化

絞り込まれたテーブルのデータを配列の形にするのが図５－１０です。引数として対象ListObjectオブジェクト（T）を受取ります。

38. '==========　⇩(6)　絞り込みデータの配列化　============
39. Public Function SearchList(T As ListObject) As Variant
40. 　Dim buf1 As Variant 　　 '←テーブルの全データの配列
41. 　Dim buf2 As Variant 　　 '←抽出するデータの配列
42. 　Dim i As Long 　　　　　 '←テーブルの全データ行数
43. 　Dim j As Integer 　　　　 '←テーブルの列数
44. 　Dim k As Long 　　　　　 '←抽出データの行数
45. 　Dim wcnt As Long 　　　 '←テーブルの列数
46. 　Dim icnt As Long 　　　 '←抽出テーブルの要素数
48. 　On Error Resume Next
50. 　　buf1 = T.DataBodyRange
51. 　　wcnt = T.HeaderRowRange.Count
52. 　　icnt = T.DataBodyRange.SpecialCells(xlCellTypeVisible).Count
54. 　　ReDim buf2(1 To Int(icnt / wcnt), 1 To wcnt)
56. 　　For i = 1 To T.DataBodyRange.Rows.Count
57. 　　　If Not T.DataBodyRange.Rows(i).Height = 0 Then
58. 　　　　k = k + 1
59. 　　　　For j = 1 To wcnt
60. 　　　　　buf2(k, j) = buf1(i, j)
61. 　　　　Next j
62. 　　　End If
63. 　　Next i
65. 　　SearchList = buf2
67. 　On Error GoTo 0
68. End Function

図５－１０

５０行目「buf1 = T.DataBodyRange」では、まずテーブルの全てのデータを配列buf1に取り込みます。
従来「先行予約可能な備品予約・貸出システム」は、「処理をする行の絞り込み有無を確認し、絞り込まれた行であればその行の各セル値を配列に代入」するという手法だったのですが、今回は、まず「全データを配列に格納」した後、処理する行の絞り込み有無を確かめ、絞り込まれていれば全データ配列のデータから別な配列へデータをコピーするという手法にしてみました。

検証のため適当なデータを作って試してみました。1000行のデータ処理に掛かる時間を図ってみると、約0.25秒→約0.094秒と1/3に短縮します。また100行の処理でも約0.03秒→0.016秒と半減するので、処理時間の点から有利だと思います。但し、行高さを取得する必要があるため、図５－９のフィルターOffをする際に、行高さを標準に戻す作業は必須となります。（アドインなのでデータは改ざんされる事はない　と判断できるのであれば、行高さを戻すコードは不要かもしれません。）

５１行目「wcnt = T.HeaderRowRange.Count」は、テーブルの列数を取得しています。また５２行目「icnt = T.DataBodyRange.SpecialCells(xlCellTypeVisible).Count」は、絞り込まれたデータの総数（絞り込まれた行数 × テーブルの列数）を取得します。
このデータを使って、５４行目「ReDim buf2(1 To Int(icnt / wcnt), 1 To wcnt)」で、絞り込まれたデータの配列の大きさを設定しています。
処理行が絞りこまれている場合にだけ「ReDim Preserve buf2(・・・)」で１行ずつ格納する配列を広げていく手法もありますが、「絞り込みの結果が１行だった」場合には配列が「１次元配列」になってしまうため、後の処理が面倒になるために「最初に２次元配列を作って置き、そこにデータを格納していく」手法としました。

５６～６３行目では５４行目で作成した配列buf2に、絞り込んだテーブルのデータを代入しています。
５６行目「For i = 1 To T.DataBodyRange.Rows.Count」で、カウンタ変数ｉをテーブルの全データ行分だけ回します。
５７行目「If Not T.DataBodyRange.Rows(i).Height = 0 Then」では、テーブルのその対象行の高さを調べ、「高さゼロでは無い（＝絞り込まれた行）」場合に５８～６１行目を実行させます。ここで「行高さゼロ＝絞り込みから外れた」の判断をしているため、図５－９の３４行目の処理（行高さを標準にする）が必要になります。
５８行目「k = k + 1」で、配列buf2の代入する行位置（ｋ）を設定します。
５９行目「For j = 1 To wcnt」で、配列buf2・配列buf1の列位置（ｊ）を設定します。
６０行目「buf2(k, j) = buf1(i, j)」で、配列buf1（＝全データ）のデータを配列buf2（絞り込んだデータ）に代入します。

配列buf2への代入が完了しましたら、６５行目「SearchList = buf2」で、この関数の戻り値にbuf2を設定します。
なお、テーブルにデータが１つも無い場合には「DataBodyRangeが存在しない」ためにエラーが発生します。または絞りこまれたデータが１行も無い（＝全行が高さゼロ）場合には「５２行目のicntがゼロ」となり、５４行目で配列bufのサイズを決める時にエラーが発生します。
ですので、４８行目「On Error Resume Next」で、エラーが出てもそのまま実行させることで、buf2は初期値のEmptyのままとなり、Emptyが関数SearchListの戻り値となります。
また初期値をEmptyにするため、４１行目でのbuf2の宣言は「Dim buf2() As Variant」では無く「Dim buf2 As Variant」と配列では無い型での宣言が必要です。

５－５．データの最大値取得

重複しないユニーク番号を得る為に、テーブルの列内の最大値を取得する関数が図５－１１です。引数として、対象のListObjectオブジェクト（T）、最大値を取得する列名（col）を受取ります。

70. '==========　⇩(7)　データの最大値取得　============
71. Public Function TableMax(T As ListObject, col As Variant) As Long
72. 　If Not T.ListRows.Count = 0 Then
73. 　　TableMax = WorksheetFunction.Max(T.ListColumns(col).DataBodyRange)
74. 　End If
75. End Function

図５－１１

まず、７２行目「If Not T.ListRows.Count = 0 Then」で、データが１つ以上存在する時に７３行目で最大値を取得します。逆に言うとデータが一つも無い場合は、Long型の初期値のゼロを関数TableMaxは戻すことになります。
また「If Not T.ListRows.Count = 0 Then」とせずに「On Error Resume Next」として、７３行目でエラーが出る（＝データが１つも無く、DateBodyRangeが存在しない）場合にゼロを戻す方法もOKと思います。

７３行目「TableMax = WorksheetFunction.Max(T.ListColumns(col).DataBodyRange)」では、後半「T.ListColumns(col).DataBodyRange」で「対象列のデータ範囲」に対してワークシート関数Maxを使って最大値を取得しています。

５－６．新規データ挿入（Insert文）

データ行を挿入（SQLのInsert文相当）するのが図５－１２です。引数として、対象のListObjectオブジェクト（T）、挿入するデータの配列（Data）を受取ります。
７９行目「With T.ListRows.Add」で、テーブルに新たな行を追加し、８０行目「.Range = Data」でその追加行に配列Dataを貼り付けます。

77. '==========　⇩(8)　新規データ挿入　============
78. Public Sub TableDataIn(T As ListObject, Data As Variant)
79. 　With T.ListRows.Add
80. 　　.Range = Data
81. 　End With
82. End Sub

図５－１２

貼り付けるデータ「配列Data」は、テーブル（T）の列数と同じ１次元配列である必要があります。しかし、列数の不足や超過があっても、また２次元配列（＝複数行のデータ）であってもエラーで止まる事はありません。
但し列が不足した場合には、不足したセルに「#N/A」が入ってしまいますので、その後思わぬ動作をする可能性が出てきます。列数が超過の場合は、超過分が単に無視されます。
また２次元配列を貼り付けようとしても、７９行目で挿入される新たな行は１行のみですので、２次元配列の内の1行目のデータだけが貼り付くことになります。

なおAddメソッドは、追加したListRowオブジェクトを戻しているので、図５－１３のように一旦変数で受け取ってからデータを貼り付ける書き方でもOKです。やっている事は同じなので、分かり易い方を使って下さい。

84. '==========　⇩(9)　新規データ挿入（別の書き方）　============
85. Public Sub TableDataIn2(T As ListObject, Data As Variant)
86. 　Dim newRow As ListRow 　　 '←追加するテーブルの行
88. 　Set newRow = T.ListRows.Add
89. 　newRow.Range = Data
90. End Sub

図５－１３

５－７．データの変更（Update文）

データを変更（SQLのUpdate文相当）するのが図５－１４・図５－１５です。
SQLのUpdate文は、列を指定してデータを上書きしますが、今回システムでは「行のデータをまとめて書き換え」するプロシージャ（図５－１５）も作成しました。まとめて書き換える理由は「どの列もデータが変更された可能性があるので、全列のデータを上書きをする」ためです。

まず、列指定でデータ変更するのが図５－１４で、引数として、対象のListObjectオブジェクト（T）、変更する列名（col）、上書きするデータ（Data）を受取ります。ここでの引数Dataは配列では無く、単一データです。

92. '==========　⇩(10)　データの変更（１列のみ変更）　============
93. Public Sub TableDataUp(T As ListObject, col As Variant, Data As Variant)
94. 　Dim icnt As Long 　　 '←絞りこまれたデータ総数
96. 　On Error Resume Next
97. 　　icnt = T.DataBodyRange.SpecialCells(xlCellTypeVisible).Count
98. 　　If icnt = 0 Then Exit Sub
99. 　On Error GoTo 0
101. 　T.ListColumns(col).DataBodyRange = Data
102. End Sub

図５－１４

先に、本体である１０１行目を先に説明します。
１０１行目「T.ListColumns(col).DataBodyRange = Data」では、テーブル（T）の指定列（col）の、絞りこまれた（＝行高さがゼロではない）行のデータを「引数Data」の値に置き換えます。

この時、もし絞り込まれた行が複数行であれば、複数行分だけ置き換えます。また絞り込まれた行が１つも無い場合には、テーブルの全ての行のデータが置き換わります（＝テーブルを全く絞り込まずに、全行に対してデータを置き換えたのと同一）。

この「絞り込まれた行が１つも無いのに、テーブルの全てのデータを書き換えてしまう」という現象には、今回初めて気が付きました。それまでは「絞り込まれた行が１つも無い場合は、１つもデータを書き換えない」だろう　という先入観があり、確認を怠っていました。 これはSQLで言えば「where句で何も抽出されなかった時には、where句は無いものと見なす」のと同じです。この現象は異常だと思うのですが、今のところ受け入れるしかありません。これを防ぐには以下の２つの方法が考えられます。 　・絞り込んだ時に１行も抽出されていない場合には、TableDataUp（Update相当）プロシージャを実行しない。 　・TableDataUpプロシージャの中で、１行も抽出されていない場合はUpdate相当を実行しない。 今回は、最後の砦で防ぐ方が安心だと考え、２番目の方法を盛り込むことにしました。 なお、上記はマクロを使って絞り込みを行った場合のことです。手動で絞り込みを行うともっと不思議なことが起こります。 手動で何らかのデータ行を絞り込んだ（ゼロ行では無い）後、１０１行目「T.ListColumns(col).DataBodyRange = Data」のようなコードでデータを書き込むと、絞り込まれた行（可視されている行）に加えて絞り込まれなかった行（高さゼロの行）にもデータが書き込まれてしまうのです（つまり、全行が書き換えられてしまう）。 最初Excelの挙動がおかしくなったのかと思い再起動したりしたのですが、同じでした。ListObjectにはまだまだバグが潜んでいるのかもしれません。 少し大きなシステムにListObjectを使用する場合は、上記に充分注意する必要があると思います。今回システムではとりあえず正常に動きそうですが、絞り込んだテーブルに対して「テーブル名.DataBodyRange = 貼り付けるデータ」とSQLのUpdate文のように使うのでは無く、絞り込まれた行をまず検出して行位置を特定し、その行に対してデータ貼付けを実行する　という様な方法を取るのが安心かと思います。 テーブル操作の旨味が失われてしまいますが、データがおかしくなるのでは元も子もありませんので、より確実なアルゴリズムの使用と相当の動作チェックが重要と思います。

９７行目「icnt = T.DataBodyRange.SpecialCells(xlCellTypeVisible).Count」では、絞りこまれた（＝行高さがゼロになっていない）行×データ列数＝「絞りこまれたデータ総数」を取得します。もしそのデータ総数がゼロの場合には、９７行目はエラーとなりますので、変数icntは初期値のゼロのままと言うことになります。
９８行目「icnt = 0 Then Exit Sub」で、ゼロ（＝絞り込まれたデータ行が無い）の場合は、プロシージャを抜け出して１０１行目を実行しないようにします。
なおテーブルにデータが１行も存在しない場合も１０１行目を実行させる訳にはいきません。データ行が空の場合は、９７行目のDataBodyRangeの部分でエラーが発生しますので、９６行目「On Error Resume Next」でエラーをスルーさせる必要があります。

一方、行のデータをまとめて書き換えるのが図５－１５です。引数として、対象のListObjectオブジェクト（T）、上書きするデータ配列（Data）を受取ります。配列Dataは、テーブル（T）の列数分だけある１次元配列であることが前提です。

104. '==========　⇩(11)　データの変更（全列変更）　============
105. Public Sub TableDataUpAll(T As ListObject, Data As Variant)
106. 　Dim icnt As Long 　　 '←絞りこまれたデータ総数
108. 　On Error Resume Next
109. 　　icnt = T.DataBodyRange.SpecialCells(xlCellTypeVisible).Count
110. 　　If icnt = 0 Then Exit Sub
111. 　On Error GoTo 0
113. 　T.DataBodyRange = Data
114. End Sub

図５－１５

１１３行目「T.DataBodyRange = Data」では、テーブル（T）の絞りこまれた（＝行高さがゼロではない）行の１行分のデータを「配列Data」の値に置き換えます。
イメージとしては図５－１２の「TableDataIn」と似ていますが、異なるのは新たに行を追加することなく、既存のデータ行を置き換えることになります。
なお、絞り込まれた行が複数行であるなら複数行分だけ置き換えます。また絞り込まれた行が１つも無ければ、「よりみち」でも説明したように「テーブルの全データを書き換え」てしまいます。そのため図５－１４と同等に、１０９行目「icnt = T.DataBodyRange.SpecialCells(xlCellTypeVisible).Count」で、絞りこまれたデータ総数を取得し、エラーが出た場合には１１０行目「icnt = 0 Then Exit Sub」で１１３行目を実行しないようにしています。

また、引数である配列Dataの列数の過不足についてはTableDataIn（図５－１２）の時と同じです。
但し２次元配列の時は注意が必要です。もし絞り込まれたデータ行が２行あったとして、貼り付けるデータも２次元配列だとすると、テーブルの１行目には配列の１行目のデータが、テーブルの２行目には配列の２行目のデータが書き込まれることになり「各行で同じデータが上書きされない」可能性があります。

６．操作用フォーム(UserForm1)

６－１．フォーム上レイアウト

今回システムは、「ToDoリストの閲覧と処理（Page1）」「新規タスク追加・既存タスク更新（Page2）」「完了・中止項目の閲覧と処理（Page3）」の３つの機能を１つのフォーム内に収めています。その切替にはMultiPageコントロールを使用します。

まず図６－１のように、フォーム一杯にMultiPageコントロールを配置します。そのMultiPageのPage1（ToDoリスト）の中にListBox1を配置し、その上側に操作ボタンを３つ配置しています。リストは表面的には４列（非表示列があるため、本当は７列）にデータを表示し、その列に対応するようにタイトルLabelを配置しています。Labelの配置位置は、適当な位置に手動で合わせました。

図６－１

Page2の「新規／更新」は図６－２のように、ユーザーが手入力する「タスク名」「完了日」のTextBoxを置き、優先度を選択するようにComboBoxを置いています。また下部には定期的なタスクをON-OFFするCheckBoxと、定期の内容をOptionButtonを使って指定できるようにしました。
また上部には操作ボタンを２つ置き、タスク修正の場合の内部的処理のためにタスクNoを書き込むLabelを置いています。

図６－２

Page3の「完了一覧」は、完了・中止タスク項目を表示するためのListBoxを配置し、その上部に操作ボタンを置いています。このListBoxも表面的には４列表示ですが、非表示も含めて７列のデータが入ります。

図６－３

タスク名の文字列長さを「それほど長くは無い」と仮定して、今回はこのサイズにしています。もしタスク名が長い場合はListBox等のWidthを調整して下さい。

６－２．フォームモジュール

６－２－１．フォーム起動時

フォーム起動時（＝システム起動時）には、まず図６－４のInitializeイベントが発生します。その中でフォーム内の固定的な表示等の設定をしています。

116. '==========　⇩(12)　フォーム起動時の設定　============
117. Private Sub UserForm_Initialize()
119. 　Me.Caption = "ToDoリスト"
120. 　Me.MultiPage1.Pages(0).Caption = "ToDo"
121. 　Me.MultiPage1.Pages(1).Caption = "新規/更新"
122. 　Me.MultiPage1.Pages(2).Caption = "完了一覧"
124. 　Me.CommandButton1.Caption = "完了"
125. 　Me.CommandButton2.Caption = "編集"
126. 　Me.CommandButton3.Caption = "中止"
128. 　Me.CommandButton4.Caption = "登録"
129. 　Me.CommandButton5.Caption = "クリア"
131. 　Me.CommandButton6.Caption = "復活"
133. 　Me.ListBox1.ColumnCount = 7
134. 　Me.ListBox1.ColumnWidths = "0;105;20;55;0;40;0"
136. 　Me.TextBox2.IMEMode = fmIMEModeDisable
138. 　Me.ListBox2.ColumnCount = 7
139. 　Me.ListBox2.ColumnWidths = "0;70;0;55;55;0;40"
141. End Sub

図６－４

１１９～１２２行目では、フォーム名称・マルチページのページタブ名を設定しています。
１１９行目「Me.Caption = "ToDoリスト"」は、フォームのタイトル設定。
１２０行目「Me.MultiPage1.Pages(0).Caption = "ToDo"」は、マルチページ内のPage1のタブ名の設定。
１２１行目「Me.MultiPage1.Pages(1).Caption = "新規/更新"」は、Page2のタブ名の設定。
１２２行目「Me.MultiPage1.Pages(2).Caption = "完了一覧"」は、Page3のタブ名の設定をします。

１２４～１３１行目では、各ページのボタンの名称を設定しています。
１２４行目「Me.CommandButton1.Caption = "完了"」は、Page1のボタン名設定です。ToDoリストの項目を選択した後、このボタンをクリックすることで「項目の完了」処置をします。
１２５行目「Me.CommandButton2.Caption = "編集"」もPage1のボタン名設定です。ToDoリストの項目を選択した後、このボタンをクリックすることで、データをPage2に送付し、項目の編集をします。
１２６行目「Me.CommandButton3.Caption = "中止"」もPage1のボタン名設定です。ToDoリストの項目を選択した後、このボタンをクリックすることで「項目の中止」処置をします。
１２８行目「Me.CommandButton4.Caption = "登録"」は、Page2のボタン名設定です。Page2に新規入力された内容、及びPage1・Page3から送られてきたデータを修正した内容を、データとして新規登録・修正上書きをします。
１２９行目「Me.CommandButton5.Caption = "クリア"」もPage2のボタン名設定です。このボタンをクリックすることで、Page2の各入力欄をクリアします。
１３１行目「Me.CommandButton6.Caption = "復活"」は、Page3のボタン名設定です。完了一覧の項目を選択した後、このボタンをクリックすることで、データをPage2に送付し、項目の編集・新規作成を行います。

１３３～１３４行目は、Page1（ToDoリスト）のListBox1の列設定です。
１３３行目「Me.ListBox1.ColumnCount = 7」は、７列のListBoxに設定しています。データ用シート（図４－１）のデータ列数と同じ７列にすることで「全データをListBoxデータに格納」し、「処理時に再度データ用シートからデータを呼び出さなくても良い」ようにしています。
１３４行目「Me.ListBox1.ColumnWidths = "0;105;20;55;0;40;0"」は、７列のListBoxの列幅を調整しています。非表示列はゼロとし、その合計値を「ListBoxのWidth値（今回は223ポイント）－3ポイント」とすることで「ListBoxの横スクロールバーを表示させない」ようにしています。この計算の詳細は「先入先出の入出庫管理システム」を参照下さい。

１３６行目「Me.TextBox2.IMEMode = fmIMEModeDisable」では、Page2（新規/更新）の日付欄（TextBox2）を半角のみに設定しています。

１３８～１３９行目は、Page3（完了一覧）のListBox2の列設定です。
１３８行目「Me.ListBox2.ColumnCount = 7」は、７列のListBoxに設定しています。ToDoリスト（Page1）のListBoxと同じく、データ用シートのデータ列数と同じ７列にしています。
１３９行目「Me.ListBox2.ColumnWidths = "0;70;0;55;55;0;40"」は７列のListBoxの列幅を調整しています。

フォーム起動時にInitializeイベントの次に呼び出されるのがActivateイベント（図６－５）です。今回システムはフォームをShow ⇔ Hideを繰り返すものでは無いので、図６－５の内容は図６－４（Initialize）の中に記しても良いのですが、ボタン名など固定している設定では無く、都度変化する内容であるため、Activateイベント内で実行することにしました。

143. '==========　⇩(13)　フォーム表示時の設定　============
144. Private Sub UserForm_Activate()
146. 　Call make_List1
147. 　Call make_List2
148. 　Call make_Combo1
150. 　Me.MultiPage1.Value = 0
152. 　Call CheckBox1_Click
153. End Sub

図６－５

１４６行目「Call make_List1」は図６－６を呼出し、Page1（ToDoリスト）のリストボックスにToDoリストを並べます。
１４７行目「Call make_List2」は図６－１８を呼出し、Page3（完了一覧）のリストボックスに完了・中止リストを並べます。
１４８行目「Call make_Combo1」は図６－１０を呼出し、Page2（新規/更新）の優先度選択欄のコンボボックスにＡ～Ｃの優先度リストを作成しています。

１５０行目「Me.MultiPage1.Value = 0」は、システム起動後、初めに表示するページをPage1（ToDoリスト）とします。
１５２行目「Call CheckBox1_Click」は図６－１６を呼出します。CheckBox1は初期状態をOFFにしてあるため、Clickイベントを呼び出すことで「定期的チェックボックスのレ点を外した動作を再現」させ、起動初期状態にはオプションボタン（毎日・毎週・毎月・毎年）を全て無効状態にしています。

６－２－２．Page1（ToDoリスト）

６－２－２－１．ToDoリスト作成

フォーム起動時、およびデータを追加・変更した時に呼び出される「ListBox1のリストを作成」するのが図６－６です。

155. '==========　⇩(14)　ToDoリスト作成　============
156. Private Sub make_List1()
157. 　Dim buf As Variant 　 '←絞りこまれたデータの配列
158. 　Dim i As Long 　　　　 '←データの行数
159. 　Dim j As Integer 　　 '←データの列数
161. 　Call TableSort(T1, "Priority", 1)
162. 　Call TableSort(T1, "EndD", 1)
163. 　Call TableFilter(T1, "Status", "=")
164. 　Call TableFilter(T1, "EndD", "<=" & Date + Term1)
166. 　buf = SearchList(T1)
168. 　Call TableFilterOff(T1)
170. 　Me.ListBox1.Clear
171. 　If IsEmpty(buf) = True Then Exit Sub
173. 　For i = 1 To UBound(buf, 1)
174. 　　Me.ListBox1.AddItem ""
175. 　　For j = 1 To UBound(buf, 2)
176. 　　　Me.ListBox1.List(i - 1, j - 1) = buf(i, j)
177. 　　Next j
178. 　Next i
180. End Sub

図６－６

１６１～１６４行目では、テーブルのデータを「ToDoリストとして表示するデータ」に並べ替え・絞り込みを行っています。
まずToDoリストに表示するのは①「完了・中止されていないもの」であり、且つ②「ToDoリストに載せる期間内」の項目です。②掲載期間は、図５－１の５行目で設定した「定数Term1（サンプルファイルでは7日間）」を使用します。また項目が完了・中止されると、図４－１のようにFinD列に日付を、Status列に完了か中止の文字列を入れますので、これで判断していきます。
また表示する順序は、どの項目を優先にするかで決めます。今回は、③「期限（EndD列）」、④「優先度（Priority列）」の優先順で表示することとします。

この①～④をどの順で実行していくか　ですが、まず表示順序の並べ替えを行います。③と④が順序ですが「最後に並べ替えた方が優先される」ので、まず優先度の低い④で並べ替えを行います。これが１６１行目「Call TableSort(T1, "Priority", 1)」です。
図５－３のTableSortを呼び出し、Priority列を昇順（A・B・C順）で並べています。並べ順序は図５－４の表に従って「1（またはxlAscending）」を指定します。
次に優先度の高い③で並べ替えを行うのが、１６２行目「Call TableSort(T1, "EndD", 1)」です。EndD列を昇順（日付の若い順）で並べます。

次に①②の絞り込みを行います。この絞り込み順番はどちらでも良いので、１６３行目「Call TableFilter(T1, "Status", "=")」でStatus列が空のもの（＝完了・中止されていないもの）を絞り込み、次に１６４行目「Call TableFilter(T1, "EndD", "<=" & Date + Term1)」で「期限（EndD）が、今日＋設定期間よりも前のもの」を絞りこみます。
「今日＋設定期間よりも前のもの」ですので、「今日の期限を過ぎているのに未完了のタスク」も表示されることになります。

データの並び替え、および絞り込みが完了しましたので、１６６行目「buf = SearchList(T1)」で図５－１０のSearchListを呼び出し、データを配列化し変数bufに代入します。配列bufは必要なデータが必要な順序で並んでいます。もし対象となるデータが一つもない場合には、Emptyが戻ってきます。
データの取り込みが完了しましたので、１６８行目「Call TableFilterOff(T1)」で、図５－９を呼出し、絞り込みを解除します。この際に並び替えは特に戻す必要が無いので、そのままの状態としています。

１７０～１７８行目では、取得したデータ配列bufを使って、リストボックスを作成します。
１７０行目「Me.ListBox1.Clear」で、リストボックスのデータをクリアします。
１７１行目「If IsEmpty(buf) = True Then Exit Sub」では、データが１行も無かった（Empty）場合に、プロシージャを抜け出します。１７０行目で既にリストボックスをクリアしていますので、データが無い場合は空のリストボックスになります。

１７３行目「For i = 1 To UBound(buf, 1)」は、カウンタ変数ｉで、絞り込んだデータbufの行位置を動かします。
１７４行目「Me.ListBox1.AddItem ""」で、データの各行ごとにリストボックスの行を作ります。
１７５～１７７行目で、リストボックスの各列にデータを収めていきます。まず１７５行目「For j = 1 To UBound(buf, 2)」では、カウンタ変数ｊを配列bufの列数（＝データシートの列数）分だけ回します。そして１７６行目「Me.ListBox1.List(i - 1, j - 1) = buf(i, j)」で、各列の値をリストボックスに入れていきます。

６－２－２－２．ToDoページの各ボタンの動作

Page1（ToDo）には３つのボタンを設けました。機能は以下の通りです。
「完了ボタン」は、ToDoリスト上の選択した項目に対して完了処置を行います。
「編集ボタン」は、ToDoリスト上の選択した項目の内容を編集します。
「中止ボタン」は、ToDoリスト上の選択した項目に対して中止処置を行います。

図６－７は、完了ボタンをクリックした時に実行されるClickイベントです。
１８４行目「Call FinStop("完了")」は、図６－２１を呼出し、完了処置を行います。引数としてデータテーブルのStatus列に記入する「完了」の文字列を渡します。

182. '==========　⇩(15)　完了ボタン　============
183. Private Sub CommandButton1_Click()
184. 　Call FinStop("完了")
185. End Sub

図６－７

図６－８は、編集ボタンをクリックした時に実行されるClickイベントです。
１８９行目「Call Edit(Me.ListBox1)」は、図６－２３を呼出し、編集のモード（登録/更新ページ）に移動します。引数として選択しているToDoリスト（ListBox1オブジェクト）を渡します。

187. '==========　⇩(16)　編集ボタン　============
188. Private Sub CommandButton2_Click()
189. 　Call Edit(Me.ListBox1)
190. End Sub

図６－８

図６－９は、中止ボタンをクリックした時に実行されるClickイベントです。
１９４行目「Call FinStop("中止")」は、完了の時と同じ図６－２１を呼出します。但し引数としてデータテーブルのStatus列に記入する「中止」の文字列を渡して、中止処置を行います。

192. '==========　⇩(17)　中止ボタン　============
193. Private Sub CommandButton3_Click()
194. 　Call FinStop("中止")
195. End Sub

図６－９

６－２－３．Page2（新規/更新）

６－２－３－１．優先度コンボボックスの設定

新規/更新ページでは、タスクや期限日が必須入力項目ですが、同時に優先度も必須としています。その優先度は今回コンボボックスから選択する方式とし、その選択リストを設定するのが図６－１０です。図６－５（Activateイベント）の１４８行目から呼び出されて実行します。

197. '==========　⇩(18)　優先度コンボボックスの作成　============
198. Private Sub make_Combo1()
199. 　Me.ComboBox1.AddItem "A"
200. 　Me.ComboBox1.AddItem "B"
201. 　Me.ComboBox1.AddItem "C"
203. 　Me.ComboBox1.ListIndex = 0
204. End Sub

図６－１０

１９９行目「Me.ComboBox1.AddItem "A"」でコンボボックスのリストに、優先度「A」を設定します。その後、２００行目で「B」、２０１行目で「C」を設定しますので、リストとしては、上からA・B・Cと並びます。
２０３行目「Me.ComboBox1.ListIndex = 0」では、コンボボックスの１番目（リストはゼロ始まり）を選択していますので、起動直後は一番上の「A」が表示されていることになります。

６－２－３－２．新規/更新の実行

新規/更新ページの各項目を入力後、「登録」ボタンをクリックした時に呼び出されるのが図６－１１です。

206. '==========　⇩(19)　登録ボタン　============
207. Private Sub CommandButton4_Click()
208. 　Dim buf(1 To 7) As Variant 　　 '←テーブルへ貼り付けるデータ配列
210. 　buf(2) = Me.TextBox1.Text
211. 　buf(4) = Me.TextBox2.Text
213. 　If Not Me.ComboBox1.ListIndex = -1 Then
214. 　　buf(3) = Me.ComboBox1.List(Me.ComboBox1.ListIndex)
215. 　End If
217. 　If Trim(buf(2)) = "" Or Trim(buf(3)) = "" Or Trim(buf(4)) = "" Then
218. 　　MsgBox "「タスク・優先度・完了日」は必須入力です"
219. 　　Exit Sub
220. 　End If
222. 　If Me.CheckBox1.Value = True Then
223. 　　Select Case True
224. 　　　Case Me.OptionButton1.Value
225. 　　　　buf(6) = "毎日"
226. 　　　Case Me.OptionButton2.Value
227. 　　　　buf(6) = "毎週"
228. 　　　Case Me.OptionButton3.Value
229. 　　　　buf(6) = "毎月"
230. 　　　Case Me.OptionButton4.Value
231. 　　　　buf(6) = "毎年"
232. 　　End Select
233. 　End If
235. 　If Me.Label1.Caption = "" Then
236. 　　buf(1) = TableMax(T1, "Num") + 1
237. 　　Call TableDataIn(T1, buf)
238. 　Else
239. 　　buf(1) = Me.Label1.Caption
240. 　　Call TableFilter(T1, "Num", CStr(buf(1)))
241. 　　Call TableDataUpAll(T1, buf)
242. 　　Call TableFilterOff(T1)
243. 　　Me.MultiPage1.Value = 0
244. 　End If
246. 　Call CommandButton5_Click
248. 　Call make_List1
249. 　Call make_List2
250. 　ThisWorkbook.Save
252. End Sub

図６－１１

図６－１２で、データを保管するテーブルの内容を再確認しておきます。

列	列名	内容	Page2の入力ｺﾝﾄﾛｰﾙ
1	Num	連番	Label1
2	Task	タスク	* TextBox1
3	Priority	優先度(A･B･C)	* ComboBox1
4	EndD	期限	* TextBox2
5	FinD	完了･中止日(無印は､未完)	-
6	Every	定期の内容(無印は､1回のみ)	OptionButton1～4
7	Status	状態(無印は､未完)	-

図６－１２

新規/更新ページでは、2･3･4の項目を入力必須としていますので、まず2･3･4にデータを入れてみてから、入っているか否かを確認していきます。
２１０行目「buf(2) = Me.TextBox1.Text」で、タスク名を配列bufに代入します。
２１１行目「buf(4) = Me.TextBox2.Text」で、期限日を配列bufに代入します。

２１３行目「If Not Me.ComboBox1.ListIndex = -1 Then」は、「正しくリストを選択した時」という意味になります。コンボボックスのテキストボックス部をDelete等で消したり、A・B・C以外の文字列を入力した場合には「ListIndex = -1（＝リストからは何も選んでいない）」ことになります。
正しく選択した時は、２１４行目「buf(3) = Me.ComboBox1.List(Me.ComboBox1.ListIndex)」で、選択した文字列（A・B・Cのどれか）を配列bufに代入します。

なお、Initialize（図６－４）などで「Me.ComboBox1.MatchRequired = True」と設定し、「リスト内にある項目しか、テキストボックス部に入力できない」ようにすると、コンボボックスを出る時に「プロパティの値が無効です」とExcelが代わりに指摘してくれます（エラーのコメント内容が、ちょっと素人っぽくありませんが）。
また、「Me.ComboBox1.Style = fmStyleDropDownList」と設定することで、「リスト項目からしか選択できない」ようにもできます。

ここまでで入力必須項目は取得できましたので、２１７行目「If Trim(buf(2)) = "" Or Trim(buf(3)) = "" Or Trim(buf(4)) = "" Then」で、各値が空か否かを調べます。スペースだけ入れる人もいるため、Trim関数で両端のスペースは削除してから「""（長さゼロの文字列）」と比較を行っています。
もしどれかが成立（値が空）する時は、２１８行目「MsgBox "「タスク・優先度・完了日」は必須入力です"」でコメントを出し、２１９行目「Exit Sub」で登録処理を中止します。

２２２～２３３行目は、定期的な項目として指定しているか否かをチェックしています。
まず２２２行目「If Me.CheckBox1.Value = True Then」で、「定期的」チェックボックスにレ点が付いているか否かを確認します。レ点がついている場合には２２３～２３２行目を実行します。
２２３行目「Select Case True」は、以下のCase文の式（４つのオプションボタンの値）がTrueである場合に、それ以下を実行します。例えば２２４行目は「Case Me.OptionButton1.Value」ですので、OptionButton1（＝毎日）がTrue（＝ONになっている） の場合に２２５行目「buf(6) = "毎日"」が実行され、配列bufに「毎日」が代入されることになります。
４つのOptionButtonはどれかがOnになっています（図６－１６の２７４行目で、起動時に「毎年」をONにしているため）ので、チェックボックスにレ点がついている場合は、どれかがbuf(6)に入ることになります。
（チェックボックスにレ点が付いていない場合でも「毎年」がONになっていますが、２２２行目のIF文で対象となりませんので、buf(6)は初期の空の状態になります。）

２３５行目「If Me.Label1.Caption = "" Then」では、Page2（新規/更新ページ）のLabel1の値を確認しています。
まず新規/更新ページに移動してくるには、図６－１３のように４つの経路があります。

図６－１３

１つ目は、ユーザーがMultiPageのタブをクリックして新規/更新ページに移動してきた場合①です。この時には、図６－２０のMultiPage1_Changeイベントが呼び出され、その中で図６－１５のCommandButton5_Clickを実行することで、Label1に「""（長さゼロの文字列）」を入力（２５６行目）しています。
２つ目は、ToDoページで項目選択後に「編集ボタン」をクリックすることで移動してきた場合②です。この時はEditプロシージャ内でLabel1に選択項目の番号を記入（図６－２３の３８６行目）します。
３つ目・４つ目は、完了一覧ページで項目選択後に「復活ボタン」で移動してきた場合です。復活ボタンをクリックした後のEditプロシージャ（図６－２３）の中で、選択した項目が完了だった場合③にはLabel1に「""（長さゼロの文字列）」を入力（３８４行目）しています。また中止だった場合④には、Label1に選択項目の番号を記入（３８６行目）します。
以上をまとめると、図６－１４のようになります。

	移動前のページ	条件	Label1の値	理由
①	ToDo / 完了一覧	手動で移動	""	ﾕｰｻﾞｰ意思による新規追加
②	ToDo	項目選択後､編集ﾎﾞﾀﾝ	選択項目のNo	編集目的
③	完了一覧	完了項目を選択後､復活ﾎﾞﾀﾝ	""	完了実績は保管の必要がある為､内容コピーし新規処理
④		中止項目を選択後､復活ﾎﾞﾀﾝ	選択項目のNo	中止を復活させる意思

図６－１４

繰返しになりますが、２３５行目「If Me.Label1.Caption = "" Then」では、Label1の値を確認し、Label1の値が無い場合（図６－１３、図６－１４の①③）は、２３６～２３７行目を実行します。
またそれ以外（Label1の値がある）の場合（図６－１３、図６－１４の②④）は、２３９～２４３行目を実行します。

まずLabel1の値が無い場合（図６－１３、図６－１４の①③）は、新規に番号を取得する必要があります（今回のデータテーブルでは、タスク番号はユニーク番号である必要があるため）ので、２３６行目「buf(1) = TableMax(T1, "Num") + 1」で、図５－１１を呼出し「Num列の最大値」に＋１を足してユニーク番号とし、bufに代入しています。
そして２３７行目「Call TableDataIn(T1, buf)」で、配列bufを図５－１２のTableDataInに渡して、データをテーブルに新規追加します。
なお、buf(5)・buf(7)には何も代入していませんので、FinD列とStatus列は空白セルとなるため未完項目として登録されることになります。

一方Label1の値がある場合（図６－１３、図６－１４の②④）は、２３９行目「buf(1) = Me.Label1.Caption」でその値（タスク番号）をbufに代入します。
このデータをテーブルの「同じタスク番号の行」に上書きしなければなりませんので、まず２４０行目「Call TableFilter(T1, "Num", CStr(buf(1)))」を使ってテーブルをタスク番号の行だけに絞り込みます。
絞り込んだ後、２４１行目「Call TableDataUpAll(T1, buf)」で、その行のデータ全てを配列bufのデータで置き換えます。なお絞り込んだNum列の値と貼り付けるNum列の値は同じですので、「タスク番号以外のデータは置き換えられた」という形になります。

最後に２４２行目「Call TableFilterOff(T1)」でテーブルの絞り込みを解除し、２４３行目「Me.MultiPage1.Value = 0」で「ToDoページに移動」しています。

この「新規/更新を実行した後に、どのページに移動するか。またはそのページに留まるのか」は、作る人の考え方次第です。今回Label1に値が無い（＝新規に項目を追加したい等）場合は移動せず、値がある場合はToDoページに移動させています。 私としては、まず「新規に項目を起こす場面では、複数の項目を作成する場合が多いだろう」と考え、新規作成の場合にはページ移動をさせずに連続入力が出来るようにしました。 一方「修正（Label1が有る）の場面は、それほど頻度が多く無いだろう。まして完了や中止を復活させる事は少ないだろう」と考え、修正後はToDoページに移動することとしました。このような仕様は、考えれば考えるほど難しいです。 多機能のシステムであれば、ユーザーが使い易いような詳細設定を出来るようにするのでしょうが、このような小さなシステム・個人しか使用しないようなシステムでは、使用環境に合わせてコード修正する方が良いのかもしれません。

２４６行目「Call CommandButton5_Click」は、図６－１５を呼出し、新規/更新ページの各入力欄をクリアしています。これは新規に項目を起こしている（Label1が空欄）場合に、次の項目を入れ易くしているつもりなのと併せて、ページが移動しない＋手入力欄をクリアしないと「処理が失敗したのでは？」との不安をユーザーが抱くと思い、クリアしています。

２４８行目「Call make_List1」は、図６－６を呼出し、ToDoリストを更新しています。
２４９行目「Call make_List2」は、図６－１８を呼出し、完了一覧を更新しています。
２５０行目「ThisWorkbook.Save」は、更新したデータを保存しています。

今回システムではデータをアドインファイルのワークシートに保存しています。システムが起動している時はもちろん、Excelが起動している最中はデータは残っていますが、Excelを閉じてしまうと、保存しておかない限りデータは消えてしまいます。 これは、Excelで資料を作ったのに保存せずにそのまま閉じてしまったのと同じです。しかしアドインの場合はもっと悪いことに、アドインのワークシートに変更を加えても、Excelを閉じる時に「このファイルの変更内容を保存しますか？」と訊いてきてくれないのです。 そのため変更を加えたタイミングでデータ保存しているのですが、もう一つ思いつくタイミングがフォームの「UserForm_QueryClose」イベントと「UserForm_Terminate」イベントです。この２つのイベントは、フォームを閉じる（例えば右上×印など）ときにはもちろん発生しますが、今回のようにフォームをモードレスで起動している時にExcelを終了されるとイベントは発生してくれません。 そのため、データテーブルに変更を加えた直後の２５０行目で「ThisWorkbook.Save」と、データ保存をしています。もう一箇所、タスク項目に対して完了・中止の処理をしている図６－２１の３６７行目の、合計２箇所で保存実行しています。

６－２－３－３．入力欄のクリア

新規/更新ページの「クリア」ボタンをクリックした時に実行されるのが図６－１５です。なお、手動・自動に関わらずマルチページのページが変更された時（図６－２０の３２９行目）、及び登録ボタンでデータ登録した時（図６－１１の２４６行目）にも呼び出されます。

254. '==========　⇩(20)　クリアボタン　============
255. Private Sub CommandButton5_Click()
256. 　Me.Label1.Caption = ""
257. 　Me.TextBox1.Text = ""
258. 　Me.ComboBox1.ListIndex = 0
259. 　Me.TextBox2.Text = ""
260. 　Me.CheckBox1.Value = False
261. End Sub

図６－１５

２５６行目「Me.Label1.Caption = ""」は、タスク番号を表示しているLabel1をクリアしています。
２５７行目「Me.TextBox1.Text = ""」は、タスク名の入力欄をクリアしています。
２５８行目「Me.ComboBox1.ListIndex = 0」は、優先度を既定の「A」に戻しています。
２５９行目「Me.TextBox2.Text = ""」は、期限日の入力欄をクリアしています。
２６０行目「Me.CheckBox1.Value = False」は、定期的タスクのチェックボックスのレ点を消しています。もしチェックボックスが「レ点有→レ点無」に変更された場合は、図６－１６のCheckBox1_Clickイベントが呼び出され、チェックボックスのレ点が消えるのと併せて、４つのオプションボタンも無効状態にします。

６－２－３－４．定期タスクの設定

定期的タスクのチェックボックスが「レ点無→レ点有」または「レ点有→レ点無」と、値が変わったときに呼び出されるのが図６－１６です。また、フォームが起動する時にも初期設定として呼び出されます（図６－５の１５２行目）。

263. '==========　⇩(21)　定期タスクの設定　============
264. Private Sub CheckBox1_Click()
265. 　Dim CKB As Boolean 　　 '←定期ON-OFFのチェックボックスの値
267. 　CKB = Me.CheckBox1.Value
269. 　Me.OptionButton1.Enabled = CKB
270. 　Me.OptionButton2.Enabled = CKB
271. 　Me.OptionButton3.Enabled = CKB
272. 　Me.OptionButton4.Enabled = CKB
274. 　Me.OptionButton4.Value = True
276. End Sub

図６－１６

２６７行目「CKB = Me.CheckBox1.Value」では、チェックボックスの値（False または True）を取得し、変数CKBに代入します。２６９～２７２行目では、４つのオプションボタンの有効・無効を切り替えています。
代表して２６９行目「Me.OptionButton1.Enabled = CKB」で説明すると、OptionButton1（毎日のボタン）のEnabledプロパティをチェックボックスの値と同じに設定しています。つまり、チェックボックスがON（レ点有り）の時にはオプションボタンを有効にし、チェックボックスがOFF（レ点無し）の時にはオプションボタンを無効にしています。
他のオプションボタン（２７０～２７２行目）も同様に、チェックボックスのON-OFFに従って有効・無効を切り替えます。

２７４行目「Me.OptionButton4.Value = True」は、４つのオプションボタンの内、「毎年」のボタンだけをONにしています。４つのオプションボタンのGroupNameプロパティは全て未設定（作ったまま）なので４つのボタンは１つのグループになっています。ですのでOptionButton4をONにすれば、他の３つのOptionButton1～3はOFFになります。
「毎年」を既定のONにしたのは、間違えてチェックボックスをONにしてしまって登録をしても、最もスパンの長い「毎年」であれば定期的にToDoリストに表示されても被害が少ないと考えたからです。

６－２－３－５．期限日の入力欄の制限

期限の日付欄（TextBox2）には、yyyy/mm/ddのような半角数字を「/」や「-」で区切った日付を入力します。ユーザーに全角で入力されないように「半角Only」に制限するのは、図６－４の１３６行目で設定していますが、入力された文字列が日付か否かを判断し、かつデータテーブルに同一の形でデータ保管するために、書式を整えるのが図６－１７です。
このイベントは、日付欄を抜け出す（Exit）ときに発生します。

278. '==========　⇩(22)　日付チェックと成形　============
279. Private Sub TextBox2_Exit(ByVal Cancel As MSForms.ReturnBoolean)
280. 　Dim TXB As String 　　 '←ユーザーが入力した文字列
282. 　TXB = Trim(Me.TextBox2.Value)
284. 　If IsDate(TXB) = True Then
285. 　　Me.TextBox2.Value = Format(TXB, "yyyy/mm/dd")
286. 　ElseIf TXB = "" Then
287. 　　Me.TextBox2.Value = ""
288. 　Else
289. 　　Cancel = True
290. 　　MsgBox "日付を入力して下さい"
291. 　End If
292. End Sub

図６－１７

２８２行目「TXB = Trim(Me.TextBox2.Value)」は、日付入力欄の値を取得し変数TXBに代入します。その際、Trim関数を使って両端のスペースを削除しています。
２８４行目「If IsDate(TXB) = True Then」は、その入力値が日付の形であった場合には、２８５行目「Me.TextBox2.Value = Format(TXB, "yyyy/mm/dd")」で日付をyyyy/mm/ddの形に整え、入力欄に戻します。例えば「12/2」などと入力した場合に、ちゃんと年も含めて「2021/12/02」という形にします。これにより、ユーザーも年月日を再チェックすることが出来ます。

２８６行目「ElseIf TXB = "" Then」は、入力値が日付の形では無くスペースだけだった、または一旦入力欄に入った後、何も入力せずに抜け出した時には、２８７行目「Me.TextBox2.Value = ""」で「入力したスペースを削除」した「""（長さゼロの文字列）」を入力欄に戻します。これは、データを「登録」の際のチェック（図６－１１の２１７行目）として「空か、空では無いか」だけを判断材料にしているためです。

２８８行目「Else」は、日付の形でも無く、空やスペースだけでも無い場合です。この場合は「ユーザーは日付と思って入力したけど、日付の形になっていなかった」ことになりますので、２８９行目「Cancel = True」で入力欄を抜け出す（Exit）のを中止（Cancel）させて入力欄に留まります。そして２９０行目「MsgBox "日付を入力して下さい"」でコメントを出します。
ですので正しい日付を入力し直すか、または入力値を消すかしないと、入力欄を抜け出せなくなります。

６－２－４．Page3（完了一覧）

フォーム起動時、およびデータを追加・変更した時に呼び出される「ListBox2のリスト（完了一覧リスト）を作成」するのが図６－１８です。

294. '==========　⇩(23)　完了一覧リストの作成　============
295. Private Sub make_List2()
296. 　Dim buf As Variant 　 '←絞りこまれたデータの配列
297. 　Dim i As Long 　　　　 '←データの行数
298. 　Dim j As Integer 　　 '←データの列数
300. 　Call TableSort(T1, "Priority", 1)
301. 　Call TableSort(T1, "EndD", 2)
302. 　Call TableSort(T1, "FinD", 2)
303. 　Call TableFilter(T1, "Status", "<>")
304. 　Call TableFilter(T1, "FinD", ">=" & Date - Term2)
306. 　buf = SearchList(T1)
308. 　Call TableFilterOff(T1)
310. 　Me.ListBox2.Clear
311. 　If IsEmpty(buf) = True Then Exit Sub
313. 　For i = 1 To UBound(buf, 1)
314. 　　Me.ListBox2.AddItem ""
315. 　　For j = 1 To UBound(buf, 2)
316. 　　　Me.ListBox2.List(i - 1, j - 1) = buf(i, j)
317. 　　Next j
318. 　Next i
320. End Sub

図６－１８

コードの流れは、図６－６（make_List1）とほぼ一緒です。
３００～３０４目では、テーブルのデータを「完了一覧のリストとして表示するデータ」に並べ替え・絞り込みを行います。
まず完了一覧に表示するのは①「完了・中止したもの」であり、且つ②「完了一覧リストに載せる期間内」の項目です。②掲載期間は、図５－１の６行目で設定した「定数Term2（サンプルファイルでは30日＝約1か月）」を使用します。また項目が完了・中止すると、図４－１のようにFinD列に日付を、Status列に完了か中止の文字列が入りますので、これで判断をしていきます。
また表示する順序は、どの項目を優先にするかで決めます。今回は、③「完了・中止日（FinD列）」、④「期限（EndD列）」、⑤「優先度（Priority列）」の優先順で表示することとします。

まず表示順序の並べ替えを行います。「最後に並べ替えた方が優先される」ので、優先度の低い順に、⑤→④→③の順番で並べ替えを行います。
３００行目「Call TableSort(T1, "Priority", 1)」で、図５－３のTableSortを呼び出し、Priority列を昇順（A・B・C順）で並べています。並べ順序は図５－４の表に従って「1（またはxlAscending）」を指定します。
３０１行目「Call TableSort(T1, "EndD", 2)」で、EndD列を降順（日付の大きい順）で並べます。これは「最近完了や中止した項目がリストの上の方に並ぶ」ようにするためです。
３０２行目「Call TableSort(T1, "FinD", 2)」で、FinD列を降順（日付の大きい順）で並べます。この並び順もEndD列と同じです。

次に①②の絞り込みを行います。この順番は気にする必要はありませんので、３０３行目「Call TableFilter(T1, "Status", "<>")」でStatus列が空では無いもの（＝完了・中止のもの）を絞り込み、次に３０４行目「Call TableFilter(T1, "FinD", ">=" & Date - Term2)」で「期限（FinD）が、今日ー設定期間よりも後のもの」を絞りこみます。

データの並び替え、および絞り込みが完了しましたので、３０６行目「buf = SearchList(T1)」で図５－１０のSearchListを呼び出し、データを配列化し変数bufに代入します。もし対象となるデータが一つもない場合には、Emptyが戻ってきます。
データの取り込みが完了しましたので、３０８行目「Call TableFilterOff(T1)」で、絞り込みを解除します。この際に並び替えは特に戻す必要が無いので、そのままの状態としています。

３１０～３１８行目では、取得したデータ配列bufを使って、リストボックスを作成します。
３１０行目「Me.ListBox2.Clear」で、リストボックスのデータをクリアします。
３１１行目「If IsEmpty(buf) = True Then Exit Sub」では、データが１行も無かった（Empty）場合に、プロシージャを抜け出します。３１０行目でリストボックスをクリアしていますので、データが無い場合は空のリストボックスになります。

３１３行目「For i = 1 To UBound(buf, 1)」は、カウンタ変数ｉで、絞り込んだデータ配列bufの行位置を動かします。
３１４行目「Me.ListBox2.AddItem ""」で、データの各行ごとにリストボックスの行を作ります。
３１５～３１７行目で、リストボックスの各列にデータを収めていきます。まず３１５行目「For j = 1 To UBound(buf, 2)」では、カウンタ変数ｊを配列bufの列数（＝データシートの列数）分だけ回します。そして３１６行目「Me.ListBox2.List(i - 1, j - 1) = buf(i, j)」で、各列の値をリストボックスに入れていきます。
以上で完了一覧のリストが完成します。

図６－１９は、復活ボタンをクリックした時に実行されるClickイベントです。
３２４行目「Call Edit(Me.ListBox2)」は、図６－２３を呼出し、編集のモード（登録/更新ページ）に移動します。引数として選択している完成一覧リスト（ListBox2オブジェクト）を渡します。

322. '==========　⇩(24)　復活ボタン　============
323. Private Sub CommandButton6_Click()
324. 　Call Edit(Me.ListBox2)
325. End Sub

図６－１９

６－２－５．共通プロシージャ

６－２－５－１．ページの変更

マルチページのページを変更した時に発生するChangeイベントが図６－２０です。ユーザーが手動でページを移動した時のほか、マクロ側からページ移動（例えば、図６－２３の３７９行目）を実行した時にも発生します。
内容は３２９行目「Call CommandButton5_Click」で図６－１５を呼び出し、「新規/更新ページの各入力欄をクリア」します。

327. '==========　⇩(25)　ページ移動のイベント　============
328. Private Sub MultiPage1_Change()
329. 　Call CommandButton5_Click
330. End Sub

図６－２０

６－２－５－２．完了・中止処置

ToDoリストページの完了ボタン（図６－７の１８４行目）、中止ボタン（図６－９の１９４行目）から呼び出されるのが図６－２１です。引数として、「完了」または「中止」の文字列を受け取ります。（引数値FSは、Fin Stopの略）

332. '==========　⇩(26)　完了・中止処理　============
333. Private Sub FinStop(FS As String)
334. 　Dim buf As Variant 　　 '←絞り込みデータの配列
336. 　If Me.ListBox1.ListIndex = -1 Then
337. 　　MsgBox "タスクを選択して下さい"
338. 　　Exit Sub
339. 　End If
341. 　Call TableFilter(T1, "Num", Me.ListBox1.List(Me.ListBox1.ListIndex, 0))
343. 　buf = SearchList(T1)
345. 　Call TableDataUp(T1, "Status", FS)
346. 　Call TableDataUp(T1, "FinD", Date)
347. 　Call TableFilterOff(T1)
349. 　buf(1, 1) = TableMax(T1, "Num") + 1
350. 　Select Case buf(1, 6)
351. 　　Case "毎日"
352. 　　　buf(1, 4) = DateAdd("d", 1, WorksheetFunction.Max(Date, buf(1, 4)))
353. 　　　Call TableDataIn(T1, buf)
354. 　　Case "毎週"
355. 　　　buf(1, 4) = DateAdd("ww", 1, buf(1, 4))
356. 　　　Call TableDataIn(T1, buf)
357. 　　Case "毎月"
358. 　　　buf(1, 4) = DateAdd("m", 1, buf(1, 4))
359. 　　　Call TableDataIn(T1, buf)
360. 　　Case "毎年"
361. 　　　buf(1, 4) = DateAdd("yyyy", 1, buf(1, 4))
362. 　　　Call TableDataIn(T1, buf)
363. 　End Select
365. 　Call make_List1
366. 　Call make_List2
367. 　ThisWorkbook.Save
369. End Sub

図６－２１

３３６行目「If Me.ListBox1.ListIndex = -1 Then」は、リストボックスの項目が選択されていない場合に、３３７行目「MsgBox "タスクを選択して下さい"」でコメントを出し、３３８行目「Exit Sub」で処理を中止します。
このFinStopプロシージャは「ToDoリストページ」のみから呼び出されますので、確認するリストボックスは「ListBox1」で固定しています。

３４１行目「Call TableFilter(T1, "Num", Me.ListBox1.List(Me.ListBox1.ListIndex, 0))」では図５－７を呼出し、Num列の中の「ToDoリストの選択行のタスク番号」で絞り込みを行っています。タスク番号はListBox1では非表示となっていますが、1列目（インデックスとしては「ゼロ」）に収められていますので、値を取得するには「Me.ListBox1.List(Me.ListBox1.ListIndex, 0)」とします。

絞り込んだら、３４３行目「buf = SearchList(T1)」で、絞り込みデータを配列bufとして取得しておきます。この配列bufは、定期的タスクである場合に、新たなタスクとしてデータ追加する際に使用します。

この時点では、対象のタスク番号で絞り込まれた状態ですので、３４５～３４６行目で完了・中止の処理をします。
３４５行目「Call TableDataUp(T1, "Status", FS)」で、Status列に引数FS（完了処理の場合は「完了」、中止処理の場合は「中止」）を貼り付けます。
３４６行目「Call TableDataUp(T1, "FinD", Date)」で、FinD列に「今日の日付」を貼り付けます。
３４７行目「Call TableFilterOff(T1)」で、テーブルの絞り込みを解除します。

ここまでの処理で、一応「完了・中止処理は完成」です。３４９～３６３行目は「処理タスクが定期的タスクである場合、新たなタスクをデータ追加」する部分です。新たなタスクの内容は、タスク番号はもちろん異なる必要がありますが、それ以外は「期限日」が異なるだけです。新しい期限日は、定期的の内容（毎日・毎週・毎月・毎年）により異なります。

まず、新たなタスク番号を取得するために３４９行目「buf(1, 1) = TableMax(T1, "Num") + 1」で図５－１１を呼出し、テーブルのNum列の最大値＋１（ユニーク番号）を３４３行目で取得した「変更前（FinD、Status列は空の状態）の行データ」の先頭（buf(1, 1)）に代入します。

３５０～３６３行目で「定期的タスクだった場合に、新たな期限日を計算し、タスクを新規作成」しています。
３５０行目「Select Case buf(1, 6)」では、３４３行目で取得した行データの６列目（Every列）の値を調べます。

３５１行目「Case "毎日"」は、その値が「毎日」だった場合には３５２～３５３行目を実行します。
３５２行目「buf(1, 4) = DateAdd("d", 1, WorksheetFunction.Max(Date, buf(1, 4)))」では、完了・中止処理をしたタスクのEndD列の値（期限日）と今日の日付を比べ、その大きい方（後の日付）に対して１日後の日付を配列bufのEndD列位置に戻します。
少し分かり難いので実例で説明すると、毎日行う散歩を12/20には実行できず12/21にやっと実行できたとします。12/21には散歩を実行したので完了処理をした場合、単に期限日を基準にして「buf(1, 4) = DateAdd("d", 1, buf(1, 4))」とすると、「12/20の散歩が完了」し「12/21の散歩が新規作成」され、12/21にもう一回散歩に行かなければならなくなってしまいます。
日記みたいに毎日確実にやり遂げなければならないタスクでしたら、そのような処理も必要でしょうが、都合で出来なかったらそれは無かった事にしても良いタスクの方が「毎日行うタスク」には多い気がするので、３５２行目のような式としました。

同様に３５４行目「Case "毎週"」では毎週の場合、３５５行目「buf(1, 4) = DateAdd("ww", 1, buf(1, 4))」で１週間後の日付を配列bufに代入します。「毎週」以上では、「毎日」のように「今日の日付と比較」するような式にはせず、単に「期限日の次にタスクを新設」しています。「毎週」と設定したような予定は、遅くなっても挽回しないといけない内容が多いと考えたためです。
３５７行目「Case "毎月"」では毎月の場合、３５８行目「buf(1, 4) = DateAdd("m", 1, buf(1, 4))」で１ヶ月後の日付を配列bufに代入します。DateAdd関数で月の計算をする場合は、例えば10/31の翌月は11/30と、月末を跨いでしまう時は月末まで戻してくれるようです。
３６０行目「Case "毎年"」では毎年の場合、３６１行目「buf(1, 4) = DateAdd("yyyy", 1, buf(1, 4))」で１年後の 日付を配列bufに代入します。

毎日～毎年まで、それぞれ新しい期限日を配列bufに代入したら、それぞれ「Call TableDataIn(T1, buf)」で図５－１２を呼出し、テーブルに新規データとして挿入します。
なお、DateAdd関数に使用する「単位」は、図６－２２のようになっています。
　

単位の文字 内容 yyyy 年 m 月 d 日 h 時 n 分

単位の文字 内容 s 秒 q 四半期 y 通年での日数 w 平日 ww 週

図６－２２

この図６－２２の中で、実に紛らわしいのが「w」と「y」です。色々なサイトでは以下のように説明されています。
　「w」指定した日付の曜日がいくつあるか。平日。
　「y」通年での日数。年間通算日。
しかし「w」の前半の説明は意味がわかりませんし、後半の平日という説も計算してみると「土日や日曜を抜いて計算する訳でも無い」のです。「y」も意味がわかりません。単純には「w」「y」は「d」と同じ動作になるようですが、とは言え天下のMicrosoftが設定するからには何か意味があると思うので、「何か」が分かったらまた報告します。

また、定期的タスクを追加する「Call TableDataIn(T1, buf)」が、「毎日」～「毎年」まで４回同じコードとして出てくるのは、なんともカッコ悪いです。もう少し工夫の必要があります。

定期的タスクの新たなタスクが追加されましたら、３６５行目「Call make_List1」でToDoリストを更新し、３６６行目「Call make_List2」で完了一覧リストを更新します。
最後に、データテーブルが書き換わりましたので、３６７行目「ThisWorkbook.Save」でデータ保存します。

６－２－５－３．データを編集「新規/更新」ページへ送付

ToDoページの「編集ボタン（図６－８の１８９行目）」、完了一覧ページの「復活ボタン（図６－１９の３２４行目）」から呼び出されるのが図６－２３です。引数として、データを取得するListBoxオブジェクトを受け取ります。（LBはListBoxの略）

371. '==========　⇩(27)　データを編集「新規/更新」ページへ送付　============
372. Private Sub Edit(LB As Control)
374. 　If LB.ListIndex = -1 Then
375. 　　MsgBox "タスクを選択して下さい"
376. 　　Exit Sub
377. 　End If
379. 　Me.MultiPage1.Value = 1
381. 　With LB
383. 　　If .List(.ListIndex, 6) = "完了" Then
384. 　　　Me.Label1.Caption = ""
385. 　　Else
386. 　　　Me.Label1.Caption = .List(.ListIndex, 0)
387. 　　End If
389. 　　Me.TextBox1.Text = .List(.ListIndex, 1)
390. 　　Me.ComboBox1.Value = .List(.ListIndex, 2)
391. 　　Me.TextBox2.Text = .List(.ListIndex, 3)
393. 　　If Not .List(.ListIndex, 5) = "" Then
394. 　　　Me.CheckBox1.Value = True
395. 　　　Select Case .List(.ListIndex, 5)
396. 　　　　Case "毎日"
397. 　　　　　Me.OptionButton1.Value = True
398. 　　　　Case "毎週"
399. 　　　　　Me.OptionButton2.Value = True
400. 　　　　Case "毎月"
401. 　　　　　Me.OptionButton3.Value = True
402. 　　　　Case "毎年"
403. 　　　　　Me.OptionButton4.Value = True
404. 　　　End Select
405. 　　Else
406. 　　　Me.CheckBox1.Value = False
407. 　　End If
409. 　End With
410. End Sub

図６－２３

「編集」ボタン・「復活」ボタンとも、「リストボックスの項目を選択した後に実行」するものです。ですので３７４行目「If LB.ListIndex = -1 Then」で「リストボックスの項目を選択していない」場合は、３７５行目「MsgBox "タスクを選択して下さい"」でコメントを出し、３７６行目「Exit Sub」で処理を中止します。

３７９行目「Me.MultiPage1.Value = 1」は、（Pageのインデックスはゼロ始まりのため）Page2の「新規/更新」ページに移動をします。このページ移動の時に図６－２０のMultiPage1_Changeイベントが発生し、図６－１５のCommandButton5_Clickを呼出し、「新規/更新」ページの各入力欄をクリアします。

３８１行目「With LB」は、以下のコードを引数で得たListBoxについて処理をしていきます。
まず３８３行目「If .List(.ListIndex, 6) = "完了" Then」では、操作している項目が「完了」の場合に、３８４行目「Me.Label1.Caption = ""」で、タスク番号のLabel1をクリアします。これは、図６－１３で説明した③の部分になります。
それ以外（中止④、また未完②（空データ））の場合は、３８６行目「Me.Label1.Caption = .List(.ListIndex, 0)」で、リストボックスに保存されているタスク番号をLabel1に記入します。

３８９行目「Me.TextBox1.Text = .List(.ListIndex, 1)」では「タスク名」を、３９０行目「Me.ComboBox1.Value = .List(.ListIndex, 2)」では「優先度」を、３９１行目「Me.TextBox2.Text = .List(.ListIndex, 3)」では期限日を貼り付けます。

３９３～４０７行目は、定期的タスクの情報をチェックボックス・オプションボタンに表します。
３９３行目「If Not .List(.ListIndex, 5) = "" Then」では、Every列に何か（「毎日」「毎週」「毎月」「毎年」）が入っている場合に３９４～４０４行目を実行し、何も入っていない（一回限りのタスク）場合に４０６行目を実行します。

Every列に何かが入っている場合は、３９４行目「Me.CheckBox1.Value = True」で、まず「定期的」のチェックボックスにレ点を入れます。
３９５行目「Select Case .List(.ListIndex, 5)」では、Every列の文字列を確認し、３９６行目「Case "毎日"」の場合は、３９７行目「Me.OptionButton1.Value = True」で、毎日のオプションボタン（OptionButton1）をONにします。
以下同様に、「毎週」の場合はOptionButton2を、「毎月」の場合はOptionButton3を、「毎年」の場合はOptionButton4をONにします。

Every列に何も入っていない場合は、４０６行目「Me.CheckBox1.Value = False」で定期的のチェックボックスのレ点を外します。但し、３７９行目「Me.MultiPage1.Value = 1」で「新規/更新ページ」に移動した際、図６－２０のMultiPage_Changeイベントが発生し、CommandButton5_Clickプロシージャ（図６－１５）が呼び出されることで、図６－１５の２６０行目「Me.CheckBox1.Value = False」で既にOFFに設定済みです。ですので、実質このコードは意味がありません（理解し易いように、４０６行目を付けています）。

７．アドインとしてExcelにマクロを登録

このマクロ付ファイル（サンプルファイル）をExcelのアドインに登録することで、今回の「ToDoリスト」を利用することが出来ます。アドイン方法については「年賀状リスト等の宛名検索と追記　アドイン登録」を参照下さい。
また、リボン上のボタンには、図５－２の「ToDoStart」プロシージャをマクロ登録して下さい。

なおファイルをアドインしてしまうと、マクロの内容は確認できますが、ワークシートの確認が出来ません。
確認が必要な時には図７－１のように、「VBEを開く」→「アドインファイル①のThisWorkbook ②をクリック」→「プロパティウィンドウのIsAddinプロパティ③の値をTrueからFalseに変更④」することで、アドインのワークシート⑤が開きます。

図７－１

確認・操作の後、IsAddinプロパティ③の値をTrueに戻すと、アドインファイルのワークシートが非表示になります。

また、このサンプルファイルを実行しデータ変更（新規タスク追加、完了・中止処置など）を行うと、図７－２のように「ドキュメント検査機能では削除できない個人情報がドキュメントに含まれていることがありますので、ご注意ください」という注意コメントが出る場合があります。

図７－２

これは、私がExcelファイルを作った時の個人情報を削除してからデータをアップしている＋マクロ側から保存を実行させているためです。OKをクリックすればデータが保存されますが、キャンセルをクリックするとエラーが発生しマクロ停止してしまいます。

これを解除するには図７－３のように、「ファイル」→「情報」の「ブックの検査」のところで、「これらの情報をファイルに保存できるようにする」をクリックしておけば、その後エラーは発生しなくなります。

図７－３

もう少しスマートな「ファイルのアップ方法」がある気がしますが、とりあえず今回はこの方法で対応をお願いします。

８．最後に

今回のように「期限日」だけを登録するタイプでは、１日で開始から完成まで進むようなタスク項目だと問題無いのですが、例えば10日間かかるような大きなタスクの場合には、うまくスタートが出来ないかもしれません。
そのため「タスク達成に必要な期間」みたいなものも登録して、「スタートしなければいけない時期に、リストの先頭に表示される」ようにしたいと当初考えていたのですが、分かり易い表示方法に辿り着かず今回はあきらめました。

また、リストボックスに表示する項目数は今回「日数（定数Term1、Term2）」で設定しましたが、人によりタスク項目の多い少ないがあるので、日数だけで無く表示項目数も含める考え方もあると思います。
何れにしても、システムを作ったらしばらく使ってみて、バグだけでなく要望・使い勝手などを聞き取り、その内容で修正していくことは必須です。作り上げた時がスタート地点だと思います。


ToDoリストで個人タスク管理（it-071.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。