2023/10/02
2023/11/28 一部修正（Recordset.Openの第１パラメータへのSQL文・テーブル名指定の違いについて）
2023/12/13一部補足（データの一括処理で、GetRowsメソッドの第２パラメータは使用不可？）

ADOでAccess･Excel･CSVへ接続・操作
- JET･ACEプロバイダ編 -

• １．データベースへの接続方法
• ２．ADOのオブジェクトについて
• 　２ー１．ADOオブジェクトの種類
• 　２ー２．ADOオブジェクト生成
• 　　２ー２ー１．事前バインディング
• 　　２ー２ー２．実行時バインディング
• ３．Connectionオブジェクト
• 　３ー１．Openメソッド他（データベース接続関係）
• 　　３ー１ー１．第１パラメータ（ConnectionString：接続情報）
• 　　　３ー１ー１ー１．プロバイダー名
• 　　　　よりみち（プロバイダの存在確認）
• 　　　３ー１ー１ー２．データベース名
• 　　　　よりみち（テーブル名）
• 　　　３ー１ー１ー３．ユーザー名、パスワード
• 　　　３ー１ー１ー４．拡張プロパティ（Extended properties）
• 　　　　よりみち（IMEX値の検証）
• 　　３ー１ー２．第２、第３パラメータ（UserID：ユーザー名、Password：パスワード）
• 　　３ー１ー３．第４パラメータ（Options：同期／非同期）
• 　　３ー１ー４．データベース接続までのコード例
• 　３ー２．Executeメソッド（コマンドの実行）
• ４．Recordsetオブジェクト
• 　４ー１．Openメソッド（レコードセット取得）
• 　　４ー１ー１．各パラメータの値
• 　　４ー１ー２．各パラメータの組み合わせ
• 　　　４ー１ー２ー１．Accessの場合（Openメソッドにはテーブル名を指定）
• 　　　４ー１ー２ー２．Accessの場合（OpenメソッドにはSQL文を指定）
• 　　　４ー１ー２ー３．ExcelシートDBの場合（Openメソッドにはテーブル名を指定）
• 　　　４ー１ー２ー４．ExcelシートDBの場合（OpenメソッドにはSQL文を指定）
• 　　　４ー１ー２ー５．CSVの場合（Openメソッドにはテーブル名を指定）
• 　　　４ー１ー２ー６．CSVの場合（OpenメソッドにはSQL文を指定）
• ５．Commandオブジェクト
• 　５ー１．ActiveConnectionプロパティ（データベースとの結び付け）
• 　５ー２．CommandTextプロパティ（実行コマンドの格納）
• 　５ー３．Executeメソッド（コマンドの実行）
• 　　よりみち（テーブル名指定のExcelとCSVはCommand.Execute不可）
• 　５ー４．Commandオブジェクトの使用例
• 　　５ー４ー１．実行コマンドの格納
• 　　５ー４ー２．コマンドの実行
• ６．データベースに接続する為のコード例
• 　６ー１．テーブルを操作
• 　　６ー１ー１．Connectionでテーブル名を実行し、レコードセット取得後に処理
• 　　６ー１ー２．Commandでテーブル名を実行し、レコードセット取得後に処理
• 　　６ー１ー３．Commandにテーブル名を格納後Recordset実行し、レコードセット取得後に処理
• 　　６ー１ー４．Recordsetでテーブル名を実行し、レコードセット取得後に処理
• 　６ー２．SQL（Select）文で操作
• 　　６ー２ー１．ConnectionでSQL文を実行しレコードセット取得
• 　　６ー２ー２．CommandでSQL文を実行しレコードセット取得
• 　　６ー２ー３．CommandにSQL文を格納後Recordsetで取得
• 　　６ー２ー４．Recordsetに直接SQL文を指定しレコードセット取得
• 　６ー３．SQL（Insert等）文で操作
• 　　６ー３ー１．ConnectionでSQL文を実行しデータ変更
• 　　６ー３ー２．CommandでSQL文を実行しデータ変更
• 　　６ー３ー３．CommandにSQL文を格納後Recordsetで実行しデータ変更
• 　　６ー３ー４．SQL文を直接ecordsetで実行しデータ変更
• ７．データの一括処理
• アプリ実例・関連する項目
• サンプルファイル

１．データベースへの接続方法

「DAOでAccess･Excel･CSV等へ接続・操作」で説明しましたが、ExcelのVBAから「Microsoft Access」「Excelのワークシート」「CSV等のテキストファイル」のデータベースに接続・操作する方式には、主に「ODBC」「DAO」「ADO」の３種があります。
今回はADO方式の内、JET・ACEプロバイダーを使ったルート（図０１では、黒線のルート）について説明します。

図０１別窓
これ以外の接続・操作については、以下を参照下さい。
　・DAOでAccess･Excel･CSVへ接続・操作
　・ADOでAccess･Excel･CSVへ接続・操作(JET･ACEプロバイダ編)　　←今回
　・ADOでAccess･Excel･CSVへ接続・操作(MSDASQLプロバイダ編)
　・ODBCでAccess･Excel･CSVへ接続・操作

２．ADOのオブジェクトについて

ADOでのデータベースへの接続・操作には、ADOの「Connection」「Command」「Recordset」の各オブジェクトを図０２のように組み合わせて行います。表内の指定内容の「テーブル」と「SQL文」は、Recordset.OpenメソッドやCommand.CommandTextプロパティ、Connection.Excecuteメソッドのパラメータとして指定する内容を指しています。

図０２別窓
まず「各オブジェクト、及びそのメソッド・プロパティ」について説明をした後、図０２で示した各ルートの実際のコードを紹介します。とりあえず接続するコードを知りたい場合は、先に「データベースに接続・操作するためのコード例」を確認下さい。

２ー１．ADOオブジェクトの種類

ADO直下には図０２で示した以外にも、多くのオブジェクトが存在します。図０３はそのオブジェクトが、バージョンにより使えるか否かと、実行時バインディング時にCreateObjectで生成可能か否かをまとめたものです。

ｵﾌﾞｼﾞｪｸﾄ	内容	事前ﾊﾞｲﾝﾃﾞｨﾝｸﾞ		実行時ﾊﾞｲﾝﾃﾞｨﾝｸﾞ
		Ver 2.8	Ver 6.1	CreateObject可
Command	ﾃﾞｰﾀｿｰｽに対して実行する特定ｺﾏﾝﾄﾞの定義	〇	〇	〇
Connection	ﾃﾞｰﾀｿｰｽへの接続	〇	〇	〇
Error	発生するｱｸｾｽｴﾗｰの詳細情報	〇	〇	〇
Errors		〇	〇	×
Field	ﾃﾞｰﾀ列	〇	×	×
Fields		〇	×	×
Parameter	Commandｵﾌﾞｼﾞｪｸﾄに関連付けられた引数	〇	〇	〇
Parameters		〇	〇	×
Property	ADOの動的特性	〇	〇	×
Properties		〇	〇	×
Record	Recordsetの行､又はﾌｧｲﾙｼｽﾃﾑ内のﾃﾞｨﾚｸﾄﾘやﾌｧｲﾙ	〇	〇	〇
Recordset	ｺﾏﾝﾄﾞ実行により返された結果	〇	〇	〇
Stream	ﾃﾞｰﾀの流れ	〇	〇	〇

図０３別窓
これらのオブジェクトの内、データベースとの接続・操作にかかわる「Connection」「Recordset」「Command」オブジェクトについて、今回説明していきます。
なお後述する参照設定（図０４）で「バージョン6.1」を選択した場合、図０３の「Ver6.1」列で分かるように、Field（Fields）オブジェクトは存在しません。ですので「RecordsetのFieldsをADOのFieldsオブジェクトで受け取る（今回は、その手法については説明を省略しています）」場合は、バージョンを2.8とする必要があります。
但し実行時バインディング（CreateObject使用）の場合は、Fieldsオブジェクトは単なるObject（総称オブジェクト型）として宣言しますので、RecordsetのFieldsを「一般のObject」として受け取る事が可能です。

２ー２．ADOオブジェクト生成

ADOでデータベースとやり取りするには、まずADOオブジェクトを生成する必要があります。その生成方法には以下の２種類があります。
　・「事前バインディング」・・・コードを実行する前に生成
　・「実行時バインディング」・・コードを実行した時に初めて生成
事前バインディングの特徴は、コード作成時にインテリセンス（コード補完機能＝使用可能なプロパティ等が表示され、選択することが可）が使えることと合わせ、効率が良い（≒実行速度が速い）ことです。
一方実行時バインディングは、PC環境の異なる複数ユーザーにマクロを配布する時でも安全です。

２ー２ー１．事前バインディング

事前バインディングでは、VBE（コードを書くウィンドウ）上部の「ツール」→「参照設定」から、図０４のように「Microsoft ActiveX Data Objects X.X Library」にチェックをし有効にします。

図０４別窓
X.Xの部分はバージョンを表していますが、最新Excelでは「2.8」①までと、少し飛んで「6.1」②が選択できるかと思います。
通常は「最新のもの」を選択するのが良いとされています。しかし複数のPCを対象に動かすようなシステムの場合に「最新バージョン」を選択して作ってしまうと、もしその「最新バージョン」がインストールされていないPCが存在する場合は、うまく動かない可能性が出てきます。ライブラリを選択する際には「どのPCにも入っているバージョン」を選ぶのが良いと思います。
なお、バージョンの2.8と6.1では、図０３のようにADO直下のオブジェクトが異なります。最新の6.1にはField（Fields）オブジェクトがありません。但し、図５３の２１０行目のような「カーソル行の対象列」を示すFieldsプロパティは大丈夫です。このFieldsはRecordsetオブジェクトのFieldsだからです。
プログラム的には、図０４のようにADOのライブラリーを参照設定した上で、図０５のように「オブジェクト変数をADOオブジェクトとして宣言」→「New句を使って生成」した後、オブジェクト変数を処理に使用します。

0. '==========　⇩(1)　事前バインディングでの宣言と生成 ============
1. 　Dim cn As ADODB.Connection 　 '←Connectionオブジェクトの宣言
2. 　Dim rs As ADODB.Recordset 　　 '←Recordsetオブジェクトの宣言
3. 　Dim cmd As ADODB.Command 　 '←Commandオブジェクトの宣言
5. 　Set cn = New ADODB.Connection 　 '←Connectionオブジェクトの生成
6. 　Set rs = New ADODB.Recordset 　　 '←Recordsetオブジェクトの生成
7. 　Set cmd = New ADODB.Command 　 '←Commandオブジェクトの生成
8. 　
9. 　（ 生成したcn,rs,cmdオブジェクト変数を使い、接続やデータ取得・変更の処理･･･等）

図０５別窓
０１～０３行目では、各オブジェクト型毎に変数宣言をします。
０５～０７行目では、New句を使ってオブジェクトを生成します。
オブジェクト生成後は、そのオブジェクト変数（図０５では、cn,rs,cmd ）を使って処理を行います。

２ー２ー２．実行時バインディング

実行時バインディングの場合は、使用するオブジェクト毎にCreateObjectを使って生成します。
なおCreateObjectで生成できるADOオブジェクトは、図０３で示したように一部分のみになります。

20. '==========　⇩(2)　実行時バインディングでの宣言と生成 ============
21. 　Dim cn As Object 　 '←Connectionオブジェクトの宣言
22. 　Dim rs As Object 　　 '←Recordsetオブジェクトの宣言
23. 　Dim cmd As Object 　 '←Commandオブジェクトの宣言
25. 　Set cn = CreateObject("ADODB.Connection") 　 '←Connectionオブジェクトの生成
26. 　Set rs = CreateObject("ADODB.Recordset") 　　 '←Recordsetオブジェクトの生成
27. 　Set cmd = CreateObject("ADODB.Command") 　 '←Commandオブジェクトの生成
28. 　
29. 　（ 生成したcn,rs,cmdオブジェクト変数を使い、接続やデータ取得・変更の処理･･･等）

図０６別窓
２１～２３行目では、単なるObject型として変数宣言をします。
２５～２７行目では、CreateObject関数を使って各オブジェクトを生成します。オブジェクト生成後は、そのオブジェクト変数（図０６では、cn,rs,cmd ）を使って処理を行います。

３．Connectionオブジェクト

Connectionオブジェクトには複数のプロパティ・メソッドが存在します。
データベースに接続するためには、接続条件を指定したOpenメソッドの実行が必須ですが、Openの前にConnectionStringプロパティ、Providerプロパティなどに接続条件を事前設定させる手法も使えます。
またConnectionオブジェクトのExecuteメソッドを使えば、コマンドが実行できます。

３ー１．Openメソッド他（データベース接続関係）

データベースに接続するには、下記のようにConnectionオブジェクトのOpenメソッドを使います。
　Connection.Open (ConnectionString, UserID, Password, Option)
ConnectionのOpenメソッドには、４つのパラメータ設定が可能です。全て省略可です（図０７）。

Connection.Openメソッドのパラメータ

パラメータ		内容
ConnectionString	省略可	接続情報（図０８）
UserID	省略可	接続時のユーザー名
Password	省略可	接続時のパスワード
Options	省略可	接続の同期/非同期（図２２）

図０７別窓
なお、第４パラメータのOptionsは、ExecuteメソッドのOptionsとは全く別なので混同に注意です。

３ー１ー１．第１パラメータ（ConnectionString：接続情報）

図０７の第１パラメータ（ConnectionString）には、図０８のような情報を「文字列」として組み込みます。各項目の区切りは「;（セミコロン）」です（最後の項目には、セミコロンは必須ではありません）。
図０８では「JET・ACE列」と「ODBC列」の２通りを併記していますが、「JET・ACE 列」の情報を使うことで、今回、図０１のように「JET・ACEプロバイダ」→「JET・ACEエンジン」→「各データベース」という流れで接続・操作ができます。
なお「JET・ACE列とODBC列の混在」はできません。

ADOのConnectionStringの接続情報

内容	JET・ACE	ODBC
ﾌﾟﾛﾊﾞｲﾀﾞｰ	Provider=Microsoft.ACE.OLEDB.12.0	Provider=MSDASQL
ﾄﾞﾗｲﾊﾞｰ	ー	Driver={ODBCのﾄﾞﾗｲﾊﾞｰ名}
DB名	Data Source=DB名	DBQ=DB名
読取/書込	ー	ReadOnly=True/False
DSN名	ー	DSN=DSN名
ﾕｰｻﾞｰ名	User ID=ﾕｰｻﾞｰ名	UID=ﾕｰｻﾞｰ名
ﾊﾟｽﾜｰﾄﾞ	Password=ﾊﾟｽﾜｰﾄﾞ	PWD=ﾊﾟｽﾜｰﾄﾞ
URL名	ー	URL=URL名
拡張ﾌﾟﾛﾊﾟﾃｨ	Extended Properties=情報	ー

図０８別窓
第１パラメータとして必須なのは「プロバイダー」と「データベース（DB）名」です。またExcelのワークシートやCSVファイルをデータベースとして扱う場合は、加えて「拡張プロパティ（Extended Properties）」の指定が必要です。

３ー１ー１ー１．プロバイダー名

図０８では、プロバイダーの指定（Jet・ACEの列）を「"Provider = Microsoft.ACE.OLEDB.12.0"」としましたが、右辺の「ACE」はACEプロバイダーを示し、「12.0」はバージョンを示します。プロバイダに対する「対応するデータベースファイル（拡張子）」は、図０９のようになっているようです。

プロバイダ			Access			Excel		Text
			.mdb (Jet作成)	.mdb (ACE作成)	.accdb (ACE作成)	.xls ～2003	.xlsx .xlsm .xlsb 2007～	.csv.txt
Jet系	Microsoft.Jet.OLEDB.4.0	Access2000～2003	〇	×	×	〇	×	〇
ACE系	Microsoft.ACE.OLEDB.12.0	Access2007～2010	〇	〇	〇	〇	〇	〇
	Microsoft.ACE.OLEDB.15.0	Access2013	(〇)	(〇)	(〇)	(〇)	(〇)	(〇)
	Microsoft.ACE.OLEDB.16.0	Access2016～	〇	〇	〇	〇	〇	〇

