2023/03/05

PCの固有情報の取得

• １．概要
• ２．システム補助
• 　２ー１．ワークシート
• 　２ー２．標準モジュール
• 　　２ー２ー１．API関数宣言など
• 　　２ー２ー２．情報取得と表示
• ３．IPアドレス
• 　３ー１．WMI法
• 　３ー２．WshShellのipconfig法
• 　　よりみち（事前バインディングでのデータ型指定）
• ４．MACアドレス
• 　４ー１．WMI法
• 　４ー２．WshShellのgetmac法
• ５．ユーザー名
• 　５ー１．WshNetworkオブジェクト法
• 　５ー２．WshShellのEcho環境変数法
• 　５ー３．WshShellのset環境変数法
• 　５ー４．Environ環境変数法
• 　５ー５．APIのGetUserName関数法
• 　５ー６．ExcelのUserNameプロパティ法
• ６．コンピューター名
• 　６ー１．WshNetworkオブジェクト法
• 　６ー２．WshShellのipconfig法
• 　６ー３．Environ環境変数法
• ７．ドメイン名
• 　７ー１．WshNetworkオブジェクト法
• 　７ー２．Environ環境変数法
• ８．CPU名
• 　８ー１．Environ環境変数法
• 　　よりみち（CPUビット数の取得）
• ９．Excelバージョン
• 　９ー１．Versionプロパティ法
• １０．O/Sバージョン
• 　１０ー１．OperatingSystemプロパティ法
• 　１０ー２．WMI法
• 　１０ー３．APIのGetVersionEx関数法
• １１．O/Sプロダクト番号
• 　１１ー１．WMI法
• １２．ハードディスク シリアル番号
• 　１２ー１．WMI法
• １３．まとめ
• アプリ実例
• サンプルファイル

アプリを操作しているユーザーやPCを特定するために、固有情報を取得する場面は多くあります。分かり易い例としては、ブラウザにURLを記入すればインターネット上のサイトが表示されますが、これは、要求する側の「PCのIPアドレス」をリクエストと一緒に送信しているためです。
Excelで作ったアプリでも似たような場面があります。例えばExcelで日報を作ってサーバーに保存するシステムの場合、日報作成者の名前をファイル名に添付しておかないと受け取った人は困ってしまいます。と言って、他人の名前で作成・保存できてしまっても困ります。
そのため「ユーザーやPCの固有情報」をVBAで取得し、ファイル名に付けたりする手法を用いる場合があります。もちろん完璧ではありませんが、ユーザーの面倒な作業を減らす事にはなっていると思います。

Excelでは、上記のIPアドレスやユーザー名だけでは無く、他にも色々な固有情報を取得できます。今回は、以下の１０種類の情報の取得方法を紹介します。

固有情報 １ IPアドレス ２ MACアドレス ３ ユーザー名 ４ コンピューター名 ５ ドメイン名

固有情報 ６ CPU名 ７ Excelバージョン ８ O/Sバージョン ９ O/SプロダクトID １０ HDシリアル番号

図０１別窓

１．概要

「サンプルファイル」では図０２のように、ボタンをクリックする事で各固有情報をメッセージボックスで表示するようにしました。手法も含めて項目が多いので、４つに分けてあります。

図０２別窓

２．システム補助

２ー１．ワークシート（Sheet1）

ワークシート上には、情報取得し結果を表示するためのボタン（フォームコントロール）を４つ配置しています。
各ボタンには、図０６の起動プロシージャ（Info1～Info4）をマクロ登録しています。

図０３別窓

２ー２．標準モジュール（Module1）

２ー２ー１．API関数宣言など

標準モジュール先頭（宣言部）では、ユーザー名を取得（図２７）する際に使用するWindows APIの「GetUserName関数」の宣言、及びO/Sのバージョンを取得（図４４）する際に使用する「GetVersionEx関数」の宣言をしています。

0. '==========　⇩(1)　API関数宣言　============
1. #If Win64 Then
2. 　Private Declare PtrSafe Function GetUserName Lib "advapi32.dll" _
3. 　　Alias "GetUserNameA" (ByVal lpBuffer As String, nSize As LongPtr) As LongPtr
4. 　Private Declare PtrSafe Function GetVersionEx Lib "kernel32" _
5. 　　Alias "GetVersionExA" (lpVersionInformation As OSVERSIONINFO) As LongPtr
6. #Else
7. 　Private Declare Function GetUserName Lib "advapi32.dll" _
8. 　　Alias "GetUserNameA" (ByVal lpBuffer As String, nSize As Long) As Long
9. 　Private Declare Function GetVersionEx Lib "kernel32" _
10. 　　Alias "GetVersionExA" (lpVersionInformation As OSVERSIONINFO) As Long
11. #End If

図０４別窓

Excelが32ビット版か64ビット版かで、宣言文が異なります。０１行目「#If Win64 Then」で分岐させ、64ビット版であれば０２～０５行目を実行し、32ビット版であれば０７～１０行目を実行します。
64ビット版と32ビット版の違いは、64ビット版ではFunctionの前に「PtrSafe」を付け加える事と、データ型がLong型の場合は「LongPtr」型になることです。

関数の内容を64ビット版を例に説明します。
０２～０３行目「Private Declare PtrSafe Function GetUserName Lib "advapi32.dll" Alias "GetUserNameA" (ByVal lpBuffer As String, nSize As LongPtr) As LongPtr」では、GetUserName関数を宣言します。得られるユーザー名は、引数lpBufferとして得られます。

０４～０５行目「Private Declare PtrSafe Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (lpVersionInformation As OSVERSIONINFO) As LongPtr」では、GetVersionEx関数を宣言します。得られるO/Sのバージョン情報は、図０５で構造体宣言を行っている「OSVERSIONINFO」型で渡されます。

図０５では、GetVersionEx関数で使用するOSVERSIONINFO構造体の宣言をしています。
構造体の説明等は「APIのGetVersionEx関数法」で行います。

20. '==========　⇩(2)　構造体宣言　============
21. Private Type OSVERSIONINFO
22. 　dwOSVersionInfoSize As Long 　　 '構造体のバイト数
23. 　dwMajorVersion As Long 　　 'メジャー番号
24. 　dwMinorVersion As Long 　　 'マイナー番号
25. 　dwBuildNumber As Long 　　 'ビルド番号
26. 　dwPlatformId As Long 　　 'プラットフォームのID
27. 　szCSDVersion As String * 128 　　 'OSに関する付加情報
28. End Type

図０５別窓

２ー２ー２．情報取得と表示

シート上のボタンから呼び出されるのが、図０６の４つのプロシージャです。４分割したのは説明の都合上の為だけです。

40. '==========　⇩(3)　データ取得と表示１　============
41. Public Sub Info1()
42. 　Dim s As String 　　 '←MsgBoxへの表示文字列
44. 　s = "IP-1= " & IPaddress1
45. 　s = s & vbNewLine & "IP-2= " & IPaddress2
46. 　s = s & vbNewLine & "MAC-1= " & MACaddress1
47. 　s = s & vbNewLine & "MAC-2= " & MACaddress2
48. 　MsgBox s
49. End Sub
51. '==========　⇩(4)　データ取得と表示２　============
52. Public Sub Info2()
53. 　Dim s As String 　　 '←MsgBoxへの表示文字列
55. 　s = "USER-1= " & USERname1
56. 　s = s & vbNewLine & "USER-2= " & USERname2
57. 　s = s & vbNewLine & "USER-3= " & USERname3
58. 　s = s & vbNewLine & "USER-4= " & USERname4
59. 　s = s & vbNewLine & "USER-5= " & USERname5
60. 　s = s & vbNewLine & "USER-6= " & USERname6
61. 　MsgBox s
62. End Sub
64. '==========　⇩(5)　データ取得と表示３　============
65. Public Sub Info3()
66. 　Dim s As String 　　 '←MsgBoxへの表示文字列
68. 　s = "PC-1= " & PCname1
69. 　s = s & vbNewLine & "PC-2= " & PCname2
70. 　s = s & vbNewLine & "PC-3= " & PCname3
71. 　s = s & vbNewLine & "Domain1= " & DOMAINname1
72. 　s = s & vbNewLine & "Domain2= " & DOMAINname2
73. 　MsgBox s
74. End Sub
75. '==========　⇩(6)　データ取得と表示４　============
76. Public Sub Info4()
77. 　Dim s As String 　　 '←MsgBoxへの表示文字列
79. 　s = "CPU name1= " & CPUname1
80. 　s = s & vbNewLine & "Excel ver= " & EXCELver1
81. 　s = s & vbNewLine & "O/S ver1= " & OSver1
82. 　s = s & vbNewLine & "O/S ver2= " & OSver2
83. 　s = s & vbNewLine & "O/S ver3= " & OSver3
84. 　s = s & vbNewLine & "O/S product= " & OSprod1
85. 　s = s & vbNewLine & "HD= " & HDserial1
86. 　MsgBox s
87. End Sub

図０６別窓

今回、固有情報を得る部分は関数プロシージャの形にしています。図０６内では、その関数プロシージャを呼び出して情報を取得し、MsgBoxで表示させています。

ボタン１をクリックした際には、４４～４７行目で「IPアドレス（２種）」「MACアドレス（２種）」を取得後に連結し、４８行目「MsgBox s」でメッセージとして表示します。
ボタン２をクリックした際には、５５～６０行目で「ユーザー名（６種）」を取得後に連結し、６１行目「MsgBox s」でメッセージとして表示します。

ボタン３をクリックした際には、６８～７２行目で「コンピューター名（３種）」「ドメイン名（２種）」を取得後に連結し、７３行目「MsgBox s」でメッセージとして表示します。
ボタン４をクリックした際には、７９～８５行目で「CPU名（１種）」「Excelのバージョン番号（１種）」「O/Sのバージョン番号（３種）」「O/Sのプロダクト番号（１種）」「ハードディスクのシリアル番号（１種）」を取得後に連結し、８６行目「MsgBox s」でメッセージとして表示します。

３．IPアドレス

３ー１．WMI法

WMI（Windows Management Instrumentation）でＩＰアドレスを取得するのが図０７です。

90. '==========　⇩(7)　IPアドレス（WMI法）　============
91. Private Function IPaddress1() As String
92. 　Dim ObjSet As Object 　　 'ネットワークアダプタ情報のオブジェクト
93. 　Dim ObjEx As Object 　　　 '各ネットワークアダプタ情報
94. 　Dim strIP As Variant 　　　 'IPアドレス（IPv4、IPv6）
96. 　Set ObjSet = GetObject("winmgmts:¥¥.¥root¥cimv2"). _
97. 　　ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration Where (IPEnabled = TRUE)")
99. 　For Each ObjEx In ObjSet
100. 　　For Each strIP In ObjEx.IPaddress
101. 　　　If UBound(Split(strIP, "."), 1) = 3 Then
102. 　　　　IPaddress1 = strIP
103. 　　　　Exit For
104. 　　　End If
105. 　　Next strIP
106. 　Next ObjEx
108. 　Set ObjSet = Nothing
109. End Function

