2023/06/29

VBAの配列で使うFrequencyメソッド

• １．シート上でのFrequency関数の使い方
• ２．VBAでのFrequencyメソッドの使い方
• 　２ー１．ワークシートの準備
• 　２ー２．区間固定配列での度数計算
• 　２ー３．区間をセル範囲で取得し度数計算
• 　２ー４．区間を最大最小値から自動計算し度数計算
• 　　２ー４ー１．ユーザーフォームの準備
• 　　２ー４ー２．区間を自動計算するユーザー定義関数
• ３．まとめ
• アプリ実例・関連する項目
• サンプルファイル

１．シート上でのFREQUENCY関数の使い方

ワークシート関数の１つに「FREQUENCY関数」というものがあります。図０１のように、あるセル範囲内の値（図０１の緑線枠）を区間（赤線枠）に従って「範囲内の個数をカウント」するという機能です。

図０１別窓
この関数は「区間」という複数セルを対象にした関数（配列関数）のため、数式入力範囲（図０１だとE2～E13セル）を選択後、上部の数式バーに数式（図０１の場合「=FREQUENCY(A2:A11,D2:D12)」）を入力したのち「Ctrl＋Shift＋Enter」キーを押して確定します。すると入力範囲の数式が「{}（波カッコ）」で囲まれ、各区間の度数（個数）が表示されます。
今までは上記のような操作での入力だったのですが、Microsoft365・Excel2021ではスピル機能が追加となりました。先頭セル（図０１ではI2セル）に数式「=FREQUENCY(A2:A11,H2:H12)」を入力すると、区間に指定したセル範囲に対応して自動的に数式が展開（スピルと言うそうです）されます。
この方式は動的配列数式と呼ばれ、後から区間を変更しても数式は追従してくれるのが利点です。
当然ながら従来の配列数式と結果は同じですし、Microsoft365・Excel2021でも配列数式の入力方法（Ctrl＋Shift＋Enter）も可能です。
なお区間の値は「以下」を表しています。例えば図０１のD2セル「0」は「ゼロ以下」、D12セル「100」は「100以下」となります。しかしこのままでは100を超えた値があった場合にはカウントできませんので、E13セルに「100超」の度数が入ります。配列数式では手動で「区間の１つ下のセル」まで選択する必要がありますが、動的配列数式では１つ下まで自動的に数式が入ります。
図０１は単列データでしたが、図０２のように複数列データでも使い方は同じです。

図０２別窓

２．VBAでのFrequencyメソッドの使い方

Frequencyは、WorksheetFunctionオブジェクト内にも存在します。使い方はワークシート関数（図０１）と同様で、引数として「データのセル範囲」・「区間のセル範囲」の代わりに「配列」も指定できるところが異なります。
VBAで処理をする場合、何らかの配列データが度数計算元データとなることが多いと思います。ですので元データは全てシートのセル範囲から取得する形とし、以下では「区間データ」の取得方法別、及び出力別でプログラムを分けてみました（図０３）。もちろんどれを組み合わせてもOKです。むしろ出力せずに度数計算結果をその後の処理に繋げる事の方が多いかもしれません。

ﾎﾞﾀﾝ	コード	元データ	区間	出力
1	図０５	単列	固定配列	シート上に書き込み
2	図０８	単列	セル範囲	メッセージボックス
3	図１０	複数列	自動計算	フォーム上のListBox

図０３別窓

２ー１．ワークシートの準備

サンプルファイルでは、図０４のように２つのワークシートを用意しました。Sheet1は単列データ、Sheet2は複数列データとし、データのセル範囲・区間のセル範囲は図の通りです。なお、元データ（緑色背景セル）は0～100の整数を乱数により発生させていますので、再計算やセル入力をすると値が変わります。

図０４別窓
Sheet1には「ボタン１」「ボタン２」の２個のボタンを、Sheet2には「ボタン３」を貼り付けています。それぞれのボタンには、標準モジュールの「vbaFreq1」「vbaFreq2」「vbaFreq3」をマクロ登録しています。

