2022/12/25

自動的に閉じるメッセージ

• １．概要
• ２．実行ボタンの準備
• ３．MsgBox関数
• ４．Windows APIのMessageBoxTimeoutA関数
• ５．WSHのPopupメソッド
• ６．UserForm（モードレス）
• 　６ー１．標準モジュール
• 　６ー２．ユーザーフォーム
• 　　６ー２ー１．フォームレイアウト
• 　　６ー２ー２．フォームモジュール
• ７．UserForm（モーダル）
• 　７ー１．標準モジュール
• 　７ー２．ユーザーフォーム
• 　　７ー２ー１．フォームレイアウト
• 　　７ー２ー２．フォームモジュール
• ８．テキスト図形
• 　よりみち（手動とVBAでの既定値の違い）
• ９．ステータスバー（点滅無し）
• １０．ステータスバー（点滅有り）
• １１．まとめ
• 　１１ー１．メッセージ表示位置
• 　１１ー２．メリット・デメリット
• アプリ実例
• サンプルファイル

MsgBox関数は、情報の伝達とユーザーの意図を確認するのには欠かせないツールです。しかしダイアログを閉じる為にはマウスクリック（又はTabやEnterキーを押下）が必要で、何回も出現する時には結構な手間をユーザーに強いる事になります。
ユーザーにはメッセージを良く読んでもらい、その上で「OKボタン」をクリックしてもらいたいので、その手順は良いと思います。しかし例えば、処理が長く続いた後の「終了しました」みたいなメッセージの場合は、いちいちユーザーにマウス操作をしてもらうのはどうかと思います。
そこで今回は、表示後ある程度時間が経過したら「自動的に閉じてくれるメッセージ」を紹介します。

１．概要

紹介するのは、全７種の「自動的に閉じるメッセージ」です。表示される形としては図１のようになります。

図１別窓

「サンプルファイル」では、図１のようにシート上に８つのボタンを配置しています。表示されるダイアログの位置は、説明用のために適当に配置し直しています。実際には、おおよそ「画面中央」辺りになります。

１番目「MsgBox」は「通常のMsgBox」です。OKボタンをクリックするまで閉じませんが、比較のために配置しています。
２番目「API」は、Windows APIの「MessageBoxTimeoutA」関数を使用したものです。他サイトでも良く「自動的に閉じるメッセージ」として紹介されているものです。
３番目「WSH」は、WshShellのPopupメソッドを利用したもので、これも他サイトで紹介されているものと同じです。

４～５番目の「UserForm」はフォームを起動させ、タイマーで自動的に閉じさせるものです。見かけは４番目も５番目も同じですが、４番目は「モードレス」でフォームを起動させているため、メッセージ中でもワークシート上の操作が可能です。
一方５番目は「モーダル」ですので、フォームが消えるまで他の操作は出来なくなります（フォーム右上×印をクリックすれば、時間が来なくてもフォームを終了させる事が可能です）。

６番目「図形」は、ワークシート上に「図形のテキスト」を表示するものです。今回は、背景色＋外枠＋影　という最低限の図形にしましたが、自由度は高いので「凝ったメッセージ」を作ることが可能と思います。

７～８番目「ステータスバー」は、Excel下部のステータスバー左端にメッセージを表示させるものです。但しマクロ等で「ステータスバーを非表示」にしている場合には、当然ながら表示できません（非表示のステータスバーにメッセージを出しても、特にエラーは発生しません）。ですので、今回は「一旦ステータスバーを表示」状態にしてからメッセージを出し、終了したら元の状態に戻すようにしています。
また７番目の仕様は、単純にステータスバーに一定時間だけメッセージを表示させるだけです。しかし、これだと「ユーザーが気が付かない」可能性が高いので、８番目の仕様は「メッセージを点滅」させてユーザーの注意を引くようにしてみました。

２．実行ボタンの準備（Sheet1）

「サンプルファイル」では、図２のようにシート上にボタンを並べ、クリック時に実行されるマクロとして、標準モジュールのSUBプロシージャ「Button1」「Button2」･･･を上から順に登録します。
なお、各ボタンの表面Captionは、配置時に手動で書き換えています。

図２別窓

以下でメッセージ表示のコードを紹介しますが、標準モジュール宣言部でDeclare文を記述する都合上、コードの番号が前後してしまいました。御了承下さい。
また「自動的に閉じるメッセージ」は、今回は「２秒」で閉じる仕様としています。用途により閉じる時間は調整可能ですが、小数点以下の秒数の設定が可能なものと、不可能なものがありますので御注意下さい。

３．MsgBox関数

１番目のボタンをクリックした時に呼び出されるのが、図３です。

20. '==========　⇩(1)　ボタン１による呼び出し（MsgBox）　============
21. Sub Button1()
22. 　MsgBox "おはよう こんにちは"
23. End Sub

図３別窓

２２行目「MsgBox "おはよう こんにちは"」で、メッセージを表示しますが、通常のMsgBoxですので「OKボタンをクリック」するまでは「他の処理が停止」します。MsgBox関数で表示されるメッセージは図４のようになります。

図４別窓

４．Windows APIのMessageBoxTimeoutA関数

２番目のボタンをクリックした時に呼び出されるのは一つ下の図６ですが、その前に標準モジュールの宣言部（先頭部）で「MessageBoxTimeoutA関数を使用するための外部プロシージャへの参照」を宣言します（図５）。