図０７別窓

９９行目「For Each ObjEx In ObjSet」では、ネットワークアダプタ情報を格納した変数ObjSetの中から、For Each を使って、各ネットワークアダプタ情報（変数ObjEx）を取り出します。「各ネットワークアダプタ」とは「接続されているネットワークアダプタ」ですので、たとえば有線LANと無線LANの両方が接続されている状態の時には、図０８の右側のように２つのネットワークアダプタ情報が得られます。

図０８別窓

得られたネットワークアダプタ（SWbemObjectExオブジェクト）には、図０９のように多くのプロパティがあります。

No.	プロパティ	内容	例
1	ArpAlwaysSourceRoute	ｿｰｽﾙｰﾃｨﾝｸﾞ有のﾌﾟﾛﾄｺﾙで送信	既定=False
2	ArpUseEtherSNAP	SNAPｴﾝｺｰﾄﾞに従う	既定=False
3	Caption	ｵﾌﾞｼﾞｪｸﾄの簡単説明	[00000001] Intel(R) Wi-Fi 6 AX201 160MHz
4	DatabasePath	ｲﾝﾀｰﾈｯﾄDBﾌｧｲﾙのﾊﾟｽ	%SystemRoot%¥System32¥drivers¥etc
5	DeadGWDetectEnabled	配信不能ｹﾞｰﾄｳｪｲを検出	True or False
6	DefaultIPGateway	既定ｹﾞｰﾄｳｪｲのIPｱﾄﾞﾚｽ	(配列)例=192.168.12.1 192.168.46.1
7	DefaultTOS	既定ｻｰﾋﾞｽ種	0(既定)～255
8	DefaultTTL	既定TTL値	1～255 既定=32
9	Description	ｵﾌﾞｼﾞｪｸﾄの説明	Intel(R) Wi-Fi 6 AX201 160MHz
10	DHCPEnabled	DHCP自動割り当て	True
11	DHCPLeaseExpires	IPｱﾄﾞﾚｽの有効期限	20230303100000.000000+540
12	DHCPLeaseObtained	IPｱﾄﾞﾚｽ取得日時	2023030200000.000000+540
13	DHCPServer	DHCPのIPｱﾄﾞﾚｽ	192.168.0.1
14	DNSDomain	DNSﾄﾞﾒｲﾝ	microsoft.com
15	DNSDomainSuffixSearchOrder	DNSﾄﾞﾒｲﾝのｻﾌｨｯｸｽ	(配列) 例=samples.microsoft.com/example.microsoft.com
16	DNSEnabledForWINSResolution	WINS名前解決有効化	False
17	DNSHostName	識別ﾎｽﾄ名	例=corpdns
18	DNSServerSearchOrder	ｸｴﾘで使用するｻｰﾊﾞｰのIPｱﾄﾞﾚｽ	(配列)
19	DomainDNSRegistrationEnabled	IPｱﾄﾞﾚｽをﾄﾞﾒｲﾝに登録する	False
20	ForwardBufferMemory	IPにより割り当てられたﾒﾓﾘ	既定=74240
21	FullDNSRegistrationEnabled	IPｱﾄﾞﾚｽをDNSに登録する	True
22	GatewayCostMetric	整数ｺｽﾄﾒﾄﾘｯｸ値	(配列)1～9999の範囲
23	IGMPLevel	ﾏﾙﾁｷｬｽﾄをｻﾎﾟｰﾄし､IGMPに参加する範囲	0=No Multicast 1=IP Multicast 2(既定)=IP & IGMP Multicast
24	Index	ﾈｯﾄﾜｰｸｱﾀﾞﾌﾟﾀのｲﾝﾃﾞｯｸｽ番号	1
25	InterfaceIndex	ｲﾝﾀｰﾌｪｲｽを識別するｲﾝﾃﾞｯｸｽ値	18
26	IPAddress	関連付けられているIPｱﾄﾞﾚｽ(IPv4,IPv6)	(配列)
27	IPConnectionMetric	ﾙｰﾄの重み付け値	既定=1
28	IPEnabled	ｱﾀﾞﾌﾟﾀの有効化	True
29	IPFilterSecurityEnabled	IPﾎﾟｰﾄｾｷｭﾘﾃｨの有効化	False
30	IPPortSecurityEnabled	IPﾎﾟｰﾄｾｷｭﾘﾃｨの有効化 (今後使用されず)	Null
31	IPSecPermitIPProtocols	IP経由で実行可能なﾌﾟﾛﾄｺﾙ	(配列)
32	IPSecPermitTCPPorts	TCPのｱｸｾｽが許可されるﾎﾟｰﾄ	(配列)
33	IPSecPermitUDPPorts	UDPのｱｸｾｽが許可されるﾎﾟｰﾄ	(配列)
34	IPSubnet	ｻﾌﾞﾈｯﾄﾏｽｸ	(配列)例=255.255.0.0
35	IPUseZeroBroadcast	IPｾﾞﾛﾌﾞﾛｰﾄﾞｷｬｽﾄを使用	既定=False
36	IPXAddress	(IPXｻﾎﾟｰﾄされず)	Null
37	IPXEnabled	(IPXｻﾎﾟｰﾄされず)	Null
38	IPXFrameType	(IPXｻﾎﾟｰﾄされず)	Null
39	IPXMediaType	(IPXｻﾎﾟｰﾄされず)	Null
40	IPXNetworkNumber	(IPXｻﾎﾟｰﾄされず)	Null
41	IPXVirtualNetNumber	(IPXｻﾎﾟｰﾄされず)	Null
42	KeepAliveInterval	KeepAlive再送信を分離する間隔(ms)	既定=1000
43	KeepAliveTime	接続維持を確認する頻度(ms)	既定7,200,000(2時間)
44	MACAddress	MACｱﾄﾞﾚｽ	例= 00:80:C7:8F:6C:96
45	MTU	最大転送単位(byte)	Null
46	NumForwardPackets	IPﾊﾟｹｯﾄﾍｯﾀﾞｰ数	既定値: 50
47	PMTUBHDetectEnabled	ｾｸﾞﾒﾝﾄ再送信の未確認時に送信する	既定=False
48	PMTUDiscoveryEnabled	異なるMTUﾈｯﾄﾜｰｸで断片化を排除	既定=True
49	ServiceName	ｱﾀﾞﾌﾟﾀｰのｻｰﾋﾞｽ名	Elnkii
50	SettingID	ｵﾌﾞｼﾞｪｸﾄの識別子	{00000000-0000-0000-0000-0000000000000}
51	TcpipNetbiosOptions	TCP/IP経由のNetBIOSの設定ﾋﾞｯﾄﾏｯﾌﾟ	0=EnableNetbiosViaDhcp 1=EnableNetbios 2=DisableNetbios
52	TcpMaxConnectRetransmissions	要求再送信回数	既定値=3
53	TcpMaxDataRetransmissions	ﾃﾞｰﾀｾｸﾞﾒﾝﾄ再送信回数	既定値=5
54	TcpNumConnections	同時接続最大数	既定値=0xFFFFFE
55	TcpUseRFC1122UrgentPointer	緊急ﾃﾞｰﾀにRFC1122仕様を使用	Null
56	TcpWindowSize	TCP受信ｳｨﾝﾄﾞｳの最大ｻｲｽﾞ	ｲｰｻﾈｯﾄの既定値8760
57	WINSEnableLMHostsLookup	ﾛｰｶﾙ参照ﾌｧｲﾙを使用する	True
58	WINSHostLookupFile	WINS参照ﾌｧｲﾙへのﾊﾟｽ	Null
59	WINSPrimaryServer	ﾌﾟﾗｲﾏﾘWINSｻｰﾊﾞｰのIPｱﾄﾞﾚｽ	Null
60	WINSScopeID	NetBIOS名の末尾の値	(なし)
61	WINSSecondaryServer	ｾｶﾝﾀﾞﾘWINSｻｰﾊﾞｰのIPｱﾄﾞﾚｽ	Null

図０９別窓

なお図０９についての詳細は、Microsoftのサイト「Win32_NetworkAdapterConfigurationクラス」を参照下さい。
またPCの環境によっては、存在しないプロパティもあると思われますので御注意願います。

IPアドレスにはIPv4とIPv6の２種類があり、現状ではIPv4で管理しているところも多いと思います。しかし、IPv6も表示されるようなPC設定になっていれば、図１０のように「IPv4アドレス」と「IPv6アドレス」が「IPAddressプロパティ（図０９のNo.26）」内に入っている事になります。

図１０別窓

なお、図１１のように「IPv6を不使用」に設定にしているPCの場合は、IPv4のみの配列となります。

図１１別窓

この「IPAddressプロパティ値（配列）」を、１００行目「For Each strIP In ObjEx.IPaddress」で、１つ１つ取り出して変数strIPにセットします。
１０１行目「If UBound(Split(strIP, "."), 1) = 3 Then」ではセットされた変数strIPが「IPv4かIPv6か」を調べています。
まず、IPv4・IPv6の表記の違いは以下の通りです。

種類	データ数	表記	分岐コード(例)
IPv4	32ビット	XXX.XXX.XXX.XXX （XXXは0～255の10進数の数値）	UBound(Split(strIP, "."), 1) = 3
IPv6	128ビット	XXXX:XXXX:XXXX:XXXX:XXXX:XXXX:XXXX:XXXX （Xは0～Fの16進数の数値）	InStr(strIP,":")>0

図１２別窓

今回１０１行目で使用した「UBound(Split(strIP, "."), 1) = 3」は、IPv4表記の中に「.（ピリオド）」が３つ存在することを利用したIF文になっています。
もしIPv6を拾うのであれば、１０１行目のIF文をNotで否定文にするか、またはIPv6にのみ「：（コロン）」が有ることから「InStr(strIP,":")>0」等とすれば良い事になります。

しかし「IPv4アドレス」「IPv6アドレス」のどちらを取得するにしても、図０８に示したように「複数のアダプタが接続状態」の時には、思った通りの値が取得できない可能性はあります。
と言うのは、アダプタの順番は（私のPCの場合は）有線LANの方が先に来るようですが、For～Eachを使っているため「最初に取得するアダプタが有線LAN」である保証は無いからです。
ちなみに今回のコードでは、最終的に「最後のアダプタのIPアドレス」が戻されることになりますが、もし「最初のアダプタのIPアドレス」を戻したければ、１０３行目「Exit For」を「Exit Function」に変更すれば良いことになります。

１０２行目「IPaddress1 = strIP」では、１０１行目で選んだIPアドレスを関数プロシージャの戻り値にしています。

３ー２．WshShellのipconfig法

