2024/03/14

処理を一定時間停止させる

• １．Waitメソッドで一定時間停止
• 　１－１．Waitメソッドの特性等
• 　　よりみち(ミリ秒の文字列指定)
• 　１－２．実停止時間の測定について
• 　１－３．秒単位での停止制御
• 　１－４．ミリ秒単位で制御
• 　　よりみち(再開が遅れる理由)
• 　１－５．タイマー精度を変更して制御
• 　１－６．Waitメソッドの停止精度の限界
• ２．Do～Loopで一定時間滞留
• 　２－１．秒単位で制御
• 　　２－１－１．Date型での足し算方式
• 　　２－１－２．一旦String型に変更する方式
• 　　２－１－３．不等号に「>=」を使用する方式
• 　２－２．ミリ秒単位で制御
• 　２－３．タイマー精度を変更して制御
• 　２－４．QueryPerformanceCounterを使用して制御
• ３．Sleep関数で一定時間中断
• 　３－１．ミリ秒単位で制御
• 　３－２．タイマー精度を変更して制御
• ４．OnTimeメソッドで一定時間後に別プロシージャを起動
• 　４－１．秒単位で制御
• 　４－２．ミリ秒単位で制御
• 　４－３．タイマー精度を変更して制御
• ５．まとめ
• アプリ実例・関連する項目
• サンプルファイル

表示を点滅させたり一定時間で自動的にメッセージを閉じたりする時、またユーザーの入力待ちの時には、プログラムを一定時間停止させる必要があります。一時停止の手段として一般的にWaitやSleepが良く使われますが、それらを含めて以下４つの方法があると思います。
　・Waitメソッドで、指定時間に再開させる
　・Do～Loopで、指定時間まで滞留させる
　・Sleep関数（Win32API）で、一定時間停止させる
　・OnTimeメソッドで、一定時間後に別プロシージャを実行する
また同じ手段でも、取得した時間の分解能で実停止時間のバラツキ等が変わってきます。時間取得方法には複数種類がありますが、詳細については「日時や時間の取得」を参照下さい。今回はその内の一部を使って停止時間を制御しますが、他の手法でも可能です。
なお「サンプルファイル」では、ここで紹介したコードをシート上に配置したボタンから実行できるようにしています。
関数等の種類名＋ボタン表面文字＝プロシージャ名としてあります。

図０１別窓

１．Waitメソッドで一定時間停止

１－１．Waitメソッドの特性等

ExcelのAplicationオブジェクトのWaitメソッドは、引数に指定した時刻まで停止（＝指定した時刻に再開）するものです。
構文としては、以下になります。
　Excel.Application.Wait(Time)
ExcelのVBAから実行するのであれば、先頭の「Excel.」は不要になります。
引数のTime（再開時刻）はVariant型で、文字列で時刻を指定する方法と、日付値で指定する方法とに分かれます。
まず文字列として指定する方法です。
「Application.Wait "12:34:56"」と文字列で時刻を指定すれば、指定した時刻に再開して、次行のコード行に移ります。
また時刻の表記法を変え、「Application.Wait "12時34分56秒"」や「Application.Wait "0:34:56 PM"」でもOKです。
なお「Application.Wait "12:34:67"」のように間違えても、Excel側で勝手に「12:35:07」と解釈してくるようです。
指定する時刻は「"12:34:56"」のように秒単位とMicrosoftでも説明していますが、試してみるとミリ秒の指定もできます。つまり「"12:34:56.789"」のように指定すれば、ミリ秒で制御された再開時間になります。

(ミリ秒の文字列指定) この「ミリ秒を文字列として指定」できる事は、他のサイトではあまり触れていません。しかし他サイトでも、シリアル値を使う方法としては「Application.Wait Evaluate("now()") + 1 / 86400」のようにEvaluateメソッドを使うと「ミリ秒制御が可能」との説明が行われています。 考えてみるとWaitメソッドの引数は、「文字列の時刻」と「シリアル値（数値）の時刻」のどちらもOKなのだから、シリアル値でミリ秒が可能 →「文字列でもミリ秒が可能」と考えた次第です。 Waitメソッドで時刻を直値指定する事は少ないと思いますが、機能を比較して試してみると面白い発見があるかもしれません。

Waitメソッドの引数は「時刻データ」とMicrosoftでも説明していますが、日付も含めて指定する事が可能です。例えば「Application.Wait "2024/03/01 12:34:56"」のようにすれば「指定日付＋指定時刻に再開」することが出来ます。
しかし、日付も含めて指定した場合と時刻指定のみでは、Waitメソッドの動きは以下の様に異なります。

実行時	Waitの引数
	時刻のみ(A) (ｼﾘｱﾙ値=1未満)	日付＋時刻(A) (ｼﾘｱﾙ値=1以上)
Aより前	A時に再開	A時に再開
Aより後	翌日のA時に再開	即時再開

図０２別窓
Waitに指定したのが時刻のみで、例えば10:00を指定した場合、現在が10:00前なら「10:00に再開」し、10:00を過ぎていれば「翌日の10:00に再開」することになります。
一方Waitに指定したのが日付＋時刻で、例えば2024/02/01の10:00を指定した場合、現在が2024/02/01の10:00より前なら「2024/02/01の10:00に再開」し、過ぎていれば「即時に再開」することになります。
なお、この関係は日付値（数値）でも成立します。図０２の表中にも記載しましたが、時刻のみを指定するとシリアル値は1未満となり、日付を含めるとシリアル値が1以上となります。
日付値（数値）を指定する方法は、色々考えられます。
もっとも一般的なのは「Application.Wait Now() + TimeValue("0:00:01")」のようにNow関数を使用するものです。実行するとNow関数の部分で「現在の日時」が得られ、その値に対しTimeValueで秒数などを加えるため、「現日時から指定時間後に再開（＝指定した時間だけ停止）」という動きになります。
Now関数では無く、Nowの時刻部分のみの「Time関数」を使い「Application.Wait time() + TimeValue("0:00:01")」としてもほぼ問題ありません。但し24時近くに実行し「time() + TimeValue("0:00:01")」のシリアル合計値が1を超してしまうと、日付も指定した事になってしまいます。シリアル値の1は 1899年12月31日（「日付の基準値」参照 ）ですので、大昔の日付を指定したという事になってしまい、Waitで停止することなく即時に次行に移ります。
またTimeValueを使わず「数値の１＝１日」というシリアル値のルールを使い、停止秒数を「60秒 × 60分 × 24時間 = 86,400」で除算して「Application.Wait Now() + 1 / 86400」とする方法も可です。
またVBA関数を使い「Application.Wait DateAdd("s", 1, Now())」と、現日時に停止時間を加算する式でもOKです。
絶対時刻を指定する方法としては「Application.Wait TimeSerial(12, 34, 56)」のようにTimeSerial関数を使用する手法もあります。この方法でも例え「TimeSerial(12, 34, 67)」となっても「12:35:07」と勝手に変換してくれます。
なおWaitメソッドでは一時停止している間に「ESCキー」を押すと、再開時刻が来ていなくても再開し次の行に移行します。
以下では「１秒間停止」させるコードを紹介します。