0. '==========　⇩(2)　Declare文　============
1. #If Win64 Then
2. 　Private Declare PtrSafe Function MessageBoxTimeoutA Lib "User32" ( _
3. 　　ByVal Hwnd As LongPtr, ByVal lpText As String, ByVal lpCaption As String, _
4. 　　ByVal uType As VbMsgBoxStyle, ByVal wLanguageID As LongPtr, ByVal dwMilliseconds As LongPtr) As LongPtr
5. #Else
6. 　Private Declare Function MessageBoxTimeoutA Lib "User32" ( _
7. 　　ByVal Hwnd As Long, ByVal lpText As String, ByVal lpCaption As String, _
8. 　　ByVal uType As VbMsgBoxStyle, ByVal wLanguageID As Long, ByVal dwMilliseconds As Long) As Long
9. #End If

図５別窓

図５は今回使用する「MessageBoxTimeoutA」関数を宣言するものですが、Excelが「32ビット」か「64ビット」かでDeclare文が異なります。32ビットの場合は図５の０６～０８行目の式となりますし、64ビットの場合は０２～０４行目の式となります。

違いは、64ビットはFunctionの前に「PtrSafe」を付けることと、Long型は「LongPtr」型とすることです。32ビットと64ビットを分岐させるために０１行目「#If Win64 Then」でOfficeのビット数を確認し分岐しています。

なお64ビット版ExcelのVBE上では、０６～０８行目の式が「エラーのような表示」となりますが、実行されるのは０２～０４行目なので特に問題は無いようです。

２番目のボタンをクリックした時に呼び出されるのが図６のButton2プロシージャです。

30. '==========　⇩(3)　ボタン２による呼び出し（API）　============
31. Sub Button2()
32. 　Call myMsgBox2("おはよう こんにちは", 2)
33. End Sub
35. '==========　⇩(4)　MessageBoxTimeoutA　============
36. Public Sub myMsgBox2(Word As String, T As Long)
37. 　MessageBoxTimeoutA Application.Hwnd, Word, "", vbOKOnly, 0, T * 1000
38. End Sub

図６別窓

３２行目「Call myMsgBox2("おはよう こんにちは", 2)」では、３６行目のmyMsgBox2プロシージャを呼び出します。引数として、下記の２つの値を渡します。
　第一引数：表示するメッセージ
　第二引数：自動的に閉じるまでの時間（秒）
なお閉じるまでの時間は「ミリ秒」での設定が可能です。

呼び出されたプロシージャでは、３７行目「MessageBoxTimeoutA Application.Hwnd, Word, "", vbOKOnly, 0, T * 1000」を実行します。MessageBoxTimeoutA関数には、図７のように６つのパラメータを設定します。全て必須です。

MessageBoxTimeoutA関数のパラメータ

No.	引数	内容
1	Hwnd	メッセージボックスのハンドル
2	lpText	メッセージボックスに表示されるテキスト
3	lpCaption	メッセージボックスに表示されるタイトル
4	uType	メッセージ ボックスの内容と動作を指定
5	wLanguageID	メッセージボックスに表示される言語
6	dwMilliseconds	ユーザーの応答を待機する時間 (ミリ秒)

図７別窓

第一引数「Hwnd」には、Excelのハンドルを指定するため「Application.Hwnd」または「Excel.Application.Hwnd」とします。この第一引数にNull相当の「ゼロ」の値を指定すると「オーナーウィンドウを持たない」状態になり、「メッセージボックスがExcelとは無関係」に動ける事になります。
実際に試してみると、ダイアログ表示中にExcel本体を操作すると「Excel本体が最前面」になり、逆にメッセージのダイアログが「Excelの裏」に隠れて見えなくなってしまいます。

第二引数「lpText」は、表示されるメッセージを指定します。
第三引数「lpCaption」は、ダイアログのタイトルの文字列を指定します。
第四引数「uType」は、表示するボタンの種類などを図８の値を組み合わせて指定します。

uTypeの値

グループ	定数	値	内容
ボタン 種類	vbOKOnly	0	[OK]のみ（既定）
	vbOKCancel	1	[OK]+[キャンセル]
	vbAbortRetryIgnore	2	[中止]+[再試行]+[無視]
	vbYesNoCancel	3	[はい]+[いいえ]+[キャンセル]
	vbYesNo	4	[はい]+[いいえ]
	vbRetryCancel	5	[再試行]+[キャンセル]
アイコン	vbCritical	16	警告マーク
	vbQuestion	32	問い合わせマーク
	vbExclamation	48	注意マーク
	vbInformation	64	情報マーク
標準 ボタン	vbDefaultButton1	0	第1ボタンを標準ボタンに（既定）
	vbDefaultButton2	256	第2ボタンを標準ボタンに
	vbDefaultButton3	512	第3ボタンを標準ボタンに
	vbDefaultButton4	768	第4ボタンを標準ボタンに
モーダル	vbApplicationModal	0	アプリケーションモーダルに設定（既定）
	vbSystemModal	4096	システムモーダルに設定
他	vbMsgBoxHelpButton	16384	ヘルプボタンを追加
	VbMsgBoxSetForeground	65536	最前面のウィンドウとして表示
	vbMsgBoxRight	524288	テキストを右寄せで表示
	vbMsgBoxRtlReading	1048576	テキストを右から左の方向で表示

図８別窓

第五引数「wLanguageID」は「ゼロ」を指定すると、既定のシステム言語でボタン・テキストが表示されることになります。
第六引数「dwMilliseconds」には、メッセージボックスを開いている時間をミリ秒単位で指定します。

今回は「MessageBoxTimeoutA Application.Hwnd, Word, "", vbOKOnly, 0, T * 1000」と設定しましたので、メッセージには引数で得たメッセージ文字列を、タイトルは空欄に、ボタン類はOKボタンのみを表示しています。
また開いている時間は、引数で「2」の値を受け取っていますので、2 × 1000 = 2000ミリ秒 = 2秒 となります。
なお「ゼロ秒」を指定すると、自動的には閉じなくなります。