「コマンドプロンプト（Dos窓）にコマンド入力する事で表示される情報」を使う方法が、図１３です。ここでは「ipconfig」コマンドによりIPアドレスを取得します。

120. '==========　⇩(8)　IPアドレス（WshShellのipconfig法）　============
121. Private Function IPaddress2() As String
122. 　Dim wsh As Object 　　　　 'WSH(Windows Script Host)shellオブジェクト
123. 　Dim cmd As String 　　　　 '実行コマンド
124. 　Dim result As Object 　　　 'コマンド実行結果（事前バインディングだとWshExec型）
125. 　Dim rowArray As Variant 　　 '実行結果を各行ごとに配列にしたもの
126. 　Dim i As Long 　　　　　　　 'カウンタ変数（実行結果の行位置）
127. 　Dim Pos As Long 　　 '行の中でのIPアドレスの文字位置
129. 　Set wsh = CreateObject("WScript.Shell")
130. 　cmd = "ipconfig"
132. 　Set result = wsh.exec("%ComSpec% /c " & cmd)
134. 　Do While result.Status = 0
135. 　　DoEvents: DoEvents
136. 　Loop
138. 　rowArray = Split(result.StdOut.ReadAll, vbCrLf)
140. 　For i = 0 To UBound(rowArray, 1)
141. 　　If InStr(rowArray(i), "IPv4") > 0 Then Exit For
142. 　Next i
143. 　Pos = InStr(rowArray(i), ":")
145. 　IPaddress2 = Mid(rowArray(i), Pos + 2)
147. 　Set result = Nothing
148. 　Set wsh = Nothing
149. End Function

図１３別窓

１２９行目「Set wsh = CreateObject("WScript.Shell")」は、WSH(Windows Script Host)のWshShellクラスのインスタンスを生成し、変数wshに代入しています。
１３０行目「cmd = "ipconfig"」は実行するコマンドで、今回は「ipconfig」を使用します。手動でコマンドプロンプト上で「ipconfig」を実行すると、図１４のような結果が出力されます。
図１４の左側がネットワークアダプタが１つの場合、右側が２つ（この場合は、有線LANと無線LAN）の場合です。
（なお図１４は、必要行のみを抜き出して表示し、IPv6の値は架空のものに修正してあります。）

図１４別窓

１３２行目「Set result = wsh.exec("%ComSpec% /c " & cmd)」では、１３０行目で設定したipconfigコマンドを実行し、その結果を変数resultに代入します。
実行にはWSHのExecメソッドを使用し、その引数（カッコ内）に「"%ComSpec% /c " & cmd」を指定しています。これは図１５のように３つの内容を示しています。

図１５別窓

先頭の「%ComSpec%」の、「%」で囲まれた「ComSpec」は、環境変数の１つです。
環境変数とは「Windows等のO/Sが提供するデータ共有機能」で、特定の値やPC内の場所（フォルダー等）、また特定ファイルのフルパス名などが登録されています。
例えば今回使っている環境変数「ComSpec」には、「cmd.exe というファイルのフルパス」が登録されています。

もちろんcmd.exeファイル のフルパスを「直接指定」することも可能ですが、このcmd.exeファイルが置かれている場所がPCによって異なる可能性もあります。
その場合、そのファイルを使うプログラムを作ろうとした時「PC毎にパスを設定し直す」など、非常に使い難いアプリになってしまう事が考えられます。
しかし環境変数『ComSpec』に各PC毎のcmd.exeファイルの場所を登録しておけば、フルパスを知らなくても「環境変数を実行」しさえすれば、どのPCでも「コマンドプロンプトが起動」出来る事になります。

この環境変数に於いて、登録してある値を呼び出す場合は「環境変数を『%』で囲む」ことになっているため、今回の「%ComSpec%」は「cmd.exeのフルパス」を指定することになります。cmd.exeは「実行ファイル」ですので、「コマンドプロンプトが実行される」ことになります。

２番目の「/c」は、コマンドプロンプト実行ファイル（cmd.exe）のオプションで、「コマンドを実行した後、コマンドプロンプトを終了する」ことを指定しています。
最後の「ipconfig」は「コマンドプロンプト上で実行するコマンド」になります。

ですので「"%ComSpec% /c " & cmd」は、「コマンドプロンプトを開き（実行し）、ipconfigを実行し、実行し終わったらコマンドプロンプトを閉じる」という動作になり、得られた結果（図１４）は変数resultに代入されます。

今回、コマンドの実行結果を受け取る変数resultは、１２４行目でObject型として宣言しました。これはWSHを実行時バインディングしているためです。 もし事前バインディング（VBE→ツール→参照設定で「Windows Script Host Object Model」を参照）をする時には、実行結果を受取る型は「WshExec型」となりますので、変数resultも「WshExec型」して宣言をします。

１３４行目「Do While result.Status = 0」から始まるDo～Loopは、１３２行目の「実行が完了」するのを待っています。
今回の変数resultのStatusプロパティは「プロセスが起動中の間は０を示し、プロセスが終了すると１」になりますので、起動中の間（While result.Status = 0）は次のコードに移行するのを待つことになります。

ただし今回のコマンドプロンプトでの実行は、ウィンドウを使わない「consoleアプリ」なので、Do～Loopを回して待たなくても、１３８行目の「StdOut.Readall」の部分で「完了するのを待ってくれる」ようです。
ですので、１３４～１３６行目のDo～Loopは無くても正常に動作します。

実行した結果は「変数result」に格納されていますが、それを文字列にするには「画面に表示されたものを文字列」にする指示が必要です。１３８行目の「result.StdOut.ReadAll」がそれに相当し、「標準出力（＝画面に表示）を全て読み込む」という意味になります。
得られた文字列は図１４のような複数行の文字列です。そのため１３８行目「rowArray = Split(result.StdOut.ReadAll, vbCrLf)」で、Split関数で「改行（vbCrLf）」で区切った配列にします。
この処理の結果、配列rowArrayの各要素内に１行ずつの文字列が入っていることになります。

１４０～１４２行目のFor～Nextでは、配列rowArrayから１要素ずつ取り出します。
１４０行目「For i = 0 To UBound(rowArray, 1)」で、カウンタ変数ｉを配列の行数分だけ回し、１４１行目「If InStr(rowArray(i), "IPv4") > 0 Then Exit For」で、各行の文字列の中に「IPv4」が存在するか否かを調べます。InStr関数なので、存在しなかったら０を返し、存在したら先頭からの位置（０以外の正数）を返してくれます。
ですのでもし存在（> 0 ）したら「Exit For」で、１４０～１４２行目のFor～Nextを抜け出します。

文字列IPv4が見つかりFor～Nextを抜け出した時点での１４０行目の変数ｉの値は、抜け出した後もそのまま保持されています。
そのｉの値を使った「rowArray(i)」は「IPv4の文字列がある行」であり、例えば以下のような文字列になります。
　「IPv4 アドレス . . . . . . . . . . . .: 192.168.0.3」

この文字列から右端のIPアドレス値「192.168.0.3」を取り出したいので、その直前にある「：（コロン）」に着目し、１４３行目「Pos = InStr(rowArray(i), ":")」で、その位置をInStr関数で取得して変数Posに代入します。

「：（コロン）」と「192.168.0.3」の間には、スペースが１つ入っています。ですので１４５行目「IPaddress2 = Mid(rowArray(i), Pos + 2)」では、切り出し位置を１つ多めに取ることで、IPアドレス「192.168.0.3」が文字列として取り出せます。取り出した値（IPアドレス）は、関数プロシージャの戻り値とします。

４．MACアドレス

４ー１．WMI法

WMI（Windows Management Instrumentation）でＭＡＣアドレスを取得するのが図１６です。

160. '==========　⇩(9)　MACアドレス（WMI）　============
161. Private Function MACaddress1() As String
162. 　Dim Locator As Object 　　　 'SWbemLocatorオブジェクト
163. 　Dim Service As Object 　　 'SWbemServicesExオブジェクト
164. 　Dim ObjSet As Object 　　 'SWbemObjectSetオブジェクト
165. 　Dim ObjEx As Object 　　　 'SWbemObjectExオブジェクト
167. 　Set Locator = CreateObject("WbemScripting.SWbemLocator")
168. 　Set Service = Locator.ConnectServer
169. 　Set ObjSet = Service.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where (IPEnabled = TRUE)")
171. 　For Each ObjEx In ObjSet
172. 　　MACaddress1 = ObjEx.MacAddress
173. 　Next ObjEx
175. 　Set ObjSet = Nothing
176. 　Set Service = Nothing
177. 　Set Locator = Nothing

図１６別窓

１６７行目「Set Locator = CreateObject("WbemScripting.SWbemLocator")」でWMIオブジェクトを生成し、１６８行目「Set Service = Locator.ConnectServer」で、ローカルコンピュータに接続します。
１６９行目「Set ObjSet = Service.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where (IPEnabled = TRUE)")」では、クエリー条件（カッコ内のSQL文）を 指定し、得られたデータを変数ObjSetに代入しています。このSQL文の内容は、WMIオブジェクトの「Win32_NetworkAdapterConfiguration」クラスの中から、有効（IPEnabled = TRUE）なネットワークアダプターの情報を取得するもので、得られたデータは「図０９」の内容となります。

なお、１６７～１６９行目の内容を１行でコード化したものが図１７で、この手法を使用したのが「図０７（IPアドレスのWMI法）」になります。どちらでも取得できるデータは一緒なので、分かり易い方で良いかと思いますが、直接レジストリ指定でデータを取り出すよりは、オブジェクトを１つ１つ開いていく図１６の手法を私としてはお勧めします。

• 　Set ObjSet = GetObject("winmgmts:¥¥.¥root¥cimv2"). _
• 　　ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration Where (IPEnabled = TRUE)")

図１７別窓

１７１行目「For Each ObjEx In ObjSet」では、ネットワークアダプタ情報を格納した変数ObjSetの中から For Each を使って、各ネットワークアダプタ情報（変数ObjEx）を取り出します。「各ネットワークアダプタ」とは「接続されているネットワークアダプタ」ですので、たとえば有線LANと無線LANの両方が接続されている状態の時には、「図０８（右側図）」で示したようにのように、２つのネットワークアダプタ情報が得られます。
１６９行目「MACaddress1 = ObjEx.MacAddress」では図１８のように、ネットワークアダプタ情報の中からMACAddressプロパティを使ってMACアドレスを取り出し、関数プロシージャの戻り値にしています。このMacAddressプロパティは「図０９のNo.44」になります。

図１８別窓

なお、「図０８」のように、接続されているネットワークアダプタが複数ある場合は、１６８行目からも複数のネットワークアダプタ情報が得られます。ですので「図１６」のコードだと、「最後のネットワークアダプタのMACアドレス」が関数プロシージャの戻り値になりますので、注意が必要です。

４ー２．WshShellのgetmac法

WSH（Windows Script Host）でMACアドレスを取得するものが図１９です。