図０９別窓
図０９のプロバイダ名の右列は、各プロバイダがどの時代のものかを表しています。例えば「Microsoft.ACE.OLEDB.12.0」は「Access2007～2010」と同時期のもので、バージョン番号も同じ（どちらもメジャーバージョンは 12）です。と言ってそれ以降のOfficeで使えない訳では無く下位互換なので、例えばOffice2016（メジャーバージョン ＝ 16）では「12.0 も使える」事になります。
但しAccess2013の「15.0」は特殊なようで、Office2016以上には標準では入っていませんし、逆にOffice2013で下位の12.0を使うとエラーが発生するようです。
今回のコード例では「Microsoft.ACE.OLEDB.12.0」を使って説明をしていますが、これは現状最も広く使えそうなプロバイダーだと思ったからです。本来ならば（32ビット、64ビットの違いも含めて）Officeの各バージョン毎に「どのプロバイダが使えるか」を表形式にしたかったのですが、手持ちのExcel種類が少なすぎて完成させられませんでした。複数種のO/S・Officeで使う場合には、事前に確認をした方が良いかもしれません。
なおOfficeが64ビット版の場合、Jet系プロバイダー（32ビット版のみしか無い）は動きません。
またOffice2010（メジャーバージョン＝14）と同時期の「Microsoft.ACE.OLEDB.14.0」というのも存在するとの情報もあるのですが、私の引退したPC（Win Xp + 32ビット版Excel2010）で調べたところ、残念ながら14.0ではエラーとなりました。よって図０９では「Office2010は12.0」としました。

(プロバイダの存在確認) ADOを実行するPC内で、どのプロバイダが使用可能かは、WindowsのPowerShellで下記コマンドを実行することで確認できます。 「 (New-Object data.oledb.oledbenumerator).getElements() | select SOURCES_NAME, SOURCES_DESCRIPTION 」 結果は、例えば図１０のようになり、今回の説明でも出てきたプロバイダが表示（赤矢印）されています。 図１０別窓 なおPowerShellには何種類かがありますが、ビット版で考えると「PowerShell」と「PowerShell(x86)」の２種類です。最近のWindows（64ビット）で考えると、単なる「PowerShell」が64ビット版で、「PowerShell(x86)」が32ビット版です。 使用可能なプロバイダを調べるには、以下のようにします。 　・Windowsが64ビット版 ＋ Officeが64ビット版　→　「PowerShell」で上記コマンドを実行 　・Windowsが64ビット版 ＋ Officeが32ビット版　→　「PowerShell(x86)」で上記コマンドを実行 　・Windowsが32ビット版 ＋ Officeが32ビット版　→　「PowerShell」で上記コマンドを実行 Windowsが32ビット版の場合、そのPowerShellは32ビット版となります。また、Officeは32ビット版に限りられます。 つまり「Officeのビット版と同じビット版のPowerShellを使用」すると、使用可能なプロバイダが分かるようです。 図１０は「Windowsが64ビット版 ＋ Officeが64ビット版」の時のもので、PowerShellも64ビット版ですが、逆に、32ビット版のPowerShell(x86)でコマンドを実行してみたのが以下になります。 図１１別窓 32ビット版には「Jet.4.0」が入っていますが、Officeが64ビット版なので使えないですし、32ビット版Officeがインストールされていないため32ビット系の「ACE系」プロバイダがない　という事のようです。 次の回で説明する「MSDASQL」は両方に存在します。どのビット版Officeがインストールされても大丈夫な状態です。

３ー１ー１ー２．データベース名

データベース名は、対象とするデータベースの種類により図１２のように変わります。

	データベース名
Access	ファイル名（*.accdb, *.mdb）
Excel	ファイル名（*.xlsx 等）
CSV等	CSVﾌｧｲﾙがあるフォルダー名

図１２別窓
AccessやExcelのように、ファイル内に複数のテーブルを持てるタイプでは「ファイル名＝データベース名」となりますが、CSVファイルのようにファイル＝テーブルのようなものは「フォルダー名＝データベース名」となります。

(テーブル名) 各データベースに於ける「テーブル」について図１３に示します。 テーブル 例 操作するﾃｰﾌﾞﾙ SQLのテーブルとして Access テーブル名 TestTable "TestTable" "Select * from TestTable" Excel ﾜｰｸｼｰﾄ名 Sheet1 "Sheet1$" "Select * from [Sheet1$]" CSV等 CSVﾌｧｲﾙ名 its-041.csv "its-041.csv" "Select * from [its-041.csv]" 図１３別窓 Accessに於けるテーブルは、通常のデータベースとしてのテーブルと同じ扱いになります。 Excelでは、ワークシートがテーブル扱いとなります。例えばSheet1にデータがあるとすれば、Recordset.Openの第１パラメータにテーブル名を指定するような場合は、「"Sheet1$"」のように「シート名＋$マーク」とします。またSQL文の中で使用する場合は、更に角カッコで囲み「Select * from [Sheet1$] 」のようにします。 CSVでは、CSVファイルそのものがテーブル扱いとなります。ファイル名がits-041.csvとすれば、テーブル名指定の場合はファイル名をそのまま使用して「"its-041.csv"」とし、SQL文の中で使う場合は角カッコで囲み「Select * from [its-041.csv] 」とします。

３ー１ー１ー３．ユーザー名、パスワード

データベースに「ユーザー名」や「パスワード」が設定されている場合は、ConnectionStringに指定します。
なお、Excelの「ブックの保護」で設定したパスワードは対象外です（「Password=ブック保護のパスワード」を指定しても、データは取得できません）。
このユーザー名・パスワードをExcelのVBA側で作成したAccessファイルに設定しようと試みました。やり方としては、ADOXのUsersコレクションから、NameプロパティとChangePasswordメソッドを使うようですが、残念ながらExcel VBAからは操作できませんでした。
実際のAccessで作成されたデータベース（*.accdb, *.mdb）の場合は当然設定が可能だと思います。
またこの内容は、Openメソッドの第２・第３パラメータと同じと思われます。

３ー１ー１ー４．拡張プロパティ（Extended properties）

ExcelのシートやCSVをデータベースにする際には、「Extended properties=」に続けてデータベースの種類（＝ISAM形式（Indexed Sequential Access Method））を指定します。

データベース	指定文字列
Excel2007～	"Extended properties=Excel 12.0"
Excel97～2003	"Extended properties=Excel 8.0"
CSVやﾃｷｽﾄﾌｧｲﾙ	"Extended properties=Text"

図１４別窓
そのPCで使用可能なISAM形式はレジストリで確認できるようで、例えば私のPCでは図１５のようになります。

図１５別窓
なおルール通りではありませんが、例えば「its-042.xlsm」に接続したい場合、ISAMを「Excel 8.0（Excel97～2003対応）」と指定しても問題無く接続出来ますし、「Excel 12.0 Xml（本来は拡張子xlsxに対応）」を指定してもOKです。下位互換と言えば良いのか、Excel間での壁は低いようです。
しかしデータベースの種類だけでは無く、使用するデータベースに関する「もっと細かい設定」が必要になる場合があります。例えば「データベースの先頭行がタイトルか否か」等です。その場合の構文としては「HDR=Yes」等と指定するのですが、これを図１４の情報と併せて「"Extended properties=Excel 12.0;HDR=Yes;"」という文字列を組み立て、それをConnectionStringにすると、残念ながらエラーが出てしまいます。
ConnectionStringに例えば「“Provider = Microsoft.ACE.OLEDB.12.0; Data Source=C:¥Data¥its-042.xlsm; Extended Properties= Excel 12.0; HDR=No; " 」という文字列を指定すると、VBAはその文字列を「;（セミコロン）」で区切りながら解釈し、値を図１６のように各プロパティに格納していきます。しかし、Properties("Extended Properties")プロパティには「理解できない文字列」として値が格納されてしまうためにエラーとなるのです。

図１６別窓
一番最後の「HDR=No」がなぜ先にProperties("Extended Properties")プロパティに入ってしまうのかは、良く分かりませんでした。「Excel 12.0」と「HDR=No」の順番などを色々変えて試してみたのですが、どうやっても「HDR=No; Excel 12.0」という順番で入ってしまいます。
なお、Openメソッドの第１パラメータ（ConnectionString）に設定する事は、ConnectionオブジェクトのConnectionStringプロパティに設定することと同じですが、それ以外に「Connectionの各プロパティに直接指定」する方法もあります。
例えば、以下のように分割して指定することでもOKです。
　「Connection.Provider = " Microsoft.ACE.OLEDB.12.0 "」
　「Connection.Properties("Data Source") = "C:¥Data¥its-042.xlsm"」
　「Connection.Properties("Extended Properties") = "Excel 12.0; HDR=No"」
このように、直接「Connection.Properties("Extended Properties")」に拡張プロパティ値を指定すると、上記で示した「両端を二重のダブルクォーテーションで囲む」ことは不要になるので便利です。
ISAM形式を含めた拡張プロパティの設定項目を整理すると以下のようになります。

項目	内容
ISAM形式 (先頭部)	"Excel 12.0"：Excel2007～ "Excel 8.0"：Excel97～2003 "Text"：CSVやﾃｷｽﾄﾌｧｲﾙ
HDR	YES(既定)=先頭行がタイトル NO=先頭行からﾃﾞｰﾀ
IMEX	0=書込(ﾃﾞｰﾀ型混在時はｴﾗｰ) 1=読取専用(ﾃﾞｰﾀ型混在時､文字列型で読込み) 2=読取/書込(ﾃﾞｰﾀ型混在時はｴﾗｰ)
FMT	ﾃｷｽﾄﾌｧｲﾙの区切り種類(ｶﾝﾏ区切り固定) Delimited､又はCSVDelimited
MAXSCANROWS	ﾃﾞｰﾀ型判定の行数：８行で固定

図１８別窓
「HDR」は、データの先頭行が「タイトル行（Yes）」か「データ（No）」かの指定です。
なお、この先頭行をどう判断するかは、HDR項目だけでは決まりません。実は、次のIMEX項目の値にも影響を受けてしまいます。HDRとIMEXの組み合わせでの「先頭行の判断」は次の図１９のようになります。

先頭行の判断

		HDR
		省略	Yes	No
I M E X	省略	タイトル	タイトル	データ
	0	タイトル	タイトル	タイトル
	1	タイトル	タイトル	データ
	2	タイトル	タイトル	データ

図１９別窓
先頭行をタイトル行としたい場合は「IMEX = Yes、またはIMEXを省略」すればOKです。しかし先頭行をデータ行としたい場合、「IMEX=0」を付けてしまうと、思った通りにはならないので注意が必要です。
「IMEX」は開くモードの指定です。他サイトでは、以下のように説明しています。
　IMEX=0：書き込み（データ型が混在している時にはエラー発生）
　IMEX=1：読み取り専用（データ型混在時は文字列型で読み込む）
　IMEX=2：読み取り／書き込み（データ型が混在している時にはエラー発生）
しかし、実際の動作は少し異なり「よりみち」のようになるようです。
「FMT」は、CSV等のテキストファイルのデータ区切りに何の記号を使うかの指定です。設定値としては、カンマ区切り（CSVDelimited、Delimited）、タブ区切り（TabDelimited）の設定値があるようですが、試してみたところ「カンマ区切り以外のデータには対応できない」という結果となりました。
あるサイトでは「JETでは設定可能、ACEでは不可能」との説明もあるのですが、少なくともExcelのVBAからの指定は無視されるようです。
「MAXSCANROWS」は、データ型を判断するための行数指定です。既定値は「８（データ先頭から８行目の範囲で、異なるデータ型の有無を調べる）」で、１～１６の設定が可能　との事ですが、ExcelのVBAからは何を指定しても「８行固定」でした。
なお図２０のように、レジストリでMAXSCANROWS値を設定する方法はあるようです。しかし、VBAの範囲からは外れますので今回は「MAXSCANROWSは設定不可」という事にしておきます。

図２０別窓

（IMEX値の検証） 上記IMEXの動作検証のため、「Excelシートデータベース」「CSVファイル」上でデータ型の混在／非混在状態を作り、条件を振って試してみました。併せてプロバイダも、ACE.12.0とJET.4.0を比較しました（図２１）。 なお表の左端の「Excel」「CSV」は対象とするデータベースを、「Table」「SQL」はRecordset.Openに指定する第１パラメータをテーブルにするかSQL文にするかを、「Read」「Write」は、処理が参照（Select）か変更（Insert等）かを表しています。またテーブルを指定する際は、Recordset.Openのパラメータとして第５パラメータのOptionsに512（adCmdTableDirect）を、CursorType=0、LockType=2を指定して実行させました。 IMEX ACE.12.0 JET.4.0 0 1 2 省略 0 1 2 省略 Excel Table Read 〇／△ 〇／〇 〇／△ 〇／△ 〇／△ 〇／〇 〇／△ 〇／△ Write 〇／〇 ×／× ×／× 〇／〇 〇／〇 ×／× 〇／〇 〇／〇 SQL Read 〇／× 〇／〇 〇／× 〇／× 〇／△ 〇／〇 〇／△ 〇／△ Write 〇／〇 ×／× ×／× 〇／〇 〇／〇 ×／× 〇／〇 〇／〇 CSV Table Read 〇／△ 〇／△ 〇／△ 〇／△ 〇／△ 〇／△ 〇／△ 〇／△ Write 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 SQL Read 〇／× 〇／× 〇／× 〇／× 〇／△ 〇／△ 〇／△ 〇／△ Write 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 〇／〇 データ型：混在無し／混在有り 〇印：正常処理（データ型が異なる場合も、文字列として出力） ×印：実行不可、またはデータ型が異なる行でエラーが出る △印：異なるデータ型は空白となる 赤字：プロバイダ種により異なる結果 図２１別窓 まずIMEXの機能ですが、この結果を見る限りでは、他サイトが説明している状態にはなっていません。辛うじて、IMEX=1は読取専用なので「Excelでは書き込みが不可」なことくらいでしょうか。 またプロバイダ違いで結果が異なる部分（赤字）で特記すべきは「JETでは正常に書き出し処理できていたIMEX=2が、ACEでは処理出来ない」事です。昔作ったプログラムをJetからACEに置き換えた場合、IMEX=2で処理している部分ではエラーとなってしまうので注意が必要です。 またデータ型が混在する場合、IMEX=1では「空白では無く、文字列として出力」してくれますが、この機能は「異なるデータ型が、８行目以内に存在」する場合に限られます。もし９行目以降に異なるデータ型が初めて出現した場合には、空白として出力されます。 そのための機能として「MaxScanRows」があるはずなので、色々と設定してみたのですが、今回条件ではACE・JETともに「データ型混在の判断行数は８行で不変」でした。

３ー１ー２．第２、第３パラメータ（UserID：ユーザー名、Password：パスワード）

Connection.Openの第２、第３パラメータは「UserID」と「Password」です。データベース接続にユーザー名とパスワードが必要な場合は設定をします。なおこの項目は、ConnectionStringのユーザー名・パスワードと同じもののようです。

３ー１ー３．第４パラメータ（Options：同期／非同期）

Connection.Openの第４パラメータ（Options）には、以下の値を指定します。

定数	値	内容
adAsyncConnect	16	接続を非同期で開く
adConnectUnspecified	-1	接続を同期で開く(既定)

図２２別窓
同期で開く場合は、Openの処理をしている間は他の処理が出来ませんが、非同期の場合はOpen処理をしている間も次の処理に移る事が可能になります。但しStateプロパティ等で「Open処理が完了したか」を確認してからレコードセット取得処理やExecute処理に入る必要があります。
Open処理に多くの時間が必要で、且つ併行して行う作業が存在するようなシステム以外では、既定の「同期で開く」で良いと思われます。
なお同期・非同期の情報保持は、OpenしたConnectionオブジェクトのどのプロパティが担当しているかは分かりませんでした。ですのでOpen前に「同期・非同期をプロパティ設定」する手法は不明です。

３ー１ー４．データベース接続までのコード例

接続情報を指定してデータベースに接続する手順を、最も簡単な例でいくつか紹介します。
まず、Connection.Openメソッドの第１パラメータ（ConnectionString）に、プロバイダ名とデータベース名を指定する書き方を図２３に示します。なおADOオブジェクトは実行時バインディング（以下同様）としています。

