2023/04/10

スクロールバー動的設定時の注意点

１．スクロールバーの設定をするツールの概要
２．スクロールバーの概要
３．スクロールバーの各プロパティ値の間の関係
　３ー１．Max値とMin値
　３ー２．LargeChange値
　３ー３．SmallChange値
４．ツールの説明
　４ー１．ワークシート
　４ー２．シートモジュール
　　４ー２ー１．設定スクロールバーの初期化
　　４ー２ー２．設定処理
　　　よりみち（LinkedCellのバグとマイナス値）
　　４ー２ー３．確認用スクロールバーのValue値表示
５．まとめ
アプリ実例
サンプルファイル

スクロールバーは、シート上でもユーザーフォーム上でも良く使われるコントロールです。その設定も「最大（Maxプロパティ）」「最小（Minプロパティ）」だけで無く、「シャフトの増分（LargeChangeプロパティ）」「スクロール矢印の増分（SmallChangeプロパティ）」の設定により操作性が変わってきます。
またデータ量に合わせて、動的にスクロールバーの設定値を変化させる場合もあると思います。しかし、設定値の組合せによっては「スクロールボックスが消える」「スクロールバーが操作できない」状態になることがあります。

今回は、スクロールバー（主にActiveXコントロール）のプロパティの内、「Max」「Min」「LargeChange」「SmallChange」の４つのプロパティの関係について、簡単なツールも使いながら説明をします。

１．スクロールバーの設定をするツールの概要

今回説明のために、スクロールバーの設定値を簡単に変更できるツール（サンプルファイル）を用意しました。これを使って、以下で説明をしていきます。図０１がツールの内容です。
スクロールバー用ツール概要

図０１

今回、状態や動作を確認するのは図０１の一番右側の大きなスクロールバーです。その設定値を中央部の４つの設定用スクロールバーで変更させます。
設定用スクロールバーは、上から「Max」「Min」「LargeChange」「SmallChange」を変更させます。

また設定用スクロールバーの初期化をするのが、図０１の一番左側のStartボタンです。
初期化すると各設定用スクロールバーの範囲を「-50 ～ +50」にし、また値をゼロにします。ですので、Startボタンにより、一番右の確認用スクロールバーは「Max = 0」「Min = 0」「LargeChange = 0」「SmallChange = 0」となります。

２．スクロールバーの概要

まず、スクロールバーの各部の名称は図０２のように呼ばれています。

スクロールバーの部位名

図０２

スクロールバーの操作には３つの方法があります。１つ目は「スクロールボックス」をマウスでつかんで動かす方法、２つ目は「スクロール矢印」をクリックする方法、３つ目がシャフト部をクリックする方法です。

操作する場所によって、変化する値は以下のようになります。
　「スクロールボックス」：値は１ずつ変化します。
　「スクロール矢印」　　：値は「SmallChangeの値」ずつ変化します。
　「シャフト部」　　　　：値は「LargeChangeの値」ずつ変化します。
そして、スクロールバーの左端が「Min値」、右端が「Max値」となります。縦方向に配置した時には、上端が「Min値」、下端が「Max値」です。

なお各プロパティには、Long型（-2,147,483,648 ～ +2,147,483,647）の整数値を指定します。

３．スクロールバーの各プロパティ値の間の関係

ツール（サンプルファイル）で「Startボタン」をクリックしてみると、スクロールバーは図０３のような状態になります。
設定値が全てゼロの状態

図０３

図０３は「設定値が全てゼロ」となり、確認用スクロールバーは「スクロールボックスが表示されない」状態になります。
一般のユーザーならパニックになるでしょうし、「Excelが壊れた」と思うかもしれません。
「MinもMaxもゼロ。値を動かしようが無いから、スクロールボックスが現れる訳が無い」と気が付かれた方もいるかもしれません。では、図０４のような状態はどうでしょう。
設定値がゼロでは無いが、スクロールボックスが現れない状態

図０４

