2022/07/19

設備の稼働状態を入力し、グラフで確認

• １．背景
• ２．システム概要
• ３．プログラムの流れ
• 　３－１．入力した稼働状態の記録
• 　　よりみち（SQL文の発行回数低減）
• 　３－２．稼働状態グラフの表示（画像ファイル貼付け方式）
• 　３－３．稼働状態グラフの表示（ラベルの色変更方式）
• ４．標準モジュール
• 　４－１．宣言部
• 　４－２．初期設定と起動
• 　４－３．DBファイル・テーブルの準備
• 　　よりみち（フォルダーが読取専用か否かの判断）
• 　４－４．DBファイル作成
• 　４－５．テーブルの作成
• 　４－６．SQL文の実行
• ５．フォームへの画像ファイル貼付け方式
• 　５－１．ワークシート
• 　５－２．ユーザーフォーム
• 　　５－２－１．フォーム上のコントロール類配置
• 　　５－２－２．フォームモジュール
• 　　　５－２－２－１．宣言部
• 　　　５－２－２－２．カスタムプロパティ
• 　　　５－２－２－３．フォームの初期化
• 　　　５－２－２－４．ボタンの作成
• 　　　５－２－２－５．時刻ラベルの作成
• 　　　５－２－２－６．コンボボックスの作成
• 　　　５－２－２－７．設備・日付の選択
• 　　　　よりみち（フォーム準備時のイベント処理）
• 　　　５－２－２－８．稼働状態ボタンの操作
• 　　　　よりみち（ボタン乱打でのオブジェクト処理ミスは）
• 　　　５－２－２－９．データの登録
• 　　　５－２－２－１０．対象日×選択設備の元のデータ取得
• 　　　５－２－２－１１．グラフデータ表示
• 　　　５－２－２－１２．シート上データを画像ファイル化
• ６．フォーム上ラベルの色変更方式
• 　６－１．ユーザーフォーム
• 　　６－１－１．フォーム上のコントロール類配置
• 　　６－１－２．フォームモジュール
• 　　　６－１－２－１．宣言部
• 　　　６－１－２－２．カスタムプロパティ
• 　　　６－１－２－３．フォームの初期化
• 　　　６－１－２－４．ボタンとラベルの作成
• 　　　６－１－２－５．コンボボックスの作成
• 　　　６－１－２－６．設備・日付の選択
• 　　　６－１－２－７．稼働状態ボタンの操作
• 　　　６－１－２－８．データの登録
• 　　　６－１－２－９．対象日×選択設備の元のデータ取得
• 　　　６－１－２－１０．グラフデータ表示
• ７．アドインとしてExcelにマクロを登録
• ８．最後に
• サンプルファイル

１．背景

設備の稼働状態を記録・管理することは、利益を上げるためだけでは無く、設備の健康状態を把握する上でも重要です。
その稼働状態を入力・表示するシステムについては、以前「設備の稼働状態記録とデータ集計」でも紹介しましたが、その時は、Excelワークシートを入力画面 兼 稼働状態表示画面とするもので、データも同じブック内へ保存するタイプでした。

今回紹介するのは、ユーザーフォーム上で入力および表示を行うシステムで、且つデータはデータベースファイル（Accessファイル）に保存するタイプとしました。これにより複数の担当者が同時作業できると共に、異なるExcelファイル（例えば、作業日報）を開いた状態でも入力・確認できることになります。

なお、フォーム上に稼働状態が見える形にする必要がありますが、その手法として当初は「稼働状態ごとの色別の時系列グラフ」をシート上に表示し、表示したグラフを「一旦画像ファイルに変換した後、フォーム上に表示」する手法を考えました。
しかし試してみると、まずフォームをモードレスで表示した場合には「Chartの更新がとても遅い（私のPCで約3秒）」ために、表示日付を移動させても「正しいグラフが表示されない」という結果になりました。誤表示率は100%です。
一方、フォームをモーダルで表示させると改善はされ「Chartの更新は速くなる」のですが、追いつかない場合もあり、誤表示率は20～30%というところです（アドイン状態では無く、xlsmの状態で動かすと一応正常に動きそう）。

そこでグラフを仲介するのは今回あきらめ、モードレスでもリアルタイムで反応してくれる「条件付き書式」を使って「時系列グラフ風なもの」を作り、それを「画像ファイルに変換後フォーム上に表示」させるものを今回の仕様としました。また、フォーム上に並べたLabelの背景色を変化させて「時系列グラフ風」に見せるものも併せて紹介します。

なお、AccessDBを使ったものとして、下記も併せて参照下さい。
「ExcelからAccessデータベースを作成・操作」
「Accessデータベースを使用した売上台帳」

２．システム概要

今回システムをアドイン登録し、そこから起動すると図２－１のようなフォームがモードレスで立ち上がります。なおサンプルファイルでは、Sheet1とSheet2の上にそれぞれボタンがありますので、それをクリックすると同様に起動します。
左側も右側もほぼ同じに見えますが、フォーム上の稼働状態グラフの作り方が全く異なります。

図２－１

左側は「フォームへの画像ファイル貼付け方式（Sheet1、UserForm1）」で、フォーム中央のグラフは「Imageコントロール」にグラフの画像を貼り付けています。
一方右側は「フォーム上ラベルの色変更方式（Sheet2、UserForm2）」で、フォーム上に「Labelコントロール」を24個並べてあり、その背景色をそれぞれ変えることでグラフに見えるようにしています。

フォーム上の各機能は図２－２及び図２－３のようになっています。

図２－２

No.	機能	詳細
①	設備名の選択	既に登録してある設備名のコンボボックスリストから選択
②	日付の選択	スクロールバーの左右スクロール矢印のクロックで１日ずつ移動。 選択した日付は上部Labelに表示。尚レール部クリックで１週間移動。
③	稼働状態を入力・変更	各時間帯に対応したボタン。今回は１ボタン／時間。 クリックのたび、無印→A→B→C→D→無印→･･･とトグル上に変化
④	変更した稼働状態を保存	稼働状態データを変更した場合にデータをAccessDBに保存。
⑤	稼働状態のグラフ	設備名×日付に対応した稼働状態をグラフ表示
⑥	フォーム終了	フォームを閉じる。閉じる際に自動保存はしていない。

図２－３

下図（図２－４）は、データをまだ入力していない状態から、データを入力する場面を表しています。
なお、今回設定した「設備の状態」は、「A=稼働、B=準備、C=故障、D=修理、無印=停止」の５つとしました。フォーム上に記載されている５種の説明Labelは手入力ですが、記号の「A、B、C、D、無印」はマクロ内で設定しており変更可能です。

図２－４

「未入力状態＝全日が停止状態」を初期状態としています。その初期状態から図２－４の左図のように「5:00～6:00は稼働（A）」というデータを入力するとします。
グラフ枠の下にある「無印のボタン」を１回クリック⑦すると、ボタンの文字は「A（稼働）」に変わります。ボタンはクリックするたびに「無印→A→B→C→D→無印→･･･」とトグル的に変わります。ダブルクリックのように連続クリックしてもOKです。

ボタンの値を変更した後、右上の「登録ボタン⑧」をクリックするとデータがAccessDBに登録され、中央のグラフが「ボタンの値に対応した色」に変わります⑨。
この「対応した色」は、画像ファイル貼付け方式（UserForm1）では「Sheet1の条件付き書式の背景色を手動で設定」していますが、ラベルの色変更方式（UserForm2）では、マクロ内に設定した色配列に従って色付けをしています。
（条件付き書式の色設定もマクロ側から可能ですが、コードが増えてしまうので、今回は手作業で設定しました。）

図２－４では未入力状態からのデータ入力でしたが、既に入力済みのデータを変更する際も、変更時間帯のボタンをクリックすることでトグル的に値が変わり、値変更後に「登録ボタン⑧」をクリックすることでデータが上書きされます。

なお、設備のコンボボックスと日付のスクロールバーの操作は通常の使い方と同じです。設備および日付を選択した時には、それに対応したグラフが表示されるようにしています。
また、今回のフォームは「モードレス」で起動されますので、他のExcelブックを操作しながらでも作業可能です。

３．プログラムの流れ

３－１．入力した稼働状態の記録

グラフの下の「状態ボタン」をクリックすることで、指定の設備×時間の「稼働状態」を設定します。その後でフォーム右上の「登録ボタン」をクリックした時の流れが図３－１になります。

図３－１

まずDBテーブルから、登録されている「設備稼働状態」を取得し、そのデータを「記号の配列」に格納します。その際「日付＋時刻」のデータは加工し、０,１,２,･･･と「正時」の整数値に直して配列のインデックスに置き換えます。もし対象時刻のデータが無い場合は「配列のその要素は空」になりますし、入力が初めての場合（設備×日付の組み合わせが無い）は、DBデータは空なので「全て空データの配列」となります。

その「記号の配列」とフォーム上の状態ボタンの値を１つ１つ比較し、「異なっていた場合」のみ、DBファイルへの処理を行います。SQL処理としては、元々データが無かった場合はInsertになりますし、元データがあった場合はUpdate、ボタンの値が「""（長さゼロの文字列）」だった場合はDeleteとなります。

なお、時刻を正時の整数にし２４行の配列（＝２４時間分）のインデックスにする理由は、２４個のボタンの位置と照合し易くするためであり、また配列値をそのままワークシートに貼り付けることが出来るからです。また図３－３のLabelの番号と照合する場合もコードが単純になります。

今回システムでは、ボタンは２４個（1時間に1個）あります。処理の方法として、単純に１つ１つのボタンの値に対し、DB内に同じ「設備×日付・時刻」のデータが有るか否か確認し、Insert・Update・Deleteをするというのがまず思い浮かびます。しかしその方法を実際にやってみると、１つのボタンに対し「データ有無確認 → データ処理」という２つのSQL文の実行が必要となりますので、ボタン２４個分（合計で約48回）で約6秒（私のPCで）かかってしまう結果となりました。 これではあまりにも遅く、SQL文の発行回数を減らすために「変更した箇所だけ、データを変更（新規・更新・削除）」することと併せ、「元の設備稼働状態」については、設備×日付で一括でデータを取得し配列化しておくことにしました。 その改善の結果、変更した箇所＋１回のSQL文の実行で完了できるようになり、遅くても３秒で処理が終わることとなりました。 （更に速くするには、複数のSQL文をまとめて実行するストアドプロシージャなどが考えられますが、今回は未トライです。）

３－２．稼働状態グラフの表示（画像ファイル貼付け方式）

稼働状態グラフを表示させるタイミングは、設備を選択し直した時、日付を変更した時、および登録処理をした後　となります。
まず、DBファイルから「設備稼働状態」を取得し、そのデータを記号の配列に格納します。これは上記の配列と同じもので、２４要素の配列となります。その配列をワークシートに値貼り付けます。
貼り付け先には「条件付き書式」が設定してあり、貼り付けた記号（今回だと、A・B・C・D）により彩色するようになっています（貼り付けた記号欄の一つ下の行も含めて、条件付き書式の適用先に設定）。

図３－２

条件付き書式で彩色されたセル範囲を画像としてコピーし、新たに作成したChart（グラフ）上に貼付け、Exportメソッドを使って実ファイル（今回はBMPファイル）にします。保存先は、とりあえずExcelファイルと同じ場所です。
その画像ファイルの保存先をフォームのImageコントロールに設定することで、グラフ画像（元は条件付き書式でまだらに彩色されたセル範囲）が表示されます。

３－３．稼働状態グラフの表示（ラベルの色変更方式）

フォーム上のLabelを使用する場合も、上記同様にDBファイルから「設備稼働状態」を取得し、そのデータを記号の２４要素の配列に格納します。

図３－３

その配列データを使って、フォーム上のLabel（２４個）の背景色を変更していきます。設定する背景色の指定は、マクロ内で初期設定されています。
なお、稼働状態グラフの下に並んだ「設定ボタン」の表面文字も同時に、記号の配列のデータを使って書き込みます。この作業は「画像ファイル貼付け方式」でも同じように行います。

４．標準モジュール

４－１．宣言部

標準モジュール先頭の宣言部では、システム内で使用する定数・変数の宣言を行っています。

0. '==========　⇩(1)　定数・変数の宣言　============
1. Public markArray As Variant 　　　　　　 '←稼働マーク一覧
2. Public ColorArray As Variant 　　　　　 '←マーク色一覧
3. Public MachineArray As Variant 　　　　 '←設備一覧
4. Public Const TBL As String = "MC_cond" 　　　 '←テーブル名(今回、テーブルは１つ)
5. Public Const SystemStartDay As Date = #1/1/2022# 　　 '←システム開始日
7. Private DBpath As String 　　　　　 '←データベースファイルのパス
8. Private Const DBname As String = "it-084.accdb" 　　 '←データベースファイルのファイル名
9. Public BMPpath As String 　　　　　 '←画像ファイルのパス
10. Public Const BMPname As String = "it-084.bmp" 　　　 '←画像ファイルのファイル名

図４－１