40. '==========　⇩(3)　Openメソッド実行時に全て指定 ============
41. 　Dim cn As Object 　 '←実行時バインディングのConnectionオブジェクト
42. 　Dim s As String 　 '←ConnectionStringの内容
44. 　Set cn = CreateObject("ADODB.Connection") 　 '←Connectionオブジェクトを生成
46. 　s = ThisWorkbook.Path & "¥" & "its-041.accdb" 　　　　　 '←データソース情報
47. 　s = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & s 　 '←プロバイダとデータソースを文字列化
49. 　cn.Open s 　 '←プロバイダとデータソースをOpenメソッドの第１パラメータに指定
50. 　　　（処理）

図２３別窓
４４行目「Set cn = CreateObject("ADODB.Connection")」で、Connectionオブジェクトを生成します。
４６～４７行目で、第１パラメータ（ConnectionString）の文字列を作成しています。プロバイダー（Provider=）として「Microsoft.ACE.OLEDB.12.0」を、データベース（Data Source=）として「ThisWorkbook.Path & "¥" & "its-041.accdb"」を指定します。
パラメータの文字列が完成したら、４９行目「cn.Open s」で、Openメソッドの第１パラメータに接続情報を渡して、データベースに接続します。
図２３のように「接続情報文字列をOpenメソッドの第一パラメータ（ConnectionString）に渡す」のでは無く、「ConnectionオブジェクトのConnectionStringプロパティ」に事前に渡した後、Openメソッドを実行する事も可能です。コードとしては図２４のようになります。

60. '==========　⇩(4)　ConnectionStringプロパティに値を指定 ============
61. 　Dim cn As Object 　 '←実行時バインディングのConnectionオブジェクト
62. 　Dim s As String 　 '←ConnectionStringプロパティの内容
64. 　Set cn = CreateObject("ADODB.Connection") 　 '←Connectionオブジェクトを生成
66. 　s = ThisWorkbook.Path & "¥" & "its-041.accdb" 　　　　　 '←データソース情報
67. 　s = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & s 　 '←プロバイダとデータソースを文字列化
69. 　cn.ConnectionString = s 　 '←ConnectionStringプロパティに接続情報を渡す
71. 　cn.Open 　 '←パラメータ無しでOpenメソッドを実行
72. 　　　（処理）

図２４別窓
図２４の６９行目では「Provider情報」と「Data Source情報」をConnectionStringプロパティに設定しています。この設定により、Provider情報は「Providerプロパティ」に、Data Source情報はPropertiesコレクション内の「Data Sourceプロパティ」に格納された後、７１行目「cn.Open」でデータベースに接続します。
なおConnectionStringプロパティへの設定を重複すると、各プロパティは一旦空になった後、最新の情報に置き換えられてしまいます。但しProviderプロパティだけはProvider情報を書き換えない限りは残ってくれるようです。
図２３ではOpenメソッドの第１パラメータに接続情報を渡し、図２４ではConnectionStringプロパティに接続情報を渡しましたが、Connectionオブジェクト配下には、ConnectionStringプロパティの他にも以下のようなプロパティがあります（図２５）。
（接続情報に関するプロパティのみを書き出しています。）

プロパティ		内容
ConnectionString		接続情報文字列
Provider		接続するﾌﾟﾛﾊﾞｲﾀﾞ名 (既定：MSDASQL)
Properties ｺﾚｸｼｮﾝ	Password	パスワード
	User ID	ユーザー名
	Data Source	ﾃﾞｰﾀﾍﾞｰｽ名
	Extended Properties	拡張プロパティ

図２５別窓
この各プロパティに直接的に値を格納する手法が図２６です。

80. '==========　⇩(5)　各プロパティに値を直接指定 ============
81. 　Dim cn As Object 　 '←実行時バインディングのConnectionオブジェクト
83. 　Set cn = CreateObject("ADODB.Connection") 　 '←Connectionオブジェクトを生成
85. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0" 　 '←プロバイダを設定
86. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←データソースを設定
88. 　cn.Open 　 '←パラメータ無しでOpenメソッドを実行
89. 　　　（処理）

図２６別窓
８５行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」では、ConnectionオブジェクトのProviderプロパティに、ACEプロバイダを設定しています。
８６行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb"」では、ConnectionオブジェクトのPropertiesコレクション内のData Sourceプロパティに、Accessのファイル名を設定しています。
また、ExcelやCSVをデータベースとして使用する場合は「拡張プロパティ情報」を、ConnectionオブジェクトのPropertiesコレクション内のExtendes Propertiesプロパティに指定します。
各プロパティ値にデータを設定したら、８８行目「cn.Open」でデータベース接続します。

３ー２．Executeメソッド（コマンドの実行）

ConnectionオブジェクトのExecuteメソッドの構文は以下のようになります。戻り値は「Recordsetオブジェクト」です
　Recordsetオブジェクト = Connection.Execute( CommandText, RecordsAffected, Options )
戻り値（レコードセット）をデータ処理する場合は、Setステートメントで受け取りますが、そのレコードセットは「読み取り専用」です。そのため、データの取得のみで、追加や変更・削除処理は出来ません。
なお第１パラメータに「InsertやUpdate・DeleteのSQL文を指定」した場合は、戻り値を操作している訳では無いので、追加・変更・削除処理は可能です（Excelは削除不可、CSVは変更・削除不可 である事は変わりません）。
このようなInsert文等を指定した時は、変更を目的としたレコードセットを受け取る必要が無いので、以下のように戻り値を受け取らず、そのまま実行します。
　Connection.Execute( CommandText, RecordsAffected, Options )
なおレコードセットを受け取る必要が無くても、ExecuteメソッドはRecordsetオブジェクトを戻してきます。もし、その戻されたRecordsetオブジェクトがデータか否かを調べる必要がある場合には「戻されたRecordsetオブジェクトのStateプロパティ」を確認します。
値が１（adStateOpen）であればデータとしてのレコードセットであり、ゼロ（adStateClosed）であればデータでは無い事が分かるようです。なお「Recordset.Close メソッド」を実行すると、State値はゼロになります。
Executeメソッドに指定できるパラメータは、以下の内容になります。

パラメータ		内容
CommandText	必須	テーブル名､SQL文 等
RecordsAffected	省略可	Long型の変数に､変更レコード数を戻す
Options	省略可	CommandTextの種類(図３０)

図２７別窓
第１パラメータ（CommandText）は必須で、テーブル名、またはSQL文 等を文字列で指定します。
第２パラメータ（RecordsAffected）には、Long型の変数を指定します。第１パラメータにデータ変更を伴うSQL文（Insert・Update・Delete）を指定しExecuteメソッドを実行すると、変更対象となったレコード数がこの変数に戻されます。コードで示すと、図２８のようになります。

100. '==========　⇩(6)　Connection.Executeで変更対象行数を取得 ============
101. Sub Record_Count()
102. 　Dim cn As Object 　　 '←Connectionオブジェクト
103. 　Dim SQL As String 　　 '←SQL文
104. 　Dim cnt As Long 　　 '←変更対象のレコード数
106. 　Set cn = CreateObject("ADODB.Connection") 　　 '←Connectionオブジェクトの生成
108. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0" 　　 '←プロバイダをACEに設定
109. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　 '←データベースをこのExcelに設定
110. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←拡張プロパティにExcelを設定
112. 　cn.Open 　　 '←データベースに接続
113. 　　SQL = "update [db$] set St='XYZ' where DT=#2000/11/20#" 　　 '←SQL文にUpdate文を設定
115. 　　cn.Execute SQL, cnt 　　 '←SQL文を実行し、変更対象レコード数をcnt変数で取得
116. 　　MsgBox "変更対象のレコード数：" & cnt & "行" 　　 '←変更対象レコード数を表示
117. 　cn.Close 　　 '←データベースを閉じる
119. 　Set cn = Nothing
120. End Sub

図２８別窓
１１５行目「cn.Execute SQL, cnt」で、Executeメソッドの第２パラメータに指定した「Long型の変数cnt」に、変更対象となったレコード数が戻されますので、それを１１６行目「MsgBox "変更対象のレコード数：" & cnt & "行"」でメッセージ表示をさせています。
出力された様子は図２９のようになります。

図２９別窓
SQL文は１１３行目の「update [db$] set St='XYZ' where DT=#2000/11/20#」ですので、DT列が2000/11/20のものを抽出し、St列の値をXYZに変更しています。図２９のワークシートで、Dt列が「2000/11/20」なのは６～８行の「３レコード」なので、メッセージ表示も３行となります。
但し、変更する以前からSt列がXYZだった場合でも、値が変更された事は事実なので３行と表示されます。つまり、値が変わったことを表すのでは無い事には注意が必要です。言ってみれば「Select count(*) from [db$] where DT=#2000/11/20#」を実行した時に得られる値になります。
第３パラメータ（Options）は、第１パラメータ（CommandText）に指定したものの種類を指定します。

Options（第１パラメータの種類）

定数	値	内容
adCmdUnspecified or adOptionUnspecified	-1	種類を指定せず
adCmdText	1	SQL文
adCmdTable	2	テーブル
adCmdStoredProc	4	ｽﾄｱﾄﾞﾌﾟﾛｼｰｼﾞｬ
adCmdUnknown	8	不明（既定）
adAsyncExecute	0x10(16)	非同期実行
adAsyncFetch	0x20(32)	残り行を非同期で取得
adAsyncFetchNonBlocking	0x40(64)	取得中にﾌﾞﾛｯｸせず
adExecuteNoRecords	0x80(128)	行を返さないｺﾏﾝﾄﾞ
adCmdFile	256	Recordsetファイル
adCmdTableDirect	512	全列が返るテーブル （ExcelシートDB､CSVファイル）
adExecuteStream	0x400(1024)	ｺﾏﾝﾄﾞ実行結果をｽﾄﾘｰﾑとして返すもの
adExecuteRecord	0x800(2048)	単一行を返すもの

図３０別窓
既定値はadCmdUnknown（値＝8）です。SQL文を指定した場合は既定（第３パラメータを省略）でも正しく判定してくれます。しかしテーブル名を指定する場合には注意が必要で「Excelのシート名やCSVのファイル名をテーブル名として指定した場合、adCmdTableDirect（値＝512）を指定しないとエラーが発生」します。
またAccessでテーブル名を指定する際は、Optionsパラメータを省略する他、様々な値でもOKです。詳しくは「よりみち」を参照ください。

４．Recordsetオブジェクト

４ー１．Openメソッド（レコードセット取得）

データベース接続後は、データベースから値をレコードセットとして受け取り処理をしたり、データを変更（Insert、Update、Delete処理）したりします。
レコードセットの取得やデータ変更のSQL文を実行する方法１つとして、下記のようにRecordsetオブジェクトのOpenメソッドを使う方法があります。
　Recordset.Open (Source, ActiveConnection, CursorType, LockType, Options)
このOpenメソッドを実行すると、レコードセットを取得した場合はRecordsetオブジェクトにデータが入ります。
レコードセットのOpenメソッドには、下記の５つのパラメータが設定可能です。

Recordset.Openメソッドのパラメータ

パラメータ		内容
Source	省略可	①テーブル名 ②SQL文 ③Commandｵﾌﾞｼﾞｪｸﾄ
ActiveConnection	省略可	④Connectionオブジェクト ⑤ConnectionString文 (SourceにCommandｵﾌﾞｼﾞｪｸﾄを指定した場合は省略する事)
CursorType	省略可	カーソルの種類(図３２)
LockType	省略可	ロックの種類(図３３)
Options	省略可	Source(第1ﾊﾟﾗﾒｰﾀ)の種類(図３０)

図３１別窓

４ー１ー１．各パラメータの値

第１パラメータのSourceは、テーブル名やSQL文を指定します。また事前にCommandオブジェクトのCommandTextプロパティにテーブルやSQL文をセットしておき、そのCommandオブジェクトを第１パラメータに持ってくることも可能です。
なお、Commandオブジェクトを指定する場合は、CommandTextプロパティに「テーブル名」や「SQL文」を格納するのと同時に、ActiveConnectionプロパティに接続中のConnectionオブジェクトを指定することが必要です。そして、下で説明する第２パラメータは必ず省略させます。
もし、第１パラメータにSQL文の例えば「Select * from テーブル名」を指定すると、第１パラメータにテーブル名を指定したのと同じレコードセットが得られることになります。しかし、テーブル名指定の時に可能だったデータの挿入・変更・削除処理は、Select文で全レコードを取り出したレコードセットでは実行できません。
（再確認したら、Select文指定時でもデータの挿入・変更・削除処理が可能と分かりました（テーブル名指定時と同じ）。当時のExcelの状態がおかしかったのかもしれません。誤情報を流してしまい、申し訳ありませんでした。2023/11/28）
第２パラメータのActiveConnectionは、接続しているConnectionオブジェクト変数を指定します。その他の方法として、Connectionオブジェクトの接続情報を文字列で指定することも可能です。
なお、各プロパティに値を直接指定している場合はConnectionStringのみでは充分では無く、Provider情報やデータベース名は盛り込んでおく必要があります。
また、第１パラメータにCommandオブジェクトを指定した場合は、第２パラメータは必ず省略します。
第３パラメータのCursorTypeには、以下の定数を指定します。

CursorType（カーソルの種類）

定数	値	内容
adOpenForwardOnly	0	前方スクロールタイプカーソルを開く（既定）
adOpenKeyset	1	キーセットカーソルを開く
adOpenDynamic	2	動的カーソルを開く
adOpenStatic	3	静的カーソルを開く
adOpenUnspecified	-1	カーソルを指定せず

図３２別窓
第４パラメータのLockTypeには、以下の定数を指定します。

LockType（ロックの種類）

定数	値	内容
adLockReadOnly	1	読み取り専用レコードを示す（既定）
adLockPessimistic	2	編集直後にレコードをロックする
adLockOptimistic	3	Updateメソッドを呼び出すときにのみレコードをロック
adLockBatchOptimistic	4	バッチ更新
adLockUnspecified	-1	ロックの種類を指定せず

図３３別窓
この第３（CursorType）と第４（LockType）パラメータの設定には注意が必要です。「各パラメータの組み合わせ」で詳しく説明しますが、第１パラメータにテーブル名を指定する際に「第３と第４パラメータを省略すると、思った処理ができない」可能性があります。逆に第１パラメータにSQL文を指定すれば、大きな不具合は無さそうです。
第５パラメータのOptionsは、第１パラメータ（Source）に指定したものの種類を、図３０の定数で指定します。内容はConnectionオブジェクトのExecuteメソッドの第３パラメータ、CommandオブジェクトのExecuteメソッドの第３パラメータと同じです。
第１パラメータがSQL文の場合は省略でもOKですし、テーブルの場合でもAccessデータベースであれば省略でも問題ありません（詳細は「よりみち」を参照下さい）。しかし、テーブル名としてExcelのシート名やCSVのファイル名を指定する場合は、adCmdTableDirect（値＝512）を指定しないとエラーが発生します。

４ー１ー２．各パラメータの組み合わせ

このRecordset.Open のパラメータの内、第１パラメータは「テーブル名」又は「SQL文」のどちらか（Commandオブジェクトでも関節的にはテーブル名かSQL文のどちらか）ですし、第５パラメータは、その第１パラメータに指定したものが何かを指定しますので一意で決まると言っても良いと思います。
また第２パラメータは接続したConnectionですし、その接続情報を文字列で指定したとしても、内容的には同じです。
多くの選択が可能なのは第３パラメータ（CursorType）と第４パラメータ（LockType）で、その組み合わせが実行内容にどのように影響しているかを確かめてみたのが以下になります。

４ー１ー２ー１．Accessの場合（Openメソッドにはテーブル名を指定）

データベース対象をAccessに、第１パラメータ（Source）にテーブル名を指定した状態で、CurorType（第３パラメータ）とLockType（第４パラメータ）の色々な組み合わせ状態を作ります。その各組み合わせで、データ取得（Select）・データ挿入（Insert）・データ変更（Update）・データ削除（Delete）のどの操作が可能かをまとめたのが図３４です。

AccessDB + テーブル名

LockType定数	値	CursorType定数
		0 (Forward)	1 (Keyset)	2 (Dynamic)	3 (Static)	-1 (Unspecified)