２ー２．区間固定配列での度数計算

Sheet1のボタン１から呼び出されるのが図０５です。

0. '==========　⇩(1)　区間を固定配列で取得し度数計算 ============
1. Sub vbaFreq1()
2. 　Dim Data As Variant 　　 '←元データの配列
3. 　Dim Rank As Variant 　　 '←区間データの配列
4. 　Dim Count As Variant 　 '←度数の配列
5. 　Dim i As Integer 　　　　 '←カウンタ変数（区間数）
7. 　Data = Sheet1.Range("A2:A11").Value
8. 　Rank = Array(0, 10, 20, 30, 40, 50, 60, 70, 80, 90, 100)
10. 　Count = WorksheetFunction.Frequency(Data, Rank)
12. 　ReDim Preserve Rank(0 To UBound(Rank, 1) + 1)
13. 　ReDim Preserve Count(1 To UBound(Count, 1), 1 To 2)
15. 　For i = 1 To UBound(Count, 1)
16. 　　Count(i, 2) = Count(i, 1)
17. 　　Count(i, 1) = Rank(i - 1)
18. 　Next i
20. 　Sheet1.Range("K2").Resize(UBound(Count, 1), UBound(Count, 2)) = Count
22. End Sub

図０５別窓
０７行目「Data = Sheet1.Range("A2:A11").Value」では、ワークシート上のデータ値を取得し、配列の形で変数Dataに代入しています。アプリ内で度数処理をする場合、その元データは様々な場所から取得すると思いますが、処理直前には配列の形となっている事が多いと考え、このような配列取得方法としました。
０８行目「Rank = Array(0, 10, 20, 30, 40, 50, 60, 70, 80, 90, 100)」では、Array関数を使って「区間データの配列」を作成しています。単純なArray関数ですのでインデックスはゼロ始まりの一次元配列となります。
１０行目「Count = WorksheetFunction.Frequency(Data, Rank)」で、Frequencyメソッドの第一引数に元データの配列、第二引数に区間データの配列を指定することで、ワークシート関数と同様に度数計算の結果が配列として得られます。
なお戻り値である配列の特徴は、以下の通りです。
　・二次元配列（複数行 × １列）
　・大きさは、区間配列よりも１要素多い
　・インデックスは１スタート
特徴からも分かるように、ワークシート上での計算結果がそのまま配列の形になっていると考えても良いと思います。
Frequencyメソッドの戻り値が取得できれば、あとは区間（今回の場合はRank配列）と組み合わせて処理を続けていけばよいのですが、ここでは度数と区間を１つの配列にまとめています。手順は以下のようにしました。

図０６別窓
最終的にまとめる配列は、度数側の配列（配列Count）とします。
まず、区間データの配列（配列Rank）は要素数が度数側よりも１つ少ないため、行を１つ増やしておきます①。
度数側の配列（配列Count）には、区間データを入れるスペースを作るために、列数を１つ増やします②。次に度数の値が入っている１列目から２列目にデータを移します③。なお１列目は区間のデータで「上書き」されますので、値のCopyで十分です。
最後に区間データを配列Countの１列目にデータCopy④します。その際、各配列のインデックスがズレているので注意します。
１２行目「ReDim Preserve Rank(0 To UBound(Rank, 1) + 1)」では、配列Rankの行数を１つ増やしています（図０６の①）。
１３行目「ReDim Preserve Count(1 To UBound(Count, 1), 1 To 2)」では、配列Countの列数を１つ増やしています（図０６の②）
区間データと度数データが１つの配列（配列Count）となりましたので、２０行目「Sheet1.Range("K2").Resize(UBound(Count, 1), UBound(Count, 2)) = Count」で、K2セルを左上セルとするセル範囲にデータを貼り付けます。この際、データのサイズと貼り付けセル範囲のサイズが合っている必要があるため、Resizeプロパティでセル範囲変更をしています。
出力された様子は図０７のようになります。