０１行目「Public markArray As Variant」では、稼働マーク（今回は、A・B・C・D）を格納する配列markArrayを宣言しています。マークを使用したのは「データベースに収めるデータとして、例えば『稼働』よりも『A』の方がデータ量が少ない」のもありますが、主は「状態ボタンに表示する文字列として、１文字の方がボタンを小さくできる」ためです。図４－２の２２行目でArray関数を使って値を代入しますので、Variant型としています。
０２行目「Public ColorArray As Variant」では、稼働マークごとの色番号を格納する配列ColorArrayを宣言しています。図４－２の２３行目でArray関数を使って値を代入します。
０３行目「Public MachineArray As Variant」では、設備名を格納する配列MachineArrayを宣言しています。図４－２の２４行目でArray関数を使って値を代入します。
０４行目「Public Const TBL As String = "MC_cond"」では、今回使用するテーブル名「MC_cond」を代用する定数TBLを宣言しています。テーブル名が気に入らない場合は、この定数値を変更するだけで、コード内のSQL文を修正する必要はありません。
０５行目「Public Const SystemStartDay As Date = #1/1/2022#」は、システムのスタート日を定数設定しています。但しこの定数は「日付設定のスクロールバーのValue値」で差引しているだけですので、システム運用後に変更しても問題ないはずです。スクロールバーのValue値を無駄に大きくしないために設定しました。

０７行目「Private DBpath As String」は、データベースファイルのパスの変数で、図４－２の２６行目で値を代入します。
０８行目「Private Const DBname As String = "it-084.accdb"」は、データベースファイルのファイル名の設定です。
０９行目「Public BMPpath As String」は、画像ファイル貼付け方式で使用する画像ファイル（拡張子.BMP）を置くパス位置の変数です。図４－２の２７行目で値を代入します。
１０行目「Public Const BMPname As String = "it-084.bmp"」は、画像ファイルのファイル名の設定です。

４－２．初期設定と起動

システム起動のプロシージャ（図４－３、図４－４）から呼び出される「システム変数への値代入」を行うのが図４－２です。

20. '==========　⇩(2)　システム設定　============
21. Private Sub SystemIni()
22. 　markArray = Array("", "A", "B", "C", "D")
23. 　ColorArray = Array(RGB(255, 255, 255), RGB(0, 0, 255), RGB(0, 128, 0), RGB(255, 0, 0), RGB(255, 255, 0))
24. 　MachineArray = Array("旋盤", "フライス盤", "裁断機")
26. 　DBpath = ThisWorkbook.Path & "¥" 　　　 '←データベースファイルのパス設定
27. 　BMPpath = ThisWorkbook.Path & "¥" 　　 '←画像ファイルのパス設定
28. End Sub

図４－２

２２行目「markArray = Array("", "A", "B", "C", "D")」は、４つの稼働マーク（A・B・C・D ）と、停止や未入力を表す無印を配列に代入しています。各マークの意味は、A=稼働、B=準備、C=故障、D=修理 としていますが、その紐付けはフォーム上の表示のみです。
２３行目「ColorArray = Array(RGB(255, 255, 255), RGB(0, 0, 255), RGB(0, 128, 0), RGB(255, 0, 0), RGB(255, 255, 0))」は上記マークの色を定めています。今回は、無印=停止･未入力=白色、A=稼働=青色、B=準備=緑色、C=故障=赤色、D=修理=黄色　としました。
２４行目「MachineArray = Array("旋盤", "フライス盤", "裁断機")」では、設備として３つを登録しています。この順番でコンボボックスのリストに表示されることになります。
なお通常であれば、設備名は別のテーブルに置き、設備番号などで本体のテーブルと結びつけるのでしょうが、今回は本体テーブルに直接設備名を書き込むタイプとしました。デメリットとしては、運用途中で設備名を変更した、設備を更新したが同じ設備名にした　などの時に、古いデータが取り出せなくなったり、新旧設備のデータが混じったりしてしまいますので、注意が必要です。

２６行目「DBpath = ThisWorkbook.Path & "¥"」は、DBファイルの場所を指定しています。ここでは、このExcelファイルと同じ場所にしていますが、実際にはファイルサーバー等の皆がアクセス可能な場所を設定する事になります。その場合には２６行目のように変数へのパス名代入でも良いのですが、図４－１の０７行目を定数宣言にしてパス名を設定すると良いと思います。
２７行目「BMPpath = ThisWorkbook.Path & "¥"」は、画像ファイル貼付け方式で使用する画像ファイルを置く場所の設定です。この設定は上記DBpathのようにファイルサーバー上でなくとも、自分だけのパス（アドインした場合には、アドインファイル先＝ThisWorkbook.Path）でもOKと思います。

「画像ファイル貼付け方式」でシステムを起動する場合は、図４－３を実行します。アドインに登録した場合のマクロ登録はこのプロシージャを登録します。なお、サンプルファイルではSheet1上のボタンにこのプロシージャが登録されています。

30. '==========　⇩(3)　フォーム１の起動　============
31. Public Sub SystemStart1()
32. 　Call SystemIni
33. 　Call CheckDB
35. 　UserForm1.Show 0
36. End Sub

図４－３

フォームの起動前に、３２行目「Call SystemIni」で図４－２を呼出し、システムで使用する変数の設定をします。
３３行目「Call CheckDB」では図４－５を呼び出し、DBファイル・テーブルの存在を確認した後、存在していない場合は作成する作業をします。
その後で３５行目「UserForm1.Show 0」でフォーム（UserForm1）をモードレスで起動します。なお作業に支障なければモーダルで起動してもOKです。

「ラベルの色変更方式」でシステムを起動する場合は、図４－４を実行します。アドインに登録した場合のマクロ登録はこのプロシージャを登録します。なお、サンプルファイルではSheet2上のボタンにこのプロシージャが登録されています。

40. '==========　⇩(4)　フォーム２の起動　============
41. Public Sub SystemStart2()
42. 　Call SystemIni
43. 　Call CheckDB
45. 　UserForm2.Show 0
46. End Sub

図４－４

４２行目「Call SystemIni」で図４－２を呼出し、システムで使用する変数の設定をします。
４３行目「Call CheckDB」では図４－５を呼び出し、DBファイル・テーブルの存在を確認し、存在していない場合は作成する作業をします。
その後で４５行目「UserForm2.Show 0」でフォーム（UserForm2）をモードレスで起動します。

４－３．DBファイル・テーブルの準備

図４－３の３３行目、図４－４の４３行目から呼び出される「DBファイル・テーブルの存在を確認し、存在していない場合は作成」するプロシージャが図４－５です。
加えて、指定したパスが違っていたり、ネットワークが繋がっていなかった場合にはコメントを出すようにもしています。

50. '==========　⇩(5)　DBファイル・テーブルの正常化　============
51. Private Sub CheckDB()
54. 　Select Case isMissingDB2
55. 　　Case 1
56. 　　　On Error Resume Next
57. 　　　　Call makeDB
58. 　　　　Call makeTable
59. 　　　　If Not Err.Number = 0 Then
60. 　　　　　MsgBox "DBファイルの指定フォルダが違っているか、読取専用の可能性があります"
61. 　　　　　End
62. 　　　　End If
63. 　　　On Error GoTo 0
64. 　　Case 2
65. 　　　Call makeTable
66. 　　Case 3
67. 　　　MsgBox "DBファイルの設定場所(サーバー名等)が違っているか､ネットワークが不通です"
68. 　　　End
69. 　End Select
70. End Sub

図４－５

５４行目「Select Case isMissingDB2」で図４－７を呼び出し、その戻り値によってCase分けをします。関数プロシージャ isMissingDB2の戻り値の内容は「0=テーブル正常、1=DBファイル無し、2=テーブル無し、3=サーバー名異常」となります。

戻り値が１の場合（５５行目「Case 1」）は、５６～６３行目を実行します。
この場合は「DBファイルが無い」ので、DBファイルを作成し、その中にテーブルを作る必要があります。ですので５７行目「Call makeDB」で図４－９を呼び出してDBファイルを作成し、５８行目「Call makeTable」で図４－１０を呼出してテーブルを作成します。

しかしDBファイルが作れない場合があります。その状況と検出方法を下記にまとめます。

No.	ｴﾗｰ内容	検出方法
1	PC内のPathが違う	ﾌｧｲﾙが作れない
2	ｻｰﾊﾞｰ先のPathが違う	Dir関数でｴﾗｰ発生
3	ﾌｫﾙﾀﾞｰが読取専用	ﾌｧｲﾙが作れない
4	ﾈｯﾄﾜｰｸが繋がらない	Dir関数でｴﾗｰ発生

図４－６

この表のNo.1・No.3の場合は図４－７内のDir関数では検出できず、５７行目でDBファイルを作成する時に初めてエラーが発生します。ですので５６行目「On Error Resume Next」でエラー発生時でもスルーさせ、５９行目「If Not Err.Number = 0 Then」で検出をし６０行目「MsgBox "DBファイルの指定フォルダが違っているか、読取専用の可能性があります"」でコメントを出します。指定の場所にDBファイルが無く、また作ることも出来ませんので、今回システムを使うことが出来ずに６１行目「End」でマクロを終了させます。Endステートメントが実行されると、それ以降のコードが実行されませんので、フォームは起動しないことになります。

戻り値が２の場合（６４行目「Case 2」）は「DBファイルの存在は確認できたがテーブルが無い」場合です。
ですので６５行目で図４－１０のmakeTableを呼出してテーブルを作成します。
この際、DBファイルの存在までは確認できているため、指定したDBファイルのパス名＋ファイル名は正しく、またネットワークも繋がっている状態と判断できます。残りは図４－６のNo.3のフォルダーが読取専用か否かですが、このシステムで前回少なくともDBファイルが作れたのであれば、（その後、そのフォルダーを読取専用に変えたとは考えにくいため）テーブルも作れるだろうと判断し５６行目のような「On Error Resume Next」でのエラー回避は設けませんでした。
その心配がある場合は、エラー回避とコメントの設定をして下さい。

戻り値が３の場合（６６行目「Case 3」）は、図４－６のNo.2・No.4の場合です。
この場合は、６７行目「MsgBox "DBファイルの設定場所(サーバー名等)が違っているか､ネットワークが不通です"」でコメントを出し、６８行目「End」でマクロを終了させます。

図４－５の５４行目から呼び出される「DBファイル・テーブルの存在などを調べる」のが図４－７です。
調べた結果は以下のように戻り値として返します。
　戻り値：0=テーブル正常、1=DBファイル無し、2=テーブル無し、3=サーバー名異常

80. '==========　⇩(6)　DBファイル・テーブルのチェック　============
81. Private Function isMissingDB2() As Integer
82. 　Dim Cat As Object 　 '←Catalogオブジェクト
83. 　Dim T As Object 　　 '←Tableオブジェクト
85. 　On Error Resume Next
86. 　　If Dir(DBpath & DBname) = "" Then
87. 　　　If Err.Number = 0 Then
88. 　　　　isMissingDB2 = 1 　 '←DBファイルが無い
89. 　　　Else
90. 　　　　isMissingDB2 = 3 　 '←サーバー名が違う。ネットワーク不通
91. 　　　End If
92. 　　　Exit Function
93. 　　End If
94. 　On Error GoTo 0
96. 　Set Cat = CreateObject("ADOX.Catalog")
97. 　Cat.ActiveConnection = "Provider=Microsoft.Ace.OLEDB.12.0;" & _
98. 　　　　　　　　　　　　　　"Data Source=" & DBpath & DBname
100. 　For Each T In Cat.Tables
102. 　　If T.Type = "TABLE" Then
103. 　　　If T.Name = TBL Then
104. 　　　　isMissingDB2 = 0 　 '←指定のテーブルが存在する
105. 　　　　Exit Function
106. 　　　End If
107. 　　End If
109. 　Next T
111. 　isMissingDB2 = 2 　 '←テーブルが無い
113. 　Set Cat = Nothing
114. End Function

図４－７

まず、８６行目「If Dir(DBpath & DBname) = "" Then」でDBファイルの存在を確認します。Dir関数で得られる情報を図４－６よりももう少し細かく見てみます（図４－８）。

No.	状況	Dirでの結果
1	存在しないﾄﾞﾗｲﾌﾞ名を指定	""(長さ0文字列)
2	実在ﾄﾞﾗｲﾌﾞ名＋存在しないﾌｫﾙﾀﾞ名	""(長さ0文字列)
3	存在しないｻｰﾊﾞｰ名を指定	ｴﾗｰ番号=52
4	実在ｻｰﾊﾞｰ名＋存在しないﾌｫﾙﾀﾞｰ名	ｴﾗｰ番号=52
5	ﾌｫﾙﾀﾞｰが読取専用	無関係
6	ﾈｯﾄﾜｰｸが繋がらない	ｴﾗｰ番号=52
7	Pathは存在するが､ﾌｧｲﾙは存在せず	""(長さ0文字列)
8	Pathは存在し､ﾌｧｲﾙも存在する	ﾌｧｲﾙ名を戻す

図４－８