１－２．実停止時間の測定について

停止させる時間として、Waitメソッドをはじめ他の関数等にも「１秒」を指定するのですが、実際に停止している時間が１秒とは限りません。その停止している実時間を調べるために、今回はWin32APIのQueryPerformanceCounter関数を使用します。この関数はWindowsが起動してからのカウント数を戻す関数で、今のところ最も精度良く時間が測れると思われるものです。
このQueryPerformanceCounter関数、及びQueryPerformanceFrequency関数（秒あたりのカウント数）の宣言を図０３のように宣言部で行っておきます。

0. '==========　⇩(1)　Win32API関数の宣言 ============
1. #If Win64 Then
2. 　Declare PtrSafe Function QueryPerformanceFrequency Lib "kernel32" (lpFrequency As Currency) As Long
3. 　Declare PtrSafe Function QueryPerformanceCounter Lib "kernel32" (lpPerformanceCount As Currency) As Long
4. #Else
5. 　Declare Function QueryPerformanceFrequency Lib "kernel32" (frequency As Currency) As Long
6. 　Declare Function QueryPerformanceCounter Lib "kernel32" (procTime As Currency) As Long
7. #End If

図０３別窓
図０３では、データを受け取る引数（lpFrequency、およびlpPerformanceCount）のデータ型をCurrencyとしました。このCurrency型は64ビット（8バイト）の小数点4桁の固定小数点型ですが内部的には整数として管理されているようなので、カウント数のように大きな整数を受け取るのには適していると判断しました。
QueryPerformanceCounterの詳細については「日時や時間の取得」を参照下さい。

１－３．秒単位での停止制御

秒単位の制御をするため、ここではNow関数とTimeValue関数を使っています。

20. '==========　⇩(2)　秒単位での停止制御 ============
21. Sub Wait_Second()
22. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
23. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
24. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
26. 　Call QueryPerformanceFrequency(freq)
27. 　Call QueryPerformanceCounter(CntStart)
29. 　Application.Wait Now() + TimeValue("0:00:01")
31. 　Call QueryPerformanceCounter(CntEnd)
33. 　MsgBox (CntEnd - CntStart) / freq
34. End Sub

図０４別窓
図０４の中で本体は２９行目「Application.Wait Now() + TimeValue("0:00:01")」です。Waitメソッドの引数として「Now() + TimeValue("0:00:01")」を指定することで「Waitメソッドを実行した時から1秒間停止させ、その後再開」させます。
Now関数もTimeValue関数もDate型の日付値を戻しますので、合計値もDate型となります。
そのWaitメソッドで停止している実時間を測るため、直前の２７行目「Call QueryPerformanceCounter(CntStart)」で開始時刻（ここではカウント数）を測り、直後の３１行目「Call QueryPerformanceCounter(CntEnd)」で終了時刻（ここではカウント数）を測ります。
１秒間のカウント数は２６行目「Call QueryPerformanceFrequency(freq)」で取得しておき、最後に３３行目「MsgBox (CntEnd - CntStart) / freq」で、Waitメソッドで停止した実際の時間をメッセージとして表示します。
秒単位の制御を行う手法として、今回の「Now関数＋TimeValue関数」を使う以外では、以下のような方法も考えられます。
　① Application.Wait Now() + 1 / 86400
　② Application.Wait DateAdd("s", 1, Now())
　③ Application.Wait Time() + TimeValue("0:00:01")
①はTimeValue関数の戻り値を直接分数値とする方法です。「1日 = 24時間 × 60分 × 60秒 = 86,400秒」という計算です。
②はDateAdd関数を用いて、１秒後のシリアル値を計算しています。
③はNow関数の代わりにTime関数を用いていますが、24時直前に使うと即時再開してしまうデメリットがあります。
図０４を50回繰り返して得たデータが図０５になります。

図０５別窓
Date型の分解能は１秒で、秒数が変わる直前にWaitメソッドが実行された場合は「実時間は約ゼロ秒」、変わった直後に実行された場合は「実時間は約１秒」になる事は予測されます。図０５では、データ数の不足の為かバラバラ感がありますが、平均値は予測に近い値（半分の0.5秒）になります。注目は標準偏差で、0.29と非常に大きなバラツキがあると言えます。

１－４．ミリ秒単位で制御

ミリ秒単位で制御する方法も複数の方法が考えられます。ここではワークシートのNOW関数とTimeValue関数を使って制御します。

40. '==========　⇩(3)　ミリ秒単位での停止制御 ============
41. Sub Wait_mmSecond()
42. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
43. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
44. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
46. 　Call QueryPerformanceFrequency(freq)
47. 　Call QueryPerformanceCounter(CntStart)
49. 　Application.Wait Evaluate("now()") + CDbl(TimeValue("0:00:01"))
51. 　Call QueryPerformanceCounter(CntEnd)
53. 　MsgBox (CntEnd - CntStart) / freq
54. End Sub

図０６別窓
４９行目「Application.Wait Evaluate("now()") + CDbl(TimeValue("0:00:01"))」では、Waitメソッドで１秒間停止させています。
引数の内「Evaluate("now()")」は、ミリ秒の分解能がある「ワークシートのNOW関数」をEvaluateで呼び出しています。この戻り値のデータ型はDouble型です。
停止時間の部分である「CDbl(TimeValue("0:00:01"))」は、図０４と同じくTimeValue関数で１秒を表しているのですが、ここで問題が生じます。TimeValue関数の戻り値はDate型なので、TimeValueをそのまま使い「Evaluate("now()") + TimeValue("0:00:01")」としてしまうと「Double型 ＋ Date型 = Date型」となり、せっかくミリ秒の現在日時を取得したのに、元の秒単位に戻ってしまうのです。
そのため、TimeValue値をDouble型にし「Double型 ＋ Double型 = Double型」とし、ミリ秒の分解能を確保しています。
この他には、以下のような指定方法もあります。
　① Application.Wait Evaluate("now()") + 1 / 86400
　② Application.Wait Evaluate("now()") + [TimeValue("0:00:01")]
　③ Application.Wait (Timer() + 1) / 86400
①は、TimeValue関数の戻り値を直接分数値とする方法です。分数ならDouble型となります。
②は、ミリ秒が得られるワークシートのTIMEVALUE関数を使う方法です。Evaluateを使っても同じです。
③は、ミリ秒が得られるTimer関数を使います。Timer関数は秒単位の値なので「60秒×60分×24時間=86400」で除算します。
図０６のコードで得られるデータの分布は図０７のようになります。