「動かせる範囲があるのに、スクロールボックスが現れない」という条件もあるのです。

３ー１．Max値とMin値

スクロールボックスが現れる必要条件は、図０５のように「Max値とMin値に差」があることです。
通常は「Max値 > Min値」のように設定すると思いますが、逆にして「Max値 < Min値」としてもOKです。
MinとMaxと値に差をつけるとスクロールボックスが現れる

図０５

３ー２．LargeChange値

「Max値とMin値に差」を与えても、LargeChange値によりスクロールボックスが現れるか否かが変わります。
図０６のように「Max値とMin値の差 < LargeChange値」になると、スクロールボックスが現れません。「Max値とMin値の差 ≥ LargeChange値」で現れるようになり、イコールの時でもOKです。
MinとMaxとの差よりもLargeChange値を大きくするとスクロールボックスが現れない

MinとMaxとの差よりもLargeChange値を大きくするとスクロールボックスが現れない

図０６

また、LargeChange値をマイナス値にすると、Max値・Min値にかかわらず図０７のようにスクロールボックスは現れません。
LargeChange値をマイナスにするとスクロールボックスが消える

図０７

以上を整理してグラフで表すと図０８になります。「青色＋緑色」の範囲がスクロールボックスが現れる条件です。
MinとMaxの差とLargeChange値の関係グラフ

図０８

但し、緑色の範囲（Max値とMin値に差且つ LargeChange値=ゼロ）の場合は、LargeChangeの変更場所であるシャフト部をクリックしても（LargeChangeがゼロなので）Value値は変化しません。なお緑色の範囲でも、スクロールボックスをマウスで動かすと値は変化しますし、SmallChangeがゼロ以外であればスクロール矢印でも値は変化します。

３ー３．SmallChange値

SmallChange値は、スクロールボックスが現れる・現れないに対しては無関係です。
しかし、図０９のようにSmallChange値がゼロの場合は、スクロール矢印をクリックしても値は変化しません。但しスクロールボックスでの移動やシャフト部での操作では、値を動かす事が出来ます。
SmallChangeがゼロだとスクロール矢印では動かない

図０９

なおSmallChange値がゼロの時にスクロール矢印をクリックすると、スクロールボックスは反応し点滅するので「指令は行くのに、値がゼロだから動かない」という状況のようです。

また、SmallChangeにマイナス値を設定することは可能です。但し図１０のように「スクロール矢印をクリックすると、スクロールボックスが逃げていく」という現象になります。
SmallChangeがマイナスだと逆に動く

図１０

このSmallChangeがマイナス時の「スクロールボックスが逃げていく」現象は、図１１のようにMax値とMin値を逆転させた時でも同じです。つまりSmallChangeがマイナスだと「操作感に違和感」が出るので、マイナス値を使う場面は少ないと思います。
SmallChangeがマイナスだと、MaxとMinを入れ替えても逆に動く

図１１

以上のSmallChange値の関係を整理すると図１２のようになります。緑色の範囲（Max値とMin値に差且つ SmallChange値=ゼロ）の場合は、スクロール矢印での操作は不可となります。
MinとMaxの差とSmallChange値の関係グラフ

図１２

４．ツールの説明

４ー１．ワークシート（今回はSheet1）

今回使用するツールは、シート上に図１３のようにコントロール類を配置しています。
シート上にコントロール類を配置

図１３

スクロールバーに設定するプロパティは、今回「Max」「Min」「LargeChange」「SmallChange」の４種ですので、４つの設定用スクロールバーを並べて配置します。各スクロールバーの設定値は、E列の黄色セルに表示されます。
設定される側の確認用スクロールバーは、シートの右側に配置します。そのスクロールバーの値（Value値）は、H4セル（黄色セル）に表示されるようにしています。

設定値を初期化（４つのスクロールバーのMax・Min値の設定、および値をゼロにする）する「Startボタン」をシートの左側に配置します。そのボタンには、シートモジュールの「SBiniプロシージャ（図１４）」をマクロ登録します。ボタン上の文字列は、配置時に手動設定しています。
スクロールバーの説明書きはセル上に書き込んでいます。