図４－８で分かるように、Dir関数での結果は３種類です。
１つ目は、No.8の「調べているファイルが存在する」場合です。８６行目のIf文は「 = ""」ですからこのIf文には引っ掛からずに９６行目以降（テーブルの存在確認）を実行することになります。
２つ目は、エラーが発生するNo.3～4の「サーバー先が違う」またはNo.6の「ネットワークが繋がっていない」場合です。この場合、まず８５行目「On Error Resume Next」でDir関数で発生するエラーを回避させ、８７行目「If Err.Number = 0 Then」でエラー時は９０行目「isMissingDB2 = 3」で関数戻り値を３（＝サーバー名異常）にセットして９２行目「Exit Function」で関数プロシージャを抜け出します。
３つ目はNo.7の「ファイルが存在しない」場合です。この場合はエラーは出ませんので、８７行目「If Err.Number = 0 Then」で分岐し、８８行目「isMissingDB2 = 1」で関数戻り値を１（＝DBファイルが無い）にセットして９２行目「Exit Function」で関数プロシージャを抜け出します。
但しNo.1～2の「ドライブ名やフォルダー名が違う」場合にも、ファイルが存在しない時と同じ戻り値となってしまいますので、図４－５の５６～６３行目でファイルを実際に作成する際にエラーが出たら「ドライブ名やフォルダー名が違っていた」と判断するようにしています。

なおNo.5のフォルダーが読取専用か否かはDir関数からでは見分けがつきません。ですので、ファイルが無くて図４－５でファイル作成時にエラーが出た時に「ああ、読取専用だった」と分かります。またファイルがあっても読取専用の時には、今回システムではエラー処理をしていませんので実行時エラーが発生する可能性はあります。 それならばと、図４－５の６５行目の「Call makeTable」にエラー処理を加えて・・・という対策をしても不十分です。６５行目を実行するのは「DBファイルは存在＋テーブルが無い」場合ですので、「DBファイルは存在＋テーブルも存在」する場合には、SQLによるデータ書込み時になって初めて発覚するのです。 今回は「知らない間に、フォルダーを読取専用に切り替えられてしまうことは稀だろう」と考え、「DBファイルが以前作れたのだから、テーブルも書き込むことが可能」との考え方で進めています。もし「絶対にエラーでは止めない！」という方針であれば、色々な場所に更にエラー処理を追加する必要がありますが、それと併せて「知らない間に変更」されないように、サーバー管理基準と変更情報の展開についてもチェックした方が良いかもしれません。

９６行目以降は、DBファイルの存在が確認できた上での処理となります。
９６行目「Set Cat = CreateObject("ADOX.Catalog")」では、ADOXのCatalogオブジェクトを生成し、９７～９８行目「Cat.ActiveConnection = "Provider=Microsoft.Ace.OLEDB.12.0;" & "Data Source=" & DBpath & DBname」でACE系のプロバイダで、DBファイルに接続します。

１００行目「For Each T In Cat.Tables」では、接続したDBファイルのテーブルを１つ１つ取り出して行きます。AccessのDBファイル内には、データを入れるテーブル（Type = TABLE）の他にSYSTEM TABLEなどがありますので、１０２行目「If T.Type = "TABLE" Then」で選り分けます。この時に "TABLE" は全て半角大文字である必要があり、「Table」などと書くと引っ掛かってくれないので注意が必要です。
１０３行目「If T.Name = TBL Then」は、１０２行目で選り分けた「データのテーブル」の中に「今回システムのテーブル（図４－１の０４行目で設定したMC_condテーブル）」が存在するかを確認しています。そして今回システムのテーブルが見つかった時には１０４行目「isMissingDB2 = 0」で戻り値をゼロ（＝テーブル正常）に設定し、１０５行目「Exit Function」で関数プロシージャを抜け出します。
なお、今回システムではテーブルを１つしか使用しないため、確認するテーブルも１つですが、もし複数ある場合は「Accessデータベースを使用した売上台帳」のように複数のテーブルを１つ１つ潰し込んでいくような手法が必要になります。

１００～１０９行目のFor Each～Nextでテーブルを全て調べた結果、今回システムのテーブルが見つからなかった時には１１１行目「isMissingDB2 = 2」が実行され、戻り値として２（＝テーブル無し）が設定されます。

４－４．DBファイル作成

図４－５の５７行目から呼び出される「DBファイルを作成」するプロシージャが図４－９です。

120. '==========　⇩(7)　DBファイル作成　============
121. Private Sub makeDB()
122. 　Dim Cat As Object 　　　 '←Catalogオブジェクト
124. 　Set Cat = CreateObject("ADOX.Catalog")
125. 　Cat.Create "Provider=Microsoft.Ace.OLEDB.12.0;" & _
126. 　　　　　　　"Data Source=" & DBpath & DBname
128. 　Set Cat = Nothing
129. End Sub

図４－９

１２４行目「Set Cat = CreateObject("ADOX.Catalog")」で、ADOXのCatalogオブジェクトを生成します。
１２５行目「Cat.Create "Provider=Microsoft.Ace.OLEDB.12.0;" & "Data Source=" & DBpath & DBname」では、Ace系のプロバイダを使い、DBファイルのパス＋ファイル名（DBpath & DBname）を指定して、AccessのDBファイルを作成（Create）します。

４－５．テーブルの作成

図４－５の５８行目、６５行目から呼び出される「テーブルを作成」するプロシージャが図４－１０です。

140. '==========　⇩(8)　テーブル作成　============
141. Private Sub makeTable()
142. 　Dim sql As String 　　　 '←SQL文
144. 　sql = "Create Table " & TBL & " (" & _
145. 　　　　"DT DATETIME," & _
146. 　　　　"MC STRING," & _
147. 　　　　"Cond STRING," & _
148. 　　　　"PRIMARY KEY (DT,MC)" & _
149. 　　　　")"
150. 　Call SQL_exec6(sql)
152. End Sub

図４－１０

１４４～１４９行目がテーブルを作成するSQL文です。
１４４行目「sql = "Create Table " & TBL & " (" & _」で変数TBL（図４－１の０４行目で設定したテーブル名 MC_cond ）のテーブルを作成します。今回システムのテーブルは、図４－１１のような構造です。

図４－１１

まず、１４５行目「"DT DATETIME," & _」でDT列をデータ型DATETIME（日付/時刻型）で作成し、１４６行目「"MC STRING," & _」でMC列をデータ型STRING（文字列型）で作成し、１４７行目「"Cond STRING," & _」でCond列をデータ型STRING（文字列型）で作成します。
制約は「DT列＋MC列のセットでPRIMARY KEY」ですので、１４８行目「"PRIMARY KEY (DT,MC)" & _」でカッコ内に２つの列名を列記して設定します。２列セットでの制約ですので、DT列の値が同じでもMC列の値が異なればOKとなります。
例えば「7月7日の10時＋旋盤」と「7月7日の10時＋フライス盤」は、DT列は同じ値ですがMC列が異なるために共存できることになりますし、「7月7日の10時＋旋盤」と「7月7日の11時＋旋盤」も共存できます。

SQL文が出来たら、１５０行目「Call SQL_exec6(sql)」で図４－１２を呼出し、Create文を実行してテーブルを作成します。

４－６．SQL文の実行

DBファイル・テーブルに接続し、SQL文を実行するのが図４－１２です。引数としてSQL文を受け取ります。

160. '==========　⇩(9)　SQL文の実行　============
161. Public Function SQL_exec6(sql As String) As Variant
162. 　Dim cn As Object 　　　　 '←Connectionオブジェクト
163. 　Dim rs As Object 　　　　 '←Recordsetオブジェクト
164. 　Dim i As Long 　　　　　　 '←カウンタ変数(行数)
165. 　Dim j As Integer 　　　　 '←カウンタ変数(列数)
166. 　Const adOpenStatic = 3 　 '←カーソル状態の定数値
167. 　Dim buf() As Variant 　　 '←戻り値の配列
169. 　Set cn = CreateObject("ADODB.Connection")
170. 　Set rs = CreateObject("ADODB.Recordset")
172. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
173. 　cn.Open DBpath & DBname
174. 　　rs.Open sql, cn, adOpenStatic
176. 　　If Not rs.State = 0 Then
177. 　　　ReDim buf(0 To rs.RecordCount, 1 To rs.Fields.Count)
179. 　　　For j = 1 To rs.Fields.Count
180. 　　　　buf(0, j) = rs.Fields(j - 1).Name
181. 　　　Next j
183. 　　　Do Until rs.EOF
184. 　　　　i = i + 1
185. 　　　　For j = 1 To rs.Fields.Count
186. 　　　　　buf(i, j) = IIf(IsNull(rs.Fields(j - 1).Value), "", rs.Fields(j - 1).Value)
187. 　　　　Next j
188. 　　　　rs.MoveNext
189. 　　　　DoEvents: DoEvents
190. 　　　Loop
192. 　　　SQL_exec6 = buf
193. 　　　rs.Close
194. 　　End If
195. 　cn.Close
197. 　Set rs = Nothing
198. 　Set cn = Nothing
199. End Function

図４－１２

１６９行目「Set cn = CreateObject("ADODB.Connection")」では、ADOのConnectionオブジェクトを生成します。
１７０行目「Set rs = CreateObject("ADODB.Recordset")」では、ADOのRecordsetオブジェクトを生成します。

１７２行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、Ace系のプロバイダを設定します。
１７３行目「cn.Open DBpath & DBname」で、DBファイルを開きます。
１７４行目「rs.Open sql, cn, adOpenStatic」で、引数で得たSQL文を実行します。その時のカーソルとして、Select文で得た行数を取得できる静的カーソル（adOpenStatic）を指定します。どのカーソルを指定すれば良いかについては「Accessデータベースを使用した売上台帳」を参照下さい。
なお今回はCreateObjectを使った実行時バインディングを使用していますので、定数adOpenStaticは有効になっていません。ですので１６６行目「Const adOpenStatic = 3」で定数宣言をしています。

１７６行目の、「rs.Open」を実行した後のRecordset（rs）の状態は、実行するSQL文で違います。
Insert文、Update文、Delete文の場合は、rs.Openでテーブルへの操作が完了し、Recordsetは閉じてしまいます。一方Select文の場合は、指定したレコードからデータを取り出すために、rs.Open直後はRecordsetは開いている状態です。

そのRecordsetの状態を１７６行目「If Not rs.State = 0 Then」で取得し、開いている（＝Select文）場合だけ１７７～１９３行目の「データを取り出す作業」を行います。RecordsetオブジェクトのStateプロパティは図４－１３のようになっています。

Recordset.Stateプロパティ

定数	値	内容
adStateClosed	0	閉じている
adStateOpen	1	開いている
adStateConnecting	2	接続中
adStateExecuting	4	コマンド実行中
adStateFetching	8	行を取得中

図４－１３

まず１７７行目「ReDim buf(0 To rs.RecordCount, 1 To rs.Fields.Count)」で、データを格納する配列のサイズを定めます。静的カーソル（adOpenStatic）でRecordsetを開きましたので、行数はRecordCountプロパティで取得が可能ですし、列数はFields.Countで得られます。
なおデータは１行目から格納するのですが、ゼロ行目から設定しています。その理由は「Selectの結果が何行であっても、配列を二次元の状態に保ち、後の処理を楽にする」ためで、詳細は「Accessデータベースを使用した売上台帳」を参照願います。

１７９～１８１行目のFor～Nextでは、配列のゼロ行目に「配列の列タイトル」として列名を代入します。なお、今回システムではゼロ行目の列名は利用しないため、実行しなくてもOKです。
１７９行目「For j = 1 To rs.Fields.Count」でカウンタ変数ｊを列数分だけ回し、１８０行目「buf(0, j) = rs.Fields(j - 1).Name」でゼロ行目に列名（.Name）を書き込んでいます。

１８３～１９０行目のDo～Loopでは、取得したレコードデータを配列に格納しています。
１８３行目「Do Until rs.EOF」では、レコードが無くなる（EOF = End of File）までDo～Loopを回します。
１８４行目「i = i + 1」は、行位置を１つずつ移動していきます。配列の代入前にカウンタ変数ｉを増やしますので、最初のレコードがｉ＝１となります。
１８５行目「For j = 1 To rs.Fields.Count」では、列位置のカウンタ変数ｊを列数分だけ移動していきます。
１８６行目「buf(i, j) = IIf(IsNull(rs.Fields(j - 1).Value), "", rs.Fields(j - 1).Value)」は、配列の各要素にデータを代入していきます。なお完成した配列内にNullが入っていると、Listに貼り付ける時などにエラーが発生しますので、配列に代入する前にIIFを使って「データがNullの時には、長さゼロの文字列に変換」をしてます。
１８８行目「rs.MoveNext」は、カーソル位置を次のレコードに移動します。

配列にデータの格納が完了したら、１９２行目「SQL_exec6 = buf」でこの関数プロシージャの戻り値に設定します。
１９３行目「rs.Close」ではRecordsetを閉じます。なお、Insert文などではrs.Openの直後に閉じた状態になりますので、更にCloseメソッドを実行しようとするとエラーが出ます。rs.Closeをして良いのはSelect文だけですので注意が必要です。

５．フォームへの画像ファイル貼付け方式

５－１．ワークシート（Sheet1）

Sheet1上に「設備状態グラフの元」を条件付き書式を使って作成します。
図５－１のように、データの貼り付けセルは３行目（C3～Z3セル）、グラフの元となるセル範囲は４行目（C4～Z4セル）としました。

図５－１

そしてその両方の範囲（C3～Z4セル）に対して、図５－２のように条件付き書式を設定します。数式は、例えば状態が「稼働（記号＝A）」であれば「= C$3 = "A"」と列単位で働く数式とし、数式が成立した時は図４－２の２３行目で設定した色と同じ背景色（稼働であれば青色）になるようにします。

図５－２