adLockReadOnly	1	S･･･	S･･･	S･･･	S･･･	S･･･
adLockPessimistic	2	SIUD	SIUD	SIUD	SIUD	SIUD
adLockOptimistic	3	SIUD	SIUD	SIUD	SIUD	SIUD
adLockBatchOptimistic	4	S(IUD)	S(IUD)	S(IUD)	S(IUD)	S(IUD)
adLockUnspecified	-1	S･･･	S･･･	S･･･	S･･･	S･･･

S=Select処理、I=Insert処理、U=Update処理、D=Delete処理
「・」は処理不可
図３４別窓
まずLockTypeがadLockReadOnly（値＝1：読取専用）の場合は、Select処理のみとなる事は容易に想像がつきます。またadLockUnspecified（値＝-1：指定無し）は、既定のadLockReadOnlyと同じ状態になる事も頷けます。
LockType値が２（adLockPessimistic）と３（adLockOptimistic）の場合は、全ての処理が可能です。
一方でadLockBatchOptimistic（値＝4：バッチ更新）の場合は、IUDをカッコ付きとしていますが、注意点が２つあります。
１つ目は、ExcelのVBA上では「バッチ処理として記憶できる容量が１レコード」である事です。例えばUpdateで２行分の処理を行おうとすると、２行目の処理を行う時点で「変更を保留している行の数が、設定された条件を超えました」とのエラーが発生します。それなら上限を増やせば良いのですが、残念ながらExcelのVBA側から変更する方法は見つかりませんでした。
２つ目は「レコードを変更した後にUpdateメソッドを実行しても、データベース本体には変更内容が保存されない」事です。バッチ処理という言葉の通り「UpdateBatch」メソッドを実行しない限り、変更内容はデータベースに保存されません。
この内容をプロパティ面から検証したのが図３５です。Accessデータベースにテーブル名でレコードセットを取得（Open）した後の、Recordsetのプロパティです。CursorType値とLockType値を振ってプロパティを取得し、（Access,Excel,CSVでの違いも含め）違いが有ったプロパティのみを示しています。
なお図３５のプロパティ結果一覧は、Accessにテーブルを指定した時と、SQL文を指定した時とで、全く同じ結果となりました。

図３５別窓
この内容を図３４と見比べてみると「Updatability が値７（＝１（更新）+ ２（削除）+ ４（挿入）」だと、Insert・Update・Delete処理が出来るように見えます。また「iRowsetUpdateがTrue」の時とも思えます。
しかし、SQL文を実行させた時（図３６）の結果を併せてみると、傾向はありそうなものの決定的では無いことが分かります。
また「LockType」が値４の場合、値４は「バッチ処理」を表すはずなので、Updateメソッドではデータベースが更新されない（＝図３４）はずです。しかしSQL文の時（図３６）には即更新されます。
結論から言うと「プロパティ値を見ただけでは、動作内容は特定できない」ようです。但し、テーブルを第１パラメータに指定した際には、プロパティ値によりある程度予測ができるような気がします。
なお、CursorTypeが１（adOpenKeyset）または３（adOpenStatic）の時に、Bookmark値が異常に大きな値（この時のAccessテーブルのレコード数は４行）になっているのが気になりましたが、今回の操作では特に異常は発生しません。元々ブックマーク機能は「Bookmark値を一旦保存しておき、後からBookmarkプロパティに設定することでジャンプする機能」と説明されていますが、ExcelのVBAから試してみましたがBookmark設定時にエラーが出てしまい、うまくいきませんでした。

４ー１ー２ー２．Accessの場合（OpenメソッドにはSQL文を指定）

次に、データベース対象をAccessに、第１パラメータ（Source）にSQL文を指定した時の状態が図３６です。
なお、Inset,Update,Delete文を実行する手法としては図０２のように、Connection.Execute、Command.Execute、Recordset.Openの３種類があります。ここは「Recordsetオブジェクト」の説明なので、図０２のNo.9である「Recordset.Open」を使う方法で実行可不可のチェックとプロパティ値の確認を行っています。

AccessDB + SQL文

LockType定数	値	CursorType定数
		0 (Forward)	1 (Keyset)	2 (Dynamic)	3 (Static)	-1 (Unspecified)
adLockReadOnly	1	SIUD	SI･･	SIUD	SIUD	SIUD
adLockPessimistic	2	SIUD	SIUD	SIUD	SIUD	SIUD
adLockOptimistic	3	SIUD	SIUD	SIUD	SIUD	SIUD
adLockBatchOptimistic	4	SIUD	SIUD	SIUD	SIUD	SIUD
adLockUnspecified	-1	SIUD	SI･･	SIUD	SIUD	SIUD

S=Select文、I=Insert文、U=Update文、D=Delete文
図３６別窓
第１パラメータにテーブル名を指定した図３４とは、全く異なる結果となります。
LockType＝１（ReadOnly） × CursorType＝１（Keyset）の組み合わせの時にのみ、UpdateとDeleteが実行できない状態です。それにしても、ReadOnlyなのにInsert文が実行できてしまうのも不思議です。
またLockType＝４（バッチ処理）の場合、図３４ではUpdateBatchメソッドを実行しない限り、データベースに変更内容が反映されませんでしたが、図３６ではUpdateメソッドでそのまま反映されます。
この検証としてレコードセットのプロパティ値を調べてみたのですが、テーブル指定の図３５と全く一緒でした。
結論として、SQL文を使う場合は「実行可不可をあまり気にせずに、ロックの種類を検討できる」と言えるのかもしれません。

４ー１ー２ー３．ExcelシートDBの場合（Openメソッドにはテーブル名を指定）

Excelのシートをデータベースにし、第１パラメータ（Source）にテーブル名を指定した時の状態が図３７です。
なお、ExcelシートDBをテーブルとして操作する場合、第５パラメータ（第１パラメータの種類を指定）を省略するとエラーが発生します。色々試してみた結果、第５パラメータに「adCmdTableDirect（値＝512）」を指定する事で「テーブルとしてレコードセットを取得」できます。図３７・図３８では、その設定条件になっていますのでご注意下さい。

ExcelシートDB + テーブル名

LockType定数	値	CursorType定数
		0 (Forward)	1 (Keyset)	2 (Dynamic)	3 (Static)	-1 (Unspecified)
adLockReadOnly	1	S･･	･･･	S･･	･･･	S･･
adLockPessimistic	2	SI･	･I･	SI･	･I･	SI･
adLockOptimistic	3	SI･	･I･	SI･	･I･	SI･
adLockBatchOptimistic	4	S(I)･	･(I)･	S(I)･	･(I)･	S(I)･
adLockUnspecified	-1	S･･	･･･	S･･	･･･	S･･

S=Select処理、I=Insert処理、U=Update処理
図３７別窓
図３７でも分かるように、CursorTypeが１（adOpenKeyset）または３（adOpenStatic）の時は、データ参照（Select相当）すら出来ません。と言ってデータが取得できない訳ではなく、カーソルを移動（MoveNextメソッド）しようとした時に「ブックマークが正しくない」とのエラーが発生するのです。
ですのでSelect相当だけでは無く、カーソルを移動しながら対象レコードを探す「Update相当」でもエラーが発生します（Insert相当はMoveNextを使わないため、エラー出ず）。
また、LockType＝４（adLockBatchOptimistic）はバッチ処理のため、Accessの図３４と同様に「UpdateBatch」メソッドを実行しないとデータベースは変更されません。
上記のブックマークエラーをプロパティ面から調べたのが図３８です。項目はAccessの図３５等と同じにしてあります。

図３８別窓
図３７では、CursorType値がKeyset（値＝１）とStatic（値＝３）の場合はデータ参照が出来ませんが、プロパティ値で「１・３」と「０・２」とで差が見えるのは「Bookmark」「PageCount」「RecordCount」「iRowsetLocate」「Bookmarkable」です。 エラー内容（ブックマークが正しくない）から「Bookmark」「Bookmarkable」辺りが影響しているように思われますが、良くは分かりませんでした。

４ー１ー２ー４．ExcelシートDBの場合（OpenメソッドにはSQL文を指定）

Excelのシートをデータベースにし、第１パラメータ（Source）にSQL文を指定した時の状態が図３９です。

ExcelシートDB + SQL文

LockType定数	値	CursorType定数
		0 (Forward)	1 (Keyset)	2 (Dynamic)	3 (Static)	-1 (Unspecified)
adLockReadOnly	1	SIU	SI･	SIU	SIU	SIU
adLockPessimistic	2	SIU	SIU	SIU	SIU	SIU
adLockOptimistic	3	SIU	SIU	SIU	SIU	SIU
adLockBatchOptimistic	4	SIU	SIU	SIU	SIU	SIU
adLockUnspecified	-1	SIU	SI･	SIU	SIU	SIU

S=Select処理、I=Insert処理、U=Update処理
図３９別窓
テーブル指定の図３７と比較し、SQL文を使うと、ほぼ全ての組み合わせで処理が出来ることが分かります。但し「CursorType＝１ × LockType＝１」の時にUpdate処理が出来ません（ × LockType＝-1 も同様）。
これをプロパティ値で確認してみたのが図４０になります。

図４０別窓
図３８と異なっているのは、一番上の「AbsolutePosition」と「Bookmark」のみです。しかもCursorTypeが０と２の場合は全く同じプロパティ値です。それなのに実行可否の結果（図３７と図３９）は全く異なります。Excelについては、プロパティ値から動作を予測することは難しそうです。

４ー１ー２ー５．CSVの場合（Openメソッドにはテーブル名を指定）

CSVファイルを使い、第１パラメータ（Source）にテーブル名（＝CSVファイル名）を指定した時の状態が図４１です。
なおExcelシートDBの時と同様に、CSVでも第５パラメータ（第１パラメータの種類を指定）を省略するとエラーが発生します。図４１・図４２では、第５パラメータに「adCmdTableDirect（値＝512）」を指定し、Recordset.Openを実行しています。

CSV + テーブル名

LockType定数	値	CursorType定数
		0 (Forward)	1 (Keyset)	2 (Dynamic)	3 (Static)	-1 (Unspecified)
adLockReadOnly	1	S･	･･	S･	･･	S･
adLockPessimistic	2	SI	･I	SI	･I	SI
adLockOptimistic	3	SI	･I	SI	･I	SI
adLockBatchOptimistic	4	S(I)	･(I)	S(I)	･(I)	S(I)
adLockUnspecified	-1	S･	･･	S･	･･	S･

S=Select処理、I=Insert処理
図４１別窓
Excel＋テーブル（図３７）の時と似たような結果となり、CursorTypeが１と３の場合はSelect操作すら出来ません。またLockType=4の場合は、カッコ付きとしてあるようにUpdateBatchを使わないと変更値がデータベースに反映されません。
とりあえず、プロパティ値を紹介します（図４２）が、Excel時（図３８）と同様に良く分かりません。

図４２別窓

４ー１ー２ー６．CSVの場合（OpenメソッドにはSQL文を指定）

CSVファイルに対して、第１パラメータにSQL文を指定した時の実行可否を表したのが図４３です。

CSV + SQL文

LockType定数	値	CursorType定数
		0 (Forward)	1 (Keyset)	2 (Dynamic)	3 (Static)	-1 (Unspecified)
adLockReadOnly	1	SI	SI	SI	SI	SI
adLockPessimistic	2	SI	SI	SI	SI	SI
adLockOptimistic	3	SI	SI	SI	SI	SI
adLockBatchOptimistic	4	SI	SI	SI	SI	SI
adLockUnspecified	-1	SI	SI	SI	SI	SI

S=Select処理、I=Insert処理
図４３別窓
CSVファイルに対しては、元々Select操作とInsert操作しか出来ませんが、全てのCursorTypeとLockTypeの組み合わせで両操作が出来ます。ちょうどExcel＋SQLの操作（図３９）からUpdateを取り除いた感じとなります。
この時のプロパティ値を図４４に示しますが、テーブル指定の図４２と異なっているのは、Excel時と同様の「AbsolutePosition」と「Bookmark」のみでした。

図４４別窓

５．Commandオブジェクト

Commandオブジェクトには、複数のプロパティやメソッドが存在しますが、ここでは実行コマンドの格納やコマンドの実行に必要な「ActiveConnection」プロパティ、「CommandText」プロパティ、「Execute」メソッドの３種を説明します。

５ー１．ActiveConnectionプロパティ（データベースとの結び付け）

まず生成したCommandオブジェクトが、どの「データベース接続」に属しているかを指定するのがActiveConnectionプロパティです。構文としては、下記のように「接続中のConnectionオブジェクト」を指定します。
　Command.ActiveConnection = 接続中のConnectionオブジェクト
なおConnectionオブジェクトの代わりに、Provider名・Data Source名を含めた接続文字列（Excel等の場合は、Extended Properties も必要）をActiveConnectionに指定してもOKです。Microsoftのサイトでは、「接続が閉じている時に文字列指定」との説明がありますが、試してみると接続中でもOKでした。

５ー２．CommandTextプロパティ（実行コマンドの格納）

コマンドをCommandオブジェクトで実行する場合にも、またCommandオブジェクトに格納後Recordset.Openでレコードセットを取得する場合にも、「実行コマンドはCommandTextプロパティに代入」します。構文は以下の通りです。
　Command.CommandText = 実行コマンド（String型）
実行コマンドは、今回ではデータベースの「テーブル名」や「SQL文」です。

５ー３．Executeメソッド（コマンドの実行）

Commandオブジェクトでコマンドを実行するには、Executeメソッドを使用します。構文は以下となります。
　Command.Execute ( RecordsAffected, Parameters, Options )
なおExecuteメソッドを実行する前に、「ActiveConnectionプロパティで接続データベースへ紐付け」をし、「CommandTextプロパティに実行するテーブル名やSQL文を代入」しておく必要があります。
３つのパラメータは以下の内容になります。全て省略可です。

パラメータ		内容
RecordsAffected	省略可	Long型の変数に､変更ﾚｺｰﾄﾞ数を戻す
Parameters	省略可	ﾊﾟﾗﾒｰﾀｸｴﾘ(SQL文)に渡す ﾊﾟﾗﾒｰﾀ値の配列
Options	省略可	CommandTextの種類 (図３０)

図４５別窓
第１パラメータのRecordsAffectedは、Long型変数を引数として与えておくことで、Insert・Update・Delete処理で影響を与えたレコード数を戻してくれるものです。使い方は図２８と同じです。なおSelect文でも使用は出来ますが、選択したレコード数を戻してくれる訳ではありません。
第２パラメータのParametersは、CommandTextにパラメータクエリ（≒変数をSQL文に組み込んだようなもの）を指定した際、そのパラメータ値を配列として指定するものです（今回は、説明を省略します）。
第３パラメータ（Options）は、第１パラメータに指定したものの種類を図３０のように指定します。内容はConnectionオブジェクトのExecuteメソッドの第３パラメータ、RecordsetオブジェクトのOpenメソッドの第５パラメータと同じです。