MessageBoxTimeoutAで表示されるメッセージは図９のようになります。

図９別窓

５．WSHのPopupメソッド

Windows Script Host（WSH）は、Windowsに搭載されている「スクリプト実行」機能です。その中のWshShellオブジェクトのPopupメソッドを使うことでメッセージが表示できます。

３番目のボタンをクリックした時に呼び出されるのが、図１０のButton3プロシージャです。

50. '==========　⇩(5)　ボタン３による呼び出し（WSH）　============
51. Sub Button3()
52. 　Call myMsgBox3("おはよう こんにちは", 2)
53. End Sub
55. '==========　⇩(6)　WSH　============
56. Public Sub myMsgBox3(Word As String, T As Long)
57. 　Dim WSH As Object '←WshShellオブジェクト
59. 　Set WSH = CreateObject("Wscript.Shell")
60. 　WSH.Popup Word, T
61. 　Set WSH = Nothing
62. End Sub

図１０別窓

５２行目「Call myMsgBox3("おはよう こんにちは", 2)」では、５６行目のmyMsgBox3プロシージャを呼び出します。引数として、メッセージ文字列と閉じるまでの時間（秒）を渡します。

なお閉じるまでの時間は、Popupメソッドでは「秒単位」設定ですので、５６行目では「T As Long」とLong型で受け取るようにしています。
そのため小数点付きの値を受け取った時には、基本的には四捨五入になります。但しLong型変換時（CLng関数も同じ）には、小数部分がちょうど0.5のときには「最も近い偶数」に値を丸める特性があります。例えば「0.5」を渡した場合は「1」にはならず「ゼロ」になりますので注意が必要です。

５９行目「Set WSH = CreateObject("Wscript.Shell")」では、WSHのWshShellオブジェクトを生成しています。
６０行目「WSH.Popup Word, T」では、WshShellオブジェクトのPopupメソッドを使って、メッセージを表示します。Popupメソッドには図１１のように４つのパラメータがあります。第一パラメータ以外は省略可です。

Popupメソッドのパラメータ

No.	引数	内容
1	strText（必須）	メッセージボックスに表示する文字列
2	nSecondsToWait	メッセージボックスを閉じるまでの時間（秒単位）
3	strTitle	メッセージボックス上部のタイトル名
4	nType	ボダンやアイコンの設定

図１１別窓

第一引数「strText」は、メッセージボックスに表示させるメッセージ文字列です。
第二引数「nSecondsToWait」は、メッセージを閉じるまでの時間を「秒単位」で設定します。この値に「ゼロ」値を設定すると、自動的には閉じなくなります。
なお、このWSHのPopupメソッドは不安定なようで、設定した秒数よりも長く表示されますし、自動的に閉じてくれない場合もあるようです。

第三引数「strTitle」は、ダイアログ上部のタイトル名です。省略した場合には「Windows Script Host」となります。
第四引数「nType」は、表示するボタンの種類などを図１２の値を組み合わせて指定します。

uTypeの値

グループ	定数	値	内容
ボタン 種類	vbOKOnly	0	[OK]のみ（既定）
	vbOKCancel	1	[OK]+[キャンセル]
	vbAbortRetryIgnore	2	[中止]+[再試行]+[無視]
	vbYesNoCancel	3	[はい]+[いいえ]+[キャンセル]
	vbYesNo	4	[はい]+[いいえ]
	vbRetryCancel	5	[再試行]+[キャンセル]
アイコン	vbCritical	16	警告マーク
	vbQuestion	32	問い合わせマーク
	vbExclamation	48	注意マーク
	vbInformation	64	情報マーク
標準 ボタン	vbDefaultButton1	0	第1ボタンを標準ボタンに（既定）
	vbDefaultButton2	256	第2ボタンを標準ボタンに
	vbDefaultButton3	512	第3ボタンを標準ボタンに
	vbDefaultButton4	768	第4ボタンを標準ボタンに

図１２別窓

図１２は図８の上半分の形です。図１２には無い値（例えば、システムモーダルに対応した「4096」値）を設定してしまうと、メッセージボックスが表示されなくなってしまいますので注意が必要です。

今回は「WSH.Popup Word, T」と設定しましたので、メッセージには引数で得たメッセージ文字列を、表示時間は「2秒（実際には５秒くらいしないと消えません）」となります。また第三・第四引数は省略した為、ダイアログのタイトル部は「Windows Script Host」となり、ボタンはOKボタンのみでアイコンは無い状態です。

表示終了後、６１行目「Set WSH = Nothing」では５９行目で生成したWSHオブジェクトを解放しています。
Popupメソッドで表示されるメッセージは図１３のようになります。

図１３別窓

なお、Popupでのメッセージが表示されている状態でExcelにフォーカスを移す（セル選択操作や書式設定は可能ですが、セル入力は不可能です）と、メッセージはExcelの裏側に廻り見えなくなってしまいますが、時間のカウントは続けているようです。
また「タスクマネージャー」を起動していると、なぜかPopupメッセージが閉じてくれません。いずれにしても、ちょっと不安定なメソッドです。

６．UserForm（モードレス）

６ー１．標準モジュール（Module1）

４番目のボタンをクリックした時に呼び出されるのが、図１４です。

70. '==========　⇩(7)　ボタン４による呼び出し（UserForm モードレス）　============
71. Sub Button4()
72. 　Call UserForm1.UFstart("おはよう こんにちは", 2)
73. End Sub

図１４別窓