図０７別窓
この「区間と度数」を使えば、グラフを作成する　等の処理が行えます。
なお、ワークシート関数での度数結果と値が異なっていますが、これは元データを「Rand関数」でランダムに計算させているからで、出力データを貼り付けた時に再計算が行われ「元データの値が変更」されてしまったためです。通常の処理時には、このような事は無いと思ったので、このままとしました。

２ー３．区間をセル範囲で取得し度数計算

Sheet1のボタン２から呼び出されるのが図０８です。

30. '==========　⇩(2)　区間をセル範囲で取得し度数計算 ============
31. Sub vbaFreq2()
32. 　Dim Data As Variant 　　 '←元データの配列
33. 　Dim Rank As Variant 　　 '←区間データの配列
34. 　Dim Count As Variant 　 '←度数の配列
35. 　Dim i As Integer 　　　　 '←カウンタ変数（区間数）
36. 　Dim S As String 　　　　 '←メッセージボックス用の文字列
38. 　Data = Sheet1.Range("A2:A11").Value
39. '　Rank = Array(0, 10, 20, 30, 40, 50, 60, 70, 80, 90, 100)
40. 　Rank = Sheet1.Range("D2:D12").Value
42. 　Count = WorksheetFunction.Frequency(Data, Rank)
44. 　Rank = WorksheetFunction.Transpose(Rank)
45. 　ReDim Preserve Rank(1 To UBound(Rank, 1) + 1)
46. 　ReDim Preserve Count(1 To UBound(Count, 1), 1 To 2)
48. 　For i = 1 To UBound(Count, 1)
49. 　　Count(i, 2) = Count(i, 1)
50. 　　Count(i, 1) = Rank(i)
51. 　Next i
53. 　For i = 1 To UBound(Count, 1)
54. 　　S = S & Count(i, 1) & vbTab & Count(i, 2) & vbNewLine
55. 　Next i
57. 　MsgBox S
59. End Sub

図０８別窓
３８行目「Data = Sheet1.Range("A2:A11").Value」では、ワークシート上のデータ値を取得し、配列の形で変数Dataに代入しています。この部分は図０５の０７行目と全く同じです。
４０行目「Rank = Sheet1.Range("D2:D12").Value」では、内部で区間データを作る代わりに、ワークシート上のセル範囲から区間データを取得しています。セル範囲から取得しているため、その配列（配列Rank）は「二次元配列」で「インデックスは１始まり」となります。
４２行目「Count = WorksheetFunction.Frequency(Data, Rank)」で、Frequencyメソッドに元データ（配列Data）と区間データ（配列Rank）を指定することで、度数計算の結果が配列として得られます。引数として与える配列は「１次元配列でも２次元配列でも」OKですし、また「インデックスが何から始まっても」OKです。
４４～５１行目は図０６の「配列の結合処理」を行っている部分ですが、今回は配列Rankが「二次元配列」であり、また「インデックスは１始まり」のため、図０５の１２～１８行目の時とは少し変わります。
まず図０６の①の処理（配列Rankの要素を１つ増やす）ですが、配列Rankは二次元配列で「延ばしたい方向の次元が１次元目（行方向）」です。そのためReDimでは、そのまま延ばす訳にはいきません（二次元配列の１次元目を延ばそうとするとエラーとなります）。ですので４４行目「Rank = WorksheetFunction.Transpose(Rank) 」で、配列の縦横を回転させています。この場合回転後の配列は横方向となりますので「一次元配列」に変換されます。
４４行目でTransposeを使って縦横回転をさせた為、配列のインデックスは「１始まり（元々、セル範囲からの取得なので１始まり）」となるので、４５行目「ReDim Preserve Rank(1 To UBound(Rank, 1) + 1)」のReDimも「１始まり」で、要素を１つ増やしています。
４６行目「ReDim Preserve Count(1 To UBound(Count, 1), 1 To 2)」では、配列Countの列数を１つ増やしています。
５３～５５行目では、配列のデータをメッセージボックス用の文字列に変換させています。
５３行目「For i = 1 To UBound(Count, 1)」では、カウンタ変数ｉを配列Countの行数分だけ回します。
５４行目「S = S & Count(i, 1) & vbTab & Count(i, 2) & vbNewLine」では「区間データ ＋ TAB ＋ 度数データ ＋ 改行」を１行とするデータを作っています。先頭に「S &」を入れることで、どんどんと下につなげています。
文字列が完成したら５７行目「MsgBox S」でメッセージ表示させています。
なお、４８行目と５３行目のFor文は全く同じなので、５４行目の処理は５０行目の下に入れ込む事は可能です。
メッセージボックスが表示された様子は図０９のようになります。