図０７別窓
グラフの通り「1 ± 0.015 秒」の範囲にほとんどのデータが入る感じです。しかし、Evaluate("now()")の分解能は「約15ミリ秒」なので、理論的には「1^-0.015 ～ 1⁺⁰」となりそうですが、上限側に15ミリ秒超はみ出しています。

(再開が遅れる理由) この上限側に「はみ出す」理屈を少し考えてみたのが図０８です。（間違っていたらごめんなさい） 図０８別窓 図０８の左側は基本的な考え方です。まず時間を取得するタイミング（時間の分解能）を約15ミリ秒とした時、Waitメソッドを実行するが①のタイミングの場合は0秒をa秒だけ過ぎていますが、取得する現在時間としては0秒です。その0秒に停止時間の1秒を加算し1秒の時点で再開しますが、実質停止していた時間は「1-a 秒」となります。 ②の場合は次の日時取得タイミングの直前ですが、取得する現在時間としてはやはり0秒です。計算上の1秒後に再開しますが、実質停止していた時間は「1-b 秒」となります。 つまり理論的には、実停止時間は「１-0.015 ～ １+0」になるはずです。 図０８の右図説明の前に、図０６の４９行目の再開する１秒後の日時「Evaluate("now()") + CDbl(TimeValue("0:00:01"))」を詳しく見てみます。 例えば現在の時刻が「0:01:00」ジャストだったとします。その現在時刻に1秒を加算するのですから、再開時間は「0:01:01」となります。Date型ではどこにも問題は無いのですが、日付の元となっているDouble型（8バイト）で値を比較したのが以下になります。 　[TimeValue("0:01:00")] + CDbl(TimeValue("0:00:01")) = 7.06018518518519E-04 　[TimeValue("0:01:01")] = 7.06018518518518E-04 本来は同じ値になりそうですが、上段と下段では最小桁の値が変わっています。原因はDouble型とDouble型の加算時に最小桁位置の１つ下で丸めの計算（≒四捨五入）が発生している為と考えられます。 このため二つの式をイコールで結ぶと「False（同じでは無い）」となります。 　( [TimeValue("0:01:00")] + CDbl(TimeValue("0:00:01")) = [TimeValue("0:01:01")] ) = False このため、本来の再開するはずの位置では「指定の時間に達していないと判断」されて再開せず、一つ遅れたタイミングで再開するため「上限側にはみ出る」のでは　と考えています。 但し全ての時刻の足し残がFalseになる訳では無く、ざっと調べたところ2割位がFalseとなりそうです。また１秒を足した式の方が必ず大きくなる訳でも無く、小さくなる場合もあるので、その2割全てが再開遅れになる訳でも無さそうです。 それなのに上限側にはみ出しているのが半数もあるのは、これだけが原因では無く「Waitメソッドの停止精度の限界」で説明するように、Waitメソッドが10ミリ秒毎に時間を測っている（推定）事も関係している気がします。 なお、ここでは1秒をDouble型に変換してから足していますが、足した後で全体をDouble型に変換しても同じ値になります。

１－５．タイマー精度を変更して制御

Windowsでは、Windows上のアプリやアプリ内の各動作を細かな時間で切り替えながら動かす仕組みとなっており、その切り替え時間をタイマーと呼びます。上記のEvaluate("Now()")なども、そのタイマーの間隔で時間データを取得しています。
標準のタイマーは約１５ミリ秒なので、Evaluate("Now()")などの分解能も約１５ミリ秒となるのですが、timeBeginPeriod関数を使用するとタイマー精度を変更できます。タイマー精度は最高で１ミリ秒まで向上できます、
下記ではタイマーを１ミリ秒に向上させた上でワークシートのNOW関数で停止時間を制御しています。

60. '==========　⇩(4)　Win32APIの宣言 ============
61. #If Win64 Then
62. 　Declare PtrSafe Function timeBeginPeriod Lib "winmm.dll" (ByVal uPeriod As LongPtr) As LongPtr
63. 　Declare PtrSafe Function timeEndPeriod Lib "winmm.dll" (ByVal uPeriod As LongPtr) As LongPtr
64. #Else
65. 　Declare Function timeBeginPeriod Lib "winmm.dll" (ByVal uPeriod As Long) As Long
66. 　Declare Function timeEndPeriod Lib "winmm.dll" (ByVal uPeriod As Long) As Long
67. #End If
69. '==========　⇩(5)　タイマー精度１ミリ秒での停止制御 ============
70. Sub Wait_1ms()
71. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
72. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
73. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
75. 　Call QueryPerformanceFrequency(freq)
77. 　timeBeginPeriod 1
79. 　　Call QueryPerformanceCounter(CntStart)
81. 　　Application.Wait Evaluate("now()") + CDbl(TimeValue("0:00:01"))
83. 　　Call QueryPerformanceCounter(CntEnd)
85. 　timeEndPeriod 1
87. 　MsgBox (CntEnd - CntStart) / freq
88. End Sub

図０９別窓
timeBeginPeriod関数を使用するには、６１～６７行目のようなWin32APIの宣言が必要です。またタイマーを元に戻すにはtimeEndPeriod関数が必要ですので、同時に宣言しています。
７７行目「timeBeginPeriod 1」では、タイマー精度を１ミリ秒に変更しています。timeBeginPeriod関数の引数に「変更するミリ秒」を指定することで変更できます。
８１行目「Application.Wait Evaluate("now()") + CDbl(TimeValue("0:00:01"))」は図０６の４９行目と同じでミリ秒の停止制御をさせています。
８５行目「timeEndPeriod 1」では、タイマー精度を標準（約１５ミリ秒）に戻しています。timeEndPeriod関数の引数には、７７行目のtimeBeginPeriod関数の引数（ここでは 1）と同じ値を指定する必要があります。
図０９のコードで得られるデータの分布は図１０のようになります。

図１０別窓
図０７と比較すると一周り停止精度が良くなり、「1^±0.01 秒」の範囲にほとんどのデータが入ります。なおタイマー精度が１ミリ秒の環境下ではEvaluate("now()")の分解能は、「約10ミリ秒（≒小数点２桁秒）」ですので、その値に沿っているような感じです。

１－６．Waitメソッドの停止精度の限界

「タイマー精度１ミリ秒」の環境下では、GetLocalTime関数自体の分解能は1ミリ秒まで向上します（「日時や時間の取得」参照）。このGetLocalTime関数を使ってWaitメソッドをより精密に制御しようとしたのが図１１です。

