2023/01/27

コンボボックスのテキストボックス部に複数列を表示

• １．概要
• ２．システム補助関係
• 　２ー１．ワークシート
• 　２ー２．標準モジュール
• 　２ー３．ユーザーフォーム
• 　　２ー３ー１．フォームレイアウト
• 　　２ー３ー２．フォームモジュール（メイン）
• ３．「標準」コンボボックス
• 　３ー１．設定
• 　３ー２．動作結果
• ４．「隠しリスト方式」コンボボックス
• 　４ー１．設定
• 　４ー２．動作結果
• ５．「リストボックス上乗せ方式」コンボボックス
• 　５ー１．設定
• 　　よりみち（コントロールを作る順番）
• 　５ー２．動作結果
• アプリ実例
• サンプルファイル

コンボボックスに複数列のデータをリスト化することは可能ですが、リストを選択した後のテキストボックス部には「指定した単列（指定しない場合は、既定の１列目）のみのデータ」が表示されます。
しかし、コンボボックスにフォーカスが無い時にも「複数列のデータ」が見えていて欲しい場合もありますので、今回は「コンボボックスのテキストボックス部に複数列のデータを表示」させる方法について紹介します。

１．概要

今回紹介する「テキストボックス部に複数列表示するコンボボックス」は、以下の２種類です。

隠しリスト方式	リストの非表示列に表示列のデータを連結させて書き込み、テキストボックス部には非表示列を指定。
リストボックス上乗せ方式	テキストボックス部にリストボックスを重ねて配置し、選択したデータをリストボックスに表示。

「添付ファイル」では、標準のコンボボックス＋上記２方式を確認できるように、図１のようなものを作成しました。

図１別窓

ワークシート上のボタンをクリックするとユーザーフォームが起動します。フォーム上には３つのコンボボックスがあります。
各コンボボックスのリストは、ワークシート「A1:B4」のセル範囲の２列データを元にしています。
コンボボックスは、左側から「標準①」「隠しリスト方式②」「リストボックス上乗せ方式③」となっています。リストを選択した後のテキストボックス部は、標準①は１列のみですが、②③は複数列（今回は２列）が表示されます。

また、左下の「選択クリア④」ボタンは、３つのコンボボックスを未選択状態にするものです。
なおフォームを閉じるためのボタンは設けていませんので、右上×印で閉じて下さい。

なお今回は「ユーザーフォーム上」にコンボボックスを配置しましたが、シート上に配置するコンボボックスでもほぼ同じコードで「複数列を表示」させることが出来ます。

２．システム補助関係

２ー１．ワークシート（Sheet1）

今回は図２のように、データをワークシート上に置き、またユーザーフォームを起動するボタンをシート上に配置しています。

図２別窓

データの範囲は「A1～B4セル」としています。またフォームコントロールで作るボタンには、標準モジュールにある「UFstartプロシージャ」をマクロ登録しています。

２ー２．標準モジュール（Module1）

シート上のボタンから呼び出されるのが、図３の「UFstartプロシージャ」です。

0. '==========　⇩(1)　ユーザーフォームの起動　============
1. Sub UFstart()
2. 　UserForm1.Show
3. End Sub

図３別窓

０２行目「UserForm1.Show」で、フォームを起動しています。パラメータ無しなので「モーダル」で起動されますが、「モードレス」でも問題ありません。

２ー３．ユーザーフォーム（UserForm1）

２ー３ー１．フォームレイアウト

図３の０２行目から起動されるのが、UserForm1です。そのフォーム上のレイアウトは図４のようにしました。

図４別窓

フォーム上には、コンボボックスを３つ並べます。
また「リストボックス上乗せ方式」で使用するリストボックスを「適当な場所」「適当なサイズ」で配置します。適当でもOKなのは、マクロ側から「コンボボックスに丁度重なるように位置・サイズを調整」している為です。

最後に「コンボボックスを未選択状態」にする為のボタンを左下に配置します。またコンボボックスの上側には、方式を表すLabelを配置します。ボタンとLabelの文字列は、コントロール配置時にCaptionプロパティを手動で変更しています。

２ー３ー２．フォームモジュール（メイン）

ユーザーフォームの起動時・表示時に呼び出されるのが図５の「Initializeイベント」→「Activateイベント」です。