７２行目「Call UserForm1.UFstart("おはよう こんにちは", 2)」では、UserForm1の中の「UFstart」プロシージャを呼び出しています。引数として、メッセージ文字列と閉じるまでの時間（秒）を渡します。
なお閉じるまでの時間は、フォーム内ではTimer関数で管理していますので、ミリ秒単位での設定が可能です。

６ー２．ユーザーフォーム（UserForm1）

６ー２ー１．フォームレイアウト

フォーム上には、図１５のように「Labelコントロール」を１つ配置します。Labelの高さ（Height）は今回24ポイント（≒2行分）としましたが、メッセージを複数行表示する可能性があるのであれば、その行数が入るだけを確保する必要があります。

図１５別窓

６ー２ー２．フォームモジュール

図１４の７２行目から呼び出されるのが、フォームモジュール上の図１６です。
引数として、メッセージとして表示する文字列と、閉じるまでの時間（秒）を受け取ります。

80. '==========　⇩(8)　フォームの起動と終了　============
81. Public Sub UFstart(Word As String, T As Single)
82. 　Dim startT As Single 　　 '←表示開始時の時刻
84. 　Me.Label1.Caption = Word
85. 　Me.Show vbModeless
87. 　startT = Timer()
88. 　Do While (startT + T) > Timer()
89. 　　DoEvents: DoEvents
90. 　Loop
92. 　Unload Me
93. End Sub

図１６別窓

８４行目「Me.Label1.Caption = Word」では、Labelコントロールに引数で受け取ったメッセージを設定します。
８５行目「Me.Show vbModeless」では、このフォームを「モードレス」で起動します。と言って８５行目の実行で初めてフォームが生成される訳では無く、図１６のUFstartプロシージャが呼び出された時には「UFstartプロシージャが実行されるより前にInitializeイベントが先に発生」しますのでフォーム生成済みです。なお今回はInitializeイベントプロシージャはありません。

８５行目では「フォームはモードレスで起動」しますので、処理は次のコードに移り、８７行目以降を実行します。
８７行目「startT = Timer()」では、Timer関数を使って現在の時刻（ミリ秒単位）を変数startTに代入します。
８８～９０行目のDo～Loopでは、設定時間分だけ空回しをし、次のコードへ移る待ち時間を作ります。

８８行目「Do While (startT + T) > Timer()」は、回る条件が「While (startT + T) > Timer()」となっていますので、８７行目で設定した時刻（startT）に引数の「閉じるまでの時間（T）」を足した時刻と、現在の時刻を比較します。つまり設定した「閉じるまでの時間（T）」を経過するまではDo～Loopを繰り返すことになります。
８９行目の「DoEvents」を２つ実行している部分は、万一Do～Loopが無限ループになってしまった時に「ESCキーで割り込んでVBAコードを中断」させるために、念のため入れています。

「閉じるまでの時間」が経過し Do～Loopを抜け出たら、９２行目「Unload Me」で自分自身（UserForm1）を閉じます。閉じたら制御は図１４に戻り、シート上のボタンクリックによる処理が終了します。
UserForm1を実行することで表示されるメッセージは図１７のようになります。

図１７別窓

モードレスでフォームを起動していますので、図１７のようにフォーム起動中でもExcel操作が可能です。セル入力状態になっていても、フォーム内でカウントは進められる為に、設定時刻になれば「入力中でもフォームが閉じる」ことになります。

なお、表示中のメッセージダイアログの「右上×印」をクリックすることでフォームを閉じた場合でも、８８～９０行目のDo～Loopは回り続けていますので、制御が図１４の７３行目に戻ってくるのは「設定した秒数後」となります。閉じるまでの時間を長時間に設定することは少ないと思いますが、その場合には「ユーザーに無理やり閉じられた」時のことは考慮する必要があると思います。
と言って、Do～Loop内で毎回「フォームが表示されているかを確認」するのも行き過ぎの気がしますし、特にエラーは発生しないために、そのままとしてあります。

７．UserForm（モーダル）

７ー１．標準モジュール（Module1）

５番目のボタンをクリックした時に呼び出されるのが、図１８です。

100. '==========　⇩(9)　ボタン５による呼び出し（UserForm モーダル）　============
101. Sub Button5()
102. 　Call UserForm2.UFstart("おはよう こんにちは", 2)
103. End Sub

図１８別窓

１０２行目「Call UserForm2.UFstart("おはよう こんにちは", 2)」では、UserForm2の中の「UFstart」プロシージャを呼び出しています。引数として、メッセージ文字列と閉じるまでの時間（秒）を渡します。
なお閉じるまでの時間は、フォーム内ではTimer関数で管理していますので、ミリ秒単位での設定が可能です。

７ー２．ユーザーフォーム（UserForm1）

７ー２ー１．フォームレイアウト

フォーム上には、図１９のように「Labelコントロール」を１つ配置します。Labelの高さ（Height）は今回24ポイント（≒2行分）としましたが、メッセージを複数行表示する可能性があるのであれば、その行数が入るだけを確保する必要があります。

図１９別窓

７ー２ー２．フォームモジュール

図１８の１０２行目から呼び出されるのがフォームモジュール上の図２０の１１４行目です。
引数として、メッセージとして表示する文字列と、閉じるまでの時間（秒）を受け取ります。

110. '==========　⇩(10)　フォームレベル変数の宣言　============
111. Dim T As Single '←フォーム内で使用する「閉じるまでの時間」
113. '==========　⇩(11)　メッセージのフォームを起動　============
114. Public Sub UFstart(Word As String, Tr As Single)
115. 　T = Tr
116. 　Me.Label1.Caption = Word
117. 　Me.Show vbModal
118. End Sub

図２０別窓