今回システムでは、稼働状態は５つ（停止・稼働・準備・故障・修理）ですが、停止（＝未入力）の白色は「何も背景色のないセル色」ですので、条件付き書式のどの数式にも当てはまらない場合はセル色（≒白色）としています。
但しユーザーの設定環境によっては、標準のセルに色が付いている場合があります。その場合は条件付き書式のルールを１つ増やし、「= C$3 = ""」の数式で背景色を白色にするなどの対応が必要となります。

５－２．ユーザーフォーム（UserForm1）

５－２－１．フォーム上のコントロール類配置

フォームには、上部にユーザーが選択する「設備名のComboBox」と「日付のScrollBar」を配置し、ScrollBarの上に日付を表示するLabelを置きます。また右上には登録と終了の２つのCommandButtonを置きます。

図５－３

フォーム中央にはImageコントロールを置きます。Imageが設備状態グラフになります。Imageの上と下には少しスペースを空けておき、Imageの下には状態ボタンを、Imageの上には時刻のLabelをマクロから生成します。生成するボタンやLabelは、Imageコントロールの位置と幅に合わせて作成しますので、例えば幅を少なくしてしまうとボタンの表示がおかしくなる可能性があります。

また今回は「フォーム自体の大きさ」を調整していません。例えば縦方向が少ないとボタンがフォームからはみ出してしまう可能性もあります。もし自由にボタンを作成・配置するようなアプリを作る場合は、ボタンの大きさ・数からフォームの大きさを計算しサイズを自動調整するような工夫が必要と思います。

５－２－２．フォームモジュール

５－２－２－１．宣言部

フォームモジュール先頭では、フォーム内で使用する変数の宣言、およびマクロで作成する状態ボタンのイベントを使用するための宣言をします。

210. '==========　⇩(10)　モジュールレベル変数の宣言　============
211. Private WithEvents myButton As MSForms.CommandButton
212. Dim Barray() As New UserForm1
213. Dim EventOFF As Boolean

図５－４

２１１行目「Private WithEvents myButton As MSForms.CommandButton」は、makeButton（図５－１１）で作成する「状態を入力する２４個のCommandButton」をクリックした時にClickイベントを取得するためのWithEvents宣言です。
２１２行目「Dim Barray() As New UserForm1」は、状態ボタンを２４個作成しますが、どのボタンが押されたかを把握する目的で、１つ１つのボタンにインデックスを登録するための配列の宣言です。ButtonのArrayという意味で命名しました。

設備名選択のComboBoxや日付選択のScrollBarには、操作した時に反応するためのイベントを仕込んでいます。しかし、ComboBoxやScrollBarの準備段階ではイベントに反応して欲しく無いので、イベントを中断させるための変数として２１３行目「Dim EventOFF As Boolean」でフラグ変数を宣言しています。

５－２－２－２．カスタムプロパティ

作成したボタンのプロパティ値を取得する時に呼び出すのが図５－５です。
２２２行目「Set Button = myButton」で、作成したボタン（myButton）のプロパティを呼出し先に戻しています。

220. '==========　⇩(11)　ボタンのプロパティ値を取得　============
221. Public Property Get Button() As Control
222. 　Set Button = myButton
223. End Property

図５－５

ボタンのオブジェクトを設定するのが図５－６です。引数として「オブジェクトへの参照である変数addBTN」を受け取ります。２３２行目「Set myButton = addBTN」で、受け取ったオブジェクトをボタンに設定します。

230. '==========　⇩(12)　ボタンのオブジェクトを設定　============
231. Public Property Set Button(ByVal addBTN As Control)
232. 　Set myButton = addBTN
233. End Property

図５－６

５－２－２－３．フォームの初期化

フォームの起動時にまず実行されるのが、図５－７のInitializeイベントです。

240. '==========　⇩(13)　Initializeイベント　============
241. Private Sub UserForm_Initialize()
242. 　Me.CommandButton1.Caption = "登録"
243. 　Me.CommandButton2.Caption = "終了"
245. 　Me.ComboBox1.Style = fmStyleDropDownList
247. 　Me.ScrollBar1.Min = 0
248. 　Me.ScrollBar1.Max = 3660
249. 　Me.ScrollBar1.LargeChange = 7
251. 　Me.Image1.PictureSizeMode = fmPictureSizeModeStretch
252. End Sub

図５－７

２４２行目「Me.CommandButton1.Caption = "登録"」と２４３行目「Me.CommandButton2.Caption = "終了"」では、配置したCommandButtonの表面文字を設定しています。
２４５行目「Me.ComboBox1.Style = fmStyleDropDownList」では、設備選択用のComboBoxをリストボックスとして使用する設定をします。Styleプロパティに設定可能な値は図５－８の２種です。

ComboBox.Styleプロパティ

定数	値	内容
fmStyleDropDownCombo	0	編集領域への値入力可 + ﾄﾞﾛｯﾌﾟﾀﾞｳﾝﾘｽﾄからの選択可（既定）
fmStyleDropDownList	2	ﾄﾞﾛｯﾌﾟﾀﾞｳﾝﾘｽﾄからのみ選択可

図５－８

今回のように、Styleに「fmStyleDropDownList」を設定することで、編集領域（コンボボックス一番上のテキストボックスの様に入力できる部分）には、「リストに無い値」を入力・保持することが出来なくなります。例えばリスト内に「フライス盤」があったとすると、編集領域に「フライス」や「フライス盤２」などの文字は入力できなくなります。
（実際には、今回システムでStyleプロパティを既定のfmStyleDropDownComboに設定すると、編集領域を変更した時にComboBoxのChangeイベントが発生し状態グラフの再表示を行おうとします。その時、選択中の項目を取得する時に「リストから項目を選んでいない：ListIndex = -1 」ためにエラーが出てしまうことになります。）

２４７行目「Me.ScrollBar1.Min = 0」は、日付選択のスクロールバーの最小値をゼロ（＝図４－１の０５行目で設定した、システム開始日）にし、２４８行目「Me.ScrollBar1.Max = 3660」では最大値を約１０年後（≒365日×10年）にしています。
２４９行目「Me.ScrollBar1.LargeChange = 7」は、スクロールバーのレール部をクリックした時には、１週間（＝７日間）まとめて移動するようにします。

２５１行目「Me.Image1.PictureSizeMode = fmPictureSizeModeStretch」は、図５－９のように「Imageコントロールにピッタリ合うように引き延ばす」指定です。この設定は画像が歪む可能性がありますが、今回はストライプ模様のため、歪んでも問題ありません。

Image.PictureSizeModeプロパティ

定数	値	内容
fmPictureSizeModeClip	0	はみ出し部分をﾄﾘﾐﾝｸﾞ(既定)
fmPictureSizeModeStretch	1	ｻｲｽﾞに合わせて引き延ばす
fmPictureSizeModeZoom	3	歪まない様に引き延ばす

図５－９

Initializeの次に、フォームが表示される時に実行されるのが図５－１０のActivateイベントです。ここではフォームの動的な設定をしています。

260. '==========　⇩(14)　Activateイベント　============
261. Private Sub UserForm_Activate()
263. 　EventOFF = True
264. 　　Me.ScrollBar1.Value = Date - SystemStartDay
265. 　　Call makeButton
266. 　　Call makeTimeLabel
267. 　　Call makeCombo
268. 　EventOFF = False
270. 　Call OperateCondDisp
271. End Sub

図５－１０

２６４行目「Me.ScrollBar1.Value = Date - SystemStartDay」は、日付選択のスクロールバーのスクロールボックスを今日の位置にしています。図４－１の０５行目でシステム開始日（スクロールバーの値＝ゼロ）を設定していますので、開始日の日付を引いた値がスクロールバーの値になります。
２６５行目「Call makeButton」では図５－１１を呼び出し、設備稼働状態ボタンを作成します。
２６６行目「Call makeTimeLabel」では図５－１４を呼び出し、Imageコントロールの上側に時刻を表示します。
２６７行目「Call makeCombo」では図５－１７を呼び出し、設備選択用のコンボボックスのリストを作成します。

なお今回システムでは、スクロールバーやコンボボックスを操作するのに合わせて設備稼働状態グラフを再表示させますので、２６４～２６７行目での設定時にも再表示をしようとします。しかし、全てが整った状態になっていない為にエラーが出ることになります。（makeButtonとmakeTimeLabelではエラーは出ませんが、ひっくるめて「フォーム準備時」としています。）
そこで、２６３行目「EventOFF = True」でフラグ変数のフラグを立て、実行先のChangeイベント（図５－１８、図５－１９）でフラグが立っている時にはすぐに抜け出すことにしています。

全ての準備が完了したら、２７０行目「Call OperateCondDisp」で図５－３１を呼出し、起動直後の状態の設備稼働状態グラフを表示させます。

５－２－２－４．ボタンの作成

図５－１０の２６５行目から呼び出されるのが図５－１１です。図５－１１はボタンを配列Barrayに登録する役目で、実際にボタンを作成する作業は図５－１３のaddBTN関数プロシージャに委託しています。

280. '==========　⇩(15)　稼働状態ボタンの登録　============
281. Private Sub makeButton()
282. 　Dim i As Integer 　 '←ボタンの個数
284. 　ReDim Barray(0 To 23)
286. 　With Me.Image1
287. 　　For i = 0 To 23
288. 　　　Set Barray(i).Button = _
289. 　　　　　addBTN(.Top + .Height, .Left + i * .Width / 24, .Width / 24, .Width / 24, "")
290. 　　Next i
291. 　End With
293. End Sub

図５－１１

２８４行目「ReDim Barray(0 To 23)」は、図５－４の２１２行目で設定した配列にインデックスを付けています。今回は２４個のボタンを作りますので、ゼロ～２３としています。

２８８～２８９行目「Set Barray(i).Button = addBTN(.Top + .Height, .Left + i * .Width / 24, .Width / 24, .Width / 24, "")」では図５－１３を呼出し、引数で指定した位置・サイズ、及び表面文字列でボタンを作成します。
引数は５つ有り、第一引数から「上下位置」「左右位置」「高さ」「幅」「表面文字列」となります。フォーム上に配置したImage1を基準（２８６行目「With Me.Image1」）に、その下に２４個並べるために、指定位置は図５－１２のようにしました。

図５－１２

その５つの引数を渡してボタンが作成されると、addBTN関数は「作ったボタンのオブジェクト」を戻してきます。そのオブジェクトを図５－６の「ボタンのオブジェクトを設定」するプロパティに渡し、配列Barrayの１つの要素として登録します。
この作業を２８７行目「For i = 0 To 23」で、カウンタ変数ｉを配列Barrayのインデックス分（今回２４回）だけ回します。

なお、上記コード内で使用している数値の「23」は「Ubound(Barray,1)」、「24」は「Ubound(Barray,1) - Lbound(Barray,1) + 1」などと記載するのが本当なのでしょうが、コードが長くなり流れが掴み難くなると考え、あえて数値としました。御理解下さい。

図５－１１の２８９行目から呼び出される「ボタンを作成し、そのオブジェクトを返す」関数が図５－１３です。引数として、作成するボタンの「上下位置」「左右位置」「高さ」「幅」「表面文字列」を受け取ります。なお今回システムでは、ボタンを新規作成する際には「ボタン表面文字列は全て""（長さゼロの文字列）」ですが、汎用性を持たせるために引数の１つにしています。

300. '==========　⇩(16)　ボタンの作成　============
301. Private Function addBTN(T As Single, L As Single, _
302. 　　　　　　　　　　　　　H As Single, W As Single, _
303. 　　　　　　　　　　　　　Bcaption As String) As MSForms.CommandButton
305. 　Set addBTN = Me.Controls.Add("Forms.CommandButton.1")
307. 　With addBTN
308. 　　.Top = T
309. 　　.Left = L
310. 　　.Height = H
311. 　　.Width = W
312. 　　.Caption = Bcaption
313. 　End With
315. End Function

図５－１３

３０５行目「Set addBTN = Me.Controls.Add("Forms.CommandButton.1")」で、「Forms.CommandButton」のコントロール（＝状態ボタン）を作成します。そしてそのオブジェクトを関数プロシージャの戻り値に設定しています。
３０５行目を実行した時点で、既にボタンは作られているのですが、位置もサイズも指定していないため既定の位置「フォームの左上端（Top=0、Left=0 の場所）」に、既定のサイズ「（私のPCでは）Height=24、Width=72」で作られています。

既定で作られたボタンを３０７～３１３行目で位置・サイズを整え、表面文字列（.Caption）を設定します。なお、今回フォントサイズ（.Font.Size）は変更していません。私のPCでは「９ポイント（既定値？）」になっており、ボタンの文字サイズとしては問題なかったため設定を省略しましたが、不具合ある場合にはフォントサイズも設定が必要になります。

５－２－２－５．時刻ラベルの作成

図５－１０の２６６行目から呼び出されるのが図５－１４です。図５－１４は状態グラフの上部に時刻のラベルの配置位置・サイズ・表示文字を指定する役目で、実際にラベルを作成する作業は図５－１６のaddLBL関数プロシージャに委託しています。

320. '==========　⇩(17)　時刻ラベルの作成指示　============
321. Private Sub makeTimeLabel()
322. 　Dim i As Integer 　 '←ラベルの個数
324. 　With Me.Image1
325. 　　For i = 0 To 24
326. 　　　addLBL .Top - 10, .Left + i * .Width / 24 - 3, 10, .Width / 24, CStr(i)
327. 　　Next i
328. 　End With
329. End Sub