10. '==========　⇩(2)　フォーム起動時設定　============
11. Private Sub UserForm_Initialize()
12. 　Call CB1_Ini
13. 　Call CB2_Ini
14. 　Call CB3_Ini
15. End Sub
17. '==========　⇩(3)　フォーム表示時設定　============
18. Private Sub UserForm_Activate()
19. 　Call CB1_Act
20. 　Call CB2_Act
21. 　Call CB3_Act
22. End Sub

図５別窓

本来は「Initializeイベント」及び「Activateイベント」の中で「コンボボックス等の設定」を行います。しかし今回は「３つのコンボボックスを比較」するのが目的ですので、Initialize内・Activate内では各々のコンボボックスの設定（CB〇〇_Iniプロシージャ、CB〇〇_Actプロシージャ）を呼び出して実行させています。
CB〇〇_Iniプロシージャ、CB〇〇_Actプロシージャについては、各方式の中で説明します。

「選択クリア」ボタンをクリックした時に呼び出されるのが図６です。

30. '==========　⇩(4)　「選択クリア」ボタンの動作　============
31. Private Sub CommandButton1_Click()
32. 　Me.ComboBox1.ListIndex = -1
33. 　Me.ComboBox2.ListIndex = -1
34. 　Me.ComboBox3.ListIndex = -1
35. End Sub

図６別窓

３２行目「Me.ComboBox1.ListIndex = -1」は、「標準」のコンボボックスを未選択状態にしています。
同様に３３行目は「隠しリスト方式」を、３４行目は「リストボックス上乗せ方式」を未選択状態にしています。

３．「標準」コンボボックス

３ー１．設定（フォームモジュール）

図５のInitializeイベント内の１２行目から呼び出されるのが図７です。

40. '==========　⇩(5)　フォーム起動時処理　============
41. Private Sub CB1_Ini()
42. 　Me.ComboBox1.ColumnCount = 2
43. 　Me.ComboBox1.ColumnWidths = "50;50"
44. 　Me.ComboBox1.TextColumn = 1
45. End Sub

図７別窓

今回は２列のデータをリストにしますので、４２行目「Me.ComboBox1.ColumnCount = 2」で、コンボボックスのリストを２列仕様にします。
４３行目「Me.ComboBox1.ColumnWidths = "50;50"」では、各列の幅（ポイント数）を設定しています。フォーム上に配置したコンボボックスの幅（Width値）が120ポイントでしたので、「横スクロールバーを出さないリスト」に従って列幅を決めています。

４４行目「Me.ComboBox1.TextColumn = 1」は、コンボボックスのテキストボックス部に表示する値の「列番号」を「第１列目」に指定しています。つまりワークシートのA列のデータが表示される事になります。
なお既定値は「１」ですので、省略してもOKです。

図５のActivateイベント内の１９行目から呼び出されるのが図８です。

50. '==========　⇩(6)　フォーム表示時処理　============
51. Private Sub CB1_Act()
52. 　Dim Rng As Variant 　 '←セル範囲のデータを入れる配列
54. 　Rng = Sheets("sheet1").Range("A1:B4").Value
55. 　Me.ComboBox1.List = Rng
56. End Sub

図８別窓

５４行目「Rng = Sheets("sheet1").Range("A1:B4").Value」では、ワークシートのA1～B4のセル範囲の値を取得し、配列の形で変数Rngに代入しています。
５５行目「Me.ComboBox1.List = Rng」では、その配列の値をコンボボックスのリストにしています。

リスト化する別な方法として、図９のように「リストを１行作ったらデータを入れる」方式でもOKです。

60. '==========　⇩(7)　フォーム表示時処理２　============
61. Private Sub CB1_Act2()
62. 　Dim Rng As Variant 　 '←セル範囲のデータを入れる配列
63. 　Dim i As Long 　 '←リストの行数
65. 　Rng = Sheets("sheet1").Range("A1:B4").Value
67. 　For i = 1 To UBound(Rng, 1)
68. 　　Me.ComboBox1.AddItem ""
69. 　　Me.ComboBox1.List(i - 1, 0) = Rng(i, 1)
70. 　　Me.ComboBox1.List(i - 1, 1) = Rng(i, 2)
71. 　Next i
72. End Sub