(テーブル名指定のExcelとCSVはCommand.Execute不可) Command.Executeの第１パラメータに「テーブル名」を指定した場合、Options（Command.Executeでは第３パラメータ）の設定には少し注意が必要です。Connection.Execute、Recordset.Openの時も合わせて、まとめたのが以下になります。 テーブルを指定した時にデータ取得可能なOptionsパラメータ Connection.Execute Command.Execute Recordset.Open Access 省略 他 省略 他 省略 他 Excel adCmdTableDirect(512) × adCmdTableDirect(512) CSV adCmdTableDirect(512) × adCmdTableDirect(512) 図４６別窓 ExcelやCSVのデータをテーブル名指定でレコードセットを取得する場合、Connection.ExecuteとRecordset.OpenではOptionsパラメータとして「adCmdTableDirect(512)」指定する必要があります（それ以外ではエラー発生）。しかしCommand.Executeでは、512を指定しても「引数が違う」とのエラーが発生します。ダメな理由は良く分かりませんでした。 そのため「テーブル名を指定してCommand.Executeで実行する場合は、Accessのみ」となります。 一方、図４６では「省略 他」と表記したAccessでは、Optionsパラメータを省略する他にも色々な値でテーブル名での取得が可能です。以下はOptionsパラメータ値別にテーブル名での実行が可能か否かをまとめたものです。 テーブルを指定した時にデータ取得可能なOptionsパラメータ(Access) 定数 値 内容 Connection .Execute Command .Execute Recordset .Open adCmdUnspecified or adOptionUnspecified -1 種類を指定せず 〇 〇 〇 adCmdText 1 SQL文 × × × adCmdTable 2 テーブル 〇 〇 〇 adCmdStoredProc 4 ｽﾄｱﾄﾞﾌﾟﾛｼｰｼﾞｬ × × × adCmdUnknown 8 不明（既定） 〇 〇 〇 adAsyncExecute 0x10(16) 非同期実行 〇 〇 〇 adAsyncFetch 0x20(32) 残り行を非同期で取得 〇 〇 〇 adAsyncFetchNonBlocking 0x40(64) 取得中にﾌﾞﾛｯｸせず 〇 〇 〇 adExecuteNoRecords 0x80(128) 行を返さないｺﾏﾝﾄﾞ × × × adCmdFile 256 Recordsetファイル × × × adCmdTableDirect 512 全列が返るテーブル （ExcelｼｰﾄDB､CSVﾌｧｲﾙ） 〇 × 〇 adExecuteStream 0x400(1024) ｺﾏﾝﾄﾞ実行結果をｽﾄﾘｰﾑとして返すもの × × × adExecuteRecord 0x800(2048) 単一行を返すもの × × × 図４７別窓 面白いことに、Command.Executeの時に、OptionsパラメータにadCmdTableDirect(値=512)を指定するとエラーが出てしまいます。つまり「テーブルを指定する際は、Optionsは512」というルールはCommand.Executeでは成立しないのです。 それ以外のOptions値ではConnection、Recordsetと同じ結果となりましたが、ここで説明した以外の機能でも「Commandオブジェクトだけは特殊」という事があるかもしれませんので、注意が必要と思います。

５ー４．Commandオブジェクトの使用例

５ー４ー１．実行コマンドの格納

Commandオブジェクトを使用する場面は２種類あります。
１つ目は、実行するコマンド（テーブル名、またはSQL文）をCommand.CommandTextプロパティに格納した後「Recordset.Openの第１パラメータにCommandオブジェクトを指定」することでレコードセットを取得したり、変更のSQL文を実行したりする場面です。

130. '==========　⇩(7)　Commandオブジェクトに実行コマンドを格納 ============
131. 　Dim cn As Object 　 '←実行時バインディングのConnectionオブジェクト
132. 　Dim rs As Object 　 '←実行時バインディングのRecordsetオブジェクト
133. 　Dim cmd As Object 　 '←実行時バインディングのCommandオブジェクト
135. 　Set cn = CreateObject("ADODB.Connection") 　 '←Connectionオブジェクトの生成
136. 　Set rs = CreateObject("ADODB.Recordset") 　 '←Recordsetオブジェクトの生成
137. 　Set cmd = CreateObject("ADODB.Command") 　 '←Commandオブジェクトの生成
139. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0" 　 '←プロバイダ設定
140. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←DB設定
142. 　cn.Open 　 '←データベースに接続
144. 　cmd.ActiveConnection = cn 　 '←接続条件をCommandオブジェクトに設定
145. 　cmd.CommandText = "Select * from TestTable" 　 '←実行コマンドをCommandオブジェクトに設定
147. 　rs.Open cmd 　 '←コマンドを格納したCommandを使って実行
148. 　　　（処理）

図４８別窓
１４４行目「cmd.ActiveConnection = cn」で、データベース接続条件を取り込みます。
１４５行目「cmd.CommandText = "Select * from TestTable"」で実行コマンドをCommandTextに格納します。
１４７行目「rs.Open cmd」で、そのSQL文をRecordsetオブジェクトから実行します。
一般的なRecordset.Openの使い方は「rs.Open SQL文 , Cn」のように、第１パラメータにSQL文やテーブル名を指定し、第２パラメータには接続情報のあるConnectionオブジェクトを指定しますが、Commandオブジェクトを使った１４７行目では、第２パラメータを省略します。
これは、第１パラメータに指定したCommandオブジェクトは、CommandTextプロパティにSQL文やテーブルが指定（１４５行目）し、ActiveConnectionプロパティに接続情報を指定（１４４行目）したからですが、第２パラメータを更に重複設定するとエラーが出ます。つまり「省略しないとエラー」との説明の方が正しいかもしれません
と言って、ActiveConnectionプロパティへの指定を省略し「rs.Open cmd, cn」とするとエラーが出ます。「CommandオブジェクトのCommandTextとActiveConnectionはセットで指定」する必要があります。
なお、図４８はSelect文でしたが、CommandTextプロパティにテーブル名を指定しても同じです。またデータ変更用のSQL文を指定した場合は、１４７行目の実行でデータが変更されます。

５ー４ー２．コマンドの実行

２つ目は、実行コマンド（＝テーブル名、SQL文）を指定した後、CommandオブジェクトのExecuteメソッドで実行をする場面です。その際、SQL文がSelect文であったりテーブル名であれば、ExecuteメソッドがRecordsetオブジェクトを戻してきますので、レコードセットとして取得します。またデータ変更のSQL文（Insert・Update・Delete文）であれば、データ変更を実行します。

160. '==========　⇩(8)　Commandオブジェクトで実行 ============
161. 　Dim cn As Object 　 '←実行時バインディングのConnectionオブジェクト
162. 　Dim rs As Object 　 '←実行時バインディングのRecordsetオブジェクト
163. 　Dim cmd As Object 　 '←実行時バインディングのCommandオブジェクト
165. 　Set cn = CreateObject("ADODB.Connection") 　 '←Connectionオブジェクトの生成
166. 　Set cmd = CreateObject("ADODB.Command") 　 '←Commandオブジェクトの生成
168. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0" 　 '←プロバイダ設定
169. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←DB設定
171. 　cn.Open 　 '←データベースに接続
173. 　cmd.ActiveConnection = cn 　 '←接続条件をCommandオブジェクトに設定
174. 　cmd.CommandText = "Select * from TestTable" 　 '←実行コマンドをCommandオブジェクトに設定
175. 　Set rs = cmd.Execute 　 '←実行コマンドを実行
176. 　　　（処理）

図４９別窓
１７３行目「cmd.ActiveConnection = cn」で、データベース接続条件を取り込みます。
１７４行目「cmd.CommandText = "Select * from TestTable"」で実行コマンドをCommandTextに格納します。
１７５行目「Set rs = cmd.Execute」の右辺で、そのコマンドをCommandオブジェクトで実行し、戻り値であるRecordsetオブジェクトを変数rsで受け取り、処理をします。
なおデータ変更を伴うSQL文の場合は、変数で受ける必要は無いので、１７５行目は右辺のみでOKです。

６．データベースに接続する為のコード例

図０２でも紹介した通り、データベースに接続・操作する方法はいくつかあります。図５０はその再掲ですが、下半分（薄黄色のエリア）に、各手法での可能な操作（Select、Insert、Update、Delete）をまとめました。
一般的には「ExcelはDeleteが出来ない」「CSVはUpdateとDeleteが不可」などと言われていますが、接続・操作の方法でも変わってくることが分かると思います。なお実行時に指定するパラメータによっては、更に不可の操作もあるのでご注意下さい。

図５０別窓
１２種類と多そうに見えますが、基本的には以下の４種類で、実行するもの（テーブル、SQL文）が変わるだけです。しかも３と４は、Commandオブジェクトを経由するか否かの違いですので、３種と言っても良いくらいです。
　1.「Connection.Open（DB接続）」→「Connection.Execute（実行）」→（「処理」）
　2.「Connection.Open（DB接続）」→「Command.Execute（実行）」→（「処理」）
　3.「Connection.Open（DB接続）」→「Commandへコマンド格納」→「Recordset.Open（実行）」→（「処理」）
　4.「Connection.Open（DB接続）」→「Recordset.Open（実行）」→（「処理」）
ここでは図５０に示す１２種類の実際のコードを紹介していきます。
なおコードは、主に「Excel」について説明していきますが、見え消しにしてある「Accessのコード」「CSVのコード」と切り替えれば動作確認が出来るようにしています。（図５０のNo.2はAccessしか動かないので、Accessで説明します。）
今回のコード例では、データベースとして「Access」「Excel」「CSV（カンマ区切りテキスト）を扱います。そのデータは、以下のような形の「4列×4行」としました。St、Nu、Dt、BLが列名になります。Excel、CSVも先頭行は列名行としています。

St(String型)	Nu(Double型)	Dt(Date型)	BL(Boolean型)
"abc"	123	2023/1/2	True
"def"	123	2023/2/2	False
"abc"	456	2023/3/2	False
"def"	456	2023/4/2	True

図５１別窓
なお扱っているデータベースですが、Excelは本サンプルファイル（its-042.xlsm）のワークシート「DB」、CSVは添付のits-041.csvです。またAccessはサンプルファイルとしても添付していますが、その作成方法については「DAOでAccess･Excel･CSV等へ接続・操作」を参照下さい。

６ー１．テーブルを操作

データベースに接続し、「テーブル」を操作するコードとして４種類を以下で紹介します。
なお、主にExcelのシートデータベースについて説明していきます（図５４のみAccess）が、以下のようにコードを切り替えることで、Access・CSVをデータベースの場合にすることが出来ます。丸番号は、図５３・図５４・図５５・図５６で同じにしてあります。

	Data Source	Extended Properties	ﾃｰﾌﾞﾙ名	実行
Access	① Accessﾌｧｲﾙ名	－	⑥ ﾃｰﾌﾞﾙ名そのまま	⑨ Optionsﾊﾟﾗﾒｰﾀは省略
Excel	② Excelﾌｧｲﾙ名	④ Excel 12.0 ･･･	⑦ ｼｰﾄ名+$印	⑩ Optionsﾊﾟﾗﾒｰﾀに512
CSV	③ CSVﾌｧｲﾙのﾌｫﾙﾀﾞｰ名	⑤ Text ･･･	⑧ CSVﾌｧｲﾙ名

図５２別窓

６ー１ー１．Connectionでテーブル名を実行し、レコードセット取得後に処理

図５０のNo.1のコードは、以下のようになります。

180. '==========　⇩(9)　Connectionでテーブル名を実行しレコードセットを取得 ============
181. Sub Pattern01()
182. 　Dim cn As Object 　 '←Connectionオブジェクト
183. 　Dim rs As Object 　 '←Recordsetオブジェクト
184. 　Dim SQL As String 　 '←テーブル名、又はSQL文
185. 　Dim i As Integer 　 '←レコードの行位置
187. 　Set cn = CreateObject("ADODB.Connection")
189. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
191. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
192. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　 '←②Excel
193. '　cn.Properties("Data Source") = ThisWorkbook.Path 　 '←③CSV
195. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　 '←④Excel
196. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　 '←⑤CSV
198. 　cn.Open
200. '　　SQL = "TestTable" 　 '←⑥Access
201. 　　SQL = "db$" 　 '←⑦Excel
202. '　　SQL = "its-041.csv" 　 '←⑧CSV
204. '　　Set rs = cn.Execute(SQL) 　 '←⑨Access
205. 　　Set rs = cn.Execute(SQL, , 512) 　 '←⑩Excel、CSV
207. 　　With Sheet1.Range("B2")
208. 　　　.CurrentRegion.ClearContents
209. 　　　Do While Not rs.EOF
210. 　　　　.Offset(i, 0) = rs.Fields(0).Value
211. 　　　　.Offset(i, 1) = rs.Fields(1).Value
212. 　　　　.Offset(i, 2) = rs.Fields(2).Value
213. 　　　　.Offset(i, 3) = rs.Fields(3).Value
214. 　　　　rs.MoveNext
215. 　　　　i = i + 1
216. 　　　Loop
217. 　　End With
219. 　　rs.Close
220. 　cn.Close
222. 　Set rs = Nothing
223. 　Set cn = Nothing
224. End Sub

図５３別窓
１８７行目「Set cn = CreateObject("ADODB.Connection")」で、Connectionオブジェクトを生成します。
１８９行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
１９２行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、Excelのシートデータベースを指定します。
１９５行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」で、拡張プロパティの指定をします。
１９８行目「cn.Open」で、データベースに接続します。
２０１行目「SQL = "db$"」で、テーブル名として「Excelのシート名＋$印」を変数SQLに代入します。
２０５行目「Set rs = cn.Execute(SQL, , 512)」の右辺では、ConnectionオブジェクトのExecuteメソッドでテーブル名を実行します。この時に第３パラメータには「Excel、CSVをテーブルとして読み込むためのadCmdTableDirect（値＝512）」を設定します。第３パラメータへの値512の設定は、Excel＋テーブル、CSV＋テーブルの場合は必須ですが、Access＋テーブルの場合に設定しても問題はありません。
この実行によりテーブルの全データ（レコードセット）が取得できますので、左辺の変数rsに代入します。なお、この段階では、レコードセットのカーソル（操作できる行位置）は、先頭行にあります。
２０７～２１７行目では、取得したレコードセットの全データをワークシート上に書き出しています。
２０７行目「With Sheet1.Range("B2")」では、シートへのデータ書き出しの基準点を決めています。
２０８行目「.CurrentRegion.ClearContents」は、その基準点を含むエリアに書かれていたデータをクリアします。
２０９行目「Do While Not rs.EOF」では、レコードセットの終端が来るまで２１０～２１５行目を回します。
２１０行目「.Offset(i, 0) = rs.Fields(0).Value」は、レコードセットの１列目のデータをシートの１列目に書き込みます。
２１１～２１３行目も同様に、２列目・３列目・４列目と書き込みます。
２１４行目「rs.MoveNext」では、カーソルを次の行に移動します。
２１５行目「i = i + 1」では、シート上の書き込み位置を１つ下に移動させています。
２０９行目で「rs.EOF = True」が成立すれば、データ処理が全て完了しDo～Loopを抜け出しますので、２１９行目「rs.Close」でレコードセットを閉じます。
２２０行目「cn.Close」では、データベースとの接続を終了させます。

６ー１ー２．Commandでテーブル名を実行し、レコードセット取得後に処理

図５０のNo.2のコードは、以下のようになります。

230. '==========　⇩(10)　Commandでテーブル名を実行しレコードセット取得 ============
231. Sub Pattern02()
232. 　Dim cn As Object 　 '←Connectionオブジェクト
233. 　Dim rs As Object 　 '←Recordsetオブジェクト
234. 　Dim cmd As Object 　 '←Commandオブジェクト
235. 　Dim SQL As String 　 '←テーブル名、又はSQL文
236. 　Dim i As Integer 　 '←レコードの行位置
238. 　Set cn = CreateObject("ADODB.Connection")
239. 　Set cmd = CreateObject("ADODB.Command")
241. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
243. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
244. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　 '←②Excel
245. '　cn.Properties("Data Source") = ThisWorkbook.Path 　 '←③CSV
247. '　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　 '←④Excel
248. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　 '←⑤CSV
250. 　cn.Open
252. 　　SQL = "TestTable" 　 '←⑥Access
253. '　　SQL = "db$" 　　　　　 '←⑦Excel
254. '　　SQL = "its-041.csv" 　'←⑧CSV
256. 　　cmd.ActiveConnection = cn
257. 　　cmd.CommandText = SQL
259. 　　Set rs = cmd.Execute 　　 '←⑨Access
260. '　　Set rs = cmd.Execute(, , 512) 　 '←⑩Excel、CSV
262. 　　With Sheet1.Range("B2")
263. 　　　.CurrentRegion.ClearContents
264. 　　　Do While Not rs.EOF
265. 　　　　.Offset(i, 0) = rs.Fields(0).Value
266. 　　　　.Offset(i, 1) = rs.Fields(1).Value
267. 　　　　.Offset(i, 2) = rs.Fields(2).Value
268. 　　　　.Offset(i, 3) = rs.Fields(3).Value
269. 　　　　rs.MoveNext
270. 　　　　i = i + 1
271. 　　　Loop
272. 　　End With
274. 　　rs.Close
275. 　cn.Close
277. 　Set rs = Nothing
278. 　Set cmd = Nothing
279. 　Set cn = Nothing
280. End Sub