標準モジュール側から呼び出された図２０のUFstartプロシージャ内では、フォームをモーダル（フォーム上のコントロールしか操作不可）で起動している間、１１７行目の「Me.Show vbModal」でコードの進行がストップしています。そのため引数で受け取った「閉じるまでの時間」を、UFstartプロシージャ内ではカウントできません。

一方Showメソッドでフォームを起動した際には、Activateイベント（図２１）が発生するため、その中で時間をカウントする事とします。そのため、UFstartプロシージャで受け取った「閉じるまでの時間」を一旦「フォームレベルの変数（１１１行目）」に代入し、その変数値を使ってActivateイベントプロシージャ内で「閉じるまでの時間」をカウントします。

そのフォームレベルの変数を宣言しているのが、１１１行目「Dim T As Single」で、その変数に「閉じるまでの時間」を代入しているのが１１５行目「T = Tr」になります。

１１６行目「Me.Label1.Caption = Word」ではフォーム上のLabelコントロールに、引数で受け取ったメッセージを書き込み、１１７行目「Me.Show vbModal」では、自分（UserForm2）を「モーダル」で起動します。

なお、標準モジュールの１０２行目からフォーム上のUFstartプロシージャを呼び出した際は、「　Initialize　→　UFstart　」の順序でプロシージャが実行されます。ですので１１７行目でShowメソッドを実行した時には、すでにInitializeイベントは通過しているため、次に実行されるのは「Activateイベント」となります。そのため「閉じるまでの時間」はActivate（図２１）でカウントしています。

図２０の１１７行目「Me.Show vbModal」でフォームを起動すると、図２１のActivateイベントプロシージャが実行されます。

130. '==========　⇩(12)　設定時間後にフォーム終了　============
131. Private Sub UserForm_Activate()
132. 　Dim startT As Single 　 '←表示開始時の時刻
134. 　startT = Timer()
135. 　Do While (startT + T) > Timer()
136. 　　DoEvents: DoEvents
137. 　Loop
139. 　Unload Me
140. End Sub

図２１別窓

１３４行目「startT = Timer()」では、Timer関数を使って現在の時刻（ミリ秒単位）を変数startTに代入します。
１３５～１３７行目のDo～Loopでは、設定時間分だけ空回しをし、次のコードへの待ち時間を作ります。

１３５行目「Do While (startT + T) > Timer()」では、設定した「閉じるまでの時間（T）」を経過するまではDo～Loopを繰り返した後、１３９行目「Unload Me」で自分自身（UserForm2）を閉じます。 なお１３６行目の「DoEvents」を２つ実行している部分は、万一Do～Loopが無限ループになってしまった時に「ESCキーで脱出」する為のものです

UserForm2を実行することで表示されるメッセージは図２２のようになります。

図２２別窓

図１７とは異なり、モーダル状態でフォームを起動すると「フォームが閉じるまでは、シート操作が不可」となります。

なおモードレスの時と同様に、表示中のメッセージダイアログの「右上×印」をクリックすることでフォームを閉じた場合でも、１３５～１３７行目のDo～Loopは回り続けていますので、制御が図１８の１０３行目に戻ってくるのは「設定した秒数後」となります。

８．テキスト図形

６番目のボタンをクリックした時に呼び出されるのが、図２３のButton6プロシージャです。

150. '==========　⇩(13)　ボタン６による呼び出し（図形）　============
151. Sub Button6()
152. 　Call myMsgBox6("おはよう こんにちは", 2)
153. End Sub
155. '==========　⇩(14)　メッセージ図形の描画と削除　============
156. Public Sub myMsgBox6(Word As String, T As Single)
157. 　Dim L As Shape 　 '←表示する図形
158. 　Dim startT As Single 　 '←表示開始時の時刻
159. 　Dim X As Double 　 '←図形の左上角の位置（X方向）
160. 　Dim Y As Double 　 '←図形の左上角の位置（Y方向）
162. 　With ActiveWindow.VisibleRange
163. 　　X = .Left + .Width / 2
164. 　　Y = .Top + .Height / 2
165. 　End With
167. 　Set L = ActiveSheet.Shapes.AddLabel(msoTextOrientationHorizontal, X, Y, 0, 0)
169. 　L.TextFrame2.TextRange.Characters.Text = Word
170. 　L.TextFrame2.WordWrap = msoFalse
171. 　L.Fill.BackColor.RGB = RGB(255, 0, 0)
172. 　L.Line.Visible = msoTrue
173. 　L.Shadow.Type = msoShadow21
175. 　startT = Timer()
176. 　Do While (startT + T) > Timer()
177. 　　DoEvents: DoEvents
178. 　Loop
180. 　On Error Resume Next
181. 　　L.Delete
182. 　On Error GoTo 0
184. 　Set L = Nothing
185. End Sub

図２３別窓

１５２行目「Call myMsgBox6("おはよう こんにちは", 2)」では、１５６行目のmyMsgBox6プロシージャを呼び出します。引数として、メッセージ文字列と閉じるまでの時間（秒）を渡します。

まず１６２～１６５行目で、メッセージ図形を描画する位置を計算します。
これまで説明してきた「メッセージボックスを表示するタイプ」は、極端に言えば「パソコンディスプレイのどこに表示されてもOk」です。例えば、Excelのリボンの上でも表示可能です。
しかし今回の「図形」では、それは出来ません。図形は「ワークシート上」に貼り付ける必要があります。しかも、広大なワークシートの中の「ユーザーが見える範囲」でないと意味がありません（Chartシート上に図形を貼り付けることも可能ですが、今回はワークシートにしか対応させていません）。

そこで、図２４のような「ActiveWindow.VisibleRange」というセル範囲を今回は使用します。