図９別窓

６５行目は、図８の５４行目と同じです。
６７行目「For i = 1 To UBound(Rng, 1)」で、カウンタ変数ｉをデータの行数分だけ回します。
６８行目「Me.ComboBox1.AddItem ""」で、新たな空のリスト行を作成します。
６９行目「Me.ComboBox1.List(i - 1, 0) = Rng(i, 1)」で、新たに作成したリスト行の１列目（ゼロ始まりのため、ゼロ列）に、配列の１列目（配列データはセル範囲から取得している為、１始まり）のデータを書き込みます。
７０行目「Me.ComboBox1.List(i - 1, 1) = Rng(i, 2)」も同様に、リストの２列目を作成しています。

また、コンボボックスの「RowSource」プロパティを使用した図１０のような方法も考えられます。

80. '==========　⇩(8)　フォーム表示時処理３　============
81. Private Sub CB1_Act3()
82. 　Me.ComboBox1.RowSource = Sheets("sheet1").Range("A1:B4").Address(External:=True)
83. End Sub

図１０別窓

８２行目「Me.ComboBox1.RowSource = Sheets("sheet1").Range("A1:B4").Address(External:=True)」は、RowSourceプロパティに、データ元である「ワークシートのセル範囲」を設定しています。セル範囲はString型で指定しなければならないため、Addressプロパティで文字列にしています。
なお、シート名を指定するために「External:=True」とパラメータ指定をしていますが、アクティブなシートのセル範囲であればExternalパラメータは指定しなくてもOKです。

３ー２．動作結果

標準状態のコンボボックスでリスト選択した場合には、図１１のようにテキストボックス部には「１つの列のデータのみ」が表示されることになります。

図１１別窓

なおテキストボックス部の文字列が「青反転」している事からも分かるように、標準状態ではテキストボックス部に入力した値で「リスト検索」が可能です。但し検索する範囲は「TextColumnプロパティ」で設定した列（既定では１列目）のみになります。

４．「隠しリスト方式」コンボボックス

「隠しリスト方式」は、以下の様に設定します。
　・リストの列数は、データの列数よりも＋１多くする。
　・その列は、列幅をゼロにする（＝隠し列にする）。
　・隠し列には、本来のデータ列の値を「文字列として連結したもの」を入れる。
　・テキストボックス部に表示する列（TextColumn値）は、隠し列を指定する。
絵で表すと、図１２のようになります。

図１２別窓

４ー１．設定（フォームモジュール）

図５のInitializeイベント内の１３行目から呼び出されるのが図１３です。

90. '==========　⇩(9)　フォーム起動時処理　============
91. Private Sub CB2_Ini()
92. 　Me.ComboBox2.ColumnCount = 3
93. 　Me.ComboBox2.ColumnWidths = "50;50;0"
94. 　Me.ComboBox2.TextColumn = 3
95. End Sub

図１３別窓

９２行目「Me.ComboBox2.ColumnCount = 3」ではリスト列数を、データの列数より１つ多い「３列」に設定します。
９３行目「Me.ComboBox2.ColumnWidths = "50;50;0"」では、３列目の列幅をゼロにします。
９４行目「Me.ComboBox2.TextColumn = 3」では、テキストボックス部に表示する列を「３列目」に設定します。

図５のActivateイベント内の２０行目から呼び出されるのが図１４です。

100. '==========　⇩(10)　フォーム表示時処理　============
101. Private Sub CB2_Act()
102. 　Dim Rng As Variant 　 '←セル範囲のデータを入れる配列
103. 　Dim i As Long 　 '←リストの行数
105. 　Rng = Sheets("sheet1").Range("A1:B4").Value
106. 　ReDim Preserve Rng(1 To UBound(Rng, 1), 1 To UBound(Rng, 2) + 1)
108. 　For i = 1 To UBound(Rng, 1)
109. 　　Rng(i, UBound(Rng, 2)) = Rng(i, 1) & Space(14) & Rng(i, 2)
110. 　Next i
112. 　Me.ComboBox2.List = Rng
113. End Sub

図１４別窓