図０９別窓

２ー４．区間を最大最小値から自動計算し度数計算

Sheet2のボタン３から呼び出されるのが図１０です。

70. '==========　⇩(3)　区間を最大最小値から自動計算し度数計算 ============
71. Sub vbaFreq3()
72. 　Dim Data As Variant 　　 '←元データの配列
73. 　Dim Rank As Variant 　　 '←区間データの配列
74. 　Dim Count As Variant 　 '←度数の配列
75. 　Dim i As Integer 　　　　 '←カウンタ変数（区間数）
77. 　Data = Sheet2.Range("A2:E11").Value
79. 　Rank = makeFreq(WorksheetFunction.Min(Data), WorksheetFunction.Max(Data))
81. 　Count = WorksheetFunction.Frequency(Data, Rank)
83. 　ReDim Preserve Rank(1 To UBound(Rank, 1) + 1)
84. 　ReDim Preserve Count(1 To UBound(Count, 1), 1 To 2)
86. 　For i = 1 To UBound(Count, 1)
87. 　　Count(i, 2) = Count(i, 1)
88. 　　Count(i, 1) = Rank(i)
89. 　Next i
91. 　UserForm1.ListBox1.ColumnCount = 2
92. 　UserForm1.ListBox1.List = Count
93. 　UserForm1.Show
95. End Sub

図１０別窓
７７行目「Data = Sheet2.Range("A2:E11")」では、ワークシート上のデータ値を取得し、配列の形で変数Dataに代入しています。今回は複数列のデータを取得していますが、この後の処理には変更はありません。
７９行目「Rank = makeFreq(WorksheetFunction.Min(Data), WorksheetFunction.Max(Data))」では、図１３のユーザー定義関数makeFreqを呼び出し、区間データを作成しています。引数には「データの最小値」「データの最大値」を指定するため、ワークシート関数のMaxとMinを使っています。
今回のmakeFreq関数で戻される区間配列は「一次元配列」で「インデックスは１始まり」としました。
８１行目「Count = WorksheetFunction.Frequency(Data, Rank)」で、Frequencyメソッドに元データ（配列Data）と区間データ（配列Rank）を指定することで、度数計算の結果が配列として得られます。
８３行目「ReDim Preserve Rank(1 To UBound(Rank, 1) + 1)」では、配列Rankの要素を１つ増やしています。
８４行目「ReDim Preserve Count(1 To UBound(Count, 1), 1 To 2)」では、配列Countの列を１つ増やしています。
８６行目「For i = 1 To UBound(Count, 1)」は、カウンタ変数ｉを配列Countの行数分だけ回します。
８７行目「Count(i, 2) = Count(i, 1)」では、度数値を１列目から２列目にコピーしています。
８８行目「Count(i, 1) = Rank(i)」では、配列Rankから区間データを配列Countにコピーしています。
区間と度数を合わせた配列は、今回はユーザーフォームのリストボックスにデータ表示させています。
今回のデータは「２列（区間＋度数）」ですので、リストボックスも２列対応させるため、９１行目「UserForm1.ListBox1.ColumnCount = 2」でColumnCountプロパティを変更させます。もちろんUserFormのフォームモジュールで、InitializeやActivateイベントを利用して変更してもOKです。
９２行目「UserForm1.ListBox1.List = Count」では、ListBoxに配列データを直接貼り付けています。
９３行目「UserForm1.Show」では、ユーザーフォームを表示させています。
ユーザーフォームを表示させた状態は、図１１のようになります。

図１１別窓