図２４別窓

「VisibleRange」は「見えているセル範囲」です。「見えているセル範囲」の左上セル（図２４ではA1セル）は、セルの左上角がExcelのワークシートの原点に合った位置で表示されていますが、右下セル（同N17セル）は一部分しか見えていない状態です。しかし「VisibleRange」は、少しでも見えていれば範囲に含まれますので、図２４での「VisibleRange」は「A1:N17」という事になります。

今回は、この「VisibleRange」の中央位置を、表示するメッセージ図形の左上角になるようにしました。
１６２行目「With ActiveWindow.VisibleRange」で「VisibleRange」範囲を基準とし、１６３行目「X = .Left + .Width / 2」で「VisibleRange」範囲の横（X）方向の中央位置を計算します。考え方としては、VisibleRange範囲左端までの距離とVisibleRange範囲の幅の中央を合計することで、ドキュメント座標原点（A1セルの左上角）からの距離を得ています。
また１６４行目「Y = .Top + .Height / 2」では、「VisibleRange」範囲の縦（Y）方向の中央位置を計算しています。

なお１６３行目の「.Left」の代わりに、「Columns(ActiveWindow.ScrollColumn).Left」という式を使っても同じ結果が得られます。「スクロール後の左端列の原点からの距離」という意味です。また１６４行目「.Top」の代わりは「Rows(ActiveWindow.ScrollRow).Top」となります。

「見えているセル範囲」の中央位置が計算できましたので、１６７行目「Set L = ActiveSheet.Shapes.AddLabel(msoTextOrientationHorizontal, X, Y, 0, 0)」で、新たにテキスト図形を作成し、変数Lとしています。

AddLabelメソッドには、図２５のように５つのパラメータを指定します。全て必須です。
Shapes.AddLabel(Orientation, Left, Top, Width, Height)

パラメータ	型	内容
Orientation	MsoTextOrientation	テキストの向き
Left	Single	左上角の横方向位置
Top	Single	左上角の縦方向位置
Width	Single	幅
Height	Single	高さ

図２５別窓

また１番目のパラメータ「Orientation」は、図２６のいずれかを指定します。

Orientationパラメータ(MsoTextOrientation型)

定数	値	内容
msoTextOrientationHorizontal	1	横方向
msoTextOrientationUpward	2	上向き
msoTextOrientationDownward	3	下向き
msoTextOrientationVerticalFarEast	4	垂直(アジア言語用)
msoTextOrientationVertical	5	縦

図２６別窓

今回１６７行目では、テキスト方向として「横方向」を指定し、テキスト図形の左上角の位置として「横（X）方向」を１６３行目で計算した値、「縦（Y）方向」を１６４行目で計算した値を指定しています。
またテキスト図形の幅・高さは「ゼロ」とし、メッセージとして表示するテキストのサイズに大きさを合わせる（１７０行目）こととしました。

１６９～１７３行目では、１６７行目で作成したテキスト図形に文字や色の装飾を与えています。
１６９行目「L.TextFrame2.TextRange.Characters.Text = Word」は、メッセージの文字列を設定しています。
１７０行目「L.TextFrame2.WordWrap = msoFalse」は、「図形の境界に合わせてテキスト行を折り返す」をOFFにしています。これは、シート上の図形を選択した後「図形の書式設定」→「サイズとプロパティ」→「プロパティ」→「テキストボックス」を選び、「図形内でテキストを折り返す」のレ点を外すのと同じ動作になります。
この設定により「テキストに合わせて図形がサイズを変える」ことになります。

手動で図形を作成した場合、図形のサイズをテキストに合わせる為には、上記の「図形内でテキストを折り返す」をOFFにするのと同時に、「テキストに合わせて図形のサイズを調整する」をONにする必要があります。 この「サイズ調整」をVBAで表すと「図形.TextFrame2.AutoSize = msoAutoSizeShapeToFitText」となります。なお、手動で図形を作成した時には、既定は「図形.TextFrame2.AutoSize = msoAutoSizeNone」とOFFとなっています。 一方VBAで図形を作成した直後は、「図形.TextFrame2.WordWrap」 は「msoTrue」 とONになっているため、１７０行目のように「= msoFalse」に変更してやる必要があるのですが、サイズ調整の方の既定は「図形.TextFrame2.AutoSize = msoAutoSizeShapeToFitText」なので、今回はAutoSizeプロパティを「変更する必要は無い」のです。 手動作成とVBA作成で「既定値が異なる」プロパティは、他にも存在するかもしれません。マクロ記録で取得したコードをそのまま使用すれば目的は達成できるかもしれませんが、無駄にコードを実行している場合もありそうです。

１７１行目「L.Fill.BackColor.RGB = RGB(255, 0, 0)」は、テキスト図形の背景色を「赤色」にしています。
１７２行目「L.Line.Visible = msoTrue」は、テキスト図形の枠線を「有り」にしています。
１７３行目「L.Shadow.Type = msoShadow21」は、テキスト図形に影を付けて「立体的」に見えるようにしています。Shadow.Typeプロパティには、msoShadow1 ～ msoShadow43 の43種類が設定できるようですが、今回は「右下に短く薄く伸びる影」を選んでいます。

以上でテキスト図形のメッセージが完成したため、１７５～１７８行目で設定秒数だけカウントをします。
１７５行目「startT = Timer()」で、現在の時刻（ミリ秒単位）を変数startTに代入します。
１７６行目「Do While (startT + T) > Timer()」では、設定した「閉じるまでの時間（T）」を経過するまではDo～Loopを繰り返します。