100. '==========　⇩(6)　Win32API宣言 ============
101. #If Win64 Then
102. 　Declare PtrSafe Sub GetLocalTime Lib "kernel32" (lpSystemTime As SYSTEMTIME)
103. #Else
104. 　Declare Sub GetLocalTime Lib "kernel32" (lpSystemTime As SYSTEMTIME)
105. #End If
107. '==========　⇩(7)　SYSTEMTIME構造体の定義 ============
108. Type SYSTEMTIME
109. 　wYear As Integer 　　　　 '←年
110. 　wMonth As Integer 　　　　 '←月
111. 　wDayOfWeek As Integer 　 '←曜日（0=日曜、1=月曜、･･･）
112. 　wDay As Integer 　　　　　 '←日
113. 　wHour As Integer 　　　　 '←時
114. 　wMinute As Integer 　　　 '←分
115. 　wSecond As Integer 　　　 '←秒
116. 　wMilliseconds As Integer 　 '←ミリ秒
117. End Type
119. '==========　⇩(8)　タイマー1ミリ秒環境下での停止制御 ============
120. Sub Wait_1ms2()
121. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
122. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
123. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
124. 　Dim sysT As SYSTEMTIME 　　 '←GetLocalTimeで取得する日時データ
126. 　Call QueryPerformanceFrequency(freq)
128. 　timeBeginPeriod 1
130. 　Call GetLocalTime(sysT)
132. 　　Call QueryPerformanceCounter(CntStart)
133. 　　
134. 　　Application.Wait sysT.wHour / 24 + sysT.wMinute / 24 / 60 + _
135. 　　　　　　　　　　(sysT.wSecond + 1) / 24 / 60 / 60 + sysT.wMilliseconds / 24 / 60 / 60 / 1000
137. 　　Call QueryPerformanceCounter(CntEnd)
139. 　timeEndPeriod 1
141. 　MsgBox (CntEnd - CntStart) / freq
142. End Sub

図１１別窓
GetLocalTime関数はWin32APIですので、１０１～１０５行目のようなAPI宣言が必要です。
またGetLocalTime関数は、SYSTEMTIME構造体として値を戻してきますので、１０８～１１７行目のように構造体の定義も必要です。
１２８行目「timeBeginPeriod 1」で、タイマー精度を１ミリ秒に変更しています。
１３０行目「Call GetLocalTime(sysT)」では、タイマー精度１ミリ秒の環境でGetLocalTime関数を実行しています。そのデータは、変数sysT（SYSTEMTIME構造体）に入ります。
１３４～１３５行目ではWaitメソッドを実行します。Waitメソッドの引数には日時のシリアル値を指定しなければなりませんが、GetLocalTime関数の各要素に収められている値はInteger型で整数値です。ですので各要素をシリアル値相当に換算して足し合わせる必要があります。
ですので引数としては「sysT.wHour / 24 + sysT.wMinute / 24 / 60 + (sysT.wSecond + 1) / 24 / 60 / 60 + sysT.wMilliseconds / 24 / 60 / 60 / 1000」としています。例えば「秒の位（要素：wSecond）」について説明すると、１秒は1日÷24時間÷60分÷60秒 ですので「sysT.wSecond / 24 / 60 / 60」となりますが、今回１秒後を指定しますので「(sysT.wSecond + 1) / 24 / 60 / 60」としています。
結果は図１２のようになりました。

図１２別窓
バラツキとしては図１０の約半分の「１^-0～１^+0.01 秒」です。しかしタイマー精度が１ミリ秒になってもこのバラツキがあるのは、Waitメソッドは「小数点2桁のミリ秒（≒ワークシートのNOW関数の限界分解能の10ミリ秒）」で停止制御を行っているのではないか　と推測しています。

２．Do～Loopで一定時間滞留

Do～Loopステートメントは、その間を繰り返し実行するものです。そのままだと無限ループになってしまいますので、While文（条件を満たす間繰り返しを続ける）や Until文（条件を満たしたら繰り返しを終わる）で繰り返しを制限します。
なおDo～Loop内に条件式を持ってきて「Exit Do」で抜ける手法もあります。
今回は「一定の停止時間の間だけDo～Loopを回し続ける」という方法で停止制御を行います。

２－１．秒単位で制御

２－１－１．Date型での足し算方式

まず秒単位の停止制御に、Now関数とTimeValue関数の足し算を使うのが図１３です。

150. '==========　⇩(9)　秒単位での停止制御 ============
151. Sub DoLoop_Second()
152. 　Dim DT As Date 　　　　　　 '←指定する1秒後の再開日時
153. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
154. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
155. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
157. 　Call QueryPerformanceFrequency(freq)
158. 　Call QueryPerformanceCounter(CntStart)
160. 　DT = Now() + TimeValue("0:00:01")
161. 　Do While DT > Now()
162. 　　DoEvents: DoEvents
163. 　Loop
165. 　Call QueryPerformanceCounter(CntEnd)
167. 　MsgBox (CntEnd - CntStart) / Freq
168. End Sub

図１３別窓
まず１６０行目「DT = Now() + TimeValue("0:00:01")」では、Do～Loopに入る直前の日時データ（Now関数）を取得し、それに１秒「TimeValue("0:00:01")」を足した日時値を変数DTに代入しています。
１６１～１６３行目のDo～Loopで１秒間回り続ける事で停止時間を確保します。
１６１行目「Do While DT > Now()」では、Do～Loopで回し続ける条件を「DT > Now()」としています。つまりDo～Loopの直前に測定した日時に１秒足した値（変数DT）を、現在の日時と比べています。指定時よりも現在時の方が大きくなった「 DT <= Now() 」が成立すれば、Do～Loopを抜けて１６５行目に移ります。
Do～Loopの間に入っている１６２行目「DoEvents: DoEvents」は、Do～Loopを中断するためのものです。DoEvents自体はプログラムの制御をO/Sに一旦戻す機能を持っています。
Do～Loopが問題無く動けば、このDoEventsは不要なのですが、もし何らかの原因で無限ループになってしまった場合、ESCキーやCtrl+Breakキー等を押下することでプログラムを強制停止させる事ができるため、必ず入れるようにしています。且つDoEventsを２個入れているのは、１個だと強制停止できない場合があるとの情報に基づいています。
１６７行目「MsgBox (CntEnd - CntStart) / Freq」では、Do～Loopで停止していた実秒数を表示しています。
図１３は何の問題も無さそうに見えますが、落とし穴があります。実は図１３で得られるデータ分布は以下のようになります。

図１４別窓
１秒を超え２秒まで達しているデータを見て「おや？」と思った方もいるかもしれません。理論的には図１５の左側のように「１^-1 ～ １⁺⁰」となるはずだからです。