２ー４ー１．ユーザーフォームの準備

今回使用したユーザーフォームは、図１２のようにフォーム上にListBoxを１つ置いただけのものです。
フォームモジュールも今回は特に使用しませんでした。

図１２別窓

２ー４ー２．区間を自動計算するユーザー定義関数

図１０の７９行目から呼び出されるユーザー定義関数が図１３で、引数にはMin値とMax値を指定します。「指定したMin・Max値を含む範囲を、適当な間隔で区切った区間配列」を戻します。

100. '==========　⇩(4)　区間を自動計算する関数 ============
101. Function makeFreq(Mn As Double, Mx As Double) As Variant
102. 　Dim Bas As Variant 　　 '←キリの良い値の配列
103. 　Dim Diff As Double 　　 '←差（最大 - 最小）
104. 　Dim n As Integer 　　 '←移動した桁数
105. 　Dim j As Integer 　　 '←キリの良い値のインデックス値
106. 　Dim k As Integer 　　 '←戻す配列のインデックス値
107. 　Dim temp As Variant 　　 '←処理中の配列。最終的に戻り値になる
108. 　Dim buf As Double 　　 '←引数を逆転するための一時変数
109. 　Dim Ratio As Double 　　 '←区間の幅
111. 　Const Part As Integer = 10 　　 '←目標の分割数
112. 　Bas = Array(2, 5, 10) 　　 '←キリの良い値の配列
114. 　If Mx < Mn Then
115. 　　buf = Mx
116. 　　Mx = Mn
117. 　　Mn = buf
118. 　End If
120. 　Diff = Mx - Mn
121. 　Diff = Diff / Part
123. 　Select Case Diff
124. 　　Case Is > 10
125. 　　　For n = 1 To 10
126. 　　　　Diff = Diff / 10
127. 　　　　If Diff <= 10 Then Exit For
128. 　　　Next n
129. 　　Case Is <= 1
130. 　　　For n = -1 To -10 Step -1
131. 　　　　Diff = Diff * 10
132. 　　　　If Diff > 1 Then Exit For
133. 　　　Next n
134. 　End Select
136. 　For j = 0 To UBound(Bas, 1)
137. 　　If Diff <= Bas(j) Then Exit For
138. 　Next j
140. 　Ratio = Bas(j) * 10 ^ n
142. 　Mx = -1 * (Int(-1 * Mx / Ratio) * Ratio)
143. 　Mn = Int(Mn / Ratio) * Ratio
145. 　ReDim temp(1 To (Mx - Mn) / Ratio + 1)
147. 　For k = 1 To UBound(temp, 1)
148. 　　temp(k) = Mn + ((k - 1) * Ratio)
149. 　Next k
151. 　makeFreq = temp
152. End Function

図１３別窓
この関数考え方は図１４のようになります。引数として受け取るのがMin値（コード内ではMn）とMax値（同Mx）の２つで、その値を加工していきます。なお、図１４内の黄色部分「目標の分割数（同Part）」「キリの良い値の配列（同Bas）」は、内部定数相当です。