180. '==========　⇩(10)　MACアドレス（WshShellのgetmac法）　============
181. Private Function MACaddress2()
182. 　Dim wsh As Object 　　　　 'WSH（Windows Script Host）shellオブジェクト
183. 　Dim cmd As String 　　　　 '実行コマンド
184. 　Dim result As Object 　　　 'コマンド実行結果
185. 　Dim rowArray As Variant 　 '実行結果を各行ごとに配列化したもの
187. 　Set wsh = CreateObject("WScript.Shell")
188. 　cmd = "getmac"
190. 　Set result = wsh.exec("%ComSpec% /c " & cmd)
192. 　Do While result.Status = 0
193. 　　DoEvents: DoEvents
194. 　Loop
196. 　rowArray = Split(result.StdOut.ReadAll, vbCrLf)
198. 　MACaddress2 = Left(rowArray(3), 17)
200. 　Set result = Nothing
201. 　Set wsh = Nothing
202. End Function

図１９別窓

「図１３」の WSHでIPアドレスを取得する方法と比べると、実行コマンド（ipconfig → getmac）以下が異なります。

１８７行目「Set wsh = CreateObject("WScript.Shell")」は、WSH(Windows Script Host)のWshShellクラスのインスタンスを生成し、変数wshに代入します。
そして１８８行目「cmd = "getmac"」では、実行コマンドとして「getmac」を使用します。もちろん「ipconfig /all」でもMACアドレスは取得できますが、getmacはMACアドレスのみが取得できるので、後の処理が楽だと思います。

コマンドプロンプト上で「getmac」を実行すると、図２０のような結果が得られます。図２０は、実行するPCにネットワークアダプタが２つ存在する場合での実行結果で、且つ左側は一方がOFF状態になっている場合です。
なお、アダプタが１つの時（有線LANまたは無線LANの一方しかない）は、１行しか表示されません。

図２０別窓

この「getmac」コマンドを１９０行目「Set result = wsh.exec("%ComSpec% /c " & cmd)」で実行させ、１９２～１９４行目のDo～Loopで実行（result.Status = 0）が完了するまで待ちます（この「待ち」もcmd.exeがconsoleアプリのため、無くてもＯＫです）。そして１９６行目「rowArray = Split(result.StdOut.ReadAll, vbCrLf)」のSplit関数で改行マーク（vbCrLf）で各行を配列の各要素に格納しています。

出力例の図２０をよく見ると、getmacコマンドを打ち込んだ行と「物理アドレス･･･」と出力されている行の間には空白行が１行入っています。データとしては、この空白行が１行目（＝配列の先頭要素）となります。そこから数えると、実際のMACアドレスは４行目以降になります。
Split関数で配列化したものは、インデックスがゼロから始まりますので、実際のMACアドレスはrowArray(3)以降となります。

図２０の場合だとrowArray(4)にも物理アドレスが入りますが、１つしかネットワークアダプタが存在しないPCでは「空白行」を取得してしまいますので、確実に目的の物理アドレスを取得するためには、
　①取得する行をrowArray(3)にする
　②rowArrayのサイズをUbound等で取得し、必要な物理アドレスのインデックスを求める
　③getmacで得られる「トランスポート名」に注目し、必要な物理アドレスを探しあてる
の様な手間が必要となりそうです。
なお、使用されているアダプタを取得するのであれば上記の③の方法になりますが、有線LAN・無線LANの両方とも使用されている状態で、例えば「有線LANのMACアドレスを取得したい」ような場合であれば、図２１のように実行コマンドを「getmac /v」として取得情報を多くし「接続名」から探し出すか、「ipconfig /all」を使うかの方法が良いと思います。

図２１別窓

「getmacコマンド」ではMACアドレスが各行の先頭部分にありますので、１９８行目「MACaddress2 = Left(rowArray(3), 17)」では、Left関数を使ってMACアドレスを切り出しています。切り出す量は、MACアドレスの「XX-XX-XX-XX-XX-XX（xは0～Fの16進数）」という「値部分12文字＋ハイフン5文字＝１７文字」から「17」と指定しています。

５．ユーザー名

５ー１．WshNetworkオブジェクト法

WSH（Windows Script Host）のWshNetworkオブジェクトを使ってユーザー名を取得するのが、図２２です。

210. '==========　⇩(11)　ユーザー名（WshNetworkオブジェクト法）　============
211. Private Function USERname1()
212. 　Dim wsh As Object 　　 'WSH（Windows Script Host）Networkオブジェクト
214. 　Set wsh = CreateObject("WScript.Network")
215. 　USERname1 = wsh.UserName
217. 　Set wsh = Nothing
218. End Function

図２２別窓

２１４行目「Set wsh = CreateObject("WScript.Network")」では、WshNetworkオブジェクトを生成しています。
WshNetworkオブジェクトには３つのプロパティがあります。
　① ComputerName（コンピュータ名）
　② UserDomain（ドメイン名）
　③ UserName（ユーザー名）
ここでは③のUserNameプロパティを使用して、２１５行目「USERname1 = wsh.UserName」でユーザー名を取得し、関数プロシージャの戻り値にしています。

５ー２．WshShellのEcho環境変数法

WSH（Windows Script Host）のWshShellオブジェクトを使い、echoコマンド＋環境変数でユーザー名を取得するのが、図２３です。

230. '==========　⇩(12)　ユーザー名（WshShellのEcho環境変数法）　============
231. Private Function USERname2()
232. 　Dim wsh As Object 　　　　　 'WshShellオブジェクト
233. 　Dim cmd As String 　　　　　 '実行コマンド
234. 　Dim result As Object 　　　　 'コマンド実行結果
235. 　Dim rowArray As Variant 　　 '実行結果を各行ごとに配列化したもの
237. 　Set wsh = CreateObject("WScript.Shell")
238. 　cmd = "echo %USERNAME%"
239. 　Set result = wsh.exec("%ComSpec% /c " & cmd)
241. 　Do While result.Status = 0
242. 　　DoEvents: DoEvents
243. 　Loop
245. 　rowArray = Split(result.StdOut.ReadAll, vbCrLf)
246. 　USERname2 = rowArray(0)
248. 　Set result = Nothing
249. 　Set wsh = Nothing
250. End Function

図２３別窓

２３７行目「Set wsh = CreateObject("WScript.Shell")」で、WshShellオブジェクトを生成しています。
２３８行目「cmd = "echo %USERNAME%"」は、コマンドプロンプト上での実行コマンドを「echo %USERNAME%」としています。

ここで使用している「echo」コマンドは、「そのあとに続く文字列を出力する」という機能があります。今回、その文字列は「%USERNAME%」で、「環境変数」を「%」で囲っているため、「環境変数の値」が出力されることになります。
ですので２３９行目「Set result = wsh.exec("%ComSpec% /c " & cmd)」を実行することで、環境変数USERNAMEに登録されている「ユーザー名」が、変数resultに格納されます。

２４１～２４３行目のDo～Loopは、２３９行目の実行が完了するのを待っています。

出力された文字列内にはユーザー名だけで無く、改行マークや空白行が含まれていますので、２４５行目「rowArray = Split(result.StdOut.ReadAll, vbCrLf)」で改行マーク（vbCrLf）で分割し配列化したのち、２４６行目「USERname2 = rowArray(0)」でその配列の１つ目の要素（Split関数で配列にした場合は、インデックスがゼロからスタートします）を取り出して、関数プロシージャの戻り値にします。

５ー３．WshShellのset環境変数法

WSH（Windows Script Host）のWshShellオブジェクトを使い、setコマンド＋環境変数でユーザー名を取得するのが、図２４です。

260. '==========　⇩(13)　ユーザー名（WshShellのset環境変数法）　============
261. Private Function USERname3()
262. 　Dim wsh As Object 　　　　 'WshShellオブジェクト
263. 　Dim cmd As String 　　　　 '実行コマンド
264. 　Dim result As Object 　　 'コマンド実行結果
265. 　Dim rowArray As Variant 　 '実行結果を各行ごとに配列化したもの
267. 　Set wsh = CreateObject("WScript.Shell")
268. 　cmd = "set USERNAME"
270. 　Set result = wsh.exec("%ComSpec% /c " & cmd)
272. 　Do While result.Status = 0
273. 　　DoEvents
274. 　Loop
276. 　rowArray = Split(result.StdOut.ReadAll, vbCrLf)
277. 　PCname3 = Split(rowArray(0), "=")(1)
279. 　Set wsh = Nothing
280. 　Set result = Nothing
281. End Function

図２４別窓

２６７行目「Set wsh = CreateObject("WScript.Shell")」で、WshShellオブジェクトを生成しています。
２６８行目「cmd = "set USERNAME"」では、使用する実行コマンドを「set USERNAME」とします。なお「USERNAME」と大文字にしていますが、小文字でも問題ありません。
２７０行目「Set result = wsh.exec("%ComSpec% /c " & cmd)」でコマンドを実行します。
２７２～２７４行目のDo～Loopでは、コマンド実行が完了するのを待っています。

「set USERNAME」を実行して得られる結果は、通常は図２５の左のようになります。環境変数として「USERNAME」から始まるものは（たぶん）１つのみですが、たとえ「USERNAME1="22222"」みたいなものを「ユーザー環境変数」として作られてしまったとしても、「set USERNAME」と環境変数名を「省略せず」に指定すれば、図２５の右側のように本来の「USERNAME」の方が先に表示されます。

図２５別窓

ですので２７６行目「rowArray = Split(result.StdOut.ReadAll, vbCrLf)」で、各行を格納した配列の１番目（Splitで配列化しているためインデックスは０番目）に、目的のユーザー名のデータが収められている事になります。
そこで２７７行目「PCname3 = Split(rowArray(0), "=")(1)」で、１番目のデータ（rowArray(0) ）を取り出し、それを「=」で分割して格納した配列の２番目（インデックスは１番目）のデータを取り出し、関数プロシージャの戻り値にしています。

５ー４．Environ環境変数法

Environ関数＋環境変数でユーザー名を取得するのが、図２６です。

290. '==========　⇩(14)　ユーザー名（Environ環境変数法）　============
291. Private Function USERname4()
292. 　USERname4 = Environ("USERNAME")
293. End Function

図２６別窓

Environ関数はWindowsの環境変数の値を返す関数です。２９２行目「USERname4 = Environ("USERNAME")」では、引数に環境変数「USERNAME」を指定することで「ユーザー名」を取得し、関数プロシージャの戻り値にしています。

５ー５．APIのGetUserName関数法

Windows APIのGetUserName関数を使用してユーザー名を取得するのが、図２７です。この方法を使うには、図０４の０４～０５行目（32ビットでは０９～１０行目）で示した、宣言部でのAPI宣言「Private Declare PtrSafe Function GetUserName Lib "advapi32.dll" Alias "GetUserNameA" (ByVal lpBuffer As String, nSize As LongPtr) As LongPtr」が必要です。