図５－１４

稼働状態ボタンとは異なり、時刻ラベルは「クリック等によるイベントを取得しない」また「表示文字などのプロパティを変更しない」ため、単にラベルを作成するだけになります。
３２６行目「addLBL .Top - 10, .Left + i * .Width / 24 - 3, 10, .Width / 24, CStr(i)」で図５－１６を呼び出し、引数で指定した位置・サイズ、及び文字列でラベルを作成します。
引数はボタンの時と同じ５つで、第一引数から「上下位置」「左右位置」「高さ」「幅」「表示文字列」となります。フォーム上に配置したImage1を基準（３２４行目「With Me.Image1」）に、その上側に２５個並べるために、指定位置は図５－１５のようにしました。

図５－１５

指定した位置サイズでのラベル作成を、３２５行目「For i = 0 To 24」で繰り返します。なお、ゼロから２４と「全２５個」となっているのは、次の日の０時である「24」の文字列を右端に表示しているためです。
また、横位置を「.Left + i * .Width / 24 - 3」と「-3だけ微調整」しているのは、ラべルの数字を時刻の線上に持ってくるためにTry & Errorした結果です。

図５－１４の３２６行目から呼び出される「ラベルを作成し、そのオブジェクトを返す」関数が図５－１６です。引数として、ラベルの「上下位置」「左右位置」「高さ」「幅」「表示文字列」を受け取ります。

340. '==========　⇩(18)　ラベルの作成　============
341. Private Function addLBL(T As Single, L As Single, _
342. 　　　　　　　　　　　　　H As Single, W As Single, _
343. 　　　　　　　　　　　　　Lcaption As String) As MSForms.Label
345. 　Set addLBL = Me.Controls.Add("Forms.label.1")
347. 　With addLBL
348. 　　.Top = T
349. 　　.Left = L
350. 　　.Height = H
351. 　　.Width = W
352. 　　.Caption = Lcaption
353. 　End With
355. End Function

図５－１６

３４５行目「Set addLBL = Me.Controls.Add("Forms.label.1")」で、「Forms.label」のコントロール（＝時刻のラベル）を作成し、そのオブジェクトを関数プロシージャの戻り値に設定しています。なお図５－１４では、その戻り値は使っていません。

３４５行目を実行した時点では、作られたラベルは既定の位置「フォームの左上端（Top=0、Left=0 の場所）」に、既定のサイズ「（私のPCでは）Height=18、Width=72」となっています。
既定で作られたボタンを３４７～３５３行目で位置・サイズを整え、文字列（.Caption）を設定します。なお、今回フォントサイズ（.Font.Size）は変更していません。私のPCでは「９ポイント（既定値？）」になっており、ラベルの文字サイズとしては問題なかったため設定を省略しましたが、不具合ある場合にはフォントサイズも設定が必要になります。

５－２－２－６．コンボボックスの作成

図５－１０の２６７行目から呼び出される「設備名の選択用コンボボックスのリストを作成」するのが図５－１７です。

360. '==========　⇩(19)　コンボボックスの作成　============
361. Private Sub makeCombo()
362. 　Dim i As Integer 　 '←リストの個数
364. 　Me.ComboBox1.Clear
366. 　For i = 0 To UBound(MachineArray, 1)
367. 　　Me.ComboBox1.AddItem MachineArray(i)
368. 　Next i
370. 　Me.ComboBox1.ListIndex = 0
371. End Sub

図５－１７

３６４行目「Me.ComboBox1.Clear」は、一旦コンボボックスのリストをクリアしています。今回システムでは起動時にしかmakeComboプロシージャを実行しませんし、且つフォーム終了もHideでは無くUnloadを使っていますので、Clearは必須ではありません。しかし、フォーム上から設備名を追加できるなどの改造をした場合は、Clearをしないと項目が重複してしまいますので、念の為実行しています。

設備名は、図４－２の２４行目で設定済みのMachineArray配列に格納されていますので、３６６行目「For i = 0 To UBound(MachineArray, 1)」で配列の要素数分だけ回しながら、３６７行目「Me.ComboBox1.AddItem MachineArray(i)」で１要素ずつリストに追加しています。

リスト完成後、３７０行目「Me.ComboBox1.ListIndex = 0」で、先頭の設備名を強制的に表示させています。これは、フォーム起動直後に稼働状態グラフを表示（図５－１０の２７０行目）させていますが、その時に「設備名が選択状態で無い」とエラーが出てしまうためです。

５－２－２－７．設備・日付の選択

設備名のコンボボックスを操作した時には、図５－１８のChangeイベントが発生します。

380. '==========　⇩(20)　設備の選択　============
381. Private Sub ComboBox1_Change()
382. 　If EventOFF = True Then Exit Sub
384. 　Call OperateCondDisp
385. End Sub

図５－１８

コンボボックスを作成した後、先頭の項目を表示させています（図５－１７の３７０行目）が、その時にも図５－１８が呼び出されます。しかし、呼出し元の図５－１０の２６７行目（Call makeCombo）は、その数行前の２６３行目「EventOff = True」でフラグ変数のフラグを立てている（Trueにしている）ため、３８２行目「If EventOFF = True Then Exit Sub」でChangeイベントを抜け出すことになります。

ユーザーの手で設備名を変更した場合には、３８４行目「Call OperateCondDisp」で図５－３１が呼び出され、Imageコントロールに状態グラフが表示されることになります。

図５－１０の２６７行目「Call makeCombo」を実行する前にEventOffをFalse設定にすれば、３８４行目「Call OperateCondDisp」により状態グラフを作成してくれます。そうすれば、図５－１０の２７０行目「Call OperateCondDisp」は不要になりますし、また３８２行目「If EventOFF = True Then Exit Sub」もいらなくなります。 しかし、これでうまく行くのは図５－１０の中で「Call makeCombo」が最後に実行されるからに過ぎません。フォームの準備時にやむを得ず発生してしまうイベントを利用するのは、上手なやり方に見えるかもしれませんが、私には危険な手法に思えます。 やはり、準備が完全にできてから「明示的に図５－１０の２７０行目『Call OperateCondDisp』で、初めて状態グラフを表示させる」のが正しい姿だと思います。

日付選択のスクロールバーを動かした時には、図５－１９のChangeイベントが発生します。

390. '==========　⇩(21)　日付の選択　============
391. Private Sub ScrollBar1_Change()
393. 　Me.Label1.Caption = SystemStartDay + Me.ScrollBar1.Value
395. 　If EventOFF = True Then Exit Sub
396. 　Call OperateCondDisp
398. End Sub

図５－１９

このイベントが発生する時はスクロールバーのValue値が変更されているので、変更に合わせて３９３行目「Me.Label1.Caption = SystemStartDay + Me.ScrollBar1.Value」で、スクロールバー上部のLabel1にValue値相当の日付を書き込みます。
SystemStartDayはDate型でScrollBar1.ValueはLong型ですが、それを合わせるとDate型となりますので日付の形でラベルの文字列となります。

３９５行目「If EventOFF = True Then Exit Sub」は、Activateイベント内でフォームの準備をしている最中は、フラグ変数EventOffのフラグを立てておき、３９６行目を実行されないようにします。
Activateイベントでの準備が完了し、ユーザーが日付操作した時のみ３９６行目「Call OperateCondDisp」で図５－３１が呼び出され、Imageコントロールに状態グラフが表示されます。

５－２－２－８．稼働状態ボタンの操作

今回システムの「稼働状態ボタン」は、クリックするたびに「状態を切り替え」させることを考えています。
これを実現させるため、まずCommandButtonを操作した時に、どんなイベントが発生するかを見てみます。

初めに、ボタンをゆっくり（ダブルクリックが反応しない様に）と何回もクリックすると、「MouseDown」→「MouseUp」→「Click」という順番でイベントが発生します。図に表すと、図５－２０の左側のようになります（図５－２０は、４回クリックした時を示しています）。

図５－２０

一方、ボタンを素早くクリックすると、PC側は「ダブルクリックをした」と判断して、図５－２０の右側のような「ゆっくり時とは異なるイベントの発生」となります。１回目はClickイベント、２回目はDblClickイベント、３回目は戻ってClickイベント　という感じです。

また、ボタンはマウスでなくても操作可能です。キーを使い、Tabでコントロール間を移動させ、ボタンにFocusが来たところでスペースキーやEnterキーでボタンをクリックしたことになります。その時のイベントの発生の仕方が図５－２１です（図５－２１も、４回キーを押した時を示しています）。

図５－２１

スペースキーだと「KeyDown」→「KeyPress」→「KeyUp」→「Click」という順番、Enterキーだと「KeyDown」→「Click」→「KeyUp」という順番です。速くキーを押してもこのイベント順は同じでした。（キー種によってClickとKeyUpの発生する順番が変わるのは面白いところです）

図５－２０と図５－２１から、ボタンが何回クリックまたはキー押下されたかを知るためには「Clickイベント 及び DblClickイベント」を取得すれば判断できそうです。
そこで「Clickイベント」および「DblClickイベント」の両方から同じコードを動かそうというのが下記です。

まず「Clickイベント」が図５－２２で、発生したら４０２行目「Call Button_StringChange」で図５－２４を呼び出します。

400. '==========　⇩(22)　クリック、またはキー押下時のイベント　============
401. Private Sub myButton_Click()
402. 　Call Button_StringChange
403. End Sub

図５－２２

また「DblClickイベント」が図５－２３で、発生したら４１２行目「Call Button_StringChange」で同じく図５－２４を呼び出します。

410. '==========　⇩(23)　ダブルクリック時のイベント　============
411. Private Sub myButton_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
412. 　Call Button_StringChange
413. End Sub

図５－２３

図５－２２の４０２行目、図５－２３の４１２行目から呼び出されるのが図５－２４です。この中では、ボタンの文字列（＝Captionプロパティ）を変更させています。

420. '==========　⇩(24)　ボタンの文字列変更　============
421. Private Sub Button_StringChange()
422. 　Dim i As Integer 　 '←設備の個数
424. 　For i = 0 To UBound(markArray, 1) - 1
425. 　　If myButton.Caption = markArray(i) Then
426. 　　　myButton.Caption = markArray(i + 1)
427. 　　　Exit Sub
428. 　　End If
429. 　Next i
431. 　myButton.Caption = markArray(0)
433. End Sub

図５－２４

まずボタンの文字列は、図４－２の２２行目で設定したmarkArray配列です。今回だと図５－２５の左側のようにインデックス「０～４」までの各要素に記号が入っています。（インデックス０には、長さゼロの文字列が入っています）

図５－２５

この各記号が、図５－２５の右側にょうに「順番に出てくる」ようにする為に、以下の手順で調査・実行などをします。
「現在のボタンの記号を調査」→「その記号が配列の何番目かを調査」→「その次の番号の記号をボタンの記号にする」
但し、ボタンの記号が配列の最後だった場合には、配列の先頭の記号を使用することになります。これをコードにします。

４２４行目「For i = 0 To UBound(markArray, 1) - 1」では、カウンタ変数ｉを「配列の要素数 －１」だけ回します。「－１」しているのは配列の最後のインデックス番号（＝次の番号が無い）だからです。
４２５行目「If myButton.Caption = markArray(i) Then」では、現在のボタンの記号（myButton.Caption）と配列の記号を比較し、合致していれば４２６行目「myButton.Caption = markArray(i + 1)」で、ボタンの記号を「配列の次のインデックスの記号」に変更します。
記号を変更したら、あとは調べる必要はありませんので４２７行目「Exit Sub」で抜け出します。

４２４行目のFor～Next文で回しているのは「配列より１つ少ない数」ですので、もし現在のボタンの記号が配列の最後の記号（図５－２５であれば「D」）だった場合には、４２５行目のIf文では成立せず、For～Nextが終了してしまいます。
抜け出した後は、４３１行目「myButton.Caption = markArray(0)」で「配列の先頭文字列（図５－２５であれば「""（長さゼロの文字列）」）」をボタンの記号とすることになります。

図５－２２のClickイベントが発生した時点、および図５－２３のDblClickイベントが発生した時点では、「クリックまたは押下されたボタンはmyButton」です。myButtonのイベントなのですから当然です。その各イベントプロシージャから呼び出した先の図５－２４で、同じmyButtonを対象に処理を行うのは、ちょっと心配です。ボタン文字列表示が完了する前に、次のクリックが発生するかもしれないからです。 試しに、複数ボタンをマウスで乱打してみた結果は「違うボタンの処理をするエラー」は発生しませんでした。私のPCで時間を測ってみると、処理は遅くても0.03秒、操作は速くても0.07秒なので「圧倒的に処理が速い」ので大丈夫そうです。 また「Button_StringChangeが負荷の高い（処理時間がかかる）プロシージャ」を想定し、図５－２４の中にDo～Loopで時間をかけてみても大丈夫でした。 但し、Do～Loopの中に「DoEvents」を入れると、処理対象が「グチャグチャ」になりました。 この事は、一度クリックして発生したClickイベントの「一連の動作が終了するまでは割り込みは発生せず」に、次のイベント発生は待機していてくれていることを意味していると思われます。 「永久Loopになったら大変だ」「途中でESCキーで止めたい」という理由で「DoEventsをやたらに入れる」と予期せぬ制御が割り込まれてしまい、思ったのと異なる結果が出てきてしまう可能性があるので注意が必要です。 やはり、ClickイベントとButton_StringChangeプロシージャとの間は「クリックされたボタンオブジェクトを引数としてbyValで渡す」のが一番安心かもしれません。ただし今回システムでは、人間が「ボタン表面の文字列の変化を確認しながら操作」するだろうし、またクリックがデータ保存に直結していない（保存は登録ボタンを押した時のみ）ため、特に気を遣っておりません。