図１４別窓
まず引数として受け取る最小値（図１４でのMin）・最大値（同Max）を使って差を求め、目標の分割数で割ります。この値が「区間の間隔」に近い値になるはずです。
但し区間の間隔値は何でも良い訳ではありません。例えば0～19の間を「3飛び」で刻むとすると「0,3,6,9,12,15,18,21」となり、桁が変わる時にキリの良い値になってくれません。それよりは「2飛び（0,2,4,6,8,10,12,14,16,18,20）」や「5飛び（0,5,10,15,20）」で刻んだ方が分かり易そうです。そこで今回は「10の約数（1, 2, 5, 10 ）」をキリの良い数字としました。
しかし区間とすれば「5飛び」だけでなく「50飛び」「500飛び」等があり得ますから、区間の間隔を10ⁿで乗算・除算をして整数部分を１桁の値（１超～１０以下）にしてから、キリの良い数字と比較するようにしています。
キリの良い数字が見つかったら、その数値になるように最小値・最大値を丸め（元の最小値・最大値を含むような範囲にする）、最後に丸めた最小値・区間幅・最大値を使って配列の形に並べ、戻り値とします。
１１１行目「Const Part As Integer = 10」は、目標分割数です。この値を大きくすると細かく分割されます。
１１２行目「Bas = Array(2, 5, 10)」は、キリの良い数字を配列の形にしています。今回は「1超の値」に加工してから比較を行っていますので、10の約数とは言っても1は除いています。
１１４～１１８行目は、引数の最小値・最大値を逆に指定されてしまった時に、引数値を入れ替えています。もし逆のままだと、処理後の最小値・最大値の値がおかしくなり、また戻り値の配列作成時（１４５行目）にエラーが発生します。
１１４行目「If Mx < Mn Then」で逆転有無を確認し、逆転している場合は１１５行目「buf = Mx」で一時変数bufに第二引数値（本当は最小値）を格納します。その後１１６行目「Mx = Mn」で、変数Mxに第一引数（本当は最大値）をコピーし、１１７行目「Mn = buf」で変数Mnに一時変数値（本当の最小値）を入れ直します。
１２０行目「Diff = Mx - Mn」では、引数の最小値・最大値から、その差を計算し変数Diffに代入しています。
１２１行目「Diff = Diff / Part」では、その差を「目標の分割数」で除算し、その結果を変数Diffに入れ直しています。
１２３～１３４行目では10ⁿで乗算・除算をして整数部分が１桁（1超～10以下）になるように処理をしています。なお、その処理に使ったn値（何乗したか）は、１４０行目で区間幅の計算式に使います。
１２３行目「Select Case Diff」では変数Diffの大きさを調べています。10を超えている場合は１２５～１２８行目を実行し、1以下の場合は１３０～１３３行目を実行します。
10を超えている場合（１２４行目「Case Is > 10」）は、１２５行目「For n = 1 To 10」でカウンタ変数nを回しています。
１２６行目「Diff = Diff / 10」では、変数Diffを１０で割り、変数Diff値を置き換えています。そして１２７行目「If Diff <= 10 Then Exit For」で１０以下になったか否かを調べ、まだ10超ならば再び１２６行目の10で割る処理を行います。一方１０以下ならばFor文を抜け出します。この抜け出した時のn値が「元のDiff値」との比という事になります。１０回で終了してしまうため、ゼロが１０個の「999億」が差の上限ということになります。
一方、1以下の場合（１２９行目「Case Is <= 1」）は、１３０行目「For n = -1 To -10 Step -1」でカウンタ変数nを-1から-10まで逆方向に回します。１２５行目の1から10までを回すのとは別にしているのは、「n値のみで元のDiff値の桁を減らしているのか増やしているのか」が分かるようにするためです。
１３１行目「Diff = Diff * 10」では、変数Diffに１０を掛けて、変数Diff値を置き換えています。１３２行目「If Diff > 1 Then Exit For」ではDiff値が1を超えた時にFor文を抜け出しています。
こちらも10回でFor～Nextを終了させているので、差の下限は「0.000000001」という事になります。
変数Diffの整数部分が１桁（1超～10以下）になったら、１３６～１３８行目で「最適なキリの良い数字」を見つけます。
１３６行目「For j = 0 To UBound(Bas, 1)」で、配列Bas（キリの良い数字の配列）の要素数だけ、カウンタ変数ｊを回します。
１３７行目「If Diff <= Bas(j) Then Exit For」で、適するキリの良い値が見つかったら、For文を抜け出します。抜け出した時の「Bas(j)値」がキリの良い値となります。
１４０行目「Ratio = Bas(j) * 10 ^ n」では、１２３～１３４行目のカウンタ変数nと、１３６～１３８行目で選択したキリの良い値 Bas(j) を使い「区間の幅」を計算します。
１４２～１４３行目は、引数で得た最小値・最大値を、切り上げ・切り捨てをして「キリの良い数値」に丸めます。この「切り上げ」「切り捨て」の計算にはちょっと工夫が必要です。
まず今回の目的は、引数で得た「最小値・最大値を含む範囲」を取得することです。図１５で言えば、最小値・最大値を広げ（≒切り上げ・切り捨て）て、黄色い範囲を決めます。これは、最大値・最小値がプラス側でもマイナス側でも同じです。