300. '==========　⇩(15)　ユーザー名（GetUserName関数法）　============
301. Private Function USERname5()
302. 　Dim UN As String * 255
304. 　Call GetUserName(UN, 255)
305. 　USERname5 = WorksheetFunction.Trim(UN)
306. '　USERname5 = Left(UN, InStr(UN, Chr(0)) - 1) 　
307. End Function

図２７別窓

３０２行目「Dim UN As String * 255」では、ユーザー名を格納するため「255文字」の入れ物を変数宣言しています。ユーザー名はWindowsでは最大20文字ですが、余裕を持たせて「ファイル名最大長の255文字分」としました。
このString型宣言（固定長文字列）により、変数UNは「Asciiコード=0 の文字列（ヌル文字）」が255個並んでいる事になります。

３０４行目ではAPIの「GetUserName関数」を呼び出し、第一引数（今回は変数UN）でユーザー名を受け取ります。第二引数には取り出す文字列長（宣言した255文字の長さ）を指定します。
なお、この第二引数に指定する文字列長は「実際のユーザー名の長さ＋１ 以上」である必要があります（不足する場合は、ユーザー名は部分的にも取り出される事はありません）。実際のユーザー名の最後にはヌル文字がくっついている様です。なお、３０２行目で宣言する文字列長さは「実際のユーザー名の長さ」分だけ確保されていれば、問題ありません。

取り出したユーザー名が変数UNにどの様に入っているかですが、図２８のように「255文字分の枠」の先頭部分に入ります。ユーザー名の後ろ側は全てヌル文字のままです。

図２８別窓

このままでも表示は可能ですが、ユーザー名の長さをLen関数で確認しても、ヌル文字も含めた「255文字」となってしまいます。
ですので３０５行目「USERname5 = WorksheetFunction.Trim(UN)」で、後方のヌル文字を削除しています。なおWorksheetFunction.Trimでヌル文字が削除できる仕組みについては「文字列のスペースを削除・集結するTrim関数」を参照願います。

なお、ユーザー名にはスペースを含める事は可能なため「文字列と文字列の間に複数のスペース」が入っているユーザー名の場合には、WorksheetFunction.Trimを使用すると「スペースが１つに集結」されてしまいますので注意が必要です。
他の手法として、見え消しにしてある３０６行目「USERname5 = Left(UN, InStr(UN, Chr(0)) - 1) 」のように、左側からヌル文字（Asciiコード=0 → Chr(0) ）の位置を探し出し、ユーザー名の実体長さを調べてからLeft関数で後方を切り捨てる事でもOKです。

５ー６．ExcelのUserNameプロパティ法

上記と似たようなものに、ApplicationオブジェクトのUserNameプロパティで取得できるユーザー名があります。（図２９）

310. '==========　⇩(16)　ユーザー名（ExcelのUserNameプロパティ法）　============
311. Private Function USERname6()
312. 　USERname6 = Application.UserName
313. End Function

図２９別窓

３１２行目「USERname6 = Application.UserName」では、Applicationオブジェクト（＝Excel）のUserNameプロパティでユーザー名を取得し、関数プロシージャの戻り値にしています。

但し、このExcelのUserNameプロパティで得られる名前は「Excelをインストール/ライセンス認証する際に入力したユーザー名」であり、今まで説明してきた様な「Windowsのログインユーザー名」ではありません。
ログイン名と同じ場合もあるでしょうが、基本的に異なるものですので注意が必要です。

６．コンピューター名

６ー１．WshNetworkオブジェクト法

WSH（Windows Script Host）のWshNetworkオブジェクトを使ってコンピューター名を取得するのが、図３０です。

320. '==========　⇩(17)　コンピューター名（WSH法）　============
321. Private Function PCname1()
322. 　Dim wsh As Object 　　　 'WSH（Windows Script Host）Networkオブジェクト
324. 　Set wsh = CreateObject("WScript.Network")
325. 　PCname1 = wsh.ComputerName
327. 　Set wsh = Nothing
328. End Function

図３０別窓

３２４行目「Set wsh = CreateObject("WScript.Network")」でWshNetworkオブジェクトを生成しています。
WshNetworkオブジェクトのプロパティには、図２２でも説明した通り、３つのプロパティがあります。
　① ComputerName（コンピュータ名）
　② UserDomain（ドメイン名）
　③ UserName（ユーザー名）
ここでは①のComputerNameプロパティを使用して、３２５行目「PCname1 = wsh.ComputerName」でコンピューター名を取得し、関数プロシージャの戻り値にしています。

６ー２．WshShellのipconfig法

WSH（Windows Script Host）のWshShellオブジェクトでipconfigコマンドを使ってコンピューター名を取得するのが、図３１です。

330. '==========　⇩(18)　コンピューター名（WshShellのipconfig法）　============
331. Private Function PCname2()
332. 　Dim wsh As Object 　　　　 'WshShellオブジェクト
333. 　Dim cmd As String 　　　　 '実行コマンド
334. 　Dim result As Object 　　　 'コマンド実行結果
335. 　Dim rowArray As Variant 　　 '実行結果を各行ごとに配列化したもの
336. 　Dim i As Long 　　　　　　　 'カウンタ変数（実行結果の行位置）
337. 　Dim Pos As Long 　　 '行の中でのコンピューター名の文字位置
339. 　Set wsh = CreateObject("WScript.Shell")
340. 　cmd = "ipconfig /all"
342. 　Set result = wsh.exec("%ComSpec% /c " & cmd)
344. 　Do While result.Status = 0
345. 　　DoEvents
346. 　Loop
348. 　rowArray = Split(result.StdOut.ReadAll, vbCrLf)
349. 　For i = 0 To UBound(rowArray, 1)
350. 　　If InStr(rowArray(i), "ホスト名") > 0 Then Exit For
351. 　Next i
353. 　Pos = InStr(rowArray(i), ":")
354. 　PCname2 = Mid(rowArray(i), Pos + 2)
356. 　Set result = Nothing
357. 　Set wsh = Nothing
358. End Function

図３１別窓

３３９行目「Set wsh = CreateObject("WScript.Shell")」で、WshShellオブジェクトを生成しています。
３４０行目「cmd = "ipconfig /all"」は、コマンドプロンプト上での実行コマンドで、「ipconfig /all」とします。このコマンドは「すべて（/all）のネットワーク構成情報」を表示しますので、なんでも取得できる代わりに、多くの情報の中から自分の必要情報を取り出す処理が面倒になるというデメリットも考えてコマンド種類を選ぶべきと思います。

３４２行目「Set result = wsh.exec("%ComSpec% /c " & cmd)」で、コマンドを実行し、その結果を変数resultに代入します。３４４～３４６行目のDo～Loopは、３４２行目の実行が完了するのを待っています。

「ipconfig /all」の実行結果は、図３２のように得られます。長々と表示されますので後半を省略していますが、その先頭に「ホスト名」という内容でコンピュータ名が表示されます。

図３２別窓

コマンド実行した結果を使い、３４８行目「rowArray = Split(result.StdOut.ReadAll, vbCrLf)」で、各行単位の配列にします。そしてその配列の中から、「ホスト名」と書いてある行を３４９～３５１行目のFor～Nextで探します。
目的の行は「"ホスト名"」と書いてある行ですので、３５０行目「If InStr(rowArray(i), "ホスト名") > 0 Then Exit For」で探索し、見つかったらExit For でFor～Nextを抜け出します。

For～Nextを抜け出した時（＝ホスト名の行が見つかった時）のカウンタ変数ｉの値はまだ保持されているため、３５３行目「Pos = InStr(rowArray(i), ":")」で、その行のデータ中から「：（コロン）」を探し、その文字位置を変数Posに代入します。
コンピュータ名は、「：（コロン）」の後のスペースを挟んだその後ろに書かれているので、３５４行目「PCname2 = Mid(rowArray(i), Pos + 2)」で文字列を取り出し、関数プロシージャの戻り値にします。

６ー３．Environ環境変数法

Environ関数＋環境変数でコンピューター名を取得するのが、図３３です。

370. '==========　⇩(19)　ドメイン名（環境変数法）　============
371. Private Function CPname3()
372. 　CPname3 = Environ("COMPUTERNAME")
373. End Function

図３３別窓

Environ関数はWindowsの環境変数値を返す関数です。３７２行目「CPname3 = Environ("COMPUTERNAME")」では、引数に環境変数「COMPUTERNAME」を指定することで「コンピューター名」を取得し、関数プロシージャの戻り値にしています。

尚、この他にも以下のように環境変数を使ってコンピュータ名を取得する方法があります。
・「echo %COMPUTERNAME%」と、echoコマンドを実行し取得（図２３を参照下さい）
・「set COMPUTERNAME」と、setコマンドを実行し取得（図２４を参照下さい）

７．ドメイン名

７ー１．WshNetworkオブジェクト法

WSH（Windows Script Host）のWshNetworkオブジェクトを使ってドメイン名を取得するのが、図３４です。

380. '==========　⇩(20)　ドメイン名（WSH法）　============
381. Private Function DOMAINname1()
382. 　Dim wsh As Object 　　　　 'WSH（Windows Script Host）Networkオブジェクト
384. 　Set wsh = CreateObject("WScript.Network")
385. 　DOMAINname1 = wsh.UserDomain
387. 　Set wsh = Nothing
388. End Function

図３４別窓

３８４行目「Set wsh = CreateObject("WScript.Network")」ではWshNetworkオブジェクトを生成しています。
WshNetworkオブジェクトのプロパティには、図２２でも説明した通り、３つのプロパティがあります。
　① ComputerName（コンピュータ名）
　② UserDomain（ドメイン名）
　③ UserName（ユーザー名）
ここでは②のUserDomainプロパティを使用して、３８５行目「PCname1 = wsh.UserDomain」でドメイン名を取得し、関数プロシージャの戻り値にしています。

７ー２．Environ環境変数法

Environ関数＋環境変数でドメイン名を取得するのが、図３５です。

400. '==========　⇩(21)　ドメイン名（環境変数法）　============
401. Private Function DOMAINname2()
402. 　DOMAINname2 = Environ("USERDOMAIN")
403. End Function

図３５別窓

EnvironはWindowsの環境変数値を返す関数です。４０２行目「DOMAINname2 = Environ("USERDOMAIN")」では、引数に環境変数「USERDOMAIN」を指定することで「ドメイン名」を取得し、関数プロシージャの戻り値にしています。

尚、この他にも以下のように環境変数を使ってドメイン名を取得する方法があります。
・「echo %USERDOMAIN%」と、echoコマンドを実行し取得（図２３を参照下さい）
・「set USERDOMAIN」と、setコマンドを実行し取得（図２４を参照下さい）

８．CPU名

８ー１．Environ環境変数法

まず、CPUを表す環境変数は図３６のように複数あります。