４ー２．シートモジュール（今回はSheet1）

４ー２ー１．設定スクロールバーの初期化

「設定スクロールバー初期化」の為のStartボタンをクリックした時に呼び出されるのが図１４です。

'==========　⇩(1)　初期化　============
Sub SBini()
　Dim SBs(1 To 4) As Variant 　 '←設定用スクロールバーの配列
　Dim SB As Variant 　　　 '←１つ１つのスクロールバー
　Set SBs(1) = Me.ScrollBar1
　Set SBs(2) = Me.ScrollBar2
　Set SBs(3) = Me.ScrollBar3
　Set SBs(4) = Me.ScrollBar4
　For Each SB In SBs
　　SB.Max = 50
　　SB.Min = -50
　　SB.Value = 0
　Next SB
End Sub

図１４

今回は同じような設定用スクロールバーが４つあり、またその設定内容が一緒ですので、４つをセット（言わば、スクロールバーのコレクション）にして設定処理をします。但しShapesのようなものが存在しないので、配列の形にします。
０２行目「Dim SBs(1 To 4) As Variant」では４要素の配列を宣言し、０３行目「Dim SB As Variant」では１つ１つのスクロールバーの変数を宣言します。
０５行目「Set SBs(1) = Me.ScrollBar1」で、Max値を設定するスクロールバー（ScrollBar1）を配列の１番目に格納しています。オブジェクトとして格納する必要があるのでSetステートメントを使用します。
他のスクロールバー（Min用のScrollBar2、LargeChange用のScrollBar3、SmallChange用のScrollBar4）も同様に、０６～０８行目で配列に格納していきます。

１０行目「For Each SB In SBs」では、スクロールバーのオブジェクトを格納した配列SBsから１つずつスクロールバーを取り出します。
１１行目「SB.Max = 50」では、設定用スクロールバーの最大値を50に設定しています。
１２行目「SB.Min = -50」では、最小値を-50に設定しています。
１３行目「SB.Value = 0」では、初期の値をゼロに設定しています。
なお、今回の設定範囲は「-50 ～ 50」としましたが、Long型の範囲であれば問題ありません。

４ー２ー２．設定処理

設定用スクロールバーを操作した時には、図１５のようにそれぞれのスクロールバーのChangeイベントが発生します。そしてその中で、確認用スクロールバーの設定をしていきます。

'==========　⇩(2)　Max値設定用スクロールバー　============
Private Sub ScrollBar1_Change()
　Me.ScrollBar5.Max = Me.ScrollBar1.Value
　Me.Range("E1") = Me.ScrollBar1.Value
End Sub
'==========　⇩(3)　Min値設定用スクロールバー　============
Private Sub ScrollBar2_Change()
　Me.ScrollBar5.Min = Me.ScrollBar2.Value
　Me.Range("E2") = Me.ScrollBar2.Value
End Sub
'==========　⇩(4)　LargeChange値設定用スクロールバー　============
Private Sub ScrollBar3_Change()
　Me.ScrollBar5.LargeChange = Me.ScrollBar3.Value
　Me.Range("E3") = Me.ScrollBar3.Value
End Sub
'==========　⇩(5)　SmallChange値設定用スクロールバー　============
Private Sub ScrollBar4_Change()
　Me.ScrollBar5.SmallChange = Me.ScrollBar4.Value
　Me.Range("E4") = Me.ScrollBar4.Value
End Sub

図１５

「Max値設定用スクロールバー」の値が変化した時には、２１～２４行目のChangeイベントプロシージャが実行されます。
２２行目「Me.ScrollBar5.Max = Me.ScrollBar1.Value」では、確認用スクロールバー（ScrollBar5）のMax値を設定用スクロールバーのValue値に変更します。
２３行目「Me.Range("E1") = Me.ScrollBar1.Value」では、変更した値（確認用スクロールバーのMax値）を黄色セル（E1セル）に書き出します。