１０５行目「Rng = Sheets("sheet1").Range("A1:B4").Value」では、ワークシートのA1～B4のセル範囲の値を配列の形で取得します。
１０６行目「ReDim Preserve Rng(1 To UBound(Rng, 1), 1 To UBound(Rng, 2) + 1)」では、１０５行目で取得した配列Rng（今回は ４行×２列）を「列方向に１つ増やした配列（４行×３列）」に拡張しています。なお元のデータは消えないように「Preserveキーワード」を付けてReDimをしています。つまり「３列目が空の配列」を作ったことになります。

１０８～１１０行目では、配列の３列目のデータを作っています。
１０８行目「For i = 1 To UBound(Rng, 1)」では、カウンタ変数ｉをデータの行数分（UBound(Rng, 1)）回します。
１０９行目「Rng(i, UBound(Rng, 2)) = Rng(i, 1) & Space(14) & Rng(i, 2)」では、「１列目のデータ」＋「２列目のデータ」を連結し、その結果を配列の最終列（ここでは３列目）に書き込みます。

なお、「１列目のデータ」＋「２列目のデータ」をそのままつなげると、例えば１行目は「1」＋「A」なので「1A」となり「２列分の文字列」とは見えないので、間に「スペース」を適当に入れます。
今回はリストの列幅が50ポイントなので「スペースを13個」入れていますが、これは計算できるものでは無いのでTry & Errorで入れる数を調整しました。
尚このスペースを入れる方法だと、１列目の文字数やFont種類・Fontサイズなどで、入れる数量を調整する必要が出てきてしまいます。他には「TAB印」で区切る方法（右辺＝Rng(i, 1) & vbTab & Rng(i, 2)）もありますので、扱うデータにより試してみて下さい。

配列の最終列に連結データを入れたら、１１２行目「Me.ComboBox2.List = Rng」でコンボボックスのリストにします。

４ー２．動作結果

「隠しリスト方式」のコンボボックスでリスト選択した場合は、図１５のようになります。

図１５別窓

あたかもテキストボックス部には２列分のデータが並んでいるように見えますが、データは１つのみで「２列の値が結合された形」で表示されています。
１列目と２列目の文字列の間を一応スペースで空けて「リスト部と同じ間隔でデータが並んでいる」ように見せてはいますが、完全に揃えるのは難しいと思います。

またテキストボックス部ではリストの検索が可能ですが、その対象範囲は「TextColumnプロパティ」で設定した列（今回は隠し列）です。また検索は基本的に「前方一致」ですので、今回の場合「検索は１列目に対して実施」されることになります。

５．「リストボックス上乗せ方式」コンボボックス

「リストボックス上乗せ方式」は、図１６のように「コンボボックスのテキストボックス部に重ねるようにリストボックスを配置」する方法です。

図１６別窓

図１６で分かるように、コンボボックス自体は標準のものです。コンボボックスのリストを選択すると、そのデータは「リストボックス」に転送されるようにしています。リストボックスは「テキストボックス部に重ねるように乗せている」ため、コンボボックスのテキストボックス部が「複数列表示」になったように見える　という訳です。

５ー１．設定（フォームモジュール）

図５のInitializeイベント内の１４行目から呼び出されるのが図１７です。

120. '==========　⇩(11)　フォーム起動時処理　============
121. Private Sub CB3_Ini()
122. 　Me.ComboBox3.ColumnCount = 2
123. 　Me.ComboBox3.ColumnWidths = "50;50"
124. 　Me.ComboBox3.Style = fmStyleDropDownList
126. 　Me.ListBox1.ColumnCount = 2
127. 　Me.ListBox1.ColumnWidths = "50;35"
129. 　Me.ListBox1.Left = Me.ComboBox3.Left
130. 　Me.ListBox1.Top = Me.ComboBox3.Top
131. 　Me.ListBox1.Height = Me.ComboBox3.Height
132. 　Me.ListBox1.Width = Me.ComboBox3.Width - Me.ListBox1.Height
133. 　DoEvents: DoEvents
135. 　Me.ListBox1.Enabled = False
136. End Sub

図１７別窓