図５４別窓
２３８行目「Set cn = CreateObject("ADODB.Connection")」で、Connectionオブジェクトを生成し、２３９行目「Set cn = CreateObject("ADODB.Command")」で、Commandオブジェクトを生成します。
２４１行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
２４３行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb"」で、Accessデータベースを指定します。
２５０行目「cn.Open」で、データベースに接続します。
２５２行目「SQL = "TestTable"」で、Accessのテーブル名を変数SQLに代入します。
２５６行目「cmd.ActiveConnection = cn」は、接続中のConnectionオブジェクトをCommandオブジェクトのActiveConnectionに指定し、ConnectionとCommandを結び付けています。
２５７行目「cmd.CommandText = SQL」では、CommandオブジェクトのCommandTextにテーブル名を指定しています。
２５９行目「Set rs = cmd.Execute」の右辺では、CommandオブジェクトのExecuteメソッドを実行し、Accessのテーブルを開いてレコードセットにし、左辺の変数rsに代入しています。
レコードセットを取得した後は図５３と全く同じです。２６２～２７２行目では、取得したレコードセットをDo～Loopで回しながら全データをシート上に書き出しています。
この「Commandでテーブル名を実行しレコードセット取得」するパターンは、「Commandオブジェクト」でも説明しましたが、動く事が確認できたのはAccessのみです。ですので図５４の中に一応記載しておいたExcel・CSVのコードに切り替えてもエラーが出ますので注意下さい。

６ー１ー３．Commandにテーブル名を格納後Recordset実行し、レコードセット取得後に処理

図５０のNo.3のコードは、以下のようになります。

290. '==========　⇩(11)　Commandにテーブル名を格納後Recordset実行しレコードセット取得 ============
291. Sub Pattern03()
292. 　Dim cn As Object 　 '←Connectionオブジェクト
293. 　Dim rs As Object 　 '←Recordsetオブジェクト
294. 　Dim cmd As Object 　 '←Commandオブジェクト
295. 　Dim SQL As String 　 '←テーブル名、又はSQL文
296. 　Dim i As Integer 　 '←レコードの行位置
298. 　Set cn = CreateObject("ADODB.Connection")
299. 　Set rs = CreateObject("ADODB.Recordset")
300. 　Set cmd = CreateObject("ADODB.Command")
302. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
304. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
305. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　 '←②Excel
306. '　cn.Properties("Data Source") = ThisWorkbook.Path 　 '←③CSV
308. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　 '←④Excel
309. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　 '←⑤CSV
311. 　cn.Open
313. 　　cmd.ActiveConnection = cn
315. '　　SQL = "TestTable" 　 '←⑥Access
316. 　　SQL = "db$" 　 '←⑦Excel
317. '　　SQL = "its-041.csv" 　 '←⑧CSV
319. 　　cmd.CommandText = SQL
321. '　　rs.Open cmd, , 0, 2 　 '←⑨Access
322. 　　rs.Open cmd, , 0, 2, 512 　 '←⑩Excel、CSV
324. 　　　GoTo Sel 　 'Sel,Ins,Upd,Del ←Excel,CSVでは、Update処理・Delete処理はエラーが出ます。
326. Sel:
327. 　　　With Sheet1.Range("B2")
328. 　　　　.CurrentRegion.ClearContents
329. 　　　　Do While Not rs.EOF
330. 　　　　　.Offset(i, 0) = rs.Fields(0).Value
331. 　　　　　.Offset(i, 1) = rs.Fields(1).Value
332. 　　　　　.Offset(i, 2) = rs.Fields(2).Value
333. 　　　　　.Offset(i, 3) = rs.Fields(3).Value
334. 　　　　　rs.MoveNext
335. 　　　　　i = i + 1
336. 　　　　Loop
337. 　　　End With
339. GoTo En
340. Ins:
342. 　　　rs.AddNew
343. 　　　　rs.Fields(0) = "PQR"
344. 　　　　rs.Fields(1) = 897
345. 　　　　rs.Fields(2) = #11/20/2000#
346. 　　　　rs.Fields(3) = True
347. 　　　rs.Update
349. GoTo En
350. Upd:
352. 　　　Do While Not rs.EOF
353. 　　　　If CDate(rs.Fields(2).Value) = #11/20/2000# Then
354. 　　　　　rs.Fields(0) = "XYZ"
355. 　　　　　rs.Update
356. 　　　　End If
357. 　　　　rs.MoveNext
358. 　　　Loop
360. GoTo En
361. Del:
363. 　　　Do While Not rs.EOF
364. 　　　　If CDate(rs.Fields(2).Value) = #11/20/2000# Then
365. 　　　　　rs.Delete
366. 　　　　End If
367. 　　　　rs.MoveNext
368. 　　　Loop
370. En:
371. 　　rs.Close
372. 　cn.Close
374. 　Set rs = Nothing
375. 　Set cmd = Nothing
376. 　Set cn = Nothing
377. End Sub

図５５別窓
２９８行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成、２９９行目「Set rs = CreateObject("ADODB.Recordset")」でRecordsetオブジェクトを生成、３００行目「Set cn = CreateObject("ADODB.Command")」で、Commandオブジェクトを生成します。
３０２行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
３０５行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
３０８行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」で拡張プロパティを指定します。
３１１行目「cn.Open」で、データベースに接続します。
３１３行目「cmd.ActiveConnection = cn」は、接続中のConnectionオブジェクトをCommandオブジェクトのActiveConnectionに指定し、ConnectionとCommandを結び付けています。
３１６行目「SQL = "db$"」で、テーブル名（＝Excelのシート名＋$印）を変数SQLに代入します。
３１９行目「cmd.CommandText = SQL」では、CommandオブジェクトのCommandTextにテーブル名を指定しています。
３２２行目「rs.Open cmd, , 0, 2, 512」では、RecordsetオブジェクトのOpenメソッドを使ってレコードセットを取得しています。
第１パラメータには、３１３～３１９行目で準備をしたCommandオブジェクトを指定しています。
第２パラメータは通常はConnectionオブジェクトを指定するのですが、第１パラメータにCommandオブジェクトを指定した場合、重複してConnectionオブジェクトを指定してしまうとエラー（エラー内容：「Commandオブジェクトをソースに持つRecordsetオブジェクトのActiveConnectionプロパティを変更できません」）が発生しますので、省略とします。
第３～４パラメータは「0, 2」としていますが、これを省略（既定は　CursorType＝0、LockType＝1）してしまうと「Select操作のみが可」となってしまいます。ですので、ここではCursorType＝0、LockType＝2（図３７を参照下さい）としています。この組み合わせであれば、Accessの場合でも図３４のように全操作が出来ますし、CSVでも図４１のようにSelectとInsert操作が出来ます。
第５パラメータは、テーブル名指定なので「adCmdTableDirect（値＝512）」を指定しています。なお、ここでは第１パラメータはテーブル名では無くCommandオブジェクトを指定していますが、CommandオブジェクトのCommandTextプロパティに対してテーブル名指定をしていますので、間接的にテーブル名指定という事になります。
なお、この512値の指定は、Excel・CSVでは必須ですが、Accessで指定しても問題はありません。
３２２行目によりレコードセットが得られたので、３２４～３６８行目でデータ処理をします。図５５では４種の処理を３２４行目「GoTo Sel」で分岐させています。Selの部分を「Sel,Ins,Upd,Del」の４種で置き換える事で、Select操作・Insert操作・Update操作・Delete操作にジャンプさせています。
まずSelect処理は３２７～３３７行目です。内容は図５３・図５４と全く同じで、Do～Loopを使いレコードセットの終端になるまで繰り返し、４列のデータをワークシートに書き込んでいます。
Insert処理は３４２～３４７行目です。まず３４２行目「rs.AddNew」で新たなレコードを作成します。カーソルは、この新たに作ったレコードの位置になります。
３４３行目「rs.Fields(0) = "PQR"」では、１列目に"PQR"という文字列をセットしています。３４４～３４６行目も同様に２～４列目にデータをセットしています。
各列へのセットが完了したら３４７行目「rs.Update」でデータベースを更新します。
Update処理は３５２～３５８行目です。Do～Loopで回しながら３５７行目「rs.MoveNext」で行を移動させ、全行を走査します。３５３行目「If CDate(rs.Fields(2).Value) = #11/20/2000# Then」で、３列目のデータが2000年11月20日のものを探し出し、見つかったら３５４行目「rs.Fields(0) = "XYZ"」で１列目のデータをXYZに書き換えます。
書き換えが終わったら、３５７行目の「rs.MoveNext」でカーソルが移動してしまう前に、３５５行目「rs.Update」でデータベースを更新します。
Delete処理は３６３～３６８行目です。Do～Loopで回しながら３６７行目「rs.MoveNext」で行を移動させ、全行を走査します。３６４行目「If CDate(rs.Fields(2).Value) = #11/20/2000# Then」で、３列目のデータが2000年11月20日のものを探し出し、見つかったら３６５行目「rs.Delete」でその行を削除します。なおDeleteの場合は、Updateメソッドを実行しないでも良いようです。
レコードセットの処理が完了したら、３７１行目「rs.Close」でレコードセットを閉じます。その後３７２行目「cn.Close」で、データベースとの接続を切ります。
なお、Excelは図３７のように「CursorType=0 × LockType=2」の条件でもUpdateとDelete処理が出来ず、またCSVも図４１のようにUpdateとDelete処理が出来ませんのでご注意下さい。

６ー１ー４．Recordsetでテーブル名を実行し、レコードセット取得後に処理

図５０のNo.4のコードは、以下のようになります。

380. '==========　⇩(12)　Recordsetでテーブル名を実行しレコードセット取得 ============
381. Sub Pattern04_Excel()
382. 　Dim cn As Object 　 '←Connectionオブジェクト
383. 　Dim rs As Object 　 '←Recordsetオブジェクト
384. 　Dim SQL As String 　 '←テーブル名、又はSQL文
385. 　Dim i As Integer 　 '←レコードの行位置
387. 　Set cn = CreateObject("ADODB.Connection")
388. 　Set rs = CreateObject("ADODB.Recordset")
390. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
392. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
393. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
394. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
396. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
397. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
399. 　cn.Open
401. '　　SQL = "TestTable" 　 '←⑥Access
402. 　　SQL = "db$" 　　　 '←⑦Excel
403. '　　SQL = "its-041.csv" 　 '←⑧CSV
405. '　　rs.Open SQL, cn, 0, 2 　　 '←⑨Access
406. 　　rs.Open SQL, cn, 0, 2, 512 　　 '←⑩Excel、CSV
408. 　　　GoTo Sel 　　 'Sel,Ins,Upd,Del 　 ←Excel × Tableでは、Update処理・Delete処理はエラーが出ます。
410. Sel:
412. 　　　With Sheet1.Range("B2")
413. 　　　　.CurrentRegion.ClearContents
414. 　　　　Do While Not rs.EOF
415. 　　　　　.Offset(i, 0) = rs.Fields(0).Value
416. 　　　　　.Offset(i, 1) = rs.Fields(1).Value
417. 　　　　　.Offset(i, 2) = rs.Fields(2).Value
418. 　　　　　.Offset(i, 3) = rs.Fields(3).Value
419. 　　　　　rs.MoveNext
420. 　　　　　i = i + 1
421. 　　　　Loop
422. 　　　End With
424. GoTo En
425. Ins:
427. 　　　rs.AddNew
428. 　　　　rs.Fields(0) = "PQR"
429. 　　　　rs.Fields(1) = 897
430. 　　　　rs.Fields(2) = #11/20/2000#
431. 　　　　rs.Fields(3) = True
432. 　　　rs.Update
434. GoTo En
435. Upd:
437. 　　　Do While Not rs.EOF
438. 　　　　If CDate(rs.Fields(2).Value) = #11/20/2000# Then
439. 　　　　　rs.Fields(0) = "XYZ"
440. 　　　　　rs.Update
441. 　　　　End If
442. 　　　　rs.MoveNext
443. 　　　Loop
445. GoTo En
446. Del:
448. 　　　Do While Not rs.EOF
449. 　　　　If CDate(rs.Fields(2).Value) = #11/20/2000# Then
450. 　　　　　rs.Delete
451. 　　　　End If
452. 　　　　rs.MoveNext
453. 　　　Loop
455. En:
456. 　　rs.Close
457. 　cn.Close
459. 　Set rs = Nothing
460. 　Set cn = Nothing
461. End Sub

図５６別窓
３８７行目「Set cn = CreateObject("ADODB.Connection")」で、Connectionオブジェクトを生成します。
３８８行目「Set rs = CreateObject("ADODB.Recordset")」で、Recordsetオブジェクトを生成します。
３９０行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
３９３行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
３９６行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
３９９行目「cn.Open」で、データベースに接続します。
４０２行目「SQL = "db$"」で、テーブル名（＝Excelのシート名＋$印）を変数SQLに代入します。
４０６行目「rs.Open SQL, cn, 0, 2, 512」では、RecordsetオブジェクトのOpenメソッドを使ってレコードセットを取得しています。
第１パラメータには、４０２行目で設定したテーブル名を指定します。
第２パラメータには、Connectionオブジェクトである変数cnを指定します。
第３～４パラメータは「0, 2」としていますが、これを省略（CursorType＝0、LockType＝1）すると「Select操作のみ」となってしまいます。ですので、ここではCursorType＝0、LockType＝2（図３７を参照下さい）としています。この組み合わせであれば、ExcelではSelectとInsert処理が可能となります。またAccessの場合でも図３４のように全操作が出来ますし、CSVでも図４１のようにSelectとInsert操作が出来ます。
第５パラメータは、テーブル名指定なので「adCmdTableDirect（値＝512）」を指定しています。
４０６行目によりレコードセットが得られたので、４１２～４５３行目でデータ処理をします。図５６では４種の処理を４０８行目「GoTo Sel」で分岐させています。Selの部分を「Sel,Ins,Upd,Del」の４種で置き換える事で、Select操作・Insert操作・Update操作・Delete操作にジャンプさせています。
まずSelect処理は４１２～４２２行目です。Do～Loopを使いレコードセットの終端になるまで繰り返し、４列のデータをワークシートに書き込んでいます。
Insert処理は４２７～４３２行目です。４２７行目「rs.AddNew」で新たなレコードを作成し、４２８行目「rs.Fields(0) = "PQR"」で１列目に"PQR"という文字列をセットしています。４２９～４３１行目も同様に２～４列目にデータをセットしています。
各列にセットが完了したら４３２行目「rs.Update」でデータベースを更新します。
Update処理は４３７～４４３行目です。Do～Loopで回しながら４４２行目「rs.MoveNext」で行を移動させ、全行を走査します。４３８行目「If CDate(rs.Fields(2).Value) = #11/20/2000# Then」で、３列目のデータが2000年11月20日のものを探し出し、見つかったら４３９行目「rs.Fields(0) = "XYZ"」で１列目のデータをXYZに書き換えます。
書き換えが終わったら、４４２行目の「rs.MoveNext」でカーソルが移動してしまう前に、４４０行目「rs.Update」でデータベースを更新します。
Delete処理は４４８～４５３行目です。Do～Loopで回しながら４５２行目「rs.MoveNext」で行を移動させ、全行を走査します。４４９行目「If CDate(rs.Fields(2).Value) = #11/20/2000# Then」で、３列目のデータが2000年11月20日のものを探し出し、見つかったら４５０行目「rs.Delete」でその行を削除します。なおDeleteの場合は、Updateメソッドを実行しないでも良いようです。
レコードセットの処理が完了したら、４５６行目「rs.Close」でレコードセットを閉じます。その後４５７行目「cn.Close」で、データベースとの接続を切ります。
なお、Excelは図３７のように「CursorType=0 × LockType=2」の条件ではUpdateとDelete処理が出来ず、またCSVも図４１のようにUpdateとDelete処理が出来ませんのでご注意下さい。

６ー２．SQL（Select）文で操作

データベースに接続し、「SelectのSQL文」を操作するコードを以下で紹介します。
なお、Excelのシートデータベースについて説明しますが、以下のようにコードを切り替えることで、Access・CSVをデータベースの場合にすることが出来ます。丸番号は、図５８・図５９・図６０・図６１で同じにしてあります。

	Data Source	Extended Properties	SQL文内のﾃｰﾌﾞﾙ	実行