５－２－２－９．データの登録

「登録」ボタンをクリックすると図５－２６が呼び出され、状態ボタンでの変更の値がDBファイルに保存されます。

440. '==========　⇩(25)　データの登録　============
441. Private Sub CommandButton1_Click()
442. 　Dim mc As String 　　 '←設備名
443. 　Dim d As Date 　　　 '←表示日付
444. 　Dim dt As Date 　　　 '←日時
445. 　Dim OldMark As Variant 　 '←DB内に登録されている記号の配列
446. 　Dim NewMark As String 　 '←ボタンの記号
447. 　Dim sql As String 　　 '←正時
448. 　Dim i As Integer 　 '←実行するSQL文
450. 　mc = Me.ComboBox1.List(Me.ComboBox1.ListIndex)
451. 　d = CDate(Me.Label1.Caption)
452. 　OldMark = DayMark(d, mc)
454. 　For i = 0 To 23
455. 　　dt = DateAdd("h", i, d)
456. 　　NewMark = Barray(i).Button.Caption
458. 　　If Not OldMark(i) = NewMark Then
459. 　　　Select Case True
460. 　　　　Case OldMark(i) = ""
461. 　　　　　sql = "Insert into " & TBL & " (DT,MC,Cond) " & _
462. 　　　　　　　　　"values(#" & dt & "#,'" & mc & "','" & NewMark & "')"
463. 　　　　Case NewMark = ""
464. 　　　　　sql = "Delete from " & TBL & _
465. 　　　　　　　　　" where DT= #" & dt & "# and MC= '" & mc & "'"
466. 　　　　Case Else
467. 　　　　　sql = "Update " & TBL & " set Cond='" & NewMark & "'" & _
468. 　　　　　　　　　" where DT= #" & dt & "# and MC= '" & mc & "'"
469. 　　　End Select
471. 　　　Call SQL_exec6(sql)
472. 　　End If
474. 　Next i
476. 　Call OperateCondDisp
477. End Sub

図５－２６

４５０行目「mc = Me.ComboBox1.List(Me.ComboBox1.ListIndex)」は、コンボボックスで選択中の設備名を取得します。
４５１行目「d = CDate(Me.Label1.Caption)」は、選択中の日付のラベルを日付型にして取得します。
４５２行目「OldMark = DayMark(d, mc)」では、設備名と日付を引数に渡して図５－３０を呼び出し、「選択日付×選択設備の元データ」を取得します。このデータは２４要素の一次元配列として戻してくるので、変数OldMarkで受け取ります。

処理を行う前に、まず今回のDBテーブルの構造について説明します。テーブルは図５－２７のようになっていて、「停止」以外の記号のデータを入れています。つまり「未入力＝停止」のような扱いとなります。

DT(日時)	MC(設備名)	Cond(記号)
2022/07/02 01:00:00	旋盤	A
2022/07/02 02:00:00	旋盤	B
2022/07/02 02:00:00	裁断機	C
:	:	:

図５－２７

４５４～４７４行目のFor～Next内では、状態ボタン１つ１つについて「表示されている記号」を調査し「DBテーブル内の元の記号」と比較をして、DBファイルに対して処理を行っていきます。その処理の内容は「元の記号」と「現在の記号」の組合せにより異なります。これをまとめたのが図５－２８で、この表を元にして処理を分岐させていきます。

図５－２８

図５－２８で、まず「新旧の記号が同じ（白色の部分）」場合はデータを書き換える必要がありませんので処理をしません。
それ以外を分岐していきいます。まず、元が「""（長さゼロの文字列）」の場合は、DBテーブルにデータがないので、データ追加（Insert文：緑色）します。
変更後が「""（長さゼロの文字列）」の場合は、DBテーブルからデータを消す必要があるのでDelete文（青色）になります。
その他の組み合わせの場合は、記号を変更する必要があるのでUpdate文（黄色）を使用することになります。

４５４行目「For i = 0 To 23」では、カウンタ変数ｉをボタンの数だけ回します。変数ｉは、正時（0時、1時、2時、･･･）を表すことになります。
４５５行目「dt = DateAdd("h", i, d)」は、Label1の日付（整数値なので0時相当）に対し正時分だけ時刻を増やした日時データにします。
４５６行目「NewMark = Barray(i).Button.Caption」では、状態ボタンの表面文字列（＝記号）を取得します。

４５８行目「If Not OldMark(i) = NewMark Then」では、元の記号（OldMark）と新しい記号（NewMark）とが異なる場合のみ４５９～４７１行目を実行し、DBテーブルへの処理を行います。つまり、図５－２８の白い部分を取り除きます。

色のついた部分は４５９行目「Select Case True」で分岐させます。
まず緑色部分は４６０行目「Case OldMark(i) = ""」でTrueとなり、４６１～４６２行目「sql = "Insert into " & TBL & " (DT,MC,Cond) " & "values(#" & dt & "#,'" & mc & "','" & NewMark & "')"」で、Insert文を作成します。
挿入するデータは、DT列に日時（dt）、MC列に設備名（mc）、Cond列に記号（Newmark）となります。

次に青色部分は４６３行目「Case NewMark = ""」でTrueとなり、４６４～４６５行目「sql = "Delete from " & TBL & " where DT= #" & dt & "# and MC= '" & mc & "'"」で、Delete文を作成します。
削除するデータは、DT列が日時（dt）で且つMC列が設備名（mc）のレコードです。

最後に黄色部分は４６６行目「Case Else」に分岐され、４６７～４６８行目「sql = "Update " & TBL & " set Cond='" & NewMark & "'" & " where DT= #" & dt & "# and MC= '" & mc & "'"」で、Update文を作成します。
上書きするのは「where DT= #" & dt & "# and MC= '" & mc & "'"」と、DT列が日時（dt）、MC列が設備名（mc）のレコードで、上書きするデータは「" set Cond='" & NewMark & "'"」と「新しい記号」です。

SQL文が完成したら、４７１行目「Call SQL_exec6(sql)」で図４－１２を呼出し、DBテーブルに対して実行します。
この作業をボタンの数だけ行います。
最後に４７６行目「Call OperateCondDisp」で、状態グラフを更新します。

「終了ボタン」をクリックした時に呼び出されるのが図５－２９です。データ登録とは無関係ですが、同じボタン操作系なのでここで説明してしまいます。

480. '==========　⇩(26)　システム終了　============
481. Private Sub CommandButton2_Click()
482. 　Unload Me
483. End Sub

図５－２９

４８２行目「Unload Me」で、フォームを閉じます。
Unloadの代わりに「Me.Hide」で隠すだけでもOKですが、今回のシステムではActivateイベント内で全て初期化（設備名選択も、日付選択も初期値を表示）してしまいますので、初期化部分をInitializeに移動する等の改造をしないと意味がありません。
但しその時に、設備名をフォーム上から修正できるようなシステムにしていたとすると、再度起動した時に 「他の人が変更した設備が反映されない」事になるため、注意が必要です。

５－２－２－１０．対象日×選択設備の元のデータ取得

図５－２６の４５２行目、図５－３１の５２０行目から呼び出される「指定された日付・指定された設備の、DBテーブル内のデータ」を配列として戻す関数が図５－３０です。引数として日付と設備名を受け取ります。

490. '==========　⇩(27)　DBテーブルの元データ取得　============
491. Private Function DayMark(d As Date, mc As String) As String()
492. 　Dim buf1 As Variant 　　 '←DBテーブルから取得したデータ
493. 　Dim buf2(0 To 23) As String 　　 '←関数プロシージャの戻り値
494. 　Dim sql As String 　　 '←SQL文
495. 　Dim i As Integer 　　 '←DBテーブル内のレコード数
497. 　sql = "select val(format(dt,'h')),Cond from " & TBL & _
498. 　　　　　" where format(DT,'yyyy/mm/dd')= #" & d & "# " & _
499. 　　　　　" and MC= '" & mc & "'"
500. 　buf1 = SQL_exec6(sql)
502. 　For i = 1 To UBound(buf1, 1)
503. 　　buf2(buf1(i, 1)) = buf1(i, 2)
504. 　Next i
506. 　DayMark = buf2
507. End Function

図５－３０

まず、変数宣言の内４９３行目「Dim buf2(0 To 23) As String」は、関数の戻り値となる配列ですが、データがあっても無くても２４個の要素となるように静的な一次元配列としています。要素のインデックスは、正時を表す事になります。

DBテーブルから「指定された日付・指定された設備のデータ」を取り出すのが、４９７～４９９行目「sql = "select val(format(dt,'h')),Cond from " & TBL & " where format(DT,'yyyy/mm/dd')= #" & d & "# " & " and MC= '" & mc & "'"」です。
まず、レコードの抽出条件部分は「" where format(DT,'yyyy/mm/dd')= #" & d & "# " & " and MC= '" & mc & "'"」で、DT列のデータ（日付＋時刻）を「format(DT,'yyyy/mm/dd')」で日付のみにした後、「引数の日付（d）」と比較をします。
またand検索「" and MC= '" & mc & "'"」で、更に設備名が「引数で指定された設備」に絞り込んでいます。

なおSelectするデータは「val(format(dt,'h'))」と「Cond」の２つで、前者は抽出した日付（DT列）の正時部分（'h'）を取り出し、Val関数で整数にして取得します。後者のCond列は状態記号そのままです。
５００行目「buf1 = SQL_exec6(sql)」で図４－１２を呼出し、DBテーブルから対象のレコードを取得し、buf1に代入します。buf1はタイトル行も入っていて、二次元配列となります。

５０２～５０４行目では、４９３行目で宣言した２４要素の一次元配列に「データが存在するインデックス」の要素に「記号」を入れていきます。
５０２行目「For i = 1 To UBound(buf1, 1)」では、抽出されたレコード数だけカウンタ変数ｉを回します。
５０３行目「buf2(buf1(i, 1)) = buf1(i, 2)」は、記号をbuf2に代入しています。代入する位置は「val(format(dt,'h'))」で取得した「正時のインデックス位置」に代入します。つまり、配列に代入されなかった要素（＝時刻）は「停止＝未入力」ということになります。

代入が完了したら、「時刻ごとに記号が並んだ配列」を５０６行目「DayMark = buf2」で関数の戻り値にします。

５－２－２－１１．グラフデータ表示

図５－１０、図５－１８、図５－１９、図５－２６から呼び出される「稼働状態グラフを表示」するのが図５－３１です。

510. '==========　⇩(28)　グラフデータ表示　============
511. Private Sub OperateCondDisp()
512. 　Dim mc As String 　　 '←表示する設備名
513. 　Dim d As Date 　　　　 '←表示する日付
514. 　Dim buf As Variant 　　 '←記号の配列
515. 　Dim R As Range 　　　 '←グラフの元となるセル範囲
516. 　Dim i As Integer 　　 '←状態ボタンの数
518. 　mc = Me.ComboBox1.List(Me.ComboBox1.ListIndex)
519. 　d = CDate(Me.Label1.Caption)
520. 　buf = DayMark(d, mc)
522. 　ThisWorkbook.Sheets("Sheet1").Range("C3:Z3") = buf
524. 　Set R = ThisWorkbook.Sheets("Sheet1").Range("C4:Z4")
526. 　Me.Image1.Picture = LoadPicture(Range2File(R))
528. 　For i = 0 To 23
529. 　　Barray(i).Button.Caption = buf(i)
530. 　Next i
532. 　Me.Repaint
533. End Sub

図５－３１

５１８行目「mc = Me.ComboBox1.List(Me.ComboBox1.ListIndex)」で、コンボボックスから選択中の設備名を取得します。
５１９行目「d = CDate(Me.Label1.Caption)」で、スクロールバー上部のラベルから選択中の日付を取得します。
５２０行目「buf = DayMark(d, mc)」で図５－３０を呼出し、「時刻ごとに記号が並んだ配列」を取得します。

５２２行目「ThisWorkbook.Sheets("Sheet1").Range("C3:Z3") = buf」では、その２４個の記号の配列を、Sheet1の「条件付き書式適用先の上段（C3～Z3セル）」に貼り付けます。貼り付けると、条件付き書式によりセル背景色が変更されます。
５２４行目「Set R = ThisWorkbook.Sheets("Sheet1").Range("C4:Z4")」で、背景色が変更された範囲の下段（C4～Z4セル）を変数Rに設定します。

５２６行目「Me.Image1.Picture = LoadPicture(Range2File(R))」の右辺カッコ内の「Range2File」は、図５－３２の関数プロシージャです。Range2File関数の引数に渡した「セル範囲」を「画像ファイル」に変換し、その保存先を戻して来ますので、その「画像ファイルのパス＋ファイル名」をLoadPictureメソッドの引数にしてImageコントロールのPictureプロパティに設定することでImageコントロールに画像が表示されます。
今回Range2File関数に渡すセル範囲は、５２４行目で設定したR（条件付き書式範囲の下段＝設備状態グラフの元）ですので、設備状態グラフがImageに表示されることになります。