１２２行目「Me.ComboBox3.ColumnCount = 2」では、コンボボックスのリストを２列仕様にします。
１２３行目「Me.ComboBox3.ColumnWidths = "50;50"」では、各列の幅（ポイント数）を設定しています。
１２４行目「Me.ComboBox3.Style = fmStyleDropDownList」では、コンボボックスのテキストボックス部を「入力不可」の状態にしています。
Styleプロパティには図１８のような２種類の設定が可能です。

定数	値	内容
fmStyleDropDownCombo	0（既定値）	ﾃｷｽﾄﾎﾞｯｸｽ部入力可＋ﾘｽﾄ選択可
fmStyleDropDownList	2	ﾃｷｽﾄﾎﾞｯｸｽ部入力不可＋ﾘｽﾄ選択可 ﾃｷｽﾄﾎﾞｯｸｽ部をｸﾘｯｸするとﾘｽﾄが開く

図１８別窓

今回はコンボボックスの上にリストボックスを乗せているので、コンボボックスのテキストボックス部は「編集出来ない」状態です。また、リストボックスはもともと「編集不可」です。
通常のコンボボックスのテキストボックス部をクリックすると、Styleプロパティの設定により「編集可」または「編集不可→リストがドロップダウン」のどちらかの状態になるはずですが、既定値（＝fmStyleDropDownCombo）のままだと、テキストボックス部（＝リストボックス）をクリックしても「何も起こらない」状態になってしまいます。
ですので、今回のStyle設定（テキストボックス部の入力不可）にして、リストボックス部をクリックすると、リストがドロップダウンするようにしています。

１２６行目「Me.ListBox1.ColumnCount = 2」は、上に乗せるリストボックスを２列仕様にしています。
１２７行目「Me.ListBox1.ColumnWidths = "50;35"」は２列の列幅を設定しています。コンボボックス側（１２３行目）は「50ポイント、50ポイント」ですが、リストボックスは「50ポイント、35ポイント」と２列目を少し狭くしているのは、コンボボックス右端の下矢印ボタンの幅を引き算し、「リストボックスに横スクロールバーが出ない」ようにしているためです。

１２９～１３３行目で、コンボボックスの上にリストボックスの乗せています。
１２９行目「Me.ListBox1.Left = Me.ComboBox3.Left」で、リストボックスの左右位置をコンボボックスに合わせています。
１３０行目「Me.ListBox1.Top = Me.ComboBox3.Top」で、上下位置をコンボボックスに合わせています。
１３１行目「Me.ListBox1.Height = Me.ComboBox3.Height」で、高さをコンボボックスに合わせています。

１３２行目「Me.ListBox1.Width = Me.ComboBox3.Width - Me.ListBox1.Height」では、幅を合わせています。
但し、幅をコンボボックスと完全に同じサイズにしてしまうと「コンボボックスのドロップボタン」も隠れてしまうため、図１９のように「ボタンの高さ（≒幅）」の分だけ引き算をしています。

図１９別窓

コントロールを重ねる場合、通常はフォーム上で「後から作成したコントロールが上に乗る」ことになります。今回はコンボボックスの上にリストボックスを乗せるので、リストボックスを後から作る必要がありそうですが、試してみるとコンボボックスを後から作っても「リストボックスが上に乗る」ことになります。 他のコントロールも含めて検証してみると、なぜか「ListBoxだけは、どのコントロールよりも上に来る」ことが分かりました。 （標準でツールボックスに表示される中での確認結果です。なおFrameコントロールだけは別で、ListBoxの上になりました） ListBox以外のコントロールは、後から作ったものが上に乗るので、どうもListBoxだけが特殊のようです。もしListBoxでは無く他のコントロールを上に乗せる場合は、フォーム上で後から作成する必要があります。

１３３行目「DoEvents: DoEvents」は、「リストボックスのサイズ変更（特に高さと幅）をフォームに反映」させる為に入れています。コード的には、この様な配慮は不要なはずなのですが、なぜか高さと幅が反映されません（Left方向とTop方向はDoEventsが無くても揃えてくれます）。
なおDoEventsの代わりに「Me.Repaint」を実行させてもダメでした。原因は良く分かりませんが、Excelのバージョン等によっては無くてもOKかもしれません。