設定時間が経過したら１８１行目「L.Delete」で、メッセージのテキスト図形を削除します。
但しテキスト図形が表示されている間に、ユーザーが「テキスト図形を選択し、DELキー等で削除」してしまう事も考えられます。もし削除されてしまうと、Deleteする「オブジェクトが無い」事になりますので、１８１行目で「オブジェクトが必要です（エラー番号 = 424）」というエラーが発生してしまいます。
ですので、１８０行目「On Error Resume Next」でエラーが発生した際にはスルーをさせています。

１８４行目「Set L = Nothing」では、オブジェクトを解除しています。

なお、今回VisibleRangeで「見えているセル範囲」を取得しましたが、ウィンドウ枠の固定やウィンドウの分割をしていると、表示位置が変わるばかりか「メッセージのテキスト図形が見えない」可能性が出てきます。
対策として考えられるのは、「ウィンドウの固定や分割を一旦解除」する手法がありますが、元の状態に戻すのも結構面倒な気がしますので、固定や分割をする可能性のあるアプリでは別な手法を使った方が良いと思います。

９．ステータスバー（点滅無し）

７番目のボタンをクリックした時に呼び出されるのが、図２７のButton7プロシージャです。

190. '==========　⇩(15)　ボタン７による呼び出し（ステータスバー点滅無し）　============
191. Sub Button7()
192. 　Call myMsgBox7("おはよう こんにちは", 2)
193. End Sub
195. '==========　⇩(16)　ステータスバーへの表示（点滅なし）　============
196. Public Sub myMsgBox7(Word As String, T As Single)
197. 　Dim startT As Single 　 '←表示開始時の時刻
198. 　Dim stdStatusBar As Boolean 　 '←現状のステータスバー状態
200. 　stdStatusBar = Application.DisplayStatusBar
201. 　Application.DisplayStatusBar = True
203. 　Application.StatusBar = Word
205. 　startT = Timer()
206. 　Do While (startT + T) > Timer()
207. 　　DoEvents: DoEvents
208. 　Loop
210. 　Application.StatusBar = False
211. 　Application.DisplayStatusBar = stdStatusBar
212. End Sub

図２７別窓

１９２行目「Call myMsgBox7("おはよう こんにちは", 2)」では、１９６行目のmyMsgBox7プロシージャを呼び出します。引数として、メッセージ文字列と閉じるまでの時間（秒）を渡します。

今回は「ステータスバーにメッセージを出す」ので、そのステータスバーが表示されている必要があります。しかし、設定でステータスバーを非表示にすることが可能（以前のバージョンではON-OFFがメニューから出来ましたが、最近のバージョンではメニューがありません。しかしVBAのコード実行によりON-OFFが可能です）ですので、作るアプリによってはステータスバーが非表示にされている可能性があります。

念のため、ステータスバーの表示・非表示の状態を図２８に示します。

図２８別窓

そこで今回は、もしステータスバーが非表示に設定されている場合は、一旦「ステータスバーを表示状態」にした後「メッセージを表示」し、設定時間が経過したら「表示を消し」て「ステータスバーを元の状態に戻す」ような仕様にしています。

２００行目「stdStatusBar = Application.DisplayStatusBar」では、現在のステータスバーの状態（表示状態＝True、非表示状態＝False）を取得し、変数stdStatusBarに保存します。
２０１行目「Application.DisplayStatusBar = True」では、ステータスバーを表示状態にしています。現状が表示状態であった場合は、そのまま表示状態が続くことになります。気になる方は「If stdStatusBar = False Then Application.DisplayStatusBar = True」と、２００行目の結果を使って「非表示の場合のみ表示状態にする」方法でもOKです。

２０３行目「Application.StatusBar = Word」では、引数で受け取ったメッセージを「ステータスバーに表示」します。

２０５～２０８行目では、設定秒数だけカウントをします。
２０５行目「startT = Timer()」で、現在の時刻（ミリ秒単位）を変数startTに代入します。
２０６行目「Do While (startT + T) > Timer()」では、設定した「閉じるまでの時間（T）」を経過するまではDo～Loopを繰り返します。

設定時間が経過したら２１０行目「Application.StatusBar = False」で、ステータスバーの表示を既定状態（図２８の右側のように「準備完了・・・」など）に戻します。
最後に２１１行目「Application.DisplayStatusBar = stdStatusBar」で、ステータスバーの状態を２００行目で取得した状態「変数stdStatusBar」に戻します。

なお、ステータスバーは「１行分」しか無いため、メッセージ文字列として「改行」が入っている文字列を指定すると、図２９のように「２行目以降が隠れてしま」うことになりますので、注意が必要です。

図２９別窓

メッセージ表示中のステータスバーの状態は、図３０のようになります。

図３０別窓

１０．ステータスバー（点滅有り）

８番目のボタンをクリックした時に呼び出されるのが、図３１のButton8プロシージャです。

220. '==========　⇩(17)　ボタン８による呼び出し（ステータスバー点滅有り）　============
221. Sub Button8()
222. 　Call myMsgBox8("おはよう こんにちは", 2)
223. End Sub
225. '==========　⇩(18)　ステータスバーへの表示（点滅有り）　============
226. Public Sub myMsgBox8(Word As String, T As Single)
227. 　Dim startT As Single 　 '←表示開始時の時刻
228. 　Dim stdStatusBar As Boolean 　 '←現状のステータスバー状態
229. 　Dim i As Integer 　 '←点滅の回数
231. 　stdStatusBar = Application.DisplayStatusBar
232. 　Application.DisplayStatusBar = True
234. 　For i = 1 To 5
235. 　　Application.StatusBar = Chr(32)
236. 　　Application.Wait [Now()] + 100 / 86400000
237. 　　Application.StatusBar = Word
238. 　　Application.Wait [Now()] + 100 / 86400000
239. 　Next i
241. 　startT = Timer()
242. 　Do While (startT + T) > Timer()
243. 　　DoEvents: DoEvents
244. 　Loop
246. 　Application.StatusBar = False
247. 　Application.DisplayStatusBar = stdStatusBar
248. End Sub