図１５別窓
実はここでも「よりみち」で説明した「Double型＋Double型での丸め」が影響しているようです。コード上は全てDate型ですが、実体はDouble型なので最小桁数の丸めが起こり、再開時刻の値が本来の時刻の値よりもわずかに大きくなる場合があります。大きくなった場合には、再開するはずの１秒後の時刻（図１３の１６１行目の一番右側のNow()の値）の時点では「まだ予定時刻に達していない」と判断され、図１５の右のように再開されません。
その後、Date型のNow()の分解能は１秒（≒１秒ごとにしかデータが更新されない）であるため、、次のタイミング（＝２秒後）で条件式が成立し再開することになります。
ただし、図１４では約３割のデータが１秒超になっており、Double型の丸めの割合（多くて約２割）からすると「ちょっと多すぎ」の感があります。これが偶然の偏りなのか、まだ何か原因があるのか分かりませんが、とりあえず「Double型の丸めが原因の値ズレ」をなくす手法を下記で紹介します。

２－１－２．一旦String型に変更する方式

「Double型の丸めが原因の値ズレ」をなくす手法として考えたのは以下です（図１３の手法も①としています）。
　① TimeValueを使用「Now() + TimeValue("0:00:01")」　←これは上記の通りダメ
　② 分数値を使用「Now() + 1 / 86400」
　③ DateAdd関数を使用「DateAdd("s", 1, Now())」
　④ Date型を一旦文字列にする「CDate(CStr(Now() + TimeValue("0:00:01")))」
結果的には②も③も①と同じです。原因は内部計算はDouble型で行っている為のようです。うまく行ったのは④の「Date型の日時を一旦文字列」にする方式で、それをコード化したのが下記（図１６）です。

180. '==========　⇩(10)　秒単位での停止制御（一旦文字列化） ============
181. Sub DoLoop_Second2()
182. 　Dim DT As Date 　　　　　　 '←指定する1秒後の再開日時
183. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
184. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
185. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
187. 　Call QueryPerformanceFrequency(freq)
188. 　Call QueryPerformanceCounter(CntStart)
190. 　DT = CStr(Now() + TimeValue("0:00:01"))
191. 　Do While DT > Now()
192. 　　DoEvents: DoEvents
193. 　Loop
195. 　Call QueryPerformanceCounter(CntEnd)
197. 　MsgBox (CntEnd - CntStart) / Freq
198. End Sub

図１６別窓
１９０行目「DT = CStr(Now() + TimeValue("0:00:01"))」では、現在の１秒先の日時（Date型）をCStr関数で文字列化し、それをDate型の変数DTに代入しています。
図１３「DT = Now() + TimeValue("0:00:01")」の場合はDate型を直接Date型変数に代入していたため、内部的には「最小桁の丸めが残ったままの値」がDate型変数となっていましたが、日時データを一旦文字列化してからDate型に戻すことで「正しいDate型の値」にする事が出来るようです。
なお変数DTをDate型で宣言しているため、文字列型→Date型に勝手に変換されますが、明示的にCDate関数を使って「DT = CDate(CStr(Now() + TimeValue("0:00:01")))」としてもOKです。
この図１６で得られるデータ分布は以下のようになります。

図１７別窓
日時値を一旦文字列にすることで、１を超えた値がすっかり無くなり「１^-1 ～ １⁺⁰」の範囲に収まりました。という事は、図１４の１を超えたデータ量が少し多目なのは、単にサンプル数が少ないだけなのかもしれません。

２－１－３．不等号に「>=」を使用する方式

日時データを一旦文字列化する事で、バラツキは「１^-1 ～ １⁺⁰（最大-最小≒1）」の範囲となりました。別な手法で「最大-最小≒1」を実現する事も可能です。それが下記のコードです。

210. '==========　⇩(11)　秒単位での停止制御（不等号の改善） ============
211. Sub DoLoop_Second3()
212. 　Dim DT As Date 　　　　　　 '←指定する1秒後の再開日時
213. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
214. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
215. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
217. 　Call QueryPerformanceFrequency(freq)
218. 　Call QueryPerformanceCounter(CntStart)
220. 　DT = Now() + TimeValue("0:00:01")
221. 　Do While DT >= Now()
222. 　　DoEvents: DoEvents
223. 　Loop
225. 　Call QueryPerformanceCounter(CntEnd)
227. 　MsgBox (CntEnd - CntStart) / Freq
228. End Sub

図１８別窓
２２１行目「Do While DT >= Now()」では、不等号を「等号付きの不等号」に変更しています。
この図１８で得られるデータ分布は以下のようになります。

図１９別窓
全データが「１^-0 ～ １⁺¹」の範囲に入ります。これは図１４で１秒未満だったデータが、「等号付き」になることで「＋１秒」され、一方１秒超だったデータはそのまま「１～２秒の間」にいるため、図１９のような分布となります。

２－２．ミリ秒単位で制御

Evaluateメソッドを使ってミリ秒で制御したのが図２０です。

240. '==========　⇩(12)　ミリ秒単位で制御 ============
241. Sub DoLoop_mmSecond()
242. 　Dim DT As Double 　　　　　 '←指定する1秒後の再開日時
243. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
244. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
245. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
247. 　Call QueryPerformanceFrequency(freq)
248. 　Call QueryPerformanceCounter(CntStart)
250. 　DT = Evaluate("Now()") + CDbl(TimeValue("0:00:01"))
251. 　Do While DT > Evaluate("Now()")
252. 　　DoEvents: DoEvents
253. 　Loop
255. 　Call QueryPerformanceCounter(CntEnd)
257. 　MsgBox (CntEnd - CntStart) / Freq
258. End Sub

図２０別窓
２５０行目「DT = Evaluate("Now()") + CDbl(TimeValue("0:00:01"))」では、Evaluateメソッドを使い「ワークシート関数のNOW関数」を使ってミリ秒単位で現在日時を取得し、それに対して１秒を加えています。TimeValue関数はDate型の値を戻すので、Date型＋Double型＝Date型（秒単位）となることを防ぐためCDbl関数でDouble型にしています。
２５１行目「Do While DT > Evaluate("Now()")」では、比較する現在日時もミリ秒単位にするためEvaluateメソッドを使っています。
この図２０で得られるデータ分布は以下のようになります。

図２１別窓
理論的には「１^-0.015 ～ １⁺⁰」の範囲になるはずですが、「よりみち」でも説明したような「Double型の丸め」の影響もあり、１超にもデータが現れているものと思われます。
なお、図２０では比較演算子として「>」を使用しましたが、これを「>＝」にすると以下の様な分布になります。

図２２別窓
全体がプラス側に少し移動するのが分かりますが、１秒未満にもデータが残ってしまう理由は良く分かりません。
なお、Evaluate("Now()")の代わりに、ミリ秒が得られる「Timer()」を使っても、分布はあまり変わりませんでした。
但しこのTimer()は日付を跨ぐ時に使われると「丸１日停止」してしまう事があるため使用には注意が必要です。

２－３．タイマー精度を変更して制御