図１５別窓
この「切り上げ」「切り捨て」に良く使われる関数は「RoundUp」「RoundDown」です。「切り捨て」として使われる「Int関数」も併せて、その特性を図１６に並べました。

図１６別窓
図１６でも分かるように、各関数に値を指定した場合の移動方向は以下の通りです。

RoundUp	ゼロから離れる方向に動く
RoundDown	ゼロに近づく方向に動く
Int	値が減る方向（－∞の方向）に動く

最小値・最大値のプラスマイナスを調べてから処理の分岐をすれば、どの関数でも使えますが、場合分けをせずに図１５の動きに合わせる方法が、１４２～１４３行目のInt関数を使う方法です。
１４２行目「Mx = -1 * (Int(-1 * Mx / Ratio) * Ratio)」では、一旦最大値のプラスマイナスを逆転させた上でInt計算をしています。最大値がプラスだった場合は絶対値が大きい側に動き、最後に-1を掛けることでプラス側の大きい側（＋∞側）となります。
一方最大値がマイナスの場合は絶対値が小さい側に動き、最後に-1を掛けることで、やはり＋∞側に動くことになります。
なお変数Ratioで割ったり掛けたりしているのは、動きを「区間の幅の単位で動かす」ためです。
また１４３行目「Mn = Int(Mn / Ratio) * Ratio」では、Intで値を単純に左方向（－∞側）に動かすことで、最小値を含む範囲となるようにしています。
最小値・最大値がキリの良い数値となりましたので、１４５行目「ReDim temp(1 To (Mx - Mn) / Ratio + 1)」では、戻り値となる配列を作ります。最小値と最大値の差を区間の幅（変数Ratio）で割った値が要素数になります。
１４７～１４９行目では、作った配列に区間値を入れていきます。
１４７行目「For k = 1 To UBound(temp, 1)」では、カウンタ変数kを配列tempの要素数だけ回します。
１４８行目「temp(k) = Mn + ((k - 1) * Ratio)」では、最小値（変数Mn）からスタートし、区間幅（変数Ratio）を加えていきます。最後の要素は最大値（変数Mx）と同じ値が入ります。
配列tempが完成したら、１５１行目「makeFreq = temp」で、関数プロシージャの戻り値に設定し終了します。

３．まとめ

データ分析として区間別に度数分布グラフを作る手法は基本です。しかしその元データをExcelで作るには、Frequency関数を作り「Ctrl＋Shift＋Enterキー」という非常にやっかいな手順が必要でした。私も最初にその手順を教えてもらった時には「なんでこんなに面倒なの？」と感じたことを覚えています。
最新Excelではスピル機能により、ようやく入力が楽になってきましたが、Excelのバージョンを上げる必要もあるので、浸透するにはまだまだ時間がかかりそうです。
今回のVBA内で使用するFrequencyメソッドは、そんなやっかいさを少しでも解消したいという思いもあり紹介しました。グラフ化がとりあえずの目標であれば、最初からワークシート上のみで完結させた方が良いのかもしれません。しかしVBAを含めた様々な手法の知識があれば、少しでも使い易くなったり、更なる改善が出来たりするのでは　と思います。
また、自動で区間データを作る関数も紹介しましたが、最終的には人が目的的に「最小・最大・区間幅」を決めるものだと思います。それでも初回は「まずはデータの様子を見る」ことからスタートするはずですので、その一助になればと思います。

アプリ実例・関連する項目

「設備の稼働状態記録とデータ集計」

サンプルファイル

VBAの配列で使うFrequencyメソッド（its-040.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。

サンプルファイルのシート上には、動的配列数式も書き込んでいますが、スピル機能の無いバージョン（Microsoft365・Excel2021以前）で開くと「通常の配列数式」として見えることになります。機能上は同じです。