図３１別窓

２２２行目「Call myMsgBox8("おはよう こんにちは", 2)」では、２２６行目のmyMsgBox8プロシージャを呼び出します。引数として、メッセージ文字列と閉じるまでの時間（秒）を渡します。

この仕様も、メッセージを表示するためにはステータスバーが表示されている必要があります。ですので２３１行目「stdStatusBar = Application.DisplayStatusBar」で現在のステータスバーの状態を取得し、変数stdStatusBarに保存します。
２３２行目「Application.DisplayStatusBar = True」では、ステータスバーを表示状態にしています。現状が表示状態であった場合は、そのまま表示状態が続くことになります。

２３４～２３９行目では、メッセージを点滅させています。
２３４行目「For i = 1 To 5」では、２３５～２３８行目を５回繰り返します。つまりメッセージを５回点滅させています。
２３５行目「Application.StatusBar = Chr(32)」では、ステータスバーに「半角スペース」を表示させています。実際には図３２の左側のように、ステータスバーは空になります。

図３２別窓

ここで「Application.StatusBar = ""」と「長さゼロの文字列」を指定しても同じになりそうですが、残念ながら長さゼロの文字列を指定すると「Application.StatusBar = False」を指定した事になるようです。ですので、図２８の左側のような既定の文字列（準備完了・・・など）が表示されてしまいます。

２３６行目「Application.Wait [Now()] + 100 / 86400000」では、プログラムを0.1秒間ストップさせています。つまりステータスバーが空の状態を「0.1秒間保持」しています。
なお、通常使用している関数 Now() は「秒単位」ですが、 [Now()] と角カッコで囲むことで「ミリ秒単位」で現在の日時を取得することが出来ます。ここで使用している角カッコは「Evaluateメソッド」の代わりになるもので、「引数（文字列）をオブジェクトや値に変換」するものです。ですので [Now()] の部分は、Application.Evaluate("Now()")としてもOKです。

また２３６行目の後ろ半分の「100 / 86400000」は、100ミリ秒を表しています。日時の値は「１日＝１」ですので、１日をミリ秒で表した「24時間 * 60分 * 60秒 * 1000ミリ秒 = 86,400,000 」を分母に持ってきて、分子に設定するミリ秒を指定しています。

２３７行目「Application.StatusBar = Word」は、引数で受け取ったメッセージをステータスバーに表示し、２３８行目「Application.Wait [Now()] + 100 / 86400000」で0.1秒間保持します。
この「空白」⇔「メッセージ」を図３２のように５回繰り返します。

２３４～２３９行目のFor～Nextを抜けた時には「ステータスバーにメッセージが表示」されている状態です。その状態を２４１～２４４行目のDo～Loopで設定時間だけ保持します。
２４１行目「startT = Timer()」で、現在の時刻（ミリ秒単位）を変数startTに代入し、２４２行目「Do While (startT + T) > Timer()」で、設定した「閉じるまでの時間（T）」を経過するまではDo～Loopを繰り返しています。

設定時間が経過したら、２４６行目「Application.StatusBar = False」でステータスバーを既定状態に戻します。
最後に２４７行目「Application.DisplayStatusBar = stdStatusBar」で、ステータスバー表示・非表示を元の状態（２３１行目で取得した状態）に戻します。

１１．まとめ

１１ー１．メッセージ表示位置

ステータスバーへの表示は別として、ダイアログやテキスト図形を表示する場合、その表示位置を決める基準は図３３のように３種類あると思います。

図３３別窓

１つ目は「PCの画面枠」で、その中心（図３３の緑丸）に表示されるのが「MsgBox」「APIのMessageBoxTimeoutA」「WSHのPopup」です。
２つ目は「Excel外枠」で、その中心（図３３の赤丸）に表示されるのが「ユーザーフォーム」です。なお、フォームの表示位置をStartUpPositionプロパティで指定することは可能です。
MsgBox等とユーザーフォームは「スクリーン座標」上のオブジェクトです。

３つ目は「Excelのシート内部」です。テキスト図形はシート上（ドキュメント座標上）に配置する必要があるため、今回は見えているセル範囲として図３３の青色（VisibleRange）を基準として図形を表示させました。

１１ー２．メリット・デメリット

以上をまとめてみると、図３４のようになるかと思います。長所短所を把握して活用すれば、ユーザーへの負担（クリックする手間）少なく、情報も伝わるメッセージとすることが出来ると思います。

		API	WSH	UserForm	図形	ステータスバー
視認性		〇	〇	〇	〇	△
ﾃﾞｻﾞｲﾝ 自由度		△ ｱｲｺﾝ可	△ ｱｲｺﾝ可	〇 色･ｻｲｽﾞ等	〇 形状･色･ｻｲｽﾞ等	× 文字のみ
複数行		〇	〇	△ 事前に確保要	〇	×
時間制御		ﾐﾘ秒	秒	Timer関数使用で ﾐﾘ秒可
表示 位置	既定	画面中央	画面中央	Excel中央	ｼｰﾄ上	ｽﾃｰﾀｽﾊﾞｰ
	変更	×	×	〇	〇	×
その他			不安定

図３４別窓

アプリ実例

「DVD等の内容・保管場所等管理システム」
「図形も貼り付けられるスケジュール帳」


自動的に閉じるメッセージ（its-022.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。