timeBeginPeriod関数で、タイマー精度を「標準15ミリ秒 → 1ミリ秒」に向上させて停止制御したのが図２３です。なおここでは「タイマー精度が1ミリ秒の時には、分解能も1ミリ秒」となるtimeGetTime関数を使用しています。
timeGetTime以外でも分解能が1ミリ秒となる「GetLocalTime関数」を使用してもOKです。

270. '==========　⇩(13)　Win32API宣言 ============
271. #If Win64 Then
272. 　Declare PtrSafe Function timeGetTime Lib "winmm.dll" () As Long
273. #Else
274. 　Declare Function timeGetTime Lib "winmm.dll" () As Long
275. #End If
277. '==========　⇩(14)　タイマー精度１ミリ秒での停止制御 ============
278. Sub DoLoop_1ms()
279. 　Dim DT As Long 　　　　　 '←指定する1秒後の再開ミリ秒数
280. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
281. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
282. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
284. 　Call QueryPerformanceFrequency(freq)
286. 　timeBeginPeriod 1
288. 　Call QueryPerformanceCounter(CntStart)
290. 　DT = timeGetTime + 1000
291. 　Do While DT > timeGetTime
292. 　　DoEvents: DoEvents
293. 　Loop
295. 　Call QueryPerformanceCounter(CntEnd)
297. 　timeEndPeriod 1
299. 　MsgBox (CntEnd - CntStart) / Freq
300. End Sub

図２３別窓
２７１～２７５行目はGetLocalTime関数の宣言部です。Windows起動後の時間をミリ秒単位の整数で戻す関数です。
２８６行目「timeBeginPeriod 1」でタイマー精度を1ミリ秒に変更し、２９７行目「timeEndPeriod 1」で標準状態（タイマー精度約15ミリ秒）に戻しています。この間は、タイマー精度1ミリで動いている事になります。
２９０行目「DT = timeGetTime + 1000」で、起動後のミリ秒をtimeGetTime関数で取得し、それに対し「1000（ミリ秒）」を加算して変数DTに代入しています。timeGetTime関数の戻り値はLong型（宣言部参照）なので、変数DTも２７９行目「Dim DT As Long」でLong型宣言しています。
２９１行目「Do While DT > timeGetTime」では、１秒が経過するまでDo～Loopを回しています。
この図２３で得られるデータ分布は以下のようになります。

図２４別窓
データは「１^±0.001」に収まっており、確かにバラツキ少なく停止制御ができる手法と言えます。但しタイマー精度を元に戻すのを忘れたり戻せなかったりした場合には、システム全体のパフォーマンスが悪くなったり、PCハード自体に悪影響を与えたりしますので、慎重に使うことが必要です。

２－４．QueryPerformanceCounterを使用して制御

上記ではタイマー精度を向上させる事で精度高く停止させましたが、タイマー精度が標準状態でも停止精度を上げることは可能です。下記では「Windows起動後からのカウント数（QueryPerformanceCounter）」を使って停止時間を制御させています。

310. '==========　⇩(15)　QueryPerformanceCounterで停止制御 ============
311. Sub DoLoop_1ms2()
312. 　Dim DT As Currency 　　　　 '←指定する1秒後の再開カウント数
313. 　Dim CntStart As Currency 　 '←カウント数（停止直前）
314. 　Dim CntEnd As Currency 　　 '←カウント数（停止中、停止直後）
315. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
317. 　Call QueryPerformanceFrequency(freq)
318. 　Call QueryPerformanceCounter(CntStart)
319. 　DT = CntStart + freq * 1
321. 　Do
322. 　　Call QueryPerformanceCounter(CntEnd)
323. 　　DoEvents: DoEvents
324. 　Loop While DT > CntEnd
326. 　Call QueryPerformanceCounter(CntEnd)
328. 　MsgBox (CntEnd - CntStart) / Freq
329. End Sub

図２５別窓
まず３１８行目「Call QueryPerformanceCounter(CntStart)」では、今までは実停止時間を測るために測定していた「停止直前のカウント数（変数CntStart）」を制御のためにも取得をします。また周波数（１秒間のカウント数）は変化しない値なので、３１７行目「Call QueryPerformanceFrequency(freq)」であらかじめ取得しておきます。
その２種の値から３１９行目「DT = CntStart + freq * 1」で、再開する時点でのカウント数を計算します。ここでは１秒間停止させますので、停止直前のカウント数（変数CntStart）に１秒間のカウント数（変数freq）を足します。最後の「* 1」が停止秒数となるので、異なる停止時間の時にはこの値を変更します。
３２１～３２４行目でDo～Loopを回します。いままで抜け出す条件式はDo側に置いていましたが、今回はLoop側に与えています。これはDo側に条件式を置いてしまうと、初回の現在カウント値取得式（３２２行目相当）が必要になってしまうためです。
３２２行目「Call QueryPerformanceCounter(CntEnd)」で現在のカウント数を取得（変数CntEnd）し、３２４行目「Loop While DT > CntEnd」で再開カウント数（変数DT）と比較をし、不等式が成立している間はDo～Loopを回しています。
１秒間が経過しDo～Loopを抜け出したら３２６行目「Call QueryPerformanceCounter(CntEnd)」で停止の実時間を取得していますが、実際には３２２行目で取得済みなので不要です。しかし他のコードでは「Do～Loopを抜けた後に時間測定」をしているため、それと合わせています。
この図２５で得られるデータ分布は以下のようになります。

図２６別窓
停止時間のバラツキは「0.5ミリ秒以内」と、タイマー精度変更法（図２４）よりも精度良く停止制御ができていることになります。但しカウントの周波数（QueryPerformanceFrequencyで得られる値：今回は10,000,000Hz）はPCや環境により異なる可能性があるので、停止制御の精度は変わってくる可能性があります。

３．Sleep関数で一定時間中断

Sleep関数はWin32API関数で、引数に指定した「ミリ秒」の時間だけ停止させるものです。構文は以下の通りです。
　Sleep (中断するミリ秒単位の整数 )
Sleep関数が実行されると「O/Sによって眠らされている状態」になるようで、ESCキー等では実行中断できません。
API関数なので、宣言部で以下のような関数宣言が必要です。

340. '==========　⇩(16)　Win32API宣言 ============
341. #If Win64 Then
342. 　Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal ms As Long)
343. #Else
344. 　Declare Sub Sleep Lib "kernel32" (ByVal ms As Long)
345. #End If

図２７別窓

３－１．ミリ秒単位で制御

Sleep関数は、停止時間をミリ秒単位で指定できます。１秒（＝1000ミリ秒）停止させるのが以下のコードです。