Access	① Accessﾌｧｲﾙ名	－	⑥ ﾃｰﾌﾞﾙ名そのまま	Optionsﾊﾟﾗﾒｰﾀは省略
Excel	② Excelﾌｧｲﾙ名	④ Excel 12.0 ･･･	⑦ [ｼｰﾄ名+$印]
CSV	③ CSVﾌｧｲﾙのﾌｫﾙﾀﾞｰ名	⑤ Text ･･･	⑧ [CSVﾌｧｲﾙ名]

図５７別窓

６ー２ー１．ConnectionでSQL文を実行しレコードセット取得

図５０のNo.5のコードは、以下のようになります。

470. '==========　⇩(13)　ConnectionでSQL文を実行しレコードセット取得 ============
471. Sub Pattern05()
472. 　Dim cn As Object 　 '←Connectionオブジェクト
473. 　Dim rs As Object 　 '←Recordsetオブジェクト
474. 　Dim SQL As String 　 '←テーブル名、又はSQL文
475. 　Dim i As Integer 　 '←レコードの行位置
477. 　Set cn = CreateObject("ADODB.Connection")
479. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
481. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
482. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
483. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
485. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
486. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
488. 　cn.Open
490. '　　SQL = "TestTable" 　 '←⑥Access
491. 　　SQL = "[db$]" 　　　 '←⑦Excel
492. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
494. 　　SQL = "Select * from " & SQL
496. 　　Set rs = cn.Execute(SQL)
498. 　　　With Sheet1.Range("B2")
499. 　　　　.CurrentRegion.ClearContents
500. 　　　　Do While Not rs.EOF
501. 　　　　　.Offset(i, 0) = rs.Fields(0).Value
502. 　　　　　.Offset(i, 1) = rs.Fields(1).Value
503. 　　　　　.Offset(i, 2) = rs.Fields(2).Value
504. 　　　　　.Offset(i, 3) = rs.Fields(3).Value
505. 　　　　　rs.MoveNext
506. 　　　　　i = i + 1
507. 　　　　Loop
508. 　　　End With
510. 　　rs.Close
511. 　cn.Close
513. 　Set rs = Nothing
514. 　Set cn = Nothing
515. End Sub

図５８別窓
４７７行目「Set cn = CreateObject("ADODB.Connection")」で、Connectionオブジェクトを生成します。
４７９行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
４８２行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
４８５行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
４８８行目「cn.Open」で、データベースに接続します。
４９１行目「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入しますが、ここではSQL文内のテーブル名とするため、「Excelのシート名＋$印 を角カッコで囲む」ようにします。なおCSVファイルの場合も同様に角カッコでCSVファイル名を囲む必要があります（Accessについては、テーブル名はそのまま）。
４９４行目「SQL = "Select * from " & SQL」で、実行するSQL文を組み立てます。
４９６行目「Set rs = cn.Execute(SQL)」では、右辺でConnectionオブジェクトのExecuteメソッドにSQL文を指定して実行させます。今回のSQL文は「Select ･･･」ですのでデータとしてレコードセットが戻されます。そのレコードセットを左辺の変数rsで受け取ることで、変数rsはRecordsetオブジェクトになります。この時点ではRecordsetは開かれた状態です。
そのレコードセットの処理が４９８～５０８行目になり、Do～Loopを使いレコードセットの終端になるまで繰り返し、４列のデータをワークシートに書き込んでいます。
処理が終了したら、５１０行目「rs.Close」でレコードセットを閉じます。Recordset.Openメソッドは実行していませんが、４９６行目を実行することにより変数rs（Recordsetオブジェクト）は開いていますので、処理終了後に閉じる必要があります。最後に５１１行目「cn.Close」で接続を閉じます。

６ー２ー２．CommandでSQL文を実行しレコードセット取得

図５０のNo.6のコードは、以下のようになります。

520. '==========　⇩(14)　CommandでSQL文を実行しレコードセット取得 ============
521. Sub Pattern06()
522. 　Dim cn As Object 　 '←Connectionオブジェクト
523. 　Dim rs As Object 　 '←Recordsetオブジェクト
524. 　Dim cmd As Object 　 '←Commandオブジェクト
525. 　Dim SQL As String 　 '←テーブル名、又はSQL文
526. 　Dim i As Integer 　 '←レコードの行位置
528. 　Set cn = CreateObject("ADODB.Connection")
529. 　Set cmd = CreateObject("ADODB.Command")
531. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
533. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
534. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
535. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
537. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
538. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
540. 　cn.Open
542. '　　SQL = "TestTable" 　 '←⑥Access
543. 　　SQL = "[db$]" 　　　 '←⑦Excel
544. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
546. 　　SQL = "Select * from " & SQL
548. 　　cmd.ActiveConnection = cn
549. 　　cmd.CommandText = SQL
551. 　　Set rs = cmd.Execute
553. 　　　With Sheet1.Range("B2")
554. 　　　　.CurrentRegion.ClearContents
555. 　　　　Do While Not rs.EOF
556. 　　　　　.Offset(i, 0) = rs.Fields(0).Value
557. 　　　　　.Offset(i, 1) = rs.Fields(1).Value
558. 　　　　　.Offset(i, 2) = rs.Fields(2).Value
559. 　　　　　.Offset(i, 3) = rs.Fields(3).Value
560. 　　　　　rs.MoveNext
561. 　　　　　i = i + 1
562. 　　　　Loop
563. 　　　End With
565. 　　rs.Close
566. 　cn.Close
568. 　Set rs = Nothing
569. 　Set cmd = Nothing
570. 　Set cn = Nothing
571. End Sub

図５９別窓
５２８行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成し、５２９行目「Set cmd = CreateObject("ADODB.Command")」でCommandオブジェクトを生成します。
５３１行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
５３４行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
５３７行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
５４０行目「cn.Open」で、データベースに接続します。
５４３行目「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入しますが、ここではSQL文内のテーブル名とするため、「Excelのシート名＋$印 を角カッコで囲む」ようにします。なおCSVファイルの場合も同様に角カッコでCSVファイル名を囲む必要があります。
５４６行目「SQL = "Select * from " & SQL」で、実行するSQL文を組み立てます。
５４８行目「cmd.ActiveConnection = cn」は、接続中のConnectionオブジェクトをCommandオブジェクトのActiveConnectionに指定し、ConnectionとCommandを結び付けています。
５４９行目「cmd.CommandText = SQL」では、CommandオブジェクトのCommandTextにSQL文を指定しています。
５５１行目「Set rs = cmd.Execute」の右辺では、CommandオブジェクトのExecuteメソッドを実行し「ActiveConnectionプロパティに設定したデータベースに対し、CommandTextプロパティに設定したSQL文を実行」しています。そしてその戻り値であるレコードセットを左辺の変数rsに代入しています。
データのレコードセットが得られましたので、５５３～５６３行目で処理をしています。Do～Loopを使いレコードセットの終端になるまで繰り返し、４列のデータをワークシートに書き込みます。
処理が終了したら、５６５行目「rs.Close」でレコードセットを閉じます。Recordset.Openメソッドは実行していませんが、５５１行目を実行することにより変数rs（Recordsetオブジェクト）は開いていますので、処理終了後に閉じる必要があります。最後に５６６行目「cn.Close」で接続を閉じます。

６ー２ー３．CommandにSQL文を格納後Recordsetで取得

図５０のNo.7のコードは、以下のようになります。

580. '==========　⇩(15)　ConnectionでSQL文を実行しレコードセット取得 ============
581. Sub Pattern07()
582. 　Dim cn As Object 　 '←Connectionオブジェクト
583. 　Dim rs As Object 　 '←Recordsetオブジェクト
584. 　Dim cmd As Object 　 '←Commandオブジェクト
585. 　Dim SQL As String 　 '←テーブル名、又はSQL文
586. 　Dim i As Integer 　 '←レコードの行位置
588. 　Set cn = CreateObject("ADODB.Connection")
589. 　Set rs = CreateObject("ADODB.Recordset")
590. 　Set cmd = CreateObject("ADODB.Command")
592. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
594. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
595. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
596. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
598. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
599. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
601. 　cn.Open
603. '　　SQL = "TestTable" 　 '←⑥Access
604. 　　SQL = "[db$]" 　　　 '←⑦Excel
605. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
607. 　　SQL = "Select * from " & SQL
609. 　　cmd.ActiveConnection = cn
610. 　　cmd.CommandText = SQL
612. 　　rs.Open cmd
614. 　　　With Sheet1.Range("B2")
615. 　　　　.CurrentRegion.ClearContents
616. 　　　　Do While Not rs.EOF
617. 　　　　　.Offset(i, 0) = rs.Fields(0).Value
618. 　　　　　.Offset(i, 1) = rs.Fields(1).Value
619. 　　　　　.Offset(i, 2) = rs.Fields(2).Value
620. 　　　　　.Offset(i, 3) = rs.Fields(3).Value
621. 　　　　　rs.MoveNext
622. 　　　　　i = i + 1
623. 　　　　Loop
624. 　　　End With
626. 　　rs.Close
627. 　cn.Close
629. 　Set rs = Nothing
630. 　Set cmd = Nothing
631. 　Set cn = Nothing
632. End Sub

図６０別窓
５８８行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成し、５８９行目「Set rs = CreateObject("ADODB.Recordset")」でRecordsetオブジェクトを生成。また５９０行目「Set cmd = CreateObject("ADODB.Command")」でCommandオブジェクトを生成します。
５９２行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
５９５行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
５９８行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
６０１行目「cn.Open」で、データベースに接続します。
６０４行目「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入しますが、ここではSQL文内のテーブル名とするため、「Excelのシート名＋$印 を角カッコで囲む」ようにします。なおCSVファイルの場合も同様に角カッコでCSVファイル名を囲む必要があります。
６０７行目「SQL = "Select * from " & SQL」で、実行するSQL文を組み立てます。
６０９行目「cmd.ActiveConnection = cn」は、接続中のConnectionオブジェクトをCommandオブジェクトのActiveConnectionに指定し、ConnectionとCommandを結び付けています。
６１０行目「cmd.CommandText = SQL」では、CommandオブジェクトのCommandTextにSQL文を指定しています。
６１２行目「rs.Open cmd」では、RecordsetオブジェクトのOpenメソッドを実行しています。第１パラメータに６０９～６１０行目で情報を格納したCommandオブジェクトを指定しています。
データのレコードセットが得られましたので、６１４～６２４行目で処理をしています。Do～Loopを使いレコードセットの終端になるまで繰り返し、４列のデータをワークシートに書き込みます。
処理が終了したら、６２６行目「rs.Close」でレコードセットを閉じ、６２７行目「cn.Close」で接続を閉じます。

６ー２ー４．Recordsetに直接SQL文を指定しレコードセット取得

図５０のNo.8のコードは、以下のようになります。

640. '==========　⇩(16)　Recordsetに直接SQL文を指定しレコードセット取得 ============
641. Sub Pattern08()
642. 　Dim cn As Object 　 '←Connectionオブジェクト
643. 　Dim rs As Object 　 '←Recordsetオブジェクト
644. 　Dim SQL As String 　 '←テーブル名、又はSQL文
645. 　Dim i As Integer 　 '←レコードの行位置
647. 　Set cn = CreateObject("ADODB.Connection")
648. 　Set rs = CreateObject("ADODB.Recordset")
650. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
652. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
653. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
654. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
656. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
657. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
659. 　cn.Open
661. '　　SQL = "TestTable" 　 '←⑥Access
662. 　　SQL = "[db$]" 　　　 '←⑦Excel
663. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
665. 　　SQL = "Select * from " & SQL
667. 　　rs.Open SQL, cn
669. 　　　With Sheet1.Range("B2")
670. 　　　　.CurrentRegion.ClearContents
671. 　　　　Do While Not rs.EOF
672. 　　　　　.Offset(i, 0) = rs.Fields(0).Value
673. 　　　　　.Offset(i, 1) = rs.Fields(1).Value
674. 　　　　　.Offset(i, 2) = rs.Fields(2).Value
675. 　　　　　.Offset(i, 3) = rs.Fields(3).Value
676. 　　　　　rs.MoveNext
677. 　　　　　i = i + 1
678. 　　　　Loop
679. 　　　End With
681. 　　rs.Close
682. 　cn.Close
684. 　Set rs = Nothing
685. 　Set cn = Nothing
686. End Sub

図６１別窓
６４７行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成し、６４８行目「Set rs = CreateObject("ADODB.Recordset")」でRecordsetオブジェクトを生成します。
６５０行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
６５３行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
６５６行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
６５９行目「cn.Open」で、データベースに接続します。
６６２行目「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入しますが、ここではSQL文内のテーブル名とするため、「Excelのシート名＋$印 を角カッコで囲む」ようにします。なおCSVファイルの場合も同様に角カッコでCSVファイル名を囲む必要があります。
６６５行目「SQL = "Select * from " & SQL」で、実行するSQL文を組み立てます。
６６７行目「rs.Open SQL, cn」では、RecordsetオブジェクトのOpenメソッドを実行しています。第１パラメータには６６５行目で作成したSQL文を、第２パラメータには接続しているConnectionオブジェクト（変数cn）を指定します。
データのレコードセットが得られましたので、６６９～６７９行目で処理をしています。Do～Loopを使いレコードセットの終端になるまで繰り返し、４列のデータをワークシートに書き込みます。
処理が終了したら、６８１行目「rs.Close」でレコードセットを閉じ、６８２行目「cn.Close」で接続を閉じます。

６ー３．SQL（Insert等）文で操作

データベースに接続し、「Insertなどのデータを変更させるSQL文」を操作するコードを以下で紹介します。
なお、Excelのシートデータベースについて説明しますが、以下のようにコードを切り替えることで、Access・CSVをデータベースの場合にすることが出来ます。また、SQL文をInsert・Update・Deleteで切り替える事で異なる処理が可能です。
なお丸番号は、図６３・図６４・図６５・図６６で同じにしてあります。

	Data Source	Extended Properties	SQL文内のﾃｰﾌﾞﾙ	SQL文
Access	① Accessﾌｧｲﾙ名	－	⑥ ﾃｰﾌﾞﾙ名そのまま	⑪ Insert文 ⑫ Update文 ⑬ Delete文
Excel	② Excelﾌｧｲﾙ名	④ Excel 12.0 ･･･	⑦ [ｼｰﾄ名+$印]	⑪ Insert文 ⑫ Update文
CSV	③ CSVﾌｧｲﾙのﾌｫﾙﾀﾞｰ名	⑤ Text ･･･	⑧ [CSVﾌｧｲﾙ名]	⑪ Insert文

図６２別窓

６ー３ー１．ConnectionでSQL文を実行しデータ変更

図５０のNo.9のコードは、以下のようになります。

690. '==========　⇩(17)　ConnectionでSQL文を実行しデータ変更 ============
691. Sub Pattern09()
692. 　Dim cn As Object 　 '←Connectionオブジェクト
693. 　Dim SQL As String 　 '←テーブル名、又はSQL文
695. 　Set cn = CreateObject("ADODB.Connection")
697. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
699. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
700. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
701. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
703. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
704. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
706. 　cn.Open
708. '　　SQL = "TestTable" 　 '←⑥Access
709. 　　SQL = "[db$]" 　　　 '←⑦Excel
710. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
712. 　　SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)" 　　 '←⑪Insert文
713. '　　SQL = "update " & SQL & " set St='XYZ' where DT=#2000/11/20#" 　　 '←⑫Update文
714. '　　SQL = "Delete from " & SQL & " where dt=#11/20/2000#" 　 '←⑬Delete文
716. 　　cn.Execute SQL
718. 　cn.Close
720. 　Set cn = Nothing
721. End Sub

図６３別窓
６９５行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成します。
６９７行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
７００行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
７０３行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
７０６行目「cn.Open」で、データベースに接続します。
７０９行目「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入します。
７１２行目「SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)"」で、Insert文を組み立てています。
７１６行目「cn.Execute SQL」では、ConnectionオブジェクトのExecuteメソッドで、第１パラメータに指定した「データ変更用のSQL文」を実行します。
実行終了したら、７１８行目「cn.Close」で接続を閉じます。

６ー３ー２．CommandでSQL文を実行しデータ変更

図５０のNo.10のコードは、以下のようになります。