環境変数	内容	例
NUMBER_OF_PROCESSORS	CPUの論理コア数	8
PROCESSOR_ARCHITECTURE	アーキテクチャ	x86
PROCESSOR_ARCHITEW6432 *1	アーキテクチャ	AMD64
PROCESSOR_IDENTIFIER	CPUの説明	Intel64 Family 6 Model 30 Stepping 5, GenuineIntel
PROCESSOR_LEVEL	CPUのモデル番号	6
PROCESSOR_REVISION	CPUのリビジョン番号	1e05

図３６別窓

*1：図３６の「PROCESSOR_ARCHITEW6432」について CPUのアーキテクチャは本来、環境変数「PROCESSOR_ARCHITECTURE」に入るのですが、64bit版Windows上で WOW64（Windows 32-bit On Windows 64-bit）という「64bit版のWindows上で32bit版のアプリケーションを動かすエミュレーションシステム」が働いている時には、環境変数「PROCESSOR_ARCHITEW6432」に「プロセッサの本来のCPUアーキテクチャ」が入ります。 この「PROCESSOR_ARCHITECTURE」と「PROCESSOR_ARCHITEW6432」の組み合わせで、図３７のように本来のCPUのビット数が分かります。 PROCESSOR_ARCHITEW6432 無 有 32bit 64bit PROCESSOR_ARCHITECTURE 無 32 32 64 有 32bit 32 32 64 64bit 64 64 64 図３７別窓 図３７を言葉で言うと、「PROCESSOR_ARCHITEW6432」の値が64bit版（AMD64やIA64）の場合は「CPUは64bit」となり、また「PROCESSOR_ARCHITECTURE」の値が64bit版の場合も「CPUは64bit」となります。 それ以外の場合は「CPUは32bit」です。

図３８では、図３６の中の環境変数「PROCESSOR_IDENTIFIER」を使用して、CPU名を取得しています。

410. '==========　⇩(22)　CPU名（環境変数法１）　============
411. Private Function CPUname1()
412. 　CPUname1 = Environ("PROCESSOR_IDENTIFIER")
413. End Function

図３８別窓

４１２行目「CPUname1 = Environ("PROCESSOR_IDENTIFIER")」では、引数に環境変数「PROCESSOR_IDENTIFIER」を指定することで「CPU名（CPUの説明）」を取得し、関数プロシージャの戻り値にしています。

尚、この他にも以下のように環境変数を使ってCPU名を取得する方法があります。
・「echo %PROCESSOR_IDENTIFIER%」と、echoコマンドを実行し取得（図２３を参照下さい）
・「set PROCESSOR_IDENTIFIER」と、setコマンドを実行し取得（図２４を参照下さい）

９．Excelバージョン

９ー１．Versionプロパティ法

ApplicationオブジェクトのVersionプロパティを使用し、Excelのバージョンを取得するのが図３９です。

420. '==========　⇩(23)　Excelバージョン（Excelのプロパティ法）　============
421. Private Function EXCELver1()
422. 　EXCELver1 = Application.Version
423. End Function

図３９別窓

４２２行目「EXCELver1 = Application.Version」で、Application（この場合はExcel）オブジェクトのVersionプロパティの値（＝Excelのバージョン）を取得し、関数プロシージャの戻り値にしています。

１０．O/Sバージョン

１０ー１．OperatingSystemプロパティ法

ApplicationオブジェクトのOperatingSystemプロパティを使用し、O/S（＝Windows）のバージョンを取得するのが図４０です。

430. '==========　⇩(24)　O/Sのバージョン（Excelのプロパティ法）　============
431. Private Function OSver1()
432. 　OSver1 = Application.OperatingSystem
433. End Function

図４０別窓

４３２行目「OSver1 = Application.OperatingSystem」で、Application（この場合はExcel）のOperatingSystemプロパティの値（＝O/Sのバージョン）を取得し、関数プロシージャの戻り値にしています。
なお、このOperatingSystemプロパティで得られるバージョンは、例えばWindows10やWindows11であれば「Windows(32-bit)NT 10.00」という様な文字列になります。ここで「64-bit」とカッコ内で表示されているビット数は、O/Sのビット数では無く、Excel等のOfficeアプリのビット数です。ちょっと勘違いしてしまいそうな表示ですので、違う手法を使った方が良いかもしれません。

なお、今までのWindowsのバージョン番号は、図４１のように振られています。

Windows バージョン履歴（主なもの）

製品 ﾊﾞｰｼﾞｮﾝ番号 発売年 Windows 1.01 1.01 1985 Windows 1.03 1.03 1986 Windows 2.03 2.03 1987 Windows 2.1 2.1 1988 Windows/286 2.0 2.0 1988 Windows/386 2.1 2.1 1988 Windows 3.0 3.0 1990 Windows 3.1 3.1 1992 Windows For Workgroups 3.1 3.11 1993 Windows NT 3.1 3.1 1993 Windows NT 3.5 3.5 1994 Windows NT 3.51 3.51 1995 Windows 95 4.0 1995 Windows NT 4.0 4.0 1996 Windows 98 4.10 1998 Windows 98 SE 4.10 1999 Windows Me 4.90 2000 Windows 2000 5.0 2000 Windows XP 5.1 2001 Windows Server 2003 5.2 2003

製品 ﾊﾞｰｼﾞｮﾝ番号 発売年 Windows XP 64bit 5.2 2003 Windows XP Pro 5.2 2005 Windows Server 2003 R2 5.2 2005 Windows Vista 6.0 2007 Windows Home Server 6.0 2007 Windows Server 2008 6.0 2008 Windows 7 6.1 2009 Windows Server 2008 R2 6.1 2009 Windows Home Server 2011 6.1 2011 Windows 8 6.2 2012 Windows RT 6.2 2012 Windows Server 2012 6.2 2012 Windows 8.1 6.3 2013 Windows Server 2012 R2 6.3 2013 Windows 10 10.0 2015 Windows Server 2016 10.0 2016 Windows Server 2019 10.0 2018 Windows 11 10.0 2021 Windows Server 2022 10.0 2021

図４１別窓

１０ー２．WMI法

WMI（Windows Management Instrumentation）で、O/Sのバージョンを取得するのが図４２です。

440. '==========　⇩(25)　O/Sのバージョン（WMI法）　============
441. Private Function OSver2()
442. 　Dim Locator As Object 　　　 'SWbemLocatorオブジェクト
443. 　Dim Service As Object 　　 'SWbemServicesExオブジェクト
444. 　Dim ObjSet As Object 　　 'SWbemObjectSetオブジェクト
445. 　Dim ObjEx As Object 　　　 'SWbemObjectExオブジェクト
447. 　Set Locator = CreateObject("WbemScripting.SWbemLocator")
448. 　Set Service = Locator.ConnectServer
449. 　Set ObjSet = Service.ExecQuery("Select * From Win32_OperatingSystem")
451. 　For Each ObjEx In ObjSet
452. 　　OSver2 = ObjEx.Caption & "(" & ObjEx.OSArchitecture & ")" & ObjEx.Version
453. 　Next
455. 　Set ObjSet = Nothing
456. 　Set Service = Nothing
457. 　Set Locator = Nothing
458. End Function

図４２別窓

４４７行目「Set Locator = CreateObject("WbemScripting.SWbemLocator")」でWMIオブジェクトを生成し、４４８行目「Set Service = Locator.ConnectServer」で、ローカルコンピュータに接続します。
４４９行目「Set ObjSet = Service.ExecQuery("Select * From Win32_OperatingSystem")」では、 クエリー条件（カッコ内）を 指定してO/S情報を取得します。

取得した変数ObjSetはコレクションなので４５１行目「For Each ObjEx In ObjSet」で、その中のSWbemObjectExオブジェクト（変数ObjEx）を取り出します。
取り出したSWbemObjectExオブジェクト（データテーブル：Win32_OperatingSystem）には、図４３のように多くのプロパティがあります。