５２８～５３０行目は状態ボタンの文字列を「DBテーブルのデータ」に揃えています。
５２８行目「For i = 0 To 23」でボタンの個数だけカウンタ変数ｉを回し、５２９行目「Barray(i).Button.Caption = buf(i)」でボタン文字列をDBテーブルの値（記号）にしています。

なお単に「登録ボタン」をクリックした時には、既にボタン文字列はユーザーが指定した状態になっていますので重複した動作になりますが、コンボボックス（設備名）やスクロールバー（日付）を移動した時にはボタン文字列の更新は必須であるため、一部の重複には目を瞑りました。

Imageコントロールへの画像ファイルの設定、ボタン文字列の設定が終わりましたので、５３２行目「Me.Repaint」でフォームの画面更新をしています。当初は「Repaintをしなくても大丈夫そうだ」と思っていましたが、極まれに状態グラフが更新されないことに気が付きましたのでRepaintは必要そうです。

５－２－２－１２．シート上データを画像ファイル化

図５－３１の５２６行目から呼び出される「指定されたセル範囲を画像ファイルに変換し、その保存先を戻す」関数が図５－３２です。引数としてセル範囲を受け取ります。

540. '==========　⇩(29)　画像ファイル化　============
541. Private Function Range2File(R As Range) As String
542. 　Dim fso As Object 　　 '←FileSystemObjectオブジェクト
543. 　Dim Cht As Chart 　　　 '←チャートオブジェクト
545. 　R.CopyPicture appearance:=xlScreen, Format:=xlBitmap
546. 　Set Cht = ThisWorkbook.Sheets("Sheet1").ChartObjects.Add(0, 0, R.Width, R.Height).Chart
548. 　Cht.Parent.Select
549. 　Cht.Paste
551. 　Set fso = CreateObject("Scripting.FileSystemObject")
553. 　If Not Dir(BMPpath & BMPname) = "" Then
554. 　　fso.getfile(BMPpath & BMPname).Delete
555. 　End If
557. 　Set fso = Nothing
559. 　Cht.Export Filename:=BMPpath & BMPname, filtername:="BMP"
560. 　Cht.Parent.Delete
562. 　Range2File = BMPpath & BMPname
563. End Function

図５－３２

５４５行目「R.CopyPicture appearance:=xlScreen, Format:=xlBitmap」では、引数で受け取ったセル範囲（今回システムでは、状態グラフの元のセル範囲）を画像コピーします。CopyPictureメソッドの２つの引数については、「図形カレンダーをクリックし日付入力」を参照下さい。
５４６行目「Set Cht = ThisWorkbook.Sheets("Sheet1").ChartObjects.Add(0, 0, R.Width, R.Height).Chart」は、Sheet1にチャートオブジェクト（ChartObjects）を作成（Add）しています。作成するチャートオブジェクトのサイズは５４５行目でコピーしたセル範囲（R）と同じ大きさです。実際の動きとしては図５－３３のようになります。

図５－３３

５４５行目の画像コピーが図５－３３の①、５４６行目のチャートオブジェクト作成が②の状態です。
５４６行目の左辺の変数Chtには、作ったチャートオブジェクトのChartを設定しています。
５４８行目「Cht.Parent.Select」でChartの親（＝チャートオブジェクト）を選択した後、５４９行目「Cht.Paste」でクリップボード上のセルの画像をChartに貼り付けます。貼り付けた状態が、図５－３３の③の状態になります。

５５１行目「Set fso = CreateObject("Scripting.FileSystemObject")」では、FileSystemObjectオブジェクトを生成しています。ここでは５５４行目で「ファイルを削除」するためにFileSystemObjectを使います。
５５３行目「If Not Dir(BMPpath & BMPname) = "" Then」で、これから作ろうとしている画像ファイルのパス＋ファイル名をDir関数に渡し、存在している場合には５５４行目「fso.getfile(BMPpath & BMPname).Delete」で画像ファイルを「一旦削除」しています。ですので、図４－１の１０行目で設定する画像ファイル名は、よくある名前では無く「他では、まず使われないファイル名」としておく必要があります。

５５９行目「Cht.Export Filename:=BMPpath & BMPname, filtername:="BMP"」は、セル範囲を貼り付けたChartを画像としてファイル出力（エキスポート）します。ファイル名は「BMPpath & BMPname」、ファイル型は「BMP」です。
ファイル出力が終わりましたらチャートオブジェクトは不要ですので、５６０行目「Cht.Parent.Delete」で削除します。

５６２行目「Range2File = BMPpath & BMPname」で、関数の戻り値として「出力した画像ファイルのパス＋ファイル名」をセットします。

６．フォーム上ラベルの色変更方式

６－１．ユーザーフォーム（UserForm2）

６－１－１．フォーム上のコントロール類配置

フォーム上には、上部にユーザーが選択する「設備名のComboBox」と「日付のScrollBar」を配置し、ScrollBarの上に日付を表示するLabelを置きます。また右上には登録と終了の２つのCommandButtonを置きます。

図６－１

なお「画像ファイル貼付け方式」には存在したImageコントロールは、「ラベルの色変更方式」では不要です。Imageの代わりにマクロ側から２４個のラベルを作成して並べます。
この方式でも「フォーム自体の大きさ」は調整していません。作るラベルやボタンの大きさ・数からフォームの大きさを計算しサイズを調整するような工夫を必要に応じて実施して下さい。

６－１－２．フォームモジュール

６－１－２－１．宣言部

フォームモジュール先頭では、フォーム内で使用する変数の宣言、およびマクロで作成する「状態ボタン」のイベントを取得するための宣言をします。

570. '==========　⇩(30)　モジュールレベル変数の宣言　============
571. Private WithEvents myButton As MSForms.CommandButton
572. Private myLabel As MSForms.Label
573. Dim Barray() As New UserForm2
574. Dim Larray() As New UserForm2
575. Dim EventOFF As Boolean

図６－２

５７１行目「Private WithEvents myButton As MSForms.CommandButton」は、図６－９で作成する「状態を入力する２４個のCommandButton」をクリックした時にClickイベントを取得するためのWithEvents宣言です。
５７２行目「Private myLabel As MSForms.Label」も、図６－９で作成する「状態を色で表示する２４個のLabel」を操作するための宣言です。

５７３行目「Dim Barray() As New UserForm2」は、どの状態ボタンが押されたかを把握する目的で、１つ１つのボタンにインデックスを登録するための配列の宣言です。ButtonのArrayという意味で命名しました。
５７４行目「Dim Larray() As New UserForm2」は、どのラベルを操作すればよいかを把握する目的で、１つ１つのラベルにインデックスを登録するための配列の宣言です。LabelのArrayという意味で命名しました。
設備名選択のComboBoxや日付選択のScrollBarには、ユーザー操作に反応するためのイベントを仕込んでいます。しかし、ComboBoxやScrollBarの準備をするときにはイベントは反応して欲しく無いので、イベントを中断させるためのフラグ変数を５７５行目「Dim EventOFF As Boolean」で宣言します。

６－１－２－２．カスタムプロパティ

作成したボタンのプロパティ値を取得する時に呼び出すのが図６－３で、ボタンのオブジェクトを設定するのが図６－４です。
図６－３と図６－４は「画像ファイル貼付け方式」と同じなので、詳細説明は「画像ファイル貼付け方式のカスタムプロパティ」を参照願います。

580. '==========　⇩(31)　ボタンのプロパティ値を取得　============
581. Public Property Get Button() As Control
582. 　Set Button = myButton
583. End Property

図６－３

590. '==========　⇩(32)　ボタンのオブジェクトを設定　============
591. Public Property Set Button(ByVal addBTN As Control)
592. 　Set myButton = addBTN
593. End Property

図６－４

作成した「状態グラフ用のラベル」のプロパティ値を取得する時に呼び出すのが図６－５です。
６０２行目「Set Label = myLabel」で、作成したラベル（myLabel）のプロパティを呼出し先に戻しています。

600. '==========　⇩(33)　ラベルのプロパティ値を取得　============
601. Public Property Get Label() As Control
602. 　Set Label = myLabel
603. End Property

図６－５

「状態グラフ用のラベル」のオブジェクトを設定するのが図６－６です。引数として「オブジェクトへの参照である変数addLBL」を受け取ります。
６１２行目「Set myLabel = addLBL」で受け取ったオブジェクトをラベルに設定します。

610. '==========　⇩(34)　ラベルのオブジェクトを設定　============
611. Public Property Set Label(ByVal addLBL As Control)
612. 　Set myLabel = addLBL
613. End Property

図６－６

６－１－２－３．フォームの初期化

フォーム起動時に最初に発生するイベントが図６－７です。内容的にはImageコントロールの設定が無いだけで、残りは画像ファイル貼付け方式と同じです。詳細説明は「画像ファイル貼付け方式のフォームの初期化」を参照願います。

620. '==========　⇩(35)　Initializeイベント　============
621. Private Sub UserForm_Initialize()
622. 　Me.CommandButton1.Caption = "登録"
623. 　Me.CommandButton2.Caption = "終了"
625. 　Me.ComboBox1.Style = fmStyleDropDownList
627. 　Me.ScrollBar1.Min = 0
628. 　Me.ScrollBar1.Max = 3660
629. 　Me.ScrollBar1.LargeChange = 7
631. End Sub

図６－７

フォームが表示される時に発生するのが図６－８です。
画像ファイル貼付け方式（図５－１０）の時には状態ボタンと時刻ラベルを分けて作成していましたが、６４５行目「Call makeButtonLabel」では「状態グラフ用ラベル＋稼働状態ボタン＋時刻のラベル」を同時に作成しています。
他は、画像ファイル貼付け方式と同じですので、詳細説明は「画像ファイル貼付け方式のフォームの初期化」を参照願います。

640. '==========　⇩(36)　Activateイベント　============
641. Private Sub UserForm_Activate()
643. 　EventOFF = True
644. 　　Me.ScrollBar1.Value = Date - SystemStartDay
645. 　　Call makeButtonLabel
646. 　　Call makeCombo
647. 　EventOFF = False
649. 　Call OperateCondDisp
650. End Sub

図６－８

６４５行目「Call makeButtonLabel」では図６－９を呼出し、「状態グラフを作成するラベル」＋「稼働状態ボタン」＋「時刻のラベル」を作成します。

６－１－２－４．ボタンとラベルの作成

図６－８の６４５行目から呼び出されるのが図６－９です。

660. '==========　⇩(37)　ボタンとラベルの作成　============
661. Private Sub makeButtonLabel()
662. 　Const L As Double = 9
663. 　Const T As Double = 72
664. 　Const H As Double = 42
665. 　Const W As Double = 18
666. 　Const fmBoderStyleSingle As Long = 1
667. 　Dim i As Integer 　 '←ラベル・ボタンの数
669. 　ReDim Larray(0 To 23)
670. 　ReDim Barray(0 To 23)
672. 　For i = 0 To 23
673. 　　Set Larray(i).Label = addLBL(T, L + i * W, H, W, "")
674. 　　Larray(i).Label.BorderStyle = fmBoderStyleSingle
675. 　　Larray(i).Label.BorderColor = RGB(225, 225, 225)
677. 　　Set Barray(i).Button = addBTN(T + H, L + i * W, W, W, "")
679. 　　addLBL T - 10, L + i * W - 3, 10, W, CStr(i)
680. 　Next i
682. 　addLBL T - 10, L + i * W - 3, 10, W, CStr(i)
684. End Sub

図６－９

６６２～６６５行目では、フォーム（UserForm2）上のどこにラベル等を表示するかを定数宣言しています。今回は、画像ファイル貼付け方式（UserForm1）のImageコントロールと同じ位置に、ラベル（＝状態グラフ）を並べて表示することにしました。各定数の示してる位置は、図６－１０の通りです。

図６－１０

６６６行目「Const fmBoderStyleSingle As Long = 1」は、６７４行目で設定するBorderStyle（外枠の線の有無）の定数値です。当初は「当然登録されている定数」と思っていたのですが、そうでは無さそうなので定数宣言しています。
６６９行目「ReDim Larray(0 To 23)」は、配列Larray（ラべルの数）の要素数を２４個に設定しています。
６７０行目「ReDim Barray(0 To 23)」は、配列Barray（ボタンの数）の要素数を２４個に設定しています。
Larray、Barrayとも「プロパティを取得・設定」するために配列に設定し、指定を可能にしています。
（一方、時刻のラベルは、一度設定した後はプロパティを変更しませんので、配列化は不要です。）

６７２行目「For i = 0 To 23」は、カウンタ変数ｉを回しています。
６７３行目「Set Larray(i).Label = addLBL(T, L + i * W, H, W, "")」で図６－１２のaddLBL関数を呼び出し、左からｉ番目の位置に「状態グラフ用ラベル」を作成し、そのLabelオブジェクトを配列Larray（インデックスｉ）のLabelに登録します。この操作により、今後もインデックスでラベルの操作が可能になります。
６７４行目「Larray(i).Label.BorderStyle = fmBoderStyleSingle」は、作成したラベルの外枠を有りにします。プロパティに与えた定数「fmBoderStyleSingle」は、６６６行目で定数設定したものです。
６７５行目「Larray(i).Label.BorderColor = RGB(225, 225, 225)」では、その外枠線の色を灰色に設定しています。これは既定だと真っ黒（RGB(0, 0, 0)）となり「あまりにもラベル１つ１つが明確になりすぎて、グラフっぽく見えない」と感じたため変更しました。