なお、スクロールバーの「LinkedCell」プロパティに、例えば「$E$1」等と「Value値を書き込むセル」を指定しておくと、２３行目の様な「セルに書き込むコードが不要」になります。但しスクロールバーのValue値がマイナス値の時、例えば「-1」の時には「65535」という変な値が出力されてしまいます。
この現象はバグには違いないのですが、この「-1」の時に出力される65535を二進数で表すと「1111 1111 1111 1111」となります。

コンピュータでマイナスの数を表す時には補数を用います。補数には「1の補数」と「2の補数」がありますが、今回の数値から見ると、ここでは「２の補数」を使用しているようです。
2の補数を使ってマイナス値を求める時には、図１６のように「使用しているビット数の最大値に1を足した数」から「正の値」を引き算します。

2の補数を使ったマイナス値の計算方法

図１６

例えば、16ビットでの「-1」を求めるには、16ビットの最大値「1111 1111 1111 1111」に１を足した「1 0000 0000 0000 0000」から、求める「-1」を正の値にした「+1」の「0000 0000 0000 0001」を引き算します。
得られた「1111 1111 1111 1111」が「-1」を表すことになります。

この計算方法は、コンピュータにとっては非常に便利です。例えば「1 - 1 =」という計算をしようとした時、「+1」は16ビットでの二進数で「0000 0000 0000 0001」、「-1」は「1111 1111 1111 1111」ですので、その２つを「足し算」すると「1 0000 0000 0000 0000」になります。しかし16ビットで処理していますので、一番上の桁のあふれた「1」は無視され「0000 0000 0000 0000」となり、これは「0」を示します。つまり「1 - 1 = 0」というコンピュータにとって苦手な引き算が、得意な足し算で可能になるのです。

なお、図１６では「16ビット（＝2バイト　＝Integer型相当）」で計算していますが、スクロールバーで扱える値はLong型（4バイト＝32ビット）です。
この矛盾から「この先はどうなるんだろう？」と思い、真のValue値とLinkedCellへの出力値を並べてみたのが図１７です。
Value値とLinkedCell値の違い

図１７

結果は、-32768まで行ったら「その先は正常な値を出力」することが分かりました。この分岐点は、VBAのInteger相当（プラスマイナスのある16ビット）の範囲「-32768 ～ 32767」から頷けるものですが、同じ数値（図１７の赤字部分）が２度出てくるようなものは使えませんし、セルでの数式による変換も不可能です。
ですので「マイナス側の設定をする可能性のあるスクロールバーでは、LinkedCellプロパティは使わない」事が重要です。

Max値設定用スクロールバーと同様に、Min値設定用スクロールバーの値が変化した時には２７～３０行目が実行され「確認用スクロールバーのMin値を変更」します。
LargeChange用（３３～３６行目）、SmallChange用（３９～４２行目）も同様に、確認用スクロールバーのLargeChange値、SmallChange値を変更します。

４ー２ー３．確認用スクロールバーのValue値表示

確認用スクロールバーの値を変更した時には、図１８のChangeイベントプロシージャが呼び出されます。

'==========　⇩(6)　　============
Private Sub ScrollBar5_Change()
　Me.Range("H4") = Me.ScrollBar5.Value
End Sub

図１８

５２行目「Me.Range("H4") = Me.ScrollBar5.Value」で、Value値を黄色セル（H4セル）に書き出します。

５．まとめ

上記の現象を踏まえると、スクロールバーの設定を動的に行う時には以下のような注意が必要です。

・	LargeChange値を一定にすると、Max値とMin値の差が小さい時に「スクロールボックスが消える」
・	LargeChangeやSmallChange値を計算で設定する時、ゼロが出る計算式を使うと「スクロール矢印やシャフト部での値変更が出来なくなる」

サンプルファイル

スクロールバー動的設定時の注意点（its-035.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始）
解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。