350. '==========　⇩(17)　Sleep関数で１秒間の停止制御 ============
351. Sub Sleep_mmSecond()
352. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
353. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
354. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
356. 　Call QueryPerformanceFrequency(freq)
357. 　Call QueryPerformanceCounter(CntStart)
359. 　Sleep 1000
361. 　Call QueryPerformanceCounter(CntEnd)
363. 　MsgBox (CntEnd - CntStart) / Freq End Sub

図２８別窓
３５９行目「Sleep 1000」では、Sleep関数に1000ミリ秒（＝１秒）を指定し、プログラムを停止させています。
この図２８で得られるデータ分布は以下のようになります。

図２９別窓
データは、ほぼ「１^-0 ～ １^+0.015」に収まっています。このバラツキの「15ミリ秒」は、タイマー精度の標準約15ミリ秒に関係していると思われます。

３－２．タイマー精度を変更して制御

上記のバラツキは約15ミリ秒で、それがタイマー精度に基づいているとすれば、タイマー精度をアップさせればバラツキが小さくなる可能性があります。そこでtimeBeginPeriod関数を使って、タイマー精度を1ミリ秒に向上させたのが以下です。

370. '==========　⇩(18)　タイマー精度1msで、Sleep関数で１秒間の停止制御 ============
371. Sub Sleep_1ms()
372. 　Dim CntStart As Currency 　 '←カウント数（実行直前）
373. 　Dim CntEnd As Currency 　　 '←カウント数（実行直後）
374. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
376. 　Call QueryPerformanceFrequency(freq)
378. 　timeBeginPeriod 1
380. 　　Call QueryPerformanceCounter(CntStart)
382. 　　Sleep 1000
384. 　　Call QueryPerformanceCounter(CntEnd)
386. 　timeEndPeriod 1
388. 　MsgBox (CntEnd - CntStart) / Freq
389. End Sub

図３０別窓
３７８行目「timeBeginPeriod 1」でタイマー精度を1ミリ秒に向上させ、３８２行目「Sleep 1000」で1秒間停止させています。 一時停止が終了したら、３８６行目「timeEndPeriod 1」で元の状態（約15ミリ秒）に戻しています。
この図３０で得られるデータ分布は以下のようになります。

図３１別窓
データは「１^-0 ～ １^+0.0015」に収まっており、図２９（タイマー標準）の約1/10 になっています。

４．OnTimeメソッドで一定時間後に別プロシージャを起動

OnTimeメソッドは、指定マクロを指定日時に実行するものです。構文は以下のようになります。
　Excel.Application.OnTime(EarliestTime, Procedure, LatestTime, Schedule)
ExcelのVBAから実行するのであれば、先頭の「Excel.」は不要です。
４つの引数は、以下のような内容になります。

引数名		内容
EarliestTime	必須	プロシージャを実行する時刻
Procedure	必須	実行プロシージャ名
LatestTime	省略可	他マクロが作動中の場合の待つ限界日時 省略=実行可能になるまで待機
Schedule	省略可	True(既定)：指定時刻に実行 False：指定時刻の予約を取り消し

図３２別窓
必須は「プロシージャを実行する時刻」と「実行するプロシージャ名」です。第３引数は使った事がありません。第４引数は予約をした日時をその通りに指定しないとキャンセル出来ないので、Now関数等を使っている場合にはちょっと面倒です。
第１引数に指定する「時刻」ですが、Now関数を良く使うことからも分かるように、日付＋時刻でもOKです。その場合は指定する値により、以下のように動作が異なります。
内容的にはWaitメソッドの図０２と同じで、指定日時が過去の値であれば「即座に実行」されますので注意が必要です。

実行時	OnTimeの第一引数
	時刻のみ(A) (ｼﾘｱﾙ値=1未満)	日付＋時刻(A) (ｼﾘｱﾙ値=1以上)
Aより前	A時に実行	A時に実行
Aより後	翌日のA時に実行	即時実行

図３３別窓
第２引数の「実行プロシージャ」ですが、プロシージャ名をそのまま記しただけだと「OnTimeメソッドを実行したブックの標準モジュール」内を探します。標準モジュールに無ければエラーとなります。
もし実行プロシージャがシートモジュールにある場合は「"Sheet1.Test1"」等と「シート名＋ピリオド」で場所を指定します。
実行プロシージャがOnTimeメソッドとは別のブックにある場合等については「OnTimeメソッドの第一・第二パラメータの設定方法」を参照下さい。

４－１．秒単位で制御

秒単位での停止制御に、Now関数とTimeValue関数の足し算を使うのが図３４です。

400. '==========　⇩(19)　OnTimeメソッドで１秒間の停止制御 ============
401. Sub OnTime_Second()
402. 　Dim DT As Date 　　　　　　 '←指定する1秒後の日時
403. 　Dim CntStart As Currency 　 '←カウント数（停止直前）
405. 　Call QueryPerformanceCounter(CntStart)
407. 　DT = Now() + TimeValue("0:00:01")
408. 　Application.OnTime DT, "'MsgB1 " & CntStart & "'"
410. End Sub

図３４別窓
４０７行目「DT = Now() + TimeValue("0:00:01")」で、現在よりも１秒先の日時を取得します。
４０８行目「Application.OnTime DT, "'MsgB1 " & CntStart & "'"」では、４０７行目で設定した日時に「MsgB1」というプロシージャを起動させます。
MsgB1プロシージャには引数（停止直前のカウント数）を渡す必要があるため、指定する文字列としては「'プロシージャ名 引数'」と、プロシージャ名と引数の間には「１つの半角スペース」を入れ、また（スペースが入る事で別の文字列と判断されないように）全体を「'（シングルクォーテーション）」で囲みます。
呼び出されるプロシージャ側（MsgB1）は、以下になります。

420. '==========　⇩(20)　実行されるプロシージャ ============
421. Public Sub MsgB1(CntStart As Currency)
422. 　Dim CntEnd As Currency 　　 '←カウント数（停止直後）
423. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
425. 　Call QueryPerformanceCounter(CntEnd)
426. 　Call QueryPerformanceFrequency(freq)
428. 　MsgBox (CntEnd - CntStart) / Freq
429. End Sub

図３５別窓
呼び出されるプロシージャでは実際に停止した時間を測定するため、４２５行目「Call QueryPerformanceCounter(CntEnd)」で停止直後（≒プロシージャの呼び出し時）のカウント数を取得し、４２６行目「Call QueryPerformanceFrequency(freq)」で周波数（秒あたりのカウント数）を取得します。
実行プロシージャの引数として渡された「停止直前のカウント数（変数CntStart）」と合わせて、４２８行目「MsgBox (CntEnd - CntStart) / Freq」で実時間を表示します。
この図３４＋図３５で得られる停止時間のデータ分布は以下のようになります。

図３６別窓
結果は「(１^-1 ～ １⁺⁰ ) ＋α」と、Waitメソッド（図０５）とほぼ同レベルです。＋α の内容として「同時刻に動いている他プロセスを優先」したり「あらたにプロシージャを起動するのには時間が掛かる？」などが考えられますが、詳細は分かりません。