No.	プロパティ	内容	例
1	BootDevice	起動元ﾃﾞｨｽｸﾄﾞﾗｲﾌﾞ	¥Device¥HarddiskVolume1
2	BuildNumber	O/Sﾋﾞﾙﾄﾞ番号	22621
3	BuildType	O/Sﾋﾞﾙﾄﾞ種類	Multiprocessor Free
4	Caption	O/S名称	Microsoft Windows 11 Home
5	CodeSet	ｺｰﾄﾞﾍﾟｰｼﾞ値	932
6	CountryCode	国/地域のｺｰﾄﾞ	81
7	CreationClassName	継承ﾁｪｰﾝに表示されるｸﾗｽ名	Win32_OperatingSystem
8	CSCreationClassName	作成ｸﾗｽ名	Win32_ComputerSystem
9	CSDVersion	ｻｰﾋﾞｽﾊﾟｯｸ	Null
10	CSName	ｺﾝﾋﾟｭｰﾀ名	[ｺﾝﾋﾟｭｰﾀ名]
11	CurrentTimeZone	ｸﾞﾘﾆｯｼﾞ標準時に対するOffSet値	540
12	DataExecutionPrevention_32BitApplications	ﾃﾞｰﾀ実行防止が32bitｱﾌﾟﾘで機能	True
13	DataExecutionPrevention_Available	ﾊﾞｯﾌｧｵｰﾊﾞｰﾗﾝ攻撃を防ぐ	True
14	DataExecutionPrevention_Drivers	ﾃﾞｰﾀ実行防止をﾄﾞﾗｲﾊﾞに対して行う	True
15	DataExecutionPreventio_SupportPolicy	ﾃﾞｰﾀ実行防止設定	0=Always Off 1=Always On 2=ｵﾌﾟﾄｲﾝ 3=ｵﾌﾟﾄｱｳﾄ
16	Debug	ﾃﾞﾊﾞｯｸﾞﾊﾞｰｼﾞｮﾝのｲﾝｽﾄｰﾙ	False
17	Description	O/Sの説明	(なし)
18	Distributed	O/Sは複数ﾉｰﾄﾞに分散	False
19	EncryptionLevel	ﾄﾗﾝｻﾞｸｼｮﾝの暗号ﾚﾍﾞﾙ	256
20	ForegroundApplicationBoost	ﾌﾟﾛｾｽの優先度	0=無し 1=最小 2=最大
21	FreePhysicalMemory	空き物理メモリ(KB)	844920
22	FreeSpaceInPagingFiles	ｽﾜｯﾌﾟｱｳﾄせずにﾏｯﾌﾟできる量(KB)	5481212
23	FreeVirtualMemory	空き仮想ﾒﾓﾘ(KB)	1819680
24	InstallDate	ｲﾝｽﾄｰﾙ日時	20221005150000.000000+540
25	LargeSystemCache	(廃止)	Null
26	LastBootUpTime	最後に再起動した日時	20230215210000.000000+540
27	LocalDateTime	ﾛｰｶﾙ日時	20230228150000.000000+540
28	Locale	言語識別子	0411
29	Manufacturer	製造元名	Microsoft Corporation
30	MaxNumberOfProcesses	ｻﾎﾟｰﾄ可能ﾌﾟﾛｾｽ数	-1
31	MaxProcessMemorySize	割り当て可能ﾒﾓﾘ量(KB)	137438953344
32	MUILanguages	多言語UI Pack	Array(ja-JP,en-US)
33	Name	O/Sｲﾝｽﾀﾝｽ	Microsoft Windows 11 Home |C:¥WINDOWS |¥Device¥Harddisk0¥Partition3
34	NumberOfLicensedUsers	O/Sﾕｰｻﾞｰのﾗｲｾﾝｽ数	Null
35	NumberOfProcesses	起動中ﾌﾟﾛｾｽ数	257
36	NumberOfUsers	ﾕｰｻﾞｰｾｯｼｮﾝ数	2
37	OperatingSystemSKU	在庫保管単位番号	101
38	Organization	登録済みﾕｰｻﾞｰの会社名	Null
39	OSArchitecture	O/Sのｱｰｷﾃｸﾁｬ	64 ビット
40	OSLanguage	O/Sの言語ﾊﾞｰｼﾞｮﾝ	1041(=日本語)
41	OSProductSuite	追加製品	768
42	OSType	O/Sの種類	18(=WinNT)
43	OtherTypeDescription	O/Sﾊﾞｰｼﾞｮﾝの追加説明 （OSTypeがOther(値1)の時）	ー
44	PAEEnabled	物理ｱﾄﾞﾚｽ拡張有効	ー
45	PlusProductID	(ｻﾎﾟｰﾄせず)	Null
46	PlusVersionNumber	(ｻﾎﾟｰﾄせず)	Null
47	PortableOperatingSystem	O/SがUSB起動か否か	False
48	Primary	ﾌﾟﾗｲﾏﾘO/Sか否か	True
49	ProductType	その他のｼｽﾃﾑ情報	1=ﾜｰｸｽﾃｰｼｮﾝ 2=ﾄﾞﾒｲﾝｺﾝﾄﾛｰﾗ 3=ｻｰﾊﾞｰ
50	QuantumLength	量子当りのｸﾛｯｸﾃｨｯｸ数 (ｻﾎﾟｰﾄせず)	0=不明 1=1ﾃｨｯｸ 2=2ﾃｨｯｸ
51	QuantumType	固定量子or可変長量子 (ｻﾎﾟｰﾄせず)	0=不明 1=固定 2=変数
52	RegisteredUser	登録ユーザ	[ﾕｰｻﾞｰ名、ﾒｰﾙｱﾄﾞﾚｽなど]
53	SerialNumber	O/Sｼﾘｱﾙ番号	10XXX-OEM-00XXXXX-XXXXX
54	ServicePackMajorVersion	Service Packのﾒｼﾞｬｰﾊﾞｰｼﾞｮﾝ	0(=Service Pack無)
55	ServicePackMinorVersion	Service Packのﾏｲﾅｰﾊﾞｰｼﾞｮﾝ	0(=Service Pack無)
56	SizeStoredInPagingFiles	ﾍﾟｰｼﾞﾝｸﾞﾌｧｲﾙ可能ｻｲｽﾞ(KB)	5628828
57	Status	ｵﾌﾞｼﾞｪｸﾄの状態	OK, Error, Degraded, Unknown ･･･等
58	SuiteMask	使用可能な製品識別ﾌﾗｸﾞ	784
59	SystemDevice	O/Sの物理ﾃﾞｨｽｸﾊﾟｰﾃｨｼｮﾝ	¥Device¥HarddiskVolume3
60	SystemDirectory	O/Sのｼｽﾃﾑﾃﾞｨﾚｸﾄﾘ	C:¥WINDOWS¥system32
61	SystemDrive	O/Sのﾃﾞｨｽｸﾄﾞﾗｲﾌﾞ名	C:
62	TotalSwapSpaceSize	ｽﾜｯﾌﾟ領域の合計量(KB)	Null
63	TotalVirtualMemorySize	仮想ﾒﾓﾘのｻｲｽﾞ(KB)	13839256
64	TotalVisibleMemorySize	物理ﾒﾓﾘのｻｲｽﾞ(KB)	8210428
65	Version	O/Sのﾊﾞｰｼﾞｮﾝ	10.0.22621
66	WindowsDirectory	Windowsﾃﾞｨﾚｸﾄﾘ	C:¥WINDOWS

図４３別窓

なお図４３についての詳細は、Microsoftのサイト「Win32_OperatingSystemクラス」を参照下さい。
またPCの環境によっては、存在しないプロパティもありますので御注意願います。

４５２行目「OSver2 = ObjEx.Caption & "(" & ObjEx.OSArchitecture & ")" & ObjEx.Version」では、図４３のNo.4（Caption）、No.39（OSArchitecture）、No.65（Version）のプロパティを使い、O/Sのバージョンをもっともらしい文字列に組み立て、関数プロシージャの戻り値にしています。
もちろん、他のプロパティを組み合わせてもOKです。

１０ー３．APIのGetVersionEx関数法

Windows APIのGetVersionEx関数を使用してO/Sバージョンを取得する方法が図４４です。
この方法には、宣言部での「GetVersionEx関数の宣言（図０４）」と「OSVERSIONINFO構造体宣言（図０５）」が必要です。

470. '==========　⇩(26)　O/Sのバージョン（API関数法）　============
471. Function OSver3() As String
472. 　Dim osvi As OSVERSIONINFO 　 '図０５で指定した構造体
474. 　osvi.dwOSVersionInfoSize = Len(osvi) 　 '構造体のサイズを指定
476. 　If GetVersionEx(osvi) = 0 Then
477. 　　OSver3 = ""
478. 　Else
479. 　　With osvi
480. 　　　OSver3 = CStr(.dwMajorVersion) & "." & CStr(.dwMinorVersion) & "." & CStr(.dwBuildNumber)
481. 　　End With
482. 　End If
483. End Function

図４４別窓

４７２行目「Dim osvi As OSVERSIONINFO」では、図０５の構造体と同じデータ形の変数を宣言します。
このOSVERSIONINFO構造体の内容は、図４５のようになります。

項目	内容	詳細
dwOSVersionInfoSize	構造体のバイト数	値＝148
dwMajorVersion	メジャー番号	バージョン番号の整数部
dwMinorVersion	マイナー番号	バージョン番号の小数部
dwBuildNumber	ビルド番号	O/Sのビルド番号（Me以前は +バージョン番号）
dwPlatformId	プラットフォームのID	値＝2（Win9xは1、Win3.1は0）
szCSDVersion	O/Sに関する付加情報	サービスパック情報、追加バージョン情報

図４５別窓

なお、例えばWindows10のバージョン番号は「10.0」ですが、この番号の整数部「10」が図４５の「メジャー番号」であり、小数点以下の部分「0」がマイナー番号となります。

４７４行目「osvi.dwOSVersionInfoSize = Len(osvi)」では、構造体のサイズ「dwOSVersionInfoSize」にバイト数を設定します。構造体は「Long型×5個＋String型×128文字」なので、Long型は1つ4バイトで「4バイト × 5個 + 128バイト = 148バイト」となります。直接「osvi.dwOSVersionInfoSize = 148」としても支障ありませんが、間違いないように「Len(osvi)」を使った方が安全です。

４７６行目「If GetVersionEx(osvi) = 0 Then」は、GetVersionEx関数が失敗（４７４行目のサイズ指定忘れを含む）した場合には、ゼロが戻りますので、その時は４７７行目「OSver3 = ""」で関数プロシージャの戻り値を""（長さゼロの文字列）にして終了させます。（４７７行目が無いと、関数プロシージャのString型の初期値の「値ゼロの文字列」が戻ることになります。それでもエラー等にはなりません。）

GetVersionEx関数が成功した場合（４７８行目「Else」）には、４７９行目「With osvi」で構造体を基準にし、４８０行目「OSver3 = CStr(.dwMajorVersion) & "." & CStr(.dwMinorVersion) & "." & CStr(.dwBuildNumber)」でO/Sバージョンの形を作成し、関数プロシージャの戻り値にします。
OSVERSIONINFO構造体から受け取る値は、図４５のように（構造体サイズを除いて）５つありますが、４８０行目ではその内の３つを使用して組み立ています。

１１．O/Sプロダクト番号

１１ー１．WMI法

WMI（Windows Management Instrumentation）で、O/Sのプロダクト番号を取得するのが図４６です。

490. '==========　⇩(27)　O/Sプロダクト番号（WMI法）　============
491. Private Function OSprod1()
492. 　Dim Locator As Object 　　　 'SWbemLocatorオブジェクト
493. 　Dim Service As Object 　　 'SWbemServicesExオブジェクト
494. 　Dim ObjSet As Object 　　 'SWbemObjectSetオブジェクト
495. 　Dim ObjEx As Object 　　　 'SWbemObjectExオブジェクト
497. 　Set Locator = CreateObject("WbemScripting.SWbemLocator")
498. 　Set Service = Locator.ConnectServer
499. 　Set ObjSet = Service.ExecQuery("Select * From Win32_OperatingSystem")
501. 　For Each ObjEx In ObjSet
502. 　　OSprod1 = ObjEx.SerialNumber
503. 　Next
505. 　Set ObjSet = Nothing
506. 　Set Service = Nothing
507. 　Set Locator = Nothing
508. End Function

図４６別窓

このコードは、図４２とほぼ同等です。
４９７行目「Set Locator = CreateObject("WbemScripting.SWbemLocator")」でWMIオブジェクトを生成し、４９８行目「Set Service = Locator.ConnectServer」で、ローカルコンピュータに接続します。
４９９行目「Set ObjSet = Service.ExecQuery("Select * From Win32_OperatingSystem")」では、 クエリー条件（カッコ内）を 指定してO/S情報を取得します。

取得した変数ObjSetはコレクションなので５０１行目「For Each ObjEx In ObjSet」で、その中のSWbemObjectExオブジェクトを取り出します。
取り出したSWbemObjectExオブジェクト（変数ObjEx）には、図４３のように多くのプロパティがありますが、ここではNo.53（SerialNumber）を使用し、５０２行目「OSprod1 = ObjEx.SerialNumber」でプロダクト番号を取得し、関数プロシージャの戻り値にします。

１２．ハードディスク シリアル番号

１２ー１．WMI法

WMI（Windows Management Instrumentation）で、ハードディスクのシリアル番号を取得するのが図４７です。