１３５行目「Me.ListBox1.Enabled = False」は、リストボックスを操作不可にしています。この処理が無いと、コンボボックスの項目選択後にリストボックスのリストが選択（項目が青反転する）できてしまい、「コンボボックスの動作とは明らかに違う」感じになってしまいます。またこの処理により、リストボックスをクリックすると（リストボックスが無視されて）コンボボックスのテキスト部をクリックした事になり、ドロップダウンリストが開き「コンボボックスらしい動き」となります。

図５のActivateイベント内の２１行目から呼び出されるのが図２０です。内容は標準のActivateイベント時（図８）と同じです。

140. '==========　⇩(12)　フォーム表示時処理　============
141. Private Sub CB3_Act()
142. 　Dim Rng As Variant 　 '←セル範囲のデータを入れる配列
144. 　Rng = Sheets("sheet1").Range("A1:B4").Value
145. 　Me.ComboBox3.List = Rng
146. End Sub

図２０別窓

１４４行目「Rng = Sheets("sheet1").Range("A1:B4").Value」では、ワークシートのA1～B4のセル範囲の値を取得し、配列の形で変数Rngに代入しています。
１４５行目「Me.ComboBox3.List = Rng」では、その配列の値をコンボボックスのリストにしています。

コンボボックスのリストを選択した時に呼び出されるイベントプロシージャが図２１です。また「選択クリア」ボタンをクリック（図６）した時、コンボボックスが選択状態だった場合にも呼び出されます。
内容的には、コンボボックスのリストの選択されたデータをリストボックスに書き込んでいます。

150. '==========　⇩(13)　リストボックスへのデータ書き込み　============
151. Private Sub ComboBox3_Change()
152. 　Me.ListBox1.Clear
154. 　If Me.ComboBox3.ListIndex = -1 Then Exit Sub
156. 　Me.ListBox1.AddItem ""
157. 　Me.ListBox1.List(0, 0) = Me.ComboBox3.List(Me.ComboBox3.ListIndex, 0)
158. 　Me.ListBox1.List(0, 1) = Me.ComboBox3.List(Me.ComboBox3.ListIndex, 1)
159. End Sub

図２１別窓

１５２行目「Me.ListBox1.Clear」では、リストボックスを空にしています。
１５４行目「If Me.ComboBox3.ListIndex = -1 Then Exit Sub」は、「選択クリア」ボタンをクリック（ListIndex = -1 を指示）された時は、ここで処理を終了します。リストボックスは空の状態で表示されます。

コンボボックスのリストを選択した際には、１５６～１５８行目を実行します。
１５６行目「Me.ListBox1.AddItem ""」では、リストボックスに新しいリスト行を追加します。
１５７行目「Me.ListBox1.List(0, 0) = Me.ComboBox3.List(Me.ComboBox3.ListIndex, 0)」では、選択した項目の１列目のデータをリストボックスの１列目に書き込み、１５８行目「Me.ListBox1.List(0, 1) = Me.ComboBox3.List(Me.ComboBox3.ListIndex, 1)」で、２列目のデータをリストボックスの２列目に書き込みます。

これにより、コンボボックスの選択されたリスト（青反転されている行）のデータが、コンボボックスのテキストボックス部の上に乗っているリストボックスで表示されることになります。

５ー２．動作結果

「リストボックス上乗せ方式」のコンボボックスでリスト選択した場合は、図２２のようになります。

図２２別窓

リストを選択した場合は、テキストボックス部の上に重ねているリストボックスに「２つの列のデータ」が表示されます。
また、その重ねているリストボックスを（コンボボックスのテキストボックス部と思って）クリックすると、EnabledプロパティをFalseにしている為に、その下のコンボボックスのテキストボックス部が反応します。コンボボックスは、テキストボックス部への入力を不可状態にしていますので、リストがドロップダウンする　という動作になります。
デメリットとしては、テキストボックス部でのリスト検索は出来ないことになります。

なお、リストボックスの幅を無理矢理コンボボックスに合わせていますので、リストボックスの右端がちょっとだけ見えてしまいます。しかし「コンボボックスのリスト」と「リストボックスのリスト」の各列幅を合わせることで、列揃えはピッタリと合っているように見えるのが、「隠しリスト方式」との違いです。

アプリ実例

「共有資料の登録と閲覧ができるサーバーシステム」

サンプルファイル

コンボボックスのテキストボックス部に複数列を表示（its-026.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。