４－２．ミリ秒単位で制御

Evaluate("Now()")を使い、ミリ秒単位で停止制御をするのが下記のコードです。呼び出すプロシージャは図３５を共用で使います。

440. '==========　⇩(21)　OnTimeメソッドで１秒間をミリ秒単位で停止制御 ============
441. Sub OnTime_mmSecond()
442. 　Dim DT As Double 　　　　　 '←指定する1秒後の日時
443. 　Dim CntStart As Currency 　 '←カウント数（停止直前）
445. 　Call QueryPerformanceCounter(CntStart)
447. 　DT = Evaluate("Now()") + CDbl(TimeValue("0:00:01"))
448. 　Application.OnTime DT, "'MsgB1 " & CntStart & "'"
450. End Sub

図３７別窓
４４７行目「DT = Evaluate("Now()") + CDbl(TimeValue("0:00:01"))」では、現在の日時をミリ秒レベルで得るためにワークシートのNow関数を使用し、それに対して１秒を加えています。但しDouble型＋Date型＝Date型と「秒レベル」に戻ってしまわないように、TimeValue関数をCDbl関数でDouble型に変換しています。
この図３７＋図３５で得られる停止時間のデータ分布は以下のようになります。

図３８別窓
図３６と比べると大幅にバラツキは減り、「１^-0 ～ １^+0.05」くらいの範囲には凡そ入るのですが、たまには大きく外れる場合もあるようです。
この遅れの原因は良く分かりませんが、Windowsの裏で動いている別なプロセスが「予定されているプロシージャ実行」よりも優先されるのではないかと推定しています。１つのプロシージャ内の連続しているコードとは異なり「別な場所からプロシージャを呼び出す」という構造上、ある程度は仕方がないかな　とも思います。
なおEvaluate("Now()")の代わりに「Timer関数」を使い、図３７の４４７行目を「DT = (Timer() + 1) / 86400」と変えても、バラツキ方は図３８とほぼ一緒となりました。この式はスッキリしている気がしますが、24時近くに実行して「計算結果の変数DTが1を超し」てしまうと日付も指定した事になり、即時実行されてしまいますので注意が必要です。

４－３．タイマー精度を変更して制御

タイマー精度を向上（標準約15ミリ秒 → 1ミリ秒）させてOnTimeメソッドで停止制御させたのが以下です。なお、プロシージャ呼び出し側でタイマー精度変更を行い、呼び出されたプロシージャ側でタイマー精度を元に戻す必要があるため、呼び出されるプロシージャは図３５とは異なるものになります。

460. '==========　⇩(22)　OnTimeメソッド＋タイマー精度1msでの１秒間の停止制御 ============
461. Sub OnTime_1ms()
462. 　Dim DT As Double 　　　　　 '←指定する1秒後の日時
463. 　Dim CntStart As Currency 　 '←カウント数（停止直前）
465. 　timeBeginPeriod 1
467. 　Call QueryPerformanceCounter(CntStart)
469. 　DT = Evaluate("Now()") + CDbl(TimeValue("0:00:01"))
470. 　Application.OnTime DT, "'MsgB2 " & CntStart & "'"

図３９別窓
４６５行目「timeBeginPeriod 1」では、タイマー精度を１ミリ秒に変更し、その状態で４７０行目のOnTimeメソッドでプロシージャ実行予約をしています。実行するプロシージャは以下の内容です。

480. '==========　⇩(23)　実行されるプロシージャ（タイマー精度復元付き） ============
481. Public Sub MsgB2(CntStart As Currency)
482. 　Dim CntEnd As Currency 　　 '←カウント数（停止直後）
483. 　Dim freq As Currency 　　　 '←周波数（カウント数／秒）
485. 　Call QueryPerformanceCounter(CntEnd)
486. 　Call QueryPerformanceFrequency(freq)
488. 　timeEndPeriod 1
490. 　MsgBox (CntEnd - CntStart) / Freq
491. End Sub

図４０別窓
指定時刻になると図４０が実行され、実際の停止時間を４８５行目「Call QueryPerformanceCounter(CntEnd)」で測定します。測定が完了したら４８８行目「timeEndPeriod 1」でタイマー精度を復元（→約15ミリ秒）します。
得られる停止時間のデータ分布は以下のようになります。

図４１別窓
結果は、タイマー精度を向上させる前の図３８とそれほど変わっていないように見えます。ということはOnTimeメソッドの中では「時刻は約10～15ミリ秒の分解能で監視」していると推定されます。
また大きく外れる場合も同じように存在しました。なお外れた数が増えたのは、今のところ偶然だと考えています。
なお、タイマー精度の変更と復元を「別のプロシージャで実行」しているため、同じプロシージャ内で変更・復元しているよりも安全上のリスクがずっと高く、お勧めできる手法ではないと思います。

５．まとめ

上記で説明した「Waitメソッド」「Do～Loop」「Sleep関数」「OnTimeメソッド」での停止時間機能を簡単な表にまとめました。どれを使うかは場面場面で異なりますので、メリットデメリットを見ながら選択してください。
まとめ表だけでは表せない内容もありますので、詳細については各項目を参照下さい。

		Wait	Do～Loop	Sleep	OnTime
構文		Wait(再開時刻)	Do While 再開時刻>Now() Loop	Win32API宣言 Sleep 停止ﾐﾘ秒	Application.OnTime 実行時刻,実行ﾏｸﾛ
標準 偏差 (ms)	秒制御	294	583(文字列化で286)	-	326
	ﾐﾘ秒制御	8.1	6.5	4.9	28
	ﾀｲﾏ精度1ms	5.3(限界2.6)	0.4(限界0.1)	0.3	41
停止中の操作		×	(〇)DoEventsで可	×	〇
CPUの負荷		高	高	低	低

図４２別窓

アプリ実例・関連する項目

「再計算されたか否かのチェックをイベントで取得」
「図形も貼り付けられるスケジュール帳」
「セル色変更の情報をイベント風に受け取る」
「図形で作るアナログ時計」
「DVD等の内容・保管場所等管理システム」
「ラベルカレンダーをクリックし日付入力」
「OLEObjectのラベルカレンダー(同一ブック内)」
「自動的に閉じるメッセージ」
「OnTimeメソッドの第一・第二パラメータ設定方法」

サンプルファイル

処理を一定時間停止させる（its-046.xlsm）

セキュリティ向上を目的として「インターネット経由でダウンロードしたOfficeファイル（Excel等）のマクロは、既定でブロック」されるようにOfficeアプリケーションの既定動作が変更になりました。（2022年4月より切替開始） 解除の方法については「ダウンロードファイルのブロック解除方法」を参照下さい。