６７７行目「Set Barray(i).Button = addBTN(T + H, L + i * W, W, W, "")」は、６７３行目で作成した状態グラフ用ラベルのすぐ下に、図６－１１を呼出して「状態ボタン」を作成し、配列Barrayに登録しています。

６７９行目「addLBL T - 10, L + i * W - 3, 10, W, CStr(i)」は、再び図６－１２のaddLBL関数を呼び出し、状態グラフ用ラベルの上に「時刻表示用ラベル」を作成します。但しこの時刻表示用のラベルは、作成した後は何も変更しないので、６７３行目のように配列に登録する必要はありません。ですので「単にaddLBL関数を呼び出すだけ」になっています。

２４個の「状態グラフ用ラベル」「状態ボタン」「時刻表示用ラベル」の作成が完了した時には、時刻表示ラベルは「23」までしか作成されていません。0時始まりですので２４個で23時となるわけです。今回状態グラフの一番右上にも、翌日の0時を表示したいと考え、６８２行目「addLBL T - 10, L + i * W - 3, 10, W, CStr(i)」で「24」を書き加えています。

ここで、６８２行目で使っているカウンタ変数ｉは「24」を指しています。これは６７２行目「For i = 0 To 23」～６８０行目「Next i」の間で、カウンタ変数ｉは「回るたびに１ずつ増えている」訳ですが、i = 23 となっている時に６９７行目を実行して「時刻ラベルの23を作成」したのち、６８０行目「Next i」でｉは24と増えます。そして今まで通りに６７２行目のForに戻った時に「ｉは23までだった」ことに気が付くわけです。そこでFor～Nextを抜け出して６８２行目を実行するのですから、その時にはカウンタ変数ｉは24となっている訳です。

「ボタンを作成し、そのオブジェクトを返す」関数が図６－１１です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式のボタンの作成」を参照願います。

690. '==========　⇩(38)　ボタンの作成　============
691. Private Function addBTN(T As Single, L As Single, _
692. 　　　　　　　　　　　　　　H As Single, W As Single, _
693. 　　　　　　　　　　　　　　Bcaption As String) As MSForms.CommandButton
695. 　Set addBTN = Me.Controls.Add("Forms.CommandButton.1")
697. 　With addBTN
698. 　　.Top = T
699. 　　.Left = L
700. 　　.Height = H
701. 　　.Width = W
702. 　　.Caption = Bcaption
703. 　End With
705. End Function

図６－１１

「ラベルを作成し、そのオブジェクトを返す」関数が図６－１２です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式の時刻ラベルの作成」を参照願います。

710. '==========　⇩(39)　ラベルの作成　============
711. Private Function addLBL(T As Single, L As Single, _
712. 　　　　　　　　　　　　　　H As Single, W As Single, _
713. 　　　　　　　　　　　　　　Lcaption As String) As MSForms.Label
715. 　Set addLBL = Me.Controls.Add("Forms.Label.1")
717. 　With addLBL
718. 　　.Top = T
719. 　　.Left = L
720. 　　.Height = H
721. 　　.Width = W
722. 　　.Caption = Lcaption
723. 　End With
725. End Function

図６－１２

６－１－２－５．コンボボックスの作成

「設備名の選択用コンボボックスを作成」するのが図６－１３です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式のコンボボックスの作成」を参照願います。

730. '==========　⇩(40)　コンボボックスの作成　============
731. Private Sub makeCombo()
732. 　Dim i As Integer
734. 　Me.ComboBox1.Clear
736. 　For i = 0 To UBound(MachineArray, 1)
737. 　　Me.ComboBox1.AddItem MachineArray(i)
738. 　Next i
740. 　Me.ComboBox1.ListIndex = 0
741. End Sub

図６－１３

６－１－２－６．設備・日付の選択

設備名のコンボボックスを操作した時に発生するのが図６－１４です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式の設備・日付の選択」を参照願います。

750. '==========　⇩(41)　設備の選択　============
751. Private Sub ComboBox1_Change()
752. 　If EventOFF = True Then Exit Sub
754. 　Call OperateCondDisp
755. End Sub

図６－１４

日付選択のスクロールバーを動かした時に発生するのが図６－１５です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式の設備・日付の選択」を参照願います。

760. '==========　⇩(42)　日付の選択　============
761. Private Sub ScrollBar1_Change()
763. 　Me.Label1.Caption = SystemStartDay + Me.ScrollBar1.Value
765. 　If EventOFF = True Then Exit Sub
766. 　Call OperateCondDisp
768. End Sub

図６－１５

６－１－２－７．稼働状態ボタンの操作

稼働状態ボタンをクリックした時に発生する「Clickイベント」が図６－１６で、ダブルクリックのように素早くクリックした時に発生する「DblClickイベント」が図６－１７です。両方とも同じ処理を行うため、どちらも図６－１８が実行されます。
内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式の稼働状態ボタンの操作」を参照願います。

770. '==========　⇩(43)　クリックまたはキー押下時のイベント　============
771. Private Sub myButton_Click()
772. 　Call Button_StringChange
773. End Sub

図６－１６

780. '==========　⇩(44)　ダブルクリック時のイベント　============
781. Private Sub myButton_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
782. 　Call Button_StringChange
783. End Sub

図６－１７

790. '==========　⇩(45)　ボタンの文字列変更　============
791. Private Sub Button_StringChange()
792. 　Dim i As Integer
794. 　For i = 0 To UBound(markArray, 1) - 1
795. 　　If myButton.Caption = markArray(i) Then
796. 　　　myButton.Caption = markArray(i + 1)
797. 　　　Exit Sub
798. 　　End If
799. 　Next i
801. 　myButton.Caption = markArray(0)
803. End Sub

図６－１８

６－１－２－８．データの登録

「登録」ボタンをクリックしたときに呼び出されるのが図６－１９です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式のデータの登録」を参照願います。

810. '==========　⇩(46)　データの登録　============
811. Private Sub CommandButton1_Click()
812. 　Dim mc As String
813. 　Dim d As Date
814. 　Dim dt As Date
815. 　Dim OldMark As Variant
816. 　Dim NewMark As String
817. 　Dim sql As String
818. 　Dim i As Integer
820. 　mc = Me.ComboBox1.List(Me.ComboBox1.ListIndex)
821. 　d = CDate(Me.Label1.Caption)
822. 　OldMark = DayMark(d, mc)
824. 　For i = 0 To 23
825. 　　dt = DateAdd("h", i, d)
826. 　　NewMark = Barray(i).Button.Caption
828. 　　If Not OldMark(i) = NewMark Then
829. 　　　Select Case True
830. 　　　　Case OldMark(i) = ""
831. 　　　　　sql = "Insert into " & TBL & " (DT,MC,Cond) " & _
832. 　　　　　　　　　"values(#" & dt & "#,'" & mc & "','" & NewMark & "')"
833. 　　　　Case NewMark = ""
834. 　　　　　sql = "Delete from " & TBL & _
835. 　　　　　　　　　" where DT= #" & dt & "# and MC= '" & mc & "'"
836. 　　　　Case Else
837. 　　　　　sql = "Update " & TBL & " set Cond='" & NewMark & "'" & _
838. 　　　　　　　　　" where DT= #" & dt & "# and MC= '" & mc & "'"
839. 　　　End Select
841. 　　　Call SQL_exec6(sql)
842. 　　End If
844. 　Next i
846. 　Call OperateCondDisp
847. End Sub

図６－１９

「終了ボタン」をクリックした時に呼び出されるのが図６－２０です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式のデータの登録」を参照願います。

850. '==========　⇩(47)　システム終了　============
851. Private Sub CommandButton2_Click()
852. 　Unload Me
853. End Sub

図６－２０

６－１－２－９．対象日×選択設備の元のデータ取得

「指定された日付・指定された設備の、DBテーブル内のデータ」を配列として戻す関数が図６－２１です。内容は画像ファイル貼付け方式と全く同じです。
詳細説明は「画像ファイル貼付け方式の対象日×選択設備の元のデータ取得」を参照願います。

860. '==========　⇩(48)　DBテーブルの元データ取得　============
861. Private Function DayMark(d As Date, mc As String) As String()
862. 　Dim buf1 As Variant
863. 　Dim buf2(0 To 23) As String
864. 　Dim sql As String
865. 　Dim i As Integer
867. 　sql = "select val(format(dt,'h')),Cond from " & TBL & _
868. 　　　　　" where format(DT,'yyyy/mm/dd')= #" & d & "# " & _
869. 　　　　　" and MC= '" & mc & "'"
870. 　buf1 = SQL_exec6(sql)
872. 　For i = 1 To UBound(buf1, 1)
873. 　　buf2(buf1(i, 1)) = buf1(i, 2)
874. 　Next i
876. 　DayMark = buf2
877. End Function

図６－２１

６－１－２－１０．グラフデータ表示

「稼働状態グラフを表示」させるのが図６－２２です。

880. '==========　⇩(49)　グラフデータ表示　============
881. Private Sub OperateCondDisp()
882. 　Dim mc As String 　 '←選択した設備名
883. 　Dim d As Date 　　　 '←選択した日付
884. 　Dim buf As Variant 　 '←記号の配列
885. 　Dim i As Integer 　 '←状態ラベル・ボタンの数
886. 　Dim j As Integer 　 '←記号の数
888. 　mc = Me.ComboBox1.List(Me.ComboBox1.ListIndex)
889. 　d = CDate(Me.Label1.Caption)
890. 　buf = DayMark(d, mc)
892. 　For i = 0 To 23
893. 　　For j = 0 To UBound(markArray, 1)
894. 　　　If buf(i) = markArray(j) Then
895. 　　　　Larray(i).Label.BackColor = ColorArray(j)
896. 　　　End If
897. 　　Next j
899. 　　Barray(i).Button.Caption = buf(i)
900. 　Next i
902. '　Me.Repaint　
903. End Sub

図６－２２

８８８行目「mc = Me.ComboBox1.List(Me.ComboBox1.ListIndex)」で、コンボボックスで選択中の設備名を取得します。
８８９行目「d = CDate(Me.Label1.Caption)」で、スクロールバー上部のラベルから選択中の日付を取得します。
８９０行目「buf = DayMark(d, mc)」で図６－２１を呼び出し、「時刻ごとに記号が並んだ配列」を取得します。

８９２行目「For i = 0 To 23」で、カウンタ変数ｉを「状態グラフ用ラベル（＝時刻の数）」の数だけ回します。
８９３行目「For j = 0 To UBound(markArray, 1)」では、カウンタ変数ｊを「状態記号」の数だけ回します。
８９４行目「If buf(i) = markArray(j) Then」で、対象時刻の記号が状態記号と合致した時、８９５行目「Larray(i).Label.BackColor = ColorArray(j)」で、状態グラフ用ラベルの背景色を「記号の色」に変更します。

８９９行目「Barray(i).Button.Caption = buf(i)」では、その記号を対象時刻の「状態ボタン」の文字にします。

最後に「状態グラフ用ラベルの背景色」と「状態ボタンの文字」を変更したので、９０２行目「Me.Repaint」でフォームの画面更新をすると良いのですが、私が試したところ「Repaintを実行しなくても、更新されている」ため、とりあえずコメントアウトしています。
実行しない理由は、「Repaintをすると、フォーム全体がパラパラと動く」ため、見栄え的にはあまり良くないと感じたからです。PCの性能や環境にも寄ると思いますので、「変更が反映されない」場合にはRepaintを実行するようにして下さい。

７．アドインとしてExcelにマクロを登録

このマクロ付ファイル（サンプルファイル）をExcelのアドインに登録することで、今回の「設備稼働状態入力・確認」を他のブック使用時に呼び出して使うことが出来ます。アドイン方法については「年賀状リスト等の宛名検索と追記　アドイン登録」を参照下さい。
またリボンのボタンには、標準モジュールの「SystemStart1（図４－３）」または「SystemStart2（図４－４）」を登録して下さい。

８．最後に

背景でも書きましたが、当初は設備状態記号を使って１日分の状態グラフ（集合縦棒グラフを使用）を作成し、そのグラフを画像ファイルにしてフォーム上のImageコントロールに表示するものをトライしていました。しかし、記号をセル範囲に貼り付けてからグラフに反映させるのに時間が掛かる（私のPCで約３秒）ことが分かり、今回のような仕様に変更しました。
時間が掛かる理由は「フォームを起動」しているためのようです。色々試し、モードレスで起動するよりはモーダルの方がグラフ反映が速そうな事も分かりましたが、それでも不満足。それならと、一旦標準モジュール側に制御を移動してからRepaintすることもしましたが、グラフに反映されない状況は残りました。

フォームを使わずにワークシートだけを使っていれば、データはグラフにリアルタイム的に反映されるという例題はネット上で見掛けますが、フォーム上にグラフを動的に表示するのは、かなりの難問のようです。しかし、グラフをフォーム上に表示できれば、また色々と使い道が増えそうな気がしますので、またトライしたいと思っています。


設備の稼働状態を入力し、グラフで確認（it-084.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。