730. '==========　⇩(18)　CommandでSQL文を実行しデータ変更 ============
731. Sub Pattern10()
732. 　Dim cn As Object 　 '←Connectionオブジェクト
733. 　Dim cmd As Object 　 '←Commandオブジェクト
734. 　Dim SQL As String 　 '←テーブル名、又はSQL文
736. 　Set cn = CreateObject("ADODB.Connection")
737. 　Set cmd = CreateObject("ADODB.Command")
739. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
741. '　cn.Properties("Data Source") = ThisWorkbook.Path & "\" & "its-041.accdb" 　 '←①Access
742. 　cn.Properties("Data Source") = ThisWorkbook.Path & "\" & ThisWorkbook.Name 　　 '←②Excel
743. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
745. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
746. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
748. 　cn.Open
750. '　　SQL = "TestTable" 　 '←⑥Access
751. 　　SQL = "[db$]" 　　　 '←⑦Excel
752. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
754. 　　SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)" 　　 '←⑪Insert文
755. '　　SQL = "update " & SQL & " set St='XYZ' where DT=#2000/11/20#" 　　 '←⑫Update文
756. '　　SQL = "Delete from " & SQL & " where dt=#11/20/2000#" 　 '←⑬Delete文
758. 　　cmd.ActiveConnection = cn
759. 　　cmd.CommandText = SQL
761. 　　cmd.Execute
763. 　cn.Close
765. 　Set cmd = Nothing
766. 　Set cn = Nothing
767. End Sub

図６４別窓
７３６行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成し、７３７行目「Set cmd = CreateObject("ADODB.Command")」でCommandオブジェクトを生成します。
７３９行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
７４２行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
７４５行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
７４８行目「cn.Open」で、データベースに接続します。
７５１「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入します。
７５４行目「SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)"」で、Insert文を組み立てています。
７５８行目「cmd.ActiveConnection = cn」は、接続中のConnectionオブジェクトをCommandオブジェクトのActiveConnectionに指定し、ConnectionとCommandを結び付けています。
７５９行目「cmd.CommandText = SQL」では、CommandオブジェクトのCommandTextにSQL文を指定しています。
７６１行目「cmd.Execute」で、CommandオブジェクトのExecuteメソッドを実行し「ActiveConnectionプロパティに設定したデータベースに対し、CommandTextプロパティに設定したSQL文を実行」しています。
実行終了したら、７６３行目「cn.Close」で接続を閉じます。

６ー３ー３．CommandにSQL文を格納後Recordsetで実行しデータ変更

図５０のNo.11のコードは、以下のようになります。

770. '==========　⇩(19)　CommandにSQL文を格納後Recordsetで実行しデータ変更 ============
771. Sub Pattern11()
772. 　Dim cn As Object 　 '←Connectionオブジェクト
773. 　Dim rs As Object 　 '←Recordsetオブジェクト
774. 　Dim cmd As Object 　 '←Commandオブジェクト
775. 　Dim SQL As String 　 '←テーブル名、又はSQL文
777. 　Set cn = CreateObject("ADODB.Connection")
778. 　Set rs = CreateObject("ADODB.Recordset")
779. 　Set cmd = CreateObject("ADODB.Command")
781. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
783. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
784. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
785. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
787. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
788. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
790. 　cn.Open
792. '　　SQL = "TestTable" 　 '←⑥Access
793. 　　SQL = "[db$]" 　　　 '←⑦Excel
794. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
796. 　　SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)" 　　 '←⑪Insert文
797. '　　SQL = "update " & SQL & " set St='XYZ' where DT=#2000/11/20#" 　　 '←⑫Update文
798. '　　SQL = "Delete from " & SQL & " where dt=#11/20/2000#" 　 '←⑬Delete文
800. 　　cmd.ActiveConnection = cn
801. 　　cmd.CommandText = SQL
803. 　　rs.Open cmd
805. 　cn.Close
807. 　Set rs = Nothing
808. 　Set cmd = Nothing
809. 　Set cn = Nothing
810. End Sub

図６５別窓
７７７行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成し、７７８行目「Set rs = CreateObject("ADODB.Recordset")」でRecordsetオブジェクトを生成。７７９行目「Set cmd = CreateObject("ADODB.Command")」でCommandオブジェクトを生成します。
７８１行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
７８４行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
７８７行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
７９０行目「cn.Open」で、データベースに接続します。
７９３行目「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入します。
７９６行目「SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)"」で、Insert文を組み立てています。
８００行目「cmd.ActiveConnection = cn」は、接続中のConnectionオブジェクトをCommandオブジェクトのActiveConnectionに指定し、ConnectionとCommandを結び付けています。
８０１行目「cmd.CommandText = SQL」では、CommandオブジェクトのCommandTextにSQL文を指定しています。
８０３行目「rs.Open cmd」では、RecordsetオブジェクトのOpenメソッドの第１パラメータにCommandオブジェクトを指定して実行しています。この時、第２パラメータは省略します。
この８０３行目は「ActiveConnectionプロパティに設定したデータベースに対し、CommandTextプロパティに設定したSQL文を実行」している事になります。
実行が完了したら、８０５行目「cn.Close」でデータベース接続を閉じます。
なお、データ変更用のSQL文（Insert、Update、Delete）をRecordset.Openで実行した時は「Recordset.Closeは実行しない」ことに注意ください。このデータ変更SQLを実行した直後には、RecordsetオブジェクトのStateプロパティがゼロ（＝レコードセットは閉じられている）となり、更に「Recordset.Close を実行してしまうと、エラーが発生」します。

６ー３ー４．SQL文を直接ecordsetで実行しデータ変更

図５０のNo.12のコードは、以下のようになります。

820. '==========　⇩(20)　SQL文を直接ecordsetで実行しデータ変更 ============
821. Sub Pattern12()
822. 　Dim cn As Object 　 '←Connectionオブジェクト
823. 　Dim rs As Object 　 '←Recordsetオブジェクト
824. 　Dim SQL As String 　 '←テーブル名、又はSQL文
826. 　Set cn = CreateObject("ADODB.Connection")
827. 　Set rs = CreateObject("ADODB.Recordset")
829. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
831. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
832. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　　 '←②Excel
833. '　cn.Properties("Data Source") = ThisWorkbook.Path 　　 '←③CSV
835. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　　 '←④Excel
836. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　　 '←⑤CSV
838. 　cn.Open
840. '　　SQL = "TestTable" 　 '←⑥Access
841. 　　SQL = "[db$]" 　　　 '←⑦Excel
842. '　　SQL = "[its-041.csv]" 　 '←⑧CSV
844. 　　SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)" 　　 '←⑪Insert文
845. '　　SQL = "update " & SQL & " set St='XYZ' where DT=#2000/11/20#" 　　 '←⑫Update文
846. '　　SQL = "Delete from " & SQL & " where dt=#11/20/2000#" 　 '←⑬Delete文
848. 　　rs.Open SQL, cn
850. 　cn.Close
852. 　Set rs = Nothing
853. 　Set cn = Nothing
854. End Sub

図６６別窓
８２６行目「Set cn = CreateObject("ADODB.Connection")」でConnectionオブジェクトを生成し、８２７行目「Set rs = CreateObject("ADODB.Recordset")」でRecordsetオブジェクトを生成します。
８２９行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
８３２行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、データベースであるExcelのファイル名を指定します。
８３５行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」でExcelの拡張プロパティを指定します。
８３８行目「cn.Open」で、データベースに接続します。
８４１行目「SQL = "[db$]"」で、テーブル名を一旦変数SQLに代入します。
８４４行目「SQL = "Insert into " & SQL & " (st,nu,dt,bl) values ('pqr',897,#11/20/2000#,true)"」で、Insert文を組み立てています。
８４８行目「rs.Open SQL, cn」で、RecordsetオブジェクトのOpenメソッドの第１パラメータにSQL文を指定し、第２パラメータに接続中のConnectionオブジェクト（変数cn）を指定することで、データベースに対してデータ変更処理を行います。
実行が完了したら、８５０行目「cn.Close」でデータベース接続を閉じます。
なお、データ変更用のSQL文（Insert、Update、Delete）をRecordset.Openで実行した時は「Recordset.Closeは実行しない」ことに注意ください。このデータ変更SQLを実行した直後には、RecordsetオブジェクトのStateプロパティがゼロ（＝レコードセットは閉じられている）となり、更に「Recordset.Close を実行してしまうと、エラーが発生」します。

７．データの一括処理

上記で紹介した「レコードセットを取得し、ワークシートにデータを書き出す」コードは、レコードセットをDo～Loopで「１レコード単位」で取り出して処理する手法でした。それとは異なる方法で「全データを一括で取り出す」事も可能です。
一括で取り出すには、RecordsetオブジェクトのGetRowsメソッドを使用します。構文としては以下になります。
　配列 = Recordset.GetRows( Rows, Start, Fields)
戻り値は「インデックスがゼロ始まりの二次元配列」です。指定できるパラメータは以下の３つで、全て省略可です。

パラメータ		内容
Rows	省略可	取り出す行数 既定=現ｶｰｿﾙ位置 or Start指定位置から最終行まで
Start	省略可	取り出し開始のﾌﾞｯｸﾏｰｸ 既定=現ｶｰｿﾙ位置
Fields	省略可	取り出し列番号､又は列名 既定=全列

図６７別窓
第１パラメータのRowsは、GetRowsで取り出す行数を指定します。Recordset.Open直後のカーソル位置は先頭行にありますので、「省略すれば全行」が取り出せることになります。
なお取り出し行を「１」行に指定し、取り出した２次元配列をTranspose関数等で行列逆転させると「１次元配列」のデータとなりますので注意が必要です。
第２パラメータのStartは、ブックマーク文字列、又は図６８の値を指定します。省略（＝adBookmarkCurrent（値＝0））すると、現在のカーソル位置となります。

定数	値	内容
adBookmarkCurrent	0	現レコードから開始
adBookmarkFirst	1	最初のレコードから開始
adBookmarkLast	2	最後のレコードから開始

図６８別窓
Microsoftや他サイトでも図６８のような説明が載っているのですが、しかし試してみると既定のゼロ以外ではエラー（エラー内容：Recordsetはブックマークをサポートしていない）が発生してしまいます。Recordset.Openメソッドを使い、第３パラメータ（CursorType）を調整してみたのですが同じエラーが出るようです。
また、レコードセットへのブックマーク方法までは今回調べ切れず、ブックマーク文字列については今回省略しますが、上記のようなエラー内容から考えると、第２パラメータは「ACE・Jetプロバイダーでは使えない」のかもしれません。
第３パラメータのFieldsは、列番号（先頭列＝ゼロ）または列名（文字列）で指定します。省略すると、全列を出力します。
なお、複数列に限って出力したい場合は「Array(2,3)」のように配列の形で指定することで可能です。この例の場合は３列目＋４列目を出力せよ　という意味になります。
GetRowsメソッドを使って出力したデータは「行列が逆転した配列」になります。もちろんTransposeメソッドで行列を回転させる事は可能ですが、要素内に「Nullが入っているとエラー」が発生するので注意が必要です。また1行しか取得できなかった場合にTransposeで回転させると、二次元配列が一次元配列に変わってしまうので工夫が必要です。
図５３のコード（１行ずつ出力処理）をGetRowsで一括処理するのが、以下のコードになります。

860. '==========　⇩(21)　GetRowsでまとめてデータ取得 ============
861. Sub Pattern13()
862. 　Dim cn As Object 　 '←Connectionオブジェクト
863. 　Dim rs As Object 　 '←Recordsetオブジェクト
864. 　Dim SQL As String 　 '←テーブル名、又はSQL文
865. 　Dim GR As Variant 　 '←データ配列
867. 　Set cn = CreateObject("ADODB.Connection")
869. 　cn.Provider = "Microsoft.ACE.OLEDB.12.0"
871. '　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & "its-041.accdb" 　 '←①Access
872. 　cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name 　 '←②Excel
873. '　cn.Properties("Data Source") = ThisWorkbook.Path 　 '←③CSV
875. 　cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;" 　 '←④Excel
876. '　cn.Properties("Extended Properties") = "Text;HDR=Yes;IMEX=0;" 　 '←⑤CSV
878. 　cn.Open
880. '　　SQL = "TestTable" 　 '←⑥Access
881. 　　SQL = "db$" 　 '←⑦Excel
882. '　　SQL = "its-041.csv" 　 '←⑧CSV
884. '　　Set rs = cn.Execute(SQL) 　 '←⑨Access
885. 　　Set rs = cn.Execute(SQL, , 512) 　 '←⑩Excel、CSV
887. 　　　With Sheet1.Range("B2")
888. 　　　　.CurrentRegion.ClearContents
889. 　　　　GR = rs.GetRows
890. 　　　　GR = WorksheetFunction.Transpose(GR)
891. 　　　　.Resize(UBound(GR, 1), UBound(GR, 2)) = GR
892. 　　　End With
894. 　　rs.Close
895. 　cn.Close
897. 　Set rs = Nothing
898. 　Set cn = Nothing
899. End Sub

図６９別窓
８６７行目「Set cn = CreateObject("ADODB.Connection")」で、Connectionオブジェクトを生成します。
８６９行目「cn.Provider = "Microsoft.ACE.OLEDB.12.0"」で、ACEプロバイダを設定します。
８７２行目「cn.Properties("Data Source") = ThisWorkbook.Path & "¥" & ThisWorkbook.Name」で、Excelのシートデータベースを指定します。
８７５行目「cn.Properties("Extended Properties") = "Excel 12.0;HDR=Yes;IMEX=0;"」で、拡張プロパティの指定をします。
８７８行目「cn.Open」で、データベースに接続します。
８８１行目「SQL = "db$"」で、テーブル名として「Excelのシート名＋$印」を変数SQLに代入します。
８８５行目「Set rs = cn.Execute(SQL, , 512)」の右辺では、ConnectionオブジェクトのExecuteメソッドでテーブル名を実行します。この時に第３パラメータには「Excel、CSVをテーブルとして読み込むためのadCmdTableDirect（値＝512）」を設定します。
第３パラメータへの値512の設定は、Excel＋テーブル、CSV＋テーブルの場合は必須ですが、Access＋テーブルの場合に設定しても問題はありません。
この実行によりテーブルの全データ（レコードセット）が取得できますので、左辺の変数rsに代入します。なお、この段階では、レコードセットのカーソル（操作できる行位置）は、先頭行にあります。
８８７～８９２行目では、取得したレコードセットの全データをワークシート上に書き出しています。
８８７行目「With Sheet1.Range("B2")」では、シートへのデータ書き出しの基準点を決めています。
８８８行目「.CurrentRegion.ClearContents」は、その基準点を含むエリアに書かれていたデータをクリアします。
８８９行目「GR = rs.GetRows」では、（カーソルは先頭にあるので）レコードセットの全データを取得し、変数GRに代入しています。この段階での配列GRは、行列逆転した状態で、且つ配列インデックスはゼロ始まりです。
８９０行目「GR = WorksheetFunction.Transpose(GR)」では、Transpose関数で行列を逆にし、いわゆる正しい行列方向にデータ変換しています。また配列インデックスも１始まりに変換されます（取得したデータ行が１行分の場合は、Transposeにより二次元配列→一次元配列 になります）。
８９１行目「.Resize(UBound(GR, 1), UBound(GR, 2)) = GR」では、貼り付けサイズを配列と同じサイズにしてから、配列データを貼り付けています。（１行しか取得できなかった場合は、ここでエラー（UBound(GR, 2)が無い）が出ます）
８９４行目「rs.Close」でレコードセットを閉じ、８９５行目「cn.Close」で接続を閉じます。
なお他のパターンでも、同様にGetRowsを使い一括処理を行うことが可能です。

アプリ実例・関連する項目

「ExcelシートDBとSQLを使った会議室予約システム」
「ExcelシートDBとSQLを使った倉庫管理システム」
「共有資料の登録と閲覧ができるサーバーシステム」
「複数の備品を同時予約可能な貸出台帳」
「Accessデータベースを使用した売上台帳」
「設備の稼働状態を入力し、グラフで確認」
「ExcelからAccessデータベースを作成・操作」

サンプルファイル

ADOでAccess･Excel･CSVへ接続・操作(JET･ACEプロバイダ編)（its-042.xlsm）
Accessデータファイル（its-041.accdb）
CSVデータファイル（its-041.csv）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。