520. '==========　⇩(28)　ハードディスク シリアル番号（WMI法）　============
521. Public Function HDserial1()
522. 　Dim Locator As Object 　　　 'SWbemLocatorオブジェクト
523. 　Dim Service As Object 　　 'SWbemServicesExオブジェクト
524. 　Dim ObjSet As Object 　　 'SWbemObjectSetオブジェクト
525. 　Dim ObjEx As Object 　　　 'SWbemObjectExオブジェクト
527. 　Set Locator = CreateObject("WbemScripting.SWbemLocator")
528. 　Set Service = Locator.ConnectServer
529. 　Set ObjSet = Service.ExecQuery("Select * From Win32_DiskDrive")
531. 　For Each ObjEx In ObjSet
532. 　　If ObjEx.MediaType <> "Removable Media" Then
533. 　　　HDserial1 = Trim(ObjEx.Caption) & "(" & Trim(ObjEx.SerialNumber) & ")"
534. 　　　Exit For
535. 　　End If
536. 　Next
538. 　Set ObjSet = Nothing
539. 　Set Service = Nothing
540. 　Set Locator = Nothing
541. End Function

図４７別窓

このコードは、図４２・図４６とほぼ同等です。
５２７行目「Set Locator = CreateObject("WbemScripting.SWbemLocator")」でWMIオブジェクトを生成し、５２８行目「Set Service = Locator.ConnectServer」で、ローカルコンピュータに接続します。
５２９行目「Set ObjSet = Service.ExecQuery("Select * From Win32_DiskDrive")」では、クエリー条件（カッコ内）を 指定してディスク情報を取得します。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
図４２・図４６では、データテーブル名として「Win32_OperatingSystem」を指定することでO/S情報を取得しましたが、図４７では「Win32_DiskDrive」をデータテーブルに指定することで「ドライブ（ハードディスク）」の情報を得ます。

取得した変数ObjSetはコレクションなので５３１行目「For Each ObjEx In ObjSet」で、その中のSWbemObjectExオブジェクトを取り出します。取り出したSWbemObjectExオブジェクト（データテーブル：Win32_DiskDrive）には、図４８のように多くのプロパティがあります。

No.	プロパティ	内容	例
1	Availability	ﾃﾞﾊﾞｲｽの可用性と状態	1～21の番号,又はNull
2	BytesPerSector	各ｾｸﾀのﾊﾞｲﾄ数	512
3	Capabilities	ﾒﾃﾞｨｱｱｸｾｽﾃﾞﾊﾞｲｽの機能	(0～12の番号の配列) 3=ﾗﾝﾀﾞﾑｱｸｾｽ 4=書き込みｻﾎﾟｰﾄ 5=暗号化 等
4	CapabilityDescriptions	ｱｸｾｽﾃﾞﾊﾞｲｽの詳細説明	(配列)
5	Caption	ｵﾌﾞｼﾞｪｸﾄの簡易説明	KBG40ZNS128G BG4A XXXXXX
6	CompressionMethod	圧縮ｱﾙｺﾞﾘｽﾞﾑ	Null 等
7	ConfigManagerErrorCode	ｴﾗｰｺｰﾄﾞ	0(=正常動作)
8	ConfigManagerUserConfig	ﾕｰｻﾞ定義の構成を使用	False(=使用せず)
9	CreationClassName	具象ｸﾗｽの名前	Win32_DiskDrive
10	DefaultBlockSize	既定ﾌﾞﾛｯｸｻｲｽﾞ(byte)	Null
11	Description	ｵﾌﾞｼﾞｪｸﾄの説明	ディスク ドライブ
12	DeviceID	ﾃﾞｨｽｸﾄﾞﾗｲﾌﾞの一意識別子	\\.\PHYSICALDRIVE0
13	ErrorCleared	ｴﾗｰがｸﾘｱされた	Null
14	ErrorDescription	ｴﾗｰの詳細	Null
15	ErrorMethodology	ｴﾗｰ検出,修正の種類	Null
16	FirmwareRevision	ﾌｧｰﾑｳｪｱのﾘﾋﾞｼﾞｮﾝ	AEMS0000
17	Index	物理ﾄﾞﾗｲﾌﾞ番号	0
18	InstallDate	ｲﾝｽﾄｰﾙ日	Null
19	InterfaceType	ｲﾝﾀｰﾌｪｲｽの種類	SCSI ,HDC ,IDE ,USB ,1394
20	LastErrorCode	最後のｴﾗｰｺｰﾄﾞ	Null
21	Manufacturer	ﾄﾞﾗｲﾌﾞ製造元名	(標準ディスク ドライブ)
22	MaxBlockSize	最大ﾌﾞﾛｯｸｻｲｽﾞ(byte)	Null
23	MaxMediaSize	ｻﾎﾟｰﾄされる最大ﾒﾃﾞｨｱｻｲｽﾞ(KB)	Null
24	MediaLoaded	読み取り可能なFile Systemが有る	True(=固定ﾃﾞｨｽｸは常にTrue)
25	MediaType	ﾒﾃﾞｨｱの種類	External hard disk media(外部HD) Removable media(ﾘﾑｰﾊﾞﾌﾞﾙ) Fixed hard disk media(固定HD) Unknown(不明)
26	MinBlockSize	最小ﾌﾞﾛｯｸｻｲｽﾞ(byte)	Null
27	Model	製造元のﾓﾃﾞﾙ番号	STXXXX1W
28	Name	ｵﾌﾞｼﾞｪｸﾄが識別されるﾗﾍﾞﾙ	¥¥.¥PHYSICALDRIVE0
29	NeedsCleaning	ﾃﾞﾊﾞｲｽのｸﾘｰﾆﾝｸﾞ必要性	Null
30	NumberOfMediaSupported	挿入可能なﾒﾃﾞｨｱ最大数	Null
31	Partitions	物理ﾄﾞﾗｲﾌﾞのﾊﾟｰﾃｨｼｮﾝ数	3
32	PNPDeviceID	Plug & Playしているﾃﾞﾊﾞｲｽ	SCSI\DISK&VEN_NVME&PROD_KBGxxZNSxxxG_BGx\x&xxxBxBD&0&000000
33	PowerManagementCapabilities	論理ﾃﾞﾊﾞｲｽの電源関連機能	0～7 又は Null 2=Disabled 3=Enabled 等
34	PowerManagementSupported	中断ﾓｰﾄﾞ等の電源管理可	Null
35	SCSIBus	SCSIﾊﾞｽ番号	0
36	SCSILogicalUnit	SCSI論理ﾕﾆｯﾄ番号	0
37	SCSIPort	SCSIﾎﾟｰﾄ番号	0
38	SCSITargetId	SCSI識別子番号	0
39	SectorsPerTrack	各ﾄﾗｯｸのｾｸﾀｰ数	63
40	SerialNumber	製造元割り当て番号	WD-WMxxxxxxxxxx
41	Signature	ﾃﾞｨｽｸID	Null
42	Size	ﾄﾞﾗｲﾌﾞｻｲｽﾞ(ｼﾘﾝﾀﾞ合計数)	128034708480
43	Status	ｵﾌﾞｼﾞｪｸﾄの状態	OK ,Error ,Degraded ,･･･他
44	StatusInfo	論理ﾃﾞﾊﾞｲｽの状態	1～5 又はNull
45	SystemCreationClassName	ｽｺｰﾌﾟｼｽﾃﾑの作成ｸﾗｽ名	Win32_ComputerSystem
46	SystemName	ｽｺｰﾌﾟｼｽﾃﾑの名前	[名前]
47	TotalCylinders	物理ﾄﾞﾗｲﾌﾞのｼﾘﾝﾀﾞｰ合計数	15566
48	TotalHeads	ﾄﾞﾗｲﾌﾞのﾍｯﾄﾞの合計数	255
49	TotalSectors	物理ﾄﾞﾗｲﾌﾞのｾｸﾀｰ合計数	250067790
50	TotalTracks	物理ﾄﾞﾗｲﾌﾞのﾄﾗｯｸ合計数	3969330
51	TracksPerCylinder	物理ﾄﾞﾗｲﾌﾞの各ｼﾘﾝﾀﾞｰ内のﾄﾗｯｸ数	255

図４８別窓

なお図４８についての詳細は、Microsoftのサイト「Win32_DiskDriveクラス」を参照下さい。
またPCの環境によっては、存在しないプロパティもある可能性があるので御注意願います。

PCの構成によっては、複数のハードディスクが搭載されていたり、リムーバブルディスクが接続されていたりする場合があります。今回はハードディスク情報のみを取得することにし、５３２行目「If ObjEx.MediaType <> "Removable Media" Then」でリムーバブルディスクを除外しています。
そして１つ目のハードディスクが見つかったところで５３３行目「HDserial1 = Trim(ObjEx.Caption) & "(" & Trim(ObjEx.SerialNumber) & ")"」で、図４８のNo.5（Caption）、No.40（SerialNumber）のプロパティを使い、もっともらしい文字列に組み立てています。もちろん、他のプロパティを組み合わせてもOKです。

最後に５３４行目「Exit For」でFor Each～Next を抜け出し、１つ目のハードディスク情報だけを関数プロシージャの戻り値にしています。

１３．まとめ

取得したい固有情報と取得手法を図４９のようにマトリクスにしました。

	WMI	WshNetwork	WshShell				Environ 環境変数	Application プロパティ	API
			IpConfig	GetMac	Echo環境変数	Set環境変数
IPｱﾄﾞﾚｽ	図０７		図１３
MACｱﾄﾞﾚｽ	図１６			図１９
ﾕｰｻﾞｰ名		図２２			図２３	図２４	図２６	図２９	図２７
ｺﾝﾋﾟｭｰﾀ名		図３０	図３１				図３３
ﾄﾞﾒｲﾝ名		図３４					図３５
CPU名							図３８
Excelﾊﾞｰｼﾞｮﾝ								図３９
O/Sﾊﾞｰｼﾞｮﾝ	図４２							図４０	図４４
Excelﾌﾟﾛﾀﾞｸﾄ
O/Sﾌﾟﾛﾀﾞｸﾄ	図４６
HDｼﾘｰｽﾞ	図４７

図４９別窓

今回、固有情報を得られる事を確認したところは「黄色背景」にしましたが、手法はもちろんの事、得られる固有情報も網羅できたとは思っていません。この表の中でも更に塗りつぶせるところもあるでしょうし、この表から外れたところで得られる情報・手法もあると思います。

表中の「Excelプロダクト番号」は、今回は情報取得の方法が見つかりませんでした。古いバージョンでは取得できた様で、色々なサイトで手法が紹介されていましたが、新しいバージョン（2016以降で確認）では不可でした。
他の項目は現在は情報が取得できますが、Excelプロダクト番号と同様に未来永劫取得できるかは分かりません。新バージョンが出てきたら、今まで使ってきた手法で取得可能かを確認する必要があると思います。

なお、Application（＝Excel）オブジェクトのUserNameプロパティで得られる名前（ピンク色背景）は、他のWindowsのユーザー名とは異なるものですので御注意下さい。

アプリ実例

「アンケートの回収と集計方法」
「ExcelシートDBを使った会議室予約システム」
「セル変更履歴をコメントに残す」

サンプルファイル

PCの固有情報の取得